Sorry your browser is not supported!

` this program shows how to load an FPS Creator level
` and walk around it using the character controller

` set up general properties
sync on
sync rate 60
autocam off
phy start
set camera range 0.5, 30000
hide mouse

` move into the media directory
set dir "media"

` load the level and make a static mesh for it
load object "universe.dbo", 1
set object light 1, 0
phy make rigid body static mesh 1

` load our skybox
load object "skybox2.x", 2
set object light 2, 0
set object texture 2, 3, 1
scale object 2, 30000, 30000, 30000

` come out of the media directory
set dir ".."

` create our box controller
make object box 3, 20, 50, 20
phy make box character controller 3, 434, 42, -517, 10, 35, 10, 1, 10.5, 45.0
hide object 3

` display Dark Physics logo
load image "logo.png", 100000
sprite 1, 0, 600 - 60, 100000

` our main loop
do
   ` display instructions
   set cursor 0, 0
   print "Using Dark Physics for collision detection of an FPS Creator level"
   print "Use the arrow keys and mouse to move around"

   ` rotate and position the camera based on the box controller
   position camera object position x ( 3 ), object position y ( 3 ) + 20, object position z ( 3 )
   rotate camera object angle x ( 3 ), object angle y ( 3 ), object angle z ( 3 )

   OldCamAngleY# = CameraAngleY#
   OldCamAngleX# = CameraAngleX#

   CameraAngleY# = wrapvalue ( CameraAngleY# + mousemovex ( ) * 0.4 )
   CameraAngleX# = wrapvalue ( CameraAngleX# + mousemovey ( ) * 0.4 )

   yrotate object 3, curveangle ( CameraAngleY#, OldCamAngleY#, 24 )
   xrotate object 3, curveangle ( CameraAngleX#, OldCamAngleX#, 24 )

   ` react to key presses and move the controller
   key = 0

   if upkey ( )
      key = 1
      phy move character controller 3, 200.0
   endif

   if downkey ( )
      key = 1
      phy move character controller 3, -200.0
   endif

   if key = 0
      phy move character controller 3, 0.0
   endif

   ` update the simulation and screen
   phy update
   sync
loop

` shows how a cloth and ball react together

` set up program
phy start
sync on
sync rate 60
autocam off
color backdrop 0

` make attachment object
make object box 1,10,2,2
phy make rigid body static box 1

` create floor
make object box 2,50,1,50
color object 2,rgb(125,125,125)
position object 2,0,-9,0
phy make rigid body static box 2
load image "mediastripe6.png",2
texture object 2,2

` create background sphere
load image "mediastripe5.png",10
make object sphere 10,400,48,48
texture object 10,10
scale object texture 10,6,6
set object cull 10,0
rotate object 10,0,0,90

` create the cloth object
phy make cloth 3
phy set cloth dimensions 3, 10,10,0.2
phy set cloth position 3, -5, 0, 0
phy build cloth 3
phy attach cloth to shape 3, 1, 1
color object 3,rgb(125,125,255)
load image "mediarug512.bmp",  3
texture object 3, 3

` set up our ball object
make object sphere 4,5
color object 4,rgb(255,0,0)
position object 4,0,-5,1
set object ambient 4, 0
phy make rigid body dynamic sphere 4

` display Dark Physics logo
load image "medialogo.png",1000
sprite 1, 0, 600-60, 1000
set sprite 1, 0, 1
hide sprite 1

` position the camera
position camera 0,10,30
rotate camera 0,180,0
point camera 0,0,0

` our main program loop
do
   ` display instructions
   text 10,10, "Rigid body and cloth, use the arrow keys to move the ball"

   ` move ball around
   if upkey()=1 then phy set rigid body linear velocity 4, 0, 0, -5
   if downkey()=1 then phy set rigid body linear velocity 4, 0, 0, 5
   if leftkey()=1 then phy set rigid body linear velocity 4, 5, 0, 0
   if rightkey()=1 then phy set rigid body linear velocity 4, -5, 0, -0

   ` update simulation and screen
   phy update
   sync
loop

` this program demonstrates how a 6 degrees of freedom joint can be made

` program set up
phy start
autocam off
sync on
sync rate 60
color backdrop 0
position camera 0, 4, -10
make light 1
set directional light 1, -5, -5, 5

rem stripe textures
load image "stripe5.png",8
make object sphere 8,400,48,48
texture object 8,8
scale object texture 8,6,6
set object cull 8,0
load image "stripe6.png",1

` create ground object
make object box 1, 50, 1, 50
texture object 1, 1
phy make rigid body static box 1

` create our first cube
make object cube 2, 1
position object 2, 0, 5, 0
phy make rigid body dynamic box  2
phy set rigid body kinematic 2, 1

` create our second cube
make object cube 3, 1
position object 3, 0, 2, 0
phy make rigid body dynamic box 3

` build a 6 degrees of freedom joint, the set up of this joint
` means we have limited rotational movement for the object at
` the bottom to the top
phy make 6dof joint 1, 2, 3
phy set 6dof joint global anchor 1, 0, 0, 5, 0
phy set 6dof joint global axis 1, 0, 0, 1, 0
phy set 6dof joint twist motion 1, 1
phy set 6dof joint swing1 motion 1, 1
phy set 6dof joint swing2 motion 1, 1
phy set 6dof joint motion x 1, 0
phy set 6dof joint motion y 1, 0
phy set 6dof joint motion z 1, 0
phy set 6dof joint swing1 limit 1, 0.3 * 3.14, 0.0, 0.0, 0.0
phy set 6dof joint swing2 limit 1, 0.3 * 3.14, 0.0, 0.0, 0.0
phy set 6dof joint twist limit 1, -0.05 * 3.14, 0.0, 0.0, 0.0, -0.05 * 3.14, 0.0, 0.0, 0.0
phy build 6dof joint 1

` display Dark Physics logo
load image "logo.png", 100000
sprite 1, 0, 600 - 60, 100000

` main program loop
do
   set cursor 0, 0
   print "6 Degrees of Freedom joint demonstration"
   print "Use the arrow keys to apply force to the object"

   if upkey ( )
      phy add rigid body force 3, 0, 0, 75, 0
   endif

   if downkey ( )
      phy add rigid body force 3, 0, 0, -75, 0
   endif

   if leftkey ( )
      phy add rigid body force 3, -75, 0, 0, 0
   endif

   if rightkey ( )
      phy add rigid body force 3, 75, 0, 0, 0
   endif

   ` update simulation and screen
   phy update
   sync
loop

` one of the interesting features of Dark Physics is that of joints, many different
` kinds of joints exist and these can be used in conjunction with rigid bodies
` to form more complex objects, in this tutorial we’re going to create a crane
` with a moving arm and a sphere chain attached to it, a collection of objects
` will also be placed in the scene so we can view the kind of interactions that
` are possible

phy start
sync on
sync rate 60

color backdrop 0

make light 1
set directional light 1, -1, -1, -1

` load 2 images to be used in texturing our objects
load image "metal1.tga", 1
load image "stripe5.png", 100

` make the ground object
make object box 1, 40, 1, 40
position object 1, 0, 0, 0
texture object 1, 1
phy make rigid body static box 1
`ghost object on 1
set alpha mapping on 1, 50

` create a sphere as a background
make object sphere 100, 80
set object cull 100, 0
texture object 100, 100
set alpha mapping on 100, 20

` construct the shaft of the crane
make object box 2, 4, 16, 4
position object 2, 0, 9, 0
texture object 2, 1
phy make rigid body static box 2

` now create the control box to sit on top of the crane
make object box 3, 2, 2, 2
position object 3, 0, 18, 0
texture object 3, 1
phy make rigid body dynamic box 3

` some extra parts are required for the control box as it needs to be attached to
` the shaft of the crane and it also needs a motor joint as it is responsible for
` moving the arm, this can be achieved by using a revolute joint
phy make revolute joint 1, 2, 3, 0, 1, 0, 0, 18, 0

` a long, thin box will be created for the arm of the crane and it will be positioned
` so it is alongside the edge of the control box
make object box 4, 10, 1, 1
position object 4, 6, 18, 0
texture object 4, 1
phy make rigid body dynamic box 4

` with the arm in place a revolute joint can be created to connect it to the control box
` of the crane
phy make revolute joint 3, 2, 4, 0, 1, 0, 0, 18, 0

` the next task is to create the chain of spheres that will be attached to the arm of the
` crane at its end point, this will be done by creating a set of spheres, attaching the
` first sphere to the arm using a ball joint and then attaching the other spheres to each
` other, a simple for loop will help us construct the chain
Y# = 17

for i = 5 to 20
   make object sphere i, 1
   position object i, 10, Y#, 0
   color object i, rgb ( rnd ( 255 ), rnd ( 255 ), rnd ( 255 ) )

   phy make rigid body dynamic sphere i
   phy make sphere joint i, i, i - 1, object position x ( i ), object position y ( i ), object position z ( i )

   color object i, rgb ( rnd ( 255 ), rnd ( 255 ), rnd ( 255 ) )
   set object specular i, rgb ( rnd ( 255 ), rnd ( 255 ), rnd ( 255 ) )
   set object ambient i, 255
   set object specular power i, 255

   Y# = Y# - 1
next i

` now we have the crane in place we can think about creating some objects that the crane
` can interact with - several stacks of cubes will be created and placed around the crane
CreateCubeStack( 21, 35,   0,  17 )
CreateCubeStack( 36, 50,   0, -15 )
CreateCubeStack( 51, 65, -15,  10 )
CreateCubeStack( 66, 80, -10,  -8 )

` position the camera so we can get a good view of the scene
position camera -30, 25, 0
rotate camera 40, 90, 0

load image "logo.png", 10000
sprite 1, 0, 600 - 60, 10000
set sprite 1, 0, 1
backdrop off

y# = -1.0
frame = 0

` now our main loop
do
   inc frame

   if frame = 900
      y# = -0.5
   endif

   if frame = 1800
      y# = -0.25
   endif

   if frame = 2700
      y# = -0.12
   endif

   phy set rigid body angular velocity 4, 0, y#, 0

   ` rotate the backdrop
   rotate object 100, 0, object angle y( 100 ) + 0.1, 0

   ` update the physics and the screen
   phy update
   sync
loop

function CreateCubeStack( start, finish, x, z )
   ` this function will create a stack of cubes with ID numbers between start to finish and
   ` positioned at the locations specified by x and z
   y = 1

   for i = start to finish
      make object cube i, 1
      position object i, x, y, z
      phy make rigid body dynamic box i

      color object i, rgb ( rnd ( 255 ), rnd ( 255 ), rnd ( 255 ) )
      set object specular i, rgb ( rnd ( 255 ), rnd ( 255 ), rnd ( 255 ) )
      set object ambient i, 255
      set object specular power i, 255

      y = y + 1
   next i
endfunction

` there is a great deal of flexibility in Dark Physics and it allows for all kinds of
` complex structures to be created through the use of joints, in this tutorial
` we will look at how a simple set of boxes can be transformed into a
` bridge structure

phy start
sync on
sync rate 60

load image "stripe5.png",10000
make object sphere 10000,800,48,48
texture object 10000,10000
scale object texture 10000,6,6
set object cull 10000,0
rotate object 10000,0,0,90

load image "stripe6.png", 3

` our next stage is to create our ground object, this object is a simple box that
` then has a rigid body attached to it which then has its dynamic state set to false
make object box 1, 400, 1, 400
color object 1, rgb ( 100, 0, 0 )
phy make rigid body static box 1
ghost object on 1, 0
texture object 1, 3

` when the bridge has been created it will need to be attached to something, it cannot
` simply be positioned in empty space so we need to think about what each end of the bridge
` can be attached to, we can create 2 box objects and position these on top of the ground
` and by doing this have 2 locations upon which we can attach the bridge, the code for
` this is fairly straight forward, the first block of code creates a box with an ID number
` of 2 and size of 60, 50, 400, it is then positioned on the left side of the ground object
` and a rigid body box created for it
make object box 2, 60, 50, 400
position object 2, -170, 25, 0
phy make rigid body static box 2
texture object 2, 3

` the second block of code is similar except this time an ID number of 3 is used and the
` object is positioned on the right side of the ground as shown by the screenshot
make object box 3, 60, 50, 400
position object 3, 170, 25, 0
phy make rigid body static box 3
texture object 3, 3

` construct the support chains for the bridge
CreateSupportChain( 4, 27, 1, -137, 50, 50 )
CreateSupportChain( 28, 51, 50, -137, 50, -50 )

` the next block of code creates the beams between the support chains and also hooks
` everything together with hinge joints
JointID = 100

x# = -131
y# = 50
z# = 0

a = 4
b = 28

` run through objects
for i = 52 to 75
   ` create a beam and position it
   make object box i, 2, 2, 100
   position object i, x#, y#, z#

   ` create a rigid body box for it
   phy make rigid body dynamic box i

   color object i, rgb ( rnd ( 255 ), rnd ( 255 ), rnd ( 255 ) )
   set object specular i, rgb ( rnd ( 255 ), rnd ( 255 ), rnd ( 255 ) )
   set object specular power i, 255
   set object ambient i,0

   ` create a revolute joint between the beam and its closest support chain block on the far side
   phy make revolute joint JointID, i, a,  1, 0, 0, object position x ( a ), object position y ( a ), object position z ( a )
   JointID = JointID + 1

   ` create a revolute joint between the beam and its closest support chain block on the near side
   phy make revolute joint JointID, i, b,  1, 0, 0, object position x ( b ), object position y ( b ), object position z ( b )
   JointID = JointID + 1

   ` increment the values
   a = a + 1
   b = b + 1
   x# = x# + 12
next i

` create a heavy sphere to roll across the bridge
make object sphere 100, 50
position object 100, 175, 90, 0

phy make rigid body dynamic sphere 100

color object 100, rgb ( rnd ( 255 ), rnd ( 255 ), rnd ( 255 ) )
set object specular 100, rgb ( rnd ( 255 ), rnd ( 255 ), rnd ( 255 ) )
set object specular power 100, 255
set object ambient 100,0

` position and rotate the camera
position camera -120, 135, -161
rotate camera 35, 34, 0

make light 1
set directional light 1, -5,-5,5

load image "logo.png", 100000
sprite 1, 0, 600 - 60, 100000

` now our main loop
do
   ` display information
   set cursor 0, 0
   print "Bridge construction example, press space to move the sphere"

   rotate object 10000, 0, object angle y( 10000 ) + 0.3, 0

   ` when the space key is pressed apply a velocity to the sphere
   if spacekey ( )
      phy set rigid body linear velocity 100, -20, 10, 0
   endif

   phy update
   sync
loop


function CreateSupportChain( StartID, EndID, JointID, x#, y#, z# )
   ` this function will create a support chain for the bridge from the specified
   ` starting point

   ` create the chain of boxes
   for i = StartID to EndID
      make object box i, 10, 2, 2
      position object i, x#, y#, z#
      phy make rigid body dynamic box i

      color object i, rgb ( rnd ( 255 ), rnd ( 255 ), rnd ( 255 ) )
      set object specular i, rgb ( rnd ( 255 ), rnd ( 255 ), rnd ( 255 ) )
      set object specular power i, 255
      set object ambient i,0

      x# = x# + 12
   next i

   ` set up ball joints between them
   for i = StartID to EndID - 1
      phy make sphere joint JointID, i, i + 1, object position x ( i ), object position y ( i ), object position z ( i )
      JointID = JointID + 1
   next i

   ` ball joints going in other direction
   for i = StartID + 1 to EndID
      phy make sphere joint JointID, i, i - 1, object position x ( i ), object position y ( i ), object position z ( i )
      JointID = JointID + 1
   next i

   ` further ball joints
   phy make sphere joint JointID, 2, StartID, object position x ( StartID ), object position y ( StartID ), object position z ( StartID )
   JointID = JointID + 1

   phy make sphere joint JointID, 3, EndID - 1, object position x ( EndID - 1 ), object position y ( EndID - 1 ), object position z ( EndID - 1 )
   JointID = JointID + 1
endfunction


function strapline(mode,s$)
   if mode=0
      ink 0x66FFFFFF,0 : set text font "Tahoma" : set text size 32
   else
      center text screen width()/2,20,s$
   endif
endfunction

` demonstrates how a door can be created using joints

` set up our program
phy start
sync on
sync rate 60

` make a background sphere
load image "stripe5.png",1000
make object sphere 1000,400,48,48
texture object 1000,1000
scale object texture 1000,6,6
set object cull 1000,0
rotate object 1000,0,0,90
load image "stripe6.png", 3

` create a floor object
make object box 1, 210, 1, 210
position object 1, 0, -1, 0
phy make rigid body static box 1
texture object 1, 3

` create a wall at the back left
make object box 2, 80, 60, 1
position object 2, -60, 30, 100
phy make rigid body static box 2

` create wall at the back right
make object box 3, 80, 60, 1
position object 3, 60, 30, 100
phy make rigid body static box 3

` create left wall
make object box 4, 1, 60, 200
position object 4, -100, 30, 0
phy make rigid body static box 4

` create right wall
make object box 5, 1, 60, 200
position object 5, 100, 30, 0
phy make rigid body static box 5

` create front wall
make object box 6, 200, 60, 1
position object 6, 0, 30, -100
phy make rigid body static box 6

` create our door
make object box 7, 39.8, 60, 1
position object 7, 0, 30, 100
color object 7, rgb( 255, 0, 0 )
phy make rigid body dynamic box 7

` give all of our objects some colour
for i = 2 to 7
   color object i, rgb ( rnd ( 255 ), rnd ( 255 ), rnd ( 255 ) )
   set object specular i, rgb ( rnd ( 255 ), rnd ( 255 ), rnd ( 255 ) )
   set object specular power i, 255
   set object ambient i,0
next i

` create a revolute joint between the back left wall and the door
phy make revolute joint 1, 2, 7, 0, 1, 0, -20, 30, 100

` place a sphere so we can see the position of the joint
make object sphere 9, 5
position object 9, -20, 30, 100

` make a sphere to fire at the door
make object sphere 11, 15, 20, 20
position object 11, 0, 15, 0
phy make rigid body dynamic sphere 11
color object 11, rgb ( rnd ( 255 ), rnd ( 255 ), rnd ( 255 ) )
set object specular 11, rgb ( rnd ( 255 ), rnd ( 255 ), rnd ( 255 ) )
set object specular power 11, 255
set object ambient 11,0

` position and rotate the camera to view the scene
position camera -75, 140, -2
rotate camera 47, 42, 0

` display the Dark Physics logo
load image "logo.png", 100000
sprite 1, 0, 600 - 60, 100000

` main program loop
do
   ` display some instructions
   set cursor 0, 0
   print "Press the space key to apply velocity to the sphere"

   ` when the space key is pressed apply velocity to the door
   if spacekey( ) = 1
      phy set rigid body linear velocity 11, 0, 0, 80.0
   endif

   ` update the physics and screen
   phy update
   sync
loop

phy start
randomize timer()
sync on: sync rate 60
autocam off
position camera -50,90,-120
point camera 0,70,0

gBase = 1
gStrut1 = 2
gStrut2 = 3
gSpindle = 4
global gJoint = 0

global gArms = 8
global gArm = 10
global gBox = 30

` Static frame
load object "ferris_frame.dbo", gBase
color object gBase, rgb(128,192,128)
phy make rigid body static mesh gBase

` Main Spindle
make object box gSpindle,24,5,24
xrotate object gSpindle, 90
position object gSpindle, 0,90,0
phy make rigid body dynamic box gSpindle
phy update
j = nextJoint()
phy make cylindrical joint j, gBase, gSpindle, object position x(gSpindle), object position y(gSpindle), object position z(gSpindle), 0, 0, 1

load object "carriage.dbo", 999
` Arms
for n = 1 to gArms
   obj = gArm + n
   angle# = (360.0 / gArms) * n
   make object box obj, 4, 70, 4
   color object obj, rgb(128,128,128 + rnd(128))
   position object obj, object position x(gSpindle) + cos(angle#) * 40, object position y(gSpindle) + sin(angle#) * 40 , 15
   zrotate object obj, angle# + 90
   phy make rigid body dynamic box obj
   phy set rigid body mass obj, 1
   j = nextJoint()
   phy make fixed joint j, gSpindle, obj
   ` add carriage
   obj2 = gBox + n
   `make object box obj2, 10, 15, 15
   clone object obj2, 999
   color object obj2, rgb(128 + rnd(128),128,128)
   position object obj2, object position x(gSpindle) + cos(angle#) * 70, (object position y(gSpindle) + sin(angle#) * 70) - 6 , 4
   phy make rigid body dynamic box obj2
   phy set rigid body mass obj2, 2
   j = nextJoint()
   phy make cylindrical joint j, obj2, obj, object position x(obj2),object position y(obj2) + 6,object position z(obj2),0,0,1

next n

` Background
load image "stripe5.png", 100
make object sphere 100, 1000
set object cull 100, 0
texture object 100, 100

cam = 0

` display the Dark Physics logo
load image "logo.png", 100000
sprite 1, 0, 600 - 60, 100000

do
   phy set rigid body angular velocity gSpindle, 0, 0, 0.08

   phy update
   if cam = 0
      control camera using arrowkeys 0,0.1,0.3
      if inkey$() = "2"
         cam = 1
      endif
   else
      set camera to follow object position x(gArm + 1),object position y(gArm + 1),object position z(gArm + 1),90, 0,10, 20, 0
      point camera 100,camera position y(),0
      if inkey$() = "1"
         cam = 0
         position camera -50,90,-120
         point camera 0,70,0
      endif
   endif
   text 5,25, "1 = Third Person View"
   text 5,45, "2 = First Person Ride"

   ` rotate the backdrop
   rotate object 100, 0, object angle y( 100 ) + 0.1, 0

   sync
loop


function getBase(obj)
rem gets offset to place object base at 0

   pos# = object size y(obj) / 2.0

endfunction pos#

function nextJoint()
rem tracks joint numbers

   inc gJoint, 1

endfunction gJoint

` example of revolute joints and motors

phy enable debug
phy start
autocam off
sync on
sync rate 60
color backdrop 0
position camera 0, 20, -100
make light 1
set directional light 1, -5, -5, 5

load image "stripe5.png",800
make object sphere 800,400,48,48
texture object 800,800
scale object texture 800,6,6
set object cull 800,0

make object box 1, 20, 1, 20
texture object 1,1
phy make rigid body static box 1

make object box 2, 8, 30, 8
position object 2, 0, 16, 0
color object 2, rgb ( rnd ( 255 ), rnd ( 255 ), rnd ( 255 ) )
phy make rigid body dynamic box 2
phy make fixed joint 1, 1, 2

make object box 3, 30, 5, 5
position object 3, 15, 35, 0
phy make rigid body dynamic box 3

phy make revolute joint 2, 2, 3
phy set revolute joint global anchor 2, 0, 0, 35, 0
phy set revolute joint global axis 2, 0, 0, 1, 0
phy set revolute joint motor 2, 500, 10000, 1.0
phy build revolute joint 2

make object box 4, 5, 15, 5
position object 4, 27.5, 45, 0
phy make rigid body dynamic box 4
phy make fixed joint 3, 3, 4

make object box 5, 30, 5, 5
position object 5, 40, 55, 0
phy make rigid body dynamic box 5

phy make fixed joint 4, 4, 5

make object box 6, 5, 40, 3
position object 6, 55, 35, 0
phy make rigid body dynamic box 6

phy make fixed joint 5, 5, 6

make object box 7, 40, 5, 5
position object 7, 55, 12.5, 0
phy make rigid body dynamic box 7
phy set rigid body mass offset global 7, 55, 12.5, 0
phy set rigid body mass 7, 0.1

phy make revolute joint 6, 6, 7
phy set revolute joint global anchor 6, 0, 55, 12.5, 0
phy set revolute joint global axis 6, 0, 0, -1, 0
phy set revolute joint motor 6, 500, 1000, 1.0
phy build revolute joint 6

load image "logo.png", 100000
sprite 1, 0, 600 - 60, 100000

for i = 1 to 7
   color object i, rgb ( rnd ( 255 ), rnd ( 255 ), rnd ( 255 ) )
   set object specular i, rgb ( rnd ( 255 ), rnd ( 255 ), rnd ( 255 ) )
   set object ambient i, 255
   set object specular power i, 255
next i

do
   phy update
   sync
loop

` creates a collection of tables using boxes and joints

` set up program
phy start
autocam off
sync on
sync rate 60
color backdrop 0
position camera 0, 10, -80
make light 1
set directional light 1, -5, -5, 5

` create ground object
make object box 1, 120, 1, 100
position object 1, 0, -20, 0
rotate object 1, -10, 0, 0
phy make rigid body static box 1

` display Dark Physics logo
load image "logo.png", 100000
sprite 1, 0, 600 - 60, 100000

`prepare the variables for creating tables
global lw# = 1.0
global lt# = 10.0
global cw# = 5.0
global sw# = 11.0
global cxp# = -10.0
global cyp# = 10.0
global ch# = 35.0

` create our tables
create_table(-15.0,-15.0,0.0,10)
create_table(15.0,-15.0,0.0,20)
create_table(-15.0,15.0,0.0,30)
create_table(15.0,15.0,0.0,40)
create_table(-30.0,-15.0,0.0,50)
create_table(30.0,-15.0,0.0,60)
create_table(-30.0,15.0,0.0,70)
create_table(30.0,15.0,0.0,80)
create_table(-45.0,-15.0,0.0,90)
create_table(45.0,-15.0,0.0,100)
create_table(-45.0,15.0,0.0,110)
create_table(45.0,15.0,0.0,120)
create_table(-45.0,-30.0,0.0,130)
create_table(45.0,-30.0,0.0,140)
create_table(-45.0,30.0,0.0,150)
create_table(45.0,30.0,0.0,160)
create_table(-30.0,-30.0,0.0,170)
create_table(30.0,-30.0,0.0,180)
create_table(-30.0,30.0,0.0,190)
create_table(30.0,30.0,0.0,200)
create_table(-15.0,-30.0,0.0,210)
create_table(15.0,-30.0,0.0,220)
create_table(-15.0,30.0,0.0,230)
create_table(15.0,30.0,0.0,240)

` colour all objects
for i = 1 to 200
   if object exist ( i )
      color object i, rgb ( rnd ( 255 ), rnd ( 255 ), rnd ( 255 ) )
      set object specular i, rgb ( rnd ( 255 ), rnd ( 255 ), rnd ( 255 ) )
      set object specular power i, 255
      set object ambient i, 0
      set object smoothing i, 68.0
   endif
next i

` create background sphere
load image "stripe5.png",1
make object sphere 600,400,48,48
texture object 600,1
scale object texture 600,6,6
set object cull 600,0

` position and rotate the camera
position camera -58, 49, -95
rotate camera 39.5, 35, 0

` the main program loop
do
   ` rotate the background sphere
   rotate object 600, object angle x ( 600 ) + 0.01, object angle y( 600 ) - 0.05, object angle z ( 600 ) + 0.03

   ` update simulation and screen
   phy update
   sync
loop

function create_table(cxp#,cyp#,ch#,first_obj)
   ` this function is responsible for creating a table

   make object box first_obj,sw#,lw#,sw#
   position object first_obj,cxp#,(ch#+lt#)+0.5,cyp#

   make object box first_obj+1,lw#,lt#,lw#
   position object first_obj+1,cxp#-cw#,ch#+(lt#/2.0),cyp#+cw#

   make object box first_obj+2,lw#,lt#,lw#
   position object first_obj+2,cxp#+cw#,ch#+(lt#/2.0),cyp#+cw#

   make object box first_obj+3,lw#,lt#,lw#
   position object first_obj+3,cxp#-cw#,ch#+(lt#/2.0),cyp#-cw#

   make object box first_obj+4,lw#,lt#,lw#
   position object first_obj+4,cxp#+cw#,ch#+(lt#/2.0),cyp#-cw#

   for j = first_obj to first_obj+4
      set object smoothing j,68.0
      phy make rigid body dynamic box j
   next j

   phy make fixed joint first_obj,first_obj,first_obj+1
   phy make fixed joint first_obj+2,first_obj,first_obj+2
   phy make fixed joint first_obj+3,first_obj,first_obj+3
   phy make fixed joint first_obj+4,first_obj,first_obj+4
endfunction

` example of a fire emitter

` set up program properties

autocam off
sync on
sync rate 60
color backdrop 0
set ambient light 30
position camera 0, 50, -80
phy start

` make the fire emitter
phy make fire emitter 1, 512, 0, 20, 0
load image "fire.png", 1
texture object 1, 1
ghost object on 1, 0

` create background sphere
load image "stripe5.png",2
make object sphere 2,400,48,48
texture object 2,2
scale object texture 2,6,6
set object cull 2,0
set alpha mapping on 2, 80

` display Dark Physics logo
load image "logo.png", 100000
sprite 1, 0, 600 - 60, 100000

` main program loop
do
   ` rotate the background
   rotate object 2, 0, object angle y( 2 ) - 0.05, object angle z( 2 ) - 0.08

   ` update simulation and screen
   phy update
   sync
loop

` shows a scene with a collection of dynamic spheres

gosub prepare_environment
gosub prepare_media
gosub prepare_physics_materials
gosub prepare_simulation
gosub play_simulation
end

`PREPARE_ENVIRONMET ===========================================================
prepare_environment:
   backdrop on
   color backdrop rgb(128,128,128)
   phy start 1, 0, 1
   sync on
   sync rate 60
   autocam off
   set directional light 0,0,0,1
   position camera 10.0,14.0,-30.0
   point camera 0.0,14.0,0.0
return

`PREPARE_MEDIA ================================================================
prepare_media:
   load image "mediareflection.png",10
   load image "mediaskydome.png",11
   load image "mediafloortex.bmp",12
   load image "mediasupports.png",13

   make object sphere 10,500.0,48,48
   position object 10,0.0,-50.0,0.0
   texture object 10,11
   scale object texture 10,1.0,2.0
   set object cull 10,0
   set object light 10,0

   load image "logo.png", 10000
   sprite 1, 0, 600 - 60, 10000
return

`PREPARE_PHYSICS_MATERIALS ====================================================
prepare_physics_materials:
   `'hardplastic' (fairly bouncy low friction rating)
   phy make material 1,"hardsmooth"
   phy set material dynamic friction 1,0.2
   phy set material static friction 1,0.2
   phy set material restitution 1,0.2
   phy build material 1
return

`PREPARE_SIMULTION ============================================================
prepare_simulation:

   `make the floor object
   make object box 100,200,1,200
   position object 100,0,-0.5,0
   texture object 100,12
   scale object texture 100,4.0,4.0
   phy make rigid body static box 100,1

   `make our falldown construction
   `the base
   make object box 101,20,1,2
   position object 101,0,0.5,0
   texture object 101,13
   set sphere mapping on 101,10
   set object smoothing 101,100
   phy make rigid body static box 101,1

   `the sides
   make object box 102,2,28,2
   texture object 102,13
   position object 102,-9,16.5,0
   set sphere mapping on 102,10
   set object smoothing 102,100
   phy make rigid body static box 102,1

   make object box 103,2,29.5,2
   texture object 103,13
   position object 103,9,15.75,0
   set sphere mapping on 103,10
   set object smoothing 103,100
   phy make rigid body static box 103,1

   `front and back panels
   make object box 104,20,31,0.25
   texture object 104,10
   disable object zwrite 104
   set sphere mapping on 104,10
   set object smoothing 104,100
   ghost object on 104,2
   position object 104,0,15,1.175
   color object 104,rgb(200,200,255)
   fade object 104,250.0
   phy make rigid body static box 104,1

   make object box 105,20,31,0.25
   texture object 105,10
   disable object zwrite 105
   set sphere mapping on 105,10
   set object smoothing 105,100
   ghost object on 105,2
   position object 105,0,15,-1.175
   color object 105,rgb(200,200,255)
   fade object 105,250
   phy make rigid body static box 105,1

   make object box 106,2,2.0,4
   position object 106,-12.0,1.0,1.0
   color object 106,rgb(128,128,0)
   set sphere mapping on 106,11
   yrotate object 106,45.0
   set object smoothing 106,100
   phy make rigid body static box 106,1

   `falldown planks
   first_plank = 106
   plank_height# = 1.5
   height_step# = 3.1
   od_ev = 1
   od_dec = 0

   for j = 1 to 8
      make object box first_plank+j,10.5,0.5,1.99
      texture object first_plank+j,13
      set sphere mapping on first_plank+j,10
      set object smoothing first_plank+j,100
      if od_dec = 0
         if od_ev = 1
            zrotate object first_plank+j,6
            position object first_plank+j,3.0,plank_height#,0.0
            phy make rigid body static box first_plank+j,1
            od_dec = 1
            od_ev = 2
         endif
      endif
      if od_dec = 0
         if od_ev = 2
            zrotate object first_plank+j,354
            position object first_plank+j,-3.0,plank_height#,0.0
            phy make rigid body static box first_plank+j,1
            od_dec = 1
            od_ev = 1
         endif
      endif
      plank_height# = plank_height# + height_step#
      od_dec = 0
   next j

   `prepare some variables to make our dynamic falling column of objects that
   `show us how the collision boxes really behave.
   ang# = 0.0
   angstep# = 30
   radius# = 7.0
   h# = 30.0

   for j = 2001 to 2601
      make object sphere j,0.75
      color object j,rgb(rnd(255),rnd(255),rnd(255))
      set object specular j,rgb(255,255,255)
      set object specular power j,255
      set object ambient j,0
      s = rnd(40) + 60
      scale object j,s,s,s
      h# = h# + 0.1
      temp_x# = sin(ang#)*radius#
      temp_z# = cos(ang#)*(radius#/20.0)
      position object j,temp_x#,h#,temp_z#
      phy make rigid body dynamic sphere j,1
      ang# = wrapvalue(ang#)+angstep#
   next j
return

`PLAY_SIMULATION ==============================================================
play_simulation:
   cam_counter# = 90.0
   cam_speed# = 0.5
   repeat

      if returnkey() = 1
         for j = 2001 to 2301
            phy delete rigid body j
         next j
         ang# = 0.0
         angstep# = 30
         radius# = 7.0
         h# = 30.0
         for j = 2001 to 2301
            s = rnd(40) + 60
            scale object j,s,s,s
            h# = h# + 0.1
            temp_x# = sin(ang#)*radius#
            temp_z# = cos(ang#)*(radius#/20.0)
            position object j,temp_x#,h#,temp_z#
            phy make rigid body dynamic sphere j,1
            ang# = wrapvalue(ang#)+angstep#
         next j
         wait 500
      endif
      camx# = sin(cam_counter#)*10.0
      camy# = cos(cam_counter#)*20.0
      position camera camx#,10.0,-30.0
      point camera 0.0,14.0,0.0
      cam_counter# = cam_counter# + cam_speed#
      phy update
      sync
   until spacekey() = 1
return

rem this demo creates a vast amount of objects to form 4 walls
rem it shows how using the hardware will bring a significant
rem boost to game performance

rem Init
sync on : sync rate 0 : autocam off
set text font "Verdana"
ink rgb(255,255,250),0

rem preare counters
tmlast as double integer
tmcode as double integer
tmphysics as double integer
tmvisuals as double integer

rem Camera
set normalization on
set ambient light 50
color backdrop rgb(10,22,50)

rem settings
videomode=0
hardwaremode=0 : wallwidth=12 : walldepth=30

rem Logo sprite
load image "logo.png", 100000 : sprite 1,0,screen height()-60,100000
size sprite 1,screen width(),60

rem SW/HW loop
do

rem Setup physics
gosub _physics_init
gosub _physics_setup

rem Main
phy update 0 : rem simulate
while spacekey()=0
 `
 rem Spin camera
 inc spin#
 position camera 16+(cos(spin#)*60),50,16+(sin(spin#)*60)
 point camera 16,5,16
 `
 rem give the CPU some game logic to do (faked)
 tmlast=perftimer()
 for t=1 to 10000 : a#=sqrt(b#/c#/d#/e#/f#/g#) : next t
 if tmdelay=0 then tmcode=perftimer()-tmlast
 `
 rem prompts
 if videomode=0
  swhw$="SOFTWARE"
  if hardwaremode=1 then swhw$="HARDWARE" : center text screen width()/2,60,"! NOTICE HOW HARDWARE RUNS AT UP TO TWICE THE SPEED !"
  center text screen width()/2,20,"PHYSX IN "+swhw$+"  OBJECTS:"+str$(objid-100)+"  FPS:"+str$(screen fps())+"  CODE:"+str$(tmcode/1000)+"  PHYSICS:"+str$(tmphysics/1000)+"  VISUALS:"+str$(tmvisuals/1000)
  if physx()=1
   center text screen width()/2,40,"PRESS SPACE TO TOGGLE BETWEEN SOFTWARE AND HARDWARE"
  else
   center text screen width()/2,40,"PHYSX SOFTWARE SUPPORT ONLY"
  endif
  if inkey$()="v" then videomode=1 : set text size 50
 else
  text 40,20,"FRAME RATE : "+str$(10+screen fps())
 endif
 `
 rem update simulation
 tmlast=perftimer()
 phy update 1 : rem fetch
 phy update 0 : rem simulate
 if tmdelay=0 then tmphysics=perftimer()-tmlast
 `
 rem visual update
 tmlast=perftimer()
 sync
 if tmdelay=0 then tmvisuals=perftimer()-tmlast
 `
 rem timer handler
 inc tmdelay : if tmdelay>30 then tmdelay=0
 `
endwhile
phy update 1 : rem fetch
while spacekey()<>0 : endwhile

rem Prompt
center text screen width()/2,screen height()/2,"RESETTING SCENE" : sync

rem toggle hardware flag
hardwaremode=1-hardwaremode

rem free usages
phy update
delete objects 1,objid
phy end

rem SW/HW endloop
loop
end

_physics_init:

 rem Start the Physics Engine
 if hardwaremode=1
  if physx()=1
   phy start 1,0,1
  else
   hardwaremode=0
   phy start
  endif
 else
  phy start
 endif
 phy set skin width 0.001

 `
return

_physics_setup:
 `
 rem Make a friction material resistant to sliding (brick material)
 brickmaterial=1
 phy make material brickmaterial, "brick"
 phy set material static friction brickmaterial, 25.0
 phy set material restitution brickmaterial, 0.0
 phy set material dynamic friction brickmaterial, 1.0
 phy build material brickmaterial

 rem Make a floor of brick
 load image "stripe6.png",10
 make object box 10,50,5,50 : texture object 10,10
 position object 10,12,-2.5,12
 scale object texture 10,5,5
 phy make rigid body static box 10
 `
 rem Make a brick and rock
 load image "stripe5.png",1
 make object box 1,2,0.8,1 : texture object 1,1 : scale object texture 1,0.15,0.15 : hide object 1
 make object cube 2,2 : color object 2,rgb(255,255,0) : set object emissive 2,rgb(128,64,64) : hide object 2
 `
 rem Make a house from the bricks
 objid=100
 for compass=0 to 3
  for y=0 to walldepth
   stagger=y mod 2
   for x=0 to wallwidth
    inc objid
    instance object objid,1
    if compass=0 then yrotate object objid,0 : position object objid,stagger+(x*2),(y*0.8)+0.4,0
    if compass=1 then yrotate object objid,90 : position object objid,(wallwidth*2)+1.5,(y*0.8)+0.4,(stagger+(x*2))+0.5
    if compass=2 then yrotate object objid,0 : position object objid,(1-stagger)+(x*2),(y*0.8)+0.4,(wallwidth*2)+2
    if compass=3 then yrotate object objid,90 : position object objid,-0.5,(y*0.8)+0.4,(1-stagger)+(x*2)+0.5
    phy make rigid body dynamic box objid,brickmaterial
    phy set rigid body linear damping objid,0.0
    phy set rigid body mass objid,1
   next x
  next y
 next compass
 objidmax=objid
 `
 rem HW TIP : precreate everything for best performance
 for fall=0 to 199
  inc objid : instance object objid,2
  scale object objid,10+rnd(100),10+rnd(100),10+rnd(100)
  position object objid,5+3+rnd(wallwidth-5),50+(fall*5),5+3+rnd(wallwidth-5)
  phy make rigid body dynamic box objid,brickmaterial
  phy set rigid body linear damping objid,0
  phy set rigid body mass objid,2
  phy set rigid body angular velocity objid,100,100,0

 next fall
 `
 rem Allow the physics objects to settle into their skins
 for settle=1 to 99 : phy update : next settle
 `
 rem stripe textures
 load image "stripe5.png",8
 make object sphere 8,400,48,48
 texture object 8,8
 scale object texture 8,6,6
 set object cull 8,0
 `
return

rem hardware driven fluid poured into a container

rem Init
sync on : sync rate 0 : autocam off
set text font "Verdana"
ink rgb(255,255,255),0

rem preare counters
tmlast as double integer
tmcode as double integer
tmphysics as double integer
tmvisuals as double integer

rem Camera
position camera -3,3,-3 : point camera 0,0,0
color backdrop rgb(16,16,64) : set camera range 0.1,1000
set normalization on : set ambient light 5
set directional light 0,0.1,-0.7,0.4

rem settings
hardwaremode=0

rem Logo sprite
load image "logo.png", 100000 : sprite 1,0,screen height()-60,100000
size sprite 1,screen width(),60
hide sprite 1

rem SW/HW loop
clear=mousemovex()
clear=mousemovey()
do

rem Setup physics
gosub _physics_init
gosub _physics_setup

phy update 0

rem Main
clear=mousemovex()
clear=mousemovey()
while spacekey()=0
 `
 rem camera movement
 if upkey()=1 then move camera 0.1
 if downkey()=1 then move camera -0.1
 angy# = camera angle y()
 angx# = camera angle x()
 xrotate camera 0
 if leftkey()=1 then yrotate camera angy#-90 : move camera 0.1 : yrotate camera angy#
 if rightkey()=1 then yrotate camera angy#+90 : move camera 0.1 : yrotate camera angy#

 yrotate camera angy#
 xrotate camera angx#

 rem prompts
 swhw$="HARDWARE"
 center text screen width()/2,20, "FPS:"+str$(screen fps())

 rem update simulation
 tmlast=perftimer()
 phy update 1
 phy update 0
 if tmdelay=0 then tmphysics=perftimer()-tmlast
 `
rem BUGS
set cursor 0,0

 rem visual update
 tmlast=perftimer()
 sync
 if tmdelay=0 then tmvisuals=perftimer()-tmlast
 `
 rem timer handler
 inc tmdelay : if tmdelay>30 then tmdelay=0
 `
endwhile
while spacekey()<>0 : endwhile

rem Prompt
set text size 30
center text screen width()/2,screen height()/2,"RESETTING SCENE" : sync
set text size 12

rem otggle hardware flag
hardwaremode=1-hardwaremode

rem free usages
phy update 1
delete objects 1,objid
phy end

rem SW/HW endloop
loop
end

_physics_init:
 `
 rem Start the Physics Engine

 if hardwaremode=1
  if physx()=1
   phy start 1,1,1
  else
   hardwaremode=0
   phy start
  endif
 else
  phy start
 endif
 phy set skin width 0.02
 `
return

_physics_setup:

make object box 1, 40, 1, 40
position object 1, 0, -2, 0
load image "stripe6.png", 100
texture object 1, 100
phy make rigid body static box 1


rem make some fluid
phy make fluid 2
phy set fluid position 2, -1, 2, -1
phy set fluid viscosity 2, 200.0
phy set fluid damping 2, 1.0
phy set fluid particle buffer cap 2, 5000

phy set fluid particle radius 2, 0.1

phy build fluid 2

load image "gooblob.tga", 1 : texture object 2, 1

rem make material no bounce
nobouncematerial=1
phy make material nobouncematerial, "little bounce"
phy set material restitution nobouncematerial,0.1
phy build material nobouncematerial

rem container dir
set dir "Container"

rem create original cylinder model
objid=3 : load object "cylinder_c.X",objid
load image "cylinder_c_D2.tga",3
texture object objid,3
scale object objid,2.5,2.5,2.5
make mesh from object objid,objid
delete object objid
make object objid,objid,3
hide object objid
cylinderobj=objid

rem make a solid container for the fluid
inc objid : make object box objid,3,0.1,3
load image "f_c_01_d2.dds",4
texture object objid,4 : position object objid,0,0.05,0
phy make rigid body static box objid,nobouncematerial
for a=0 to 360-90 step 90
 high#=1.0 : if a=0 or a=180 then wid#=2.5 else wid#=3.5
 inc objid : make object box objid,wid#-0.5,high#,0.5
 texture object objid,4
 position object objid,sin(a)*1.25,0.05+(high#/2),cos(a)*1.25
 yrotate object objid,a
 if a=180
  rem this side slides out
  phy make rigid body dynamic box objid,nobouncematerial
 else
  rem these contain the fluid (slightly sloped)
  phy make rigid body static box objid,nobouncematerial
 endif
next a

rem allow fluid to settle
for settle=0 to 250 : phy update : next settle

rem make cylinders
for c=1 to 10
 inc objid : instance object objid,cylinderobj
 position object objid,(rnd(100)-50)/1000.0,10+(c*3),(rnd(100)-50)/1000.0
 rotate object objid,rnd(360),rnd(360),rnd(360)
 phy make rigid body dynamic box objid,nobouncematerial
 phy set rigid body mass objid,1
next c

rem restore dir
set dir ".."

return

rem uses a bone based model of a rope
rem and the ragdoll commands to create
rem a jointed rigid body structure that
rem uses mesh animation to create a
rem smooth rope that responds with full
rem physics awareness.

rem set up program
sync on : sync rate 60 : color backdrop rgb(0,0,0)

rem create physics and model
gosub _rope_make

rem position the camera
camr#=250.0 : camh#=170.0 : a#=45

rem main
do
 `
 rem camera
 a#=a#+(mousemovex()/10.0)
 camr#=camr#-(mousemovez()/10.0)
 position camera sin(a#)*camr#,camh#,cos(a#)*(camr#*-1)
 point camera 0,camh#/1.75,0
 `
 rem place light
 set point light 0,object position x(150),object position y(150),object position z(150)
 color light 0,rgb(255,255,0)
 set light range 0,1000
 `
 rem cheap double the speed of physics
 for quadruple=0 to 3 : phy update : next quadruple
 `
 rem update
 sync
 `
rem end loop
loop

_rope_make:
 `
 rem physics
 phy start
 `
 rem create spot light
 set normalization on
 set ambient light 0
 make light 1
 set spot light 1,5,80
 set light range 1,2000
 position light 1,0,300,0
 point light 1,0,0,0
 `
 rem create ground object
 load object "Densefloor.X",100
 load image "Densefloor.TGA",100
 scale object 100,600,100,600
 scale object texture 100,2,2
 texture object 100,100
 phy make rigid body static box 100
 `
 rem display the Dark Physics logo
 load image "logo.png", 10000
 sprite 1, 0, 0, 10000
 size sprite 1,screen width(),60

 `
 rem make bone representation
 make object sphere 10,2
 make object box 11,10,0.1,0.2
 make mesh from object 11,11
 add limb 10,1,11
 offset limb 10,1,5,0,0
 make mesh from object 10,10
 delete object 11
 delete object 10
 make object 10,10,0
 hide object 10
 `
 rem create rag doll rope
 load object "ropebones.X", 1
 position object 1,0,230,0
 rotate object 1,1,2,3
 set object light 1,0
 `
 rem make seperate objects to represent the rope
 objid=199
 perform checklist for object limbs 1
 cm=checklist quantity()
 for c=1 to cm-1
  `
  rem info from bones
  x#=limb position x(1,c-1)
  y#=limb position y(1,c-1)
  z#=limb position z(1,c-1)
  rx#=limb direction x(1,c-1)
  ry#=limb direction y(1,c-1)
  rz#=limb direction z(1,c-1)
  `
  rem new obj
  inc objid : if object exist(objid)=1 then delete object objid
  `
  rem only make capsules out of 'qualifying bones'
  c$=checklist string$(c)
  if c=1
   rem make root object
   make object cube objid,0.1
   position object objid,x#,y#,z#
   rotate object objid,rx#,ry#,rz#
   phy make rigid body static box objid
  else
   if lower$(c$)<>"$noname$"
    rem make capsule
    make object box objid,10,1,1
    position object objid,x#,y#,z#
    rotate object objid,rx#,ry#,rz#
    move object left objid,-5.0
    phy make rigid body dynamic box objid
    phy set rigid body mass objid,10
   endif
  endif
  `
 next c
 `
 rem JOINT SPECIFIC SECTION
 rem join the seperate objects to make copy of the rope model
 jid=0
 for c=1 to cm-1
  c$=checklist string$(c)
  if c=1
   link=c-1
  else
   if lower$(c$)<>"$noname$"
    linkto=c-1 : a=200+link : b=200+linkto
    inc jid : phy make revolute joint jid, a, b, 1, 0, 0, limb position x(1,linkto),limb position y(1,linkto),limb position z(1,linkto)
    link=linkto
   endif
  endif
 next c
 rem add heavy ball to rope
 make object sphere 150,20,30,30 : linkto=20
 position object 150,limb position x(1,linkto),limb position y(1,linkto),limb position z(1,linkto)-11
 color object 150,rgb(255,255,0)
 set object emissive 150,rgb(128,128,0)
 phy make rigid body dynamic sphere 150
 phy set rigid body mass 150,2000
 inc jid : phy make revolute joint jid, 150, 218, 1, 0, 0, limb position x(1,linkto),limb position y(1,linkto),limb position z(1,linkto)-20
 scale object 150,150,150,150
 `
 rem RAGDOLL SPECIFIC SECTION
 rem set the model to become a ragdoll model, and use the 'base physics object - the first capsule'
 phy make rag doll 1, 1, 200
 rem assign ragdoll model limbs to point to real world jointed physics objects
 phy assign rag doll part 1, 0, 17, 201
 phy assign rag doll part 1, 0, 16, 202
 phy assign rag doll part 1, 0, 15, 203
 phy assign rag doll part 1, 0, 14, 204
 phy assign rag doll part 1, 0, 13, 205
 phy assign rag doll part 1, 0, 12, 206
 phy assign rag doll part 1, 0, 11, 207
 phy assign rag doll part 1, 0, 10, 208
 phy assign rag doll part 1, 0, 9, 209
 phy assign rag doll part 1, 0, 8, 210
 phy assign rag doll part 1, 0, 7, 211
 phy assign rag doll part 1, 0, 6, 212
 phy assign rag doll part 1, 0, 5, 213
 phy assign rag doll part 1, 0, 4, 214
 phy assign rag doll part 1, 0, 3, 215
 phy assign rag doll part 1, 0, 2, 216
 phy assign rag doll part 1, 0, 1, 217
 phy assign rag doll part 1, 0, 0, 218
 `
 rem hide physics objects controlling tagdoll model
 for o=200 to 218 : hide object o : next o
 `
 rem make a small brick wall
 make object box 300,20,10,10 : objid=300
 for y=0 to 9
  st=0 : if y=1 or y=3 or y=5 or y=7 or y=9 then st=10
  for x=0 to 3
   inc objid : instance object objid,300
   position object objid,((x-2)*21)+st,y*10,0
   rotate object objid,0,rnd(10)/10.0,0
   phy make rigid body dynamic box objid
   phy set rigid body mass objid,50
  next x
 next y
 `
return

` this program demonstrates the use of dynamic convex meshes

` set up the program
phy start
autocam off
sync on
sync rate 60
color backdrop 0
position camera 0, 40, -170

` create ground object
make object box 1, 150, 1, 150
phy make rigid body static box 1

` display the Dark Physics logo
load image "logo.png", 100000
sprite 1, 0, 0, 100000

` create a stack of convex objects
y# = 50

for i = 2 to 200
   load object "convex1.x", i
   position object i, 0, y#, 0
   rotate object i, rnd ( 360 ), rnd ( 360 ), rnd ( 360 )
   phy make rigid body dynamic convex i
   phy set rigid body angular velocity i, 1, 1, 1
   y# = y# + 40
next i

` colour all objects
for i = 1 to 200
   if object exist ( i )
      color object i, rgb ( rnd ( 255 ), rnd ( 255 ), rnd ( 255 ) )
      set object specular i, rgb ( rnd ( 255 ), rnd ( 255 ), rnd ( 255 ) )
      set object specular power i, 255
      set object ambient i, 0
   endif
next i

` set up the background
load image "stripe5.png",1
make object sphere 600,400,48,48
texture object 600,1
scale object texture 600,6,6
set object cull 600,0

` main program loop
do
   ` rotate the background
   rotate object 600, object angle x ( 600 ) + 0.01, object angle y( 600 ) - 0.05, object angle z ( 600 ) + 0.03

   ` update the simulation and screen
   phy update
   sync
loop

` in this program we see how dynamic meshes of any shape can be utilised

` set up the program
phy start
autocam off
sync on
sync rate 60
color backdrop 0
position camera 0, 15, -50
make light 1
set directional light 1, -5, -5, 5

` create the ground object
make object box 1, 50, 1, 50
phy make rigid body static box 1
ghost object on 1

` display the Dark Physics logo
load image "logo.png", 100000
sprite 1, 0, 600 - 60, 100000

` now create our objects
y# = 20
load object "test1.x", 2
position object 2, 0, y#, 0
`phy make rigid body dynamic mesh 2
phy load rigid body dynamic mesh 2, "test1.mesh"
y# = y# + 20

for i = 3 to 25
   clone object i, 2
   position object i, 0, y#, 0
   phy load rigid body dynamic mesh i, "test1.mesh"
   y# = y# + 20
next i

` give all objects some colour
for i = 1 to 300
   if object exist ( i )
      color object i, rgb ( rnd ( 255 ), rnd ( 255 ), rnd ( 255 ) )
      set object specular i, rgb ( rnd ( 255 ), rnd ( 255 ), rnd ( 255 ) )
      set object specular power i, 255
      set object ambient i, 0
   endif
next i

` create the background
load image "stripe5.png",1
make object sphere 600,400,48,48
texture object 600,1
scale object texture 600,6,6
set object cull 600,0

` setup the camera
position camera -24, 45, -52
rotate camera 43,24, 0

` main program loop
do
   ` rotate the background
   rotate object 600, object angle x ( 600 ) + 0.01, object angle y( 600 ) - 0.05, object angle z ( 600 ) + 0.03

   ` update simulation and screen
   phy update
   sync
loop

` the way forces work are dependant on which command is used and in
` this demo program we'll show the difference between applying
` global and local force to an object

` we begin by starting the physics process and setting some initial
` properties of the application, such as sync rate and camera position
phy start
autocam off
sync on
sync rate 60
color backdrop 0
position camera 0, 20, -100

rem stripe textures
load image "stripe5.png",8
make object sphere 8,400,48,48
texture object 8,8
scale object texture 8,6,6
set object cull 8,0
load image "stripe6.png",1

` a box is made to represent our floor object
make object box 1, 50, 1, 50
texture object 1,1
phy make rigid body static box 1

` a cube is created and positioned on top of the floor over to the left
make object cube 2, 5
position object 2, -10, 5, 0
phy make rigid body dynamic box 2

` another cube is created and positioned on top of the floor and over to
` the right side, the cube is rotated by -45 degrees on the Z axis
make object cube 3, 5
position object 3, 10, 5, 0
rotate object 3, 0, 0, -45
phy make rigid body dynamic box 3

` all of the objects in the scene are given a splash of colour
for i = 2 to 3
   color object i, rgb ( rnd ( 255 ), rnd ( 255 ), rnd ( 255 ) )
   set object specular i, rgb ( rnd ( 255 ), rnd ( 255 ), rnd ( 255 ) )
   set object specular power i, 255
   set object ambient i, 0
next i

` the dark physics logo is loaded and displayed with a sprite
load image "logo.png", 100000
sprite 1, 0, 600 - 60, 100000

` now we get to our main program loop
do
   set cursor 0, 0
   print ""
   print "Press the space bar to apply forces to the objects on the global and local Y axis"
   print ""
   print "Global force is applied to object 1 on the left"
   print ""
   print "Local force is applied to object 2 on the right"

   ` when the space key is pressed some force will be added to both
   ` cubes, one will have global force applied to it and the other
   ` will have local force applied to it
   if spacekey ( ) = 1
      ` as cube 2 has not been rotated it is set up so that the X axis is
      ` pointing to the right of the scene, the Y axis is pointing upwards
      ` and the Z axis is pointing into the scene, we want to apply a
      ` global force onto this cube and push it up into the scene on the
      ` global Y axis which is pointing upwards, to do this we use the
      ` command phy add rigid body force as this will apply force globally,
      ` we pass in the object number 2, then no force on the X axis, a large
      ` force on the Y axis and no force on the Z axis, the final parameter
      ` is the force mode, we use mode 0 as we want to apply a regular force
      phy add rigid body force 2, 0, 100000, 0, 0

      ` now we will take the other cube and apply force to it locally, this
      ` works by taking the current direction of the object and then applying
      ` the force on that axis, as we have rotated this cube the Y axis is
      ` not facing upwards, instead it is facing diagonally up towards the right
      ` of the scene, therefore when force is applied on the local Y axis
      ` the cube will fly off upwards and to the right
      phy add rigid body local force 3, 0, 100000, 0, 0
   endif

   ` now we update the physics simulation and the screen
   phy update
   sync
loop

` while this program is very simple it will serve as a useful starting point
` in understanding how the different force commands operate, try experimenting
` with the rotation on the 2nd cube to see how this affects it when local
` force is applied, also try applying global force to the rotated cube and
` see how this works

` demonstrates groups

phy enable debug
phy start
autocam off
sync on
sync rate 60
color backdrop 0
position camera 0, 20, -100

` create background sphere
load image "stripe5.png",8
make object sphere 800,400,48,48
texture object 800,8
scale object texture 800,6,6
set object cull 800,0

` ground object, the group is set to 2
make object box 1, 50, 1, 50
texture object 1, 1
phy make rigid body static box 1
phy set rigid body group 1, 2

` create box to left
make object box 2, 50, 1, 50
position object 2, -50, 0, 0
phy make rigid body static box 2

` create box to right
make object box 3, 50, 1, 50
position object 3, 50, 0, 0
phy make rigid body static box 3

` make the first row of cubes, they are all set to group 3
x# = -100

for i = 4 to 100
   make object cube i, 5
   position object i, x#, 40, 0
   color object i, rgb ( rnd ( 255 ), rnd ( 255 ), rnd ( 255 ) )
   set object specular i, rgb ( rnd ( 255 ), rnd ( 255 ), rnd ( 255 ) )
   set object specular power i, 255
   set object ambient i, 0
   phy make rigid body dynamic box i
   phy set rigid body group i, 3
   x# = x# + 5
next i

` disable collision between groups 2 and 3
phy set group collision 2, 3, 0

` color all objects
for i = 1 to 100
   color object i, rgb ( rnd ( 255 ), rnd ( 255 ), rnd ( 255 ) )
   set object specular i, rgb ( rnd ( 255 ), rnd ( 255 ), rnd ( 255 ) )
   set object specular power i, 255
   set object ambient i, 0
next i

` display Dark Physics logo
load image "logo.png", 100000
sprite 1, 0, 600 - 60, 100000

` now we get to our main program loop
do
   set cursor 0, 0
   print ""
   print "Demonstrates the use of groups"
   print "The ground object on the left and right is using the default group"
   print "The ground object in the centre uses group 2"
   print "The row of boxes use group 3"
   print "Collision is disabled between group 2 and 3"

   rotate object 800, 0.0, object angle y ( 800 ) + 0.1, 0.0

   ` now we update the physics simulation and the screen
   phy update
   sync
loop

`Darkphysics box collision demo (01)




gosub prepare_environment
gosub prepare_media
gosub prepare_physics_materials
gosub prepare_simulation
gosub play_simulation
end




`PREPARE_ENVIRONMET ===========================================================
prepare_environment:
   backdrop on
   color backdrop rgb(128,128,128)
   phy start
   sync on
   sync rate 60
   autocam off
   set directional light 0,0,-1,0
   position camera 40,40.0,40
   point camera 0.0,14.0,0.0
   set ambient light 0
   make light 1
   set point light 1,30,10,0
   color light 1,255,0,0
   make light 2
   set point light 2,-30,10,0
   color light 2,0,255,0
   fog on
   fog color rgb(128,128,128)
   fog distance 100.0
return


`PREPARE_MEDIA ================================================================
prepare_media:
   load object "mediademocube.x",2000
   position object 2000,5000,5000,5000
   hide object 2000

   load image "logo.png", 100000
   sprite 1, 0, 600 - 60, 100000
return







`PREPARE_PHYSICS_MATERIALS ====================================================
prepare_physics_materials:
   `'sticky' (sticky material with minimum bounce)
   phy make material 1,"sticky"
   phy set material dynamic friction 1,1.0
   phy set material static friction 1,1.0
   phy set material restitution 1,0.0
   phy build material 1

   `'hardrubber' (semi bouncy material high in friction)
   phy make material 2,"hardrubber"
   phy set material dynamic friction 2,0.0
   phy set material static friction 2,0.0
   phy set material restitution 2,1.0
   phy build material 2

   `'hardplastic' (fairly bouncy low friction rating)
   phy make material 3,"hardsmooth"
   phy set material dynamic friction 3,0.25
   phy set material static friction 3,0.25
   phy set material restitution 3,0.75
   phy build material 3
return




`PREPARE_SIMULTION ============================================================
prepare_simulation:
   `make a container shape out of boxes that acts like a kind
   `of square bowl to stop all our physics objects falling into
   `an empty space. this demonstrates the use if interpenetrating
   `static collision boxes.

   `make the floor object
   make object box 100,100,1.0,100.0
   position object 100,0.0,-0.5,0.0
   color object 100,rgb(248,248,248)
   phy make rigid body static box 100,3

   `make the wall object 1
   make object box 101,88,40.0,1.0
   position object 101,0.0,10.0,30
   xrotate object 101,45
   color object 101,rgb(248,248,248)
   phy make rigid body static box 101,3

   `make the wall object 2
   make object box 102,88,40.0,1.0
   position object 102,0.0,10.0,-30
   xrotate object 102,135
   color object 102,rgb(248,248,248)
   phy make rigid body static box 102,3

  `make the wall object 3
   make object box 103,1.0,40.0,88
   position object 103,30,10.0,0.0
   zrotate object 103,135
   color object 103,rgb(248,248,248)
   phy make rigid body static box 103,3

   `make the wall object 4
   make object box 104,1.0,40.0,88
   position object 104,-30,10.0,0.0
   zrotate object 104,45
   color object 104,rgb(248,248,248)
   phy make rigid body static box 104,3

   `make the wall object 4
   make object box 105,1.0,10,5
   position object 105,0.0,5.0,0.0
   color object 105,rgb(248,248,248)
   phy make rigid body static box 105,3


   `make a halfpipe construction out of planks with static collision boxes
   `this is to add more complexity to the simulation and show the versatility
   `of simple collision boxes making fairly complex collision structures.

   `prepare some variables for the construction of the halfpipe
   ang# = 90
   angstep# = 9.0
   radius# = 5.0
   first_plank = 1000.0
   plank_counter = 0
   for j = 1 to 40
      plank_counter = plank_counter + 1
      temp_x# = sin(ang#)*radius#
      temp_z# = cos(ang#)*radius#
      if j<22
         make object box first_plank+plank_counter,0.7,0.25,50.0
         position object first_plank+plank_counter,temp_x#,temp_z#+15.0,0.0
         roll object right first_plank+plank_counter,ang#
         roll object right first_plank+plank_counter,90
      endif
      `this code makes the roof sections of the pipe which is visible at
      `the both of the pipe, adding more complexity to the sene.
      if j => 22
         make object box first_plank+plank_counter,0.7,0.25,10.0
         position object first_plank+plank_counter,temp_x#,temp_z#+15.0,20.0
         roll object right first_plank+plank_counter,ang#
         roll object right first_plank+plank_counter,90
         plank_counter = plank_counter + 1
         make object box first_plank+plank_counter,0.7,0.25,10.0
         position object first_plank+plank_counter,temp_x#,temp_z#+15.0,-20.0
         roll object right first_plank+plank_counter,ang#
         roll object right first_plank+plank_counter,90
      endif
      ang# = wrapvalue(ang#)+angstep#
   next j
   for j = 1 to plank_counter
      phy make rigid body static box first_plank+j,3
   next j


   `here we make the objects to pour into our construction, they are simply
   `clones of a common DX 3d model. we also make the colum as a spiral to
   `keep it coherent as it falls and preventing force overload from overlapping
   `physics objects the first time PHY UPDATE is called.

   `prepare some variables to make our dynamic falling column of objects that
   `show us how the collision boxes really behave.
   ang# = 90
   angstep# = 72.0
   radius# = 3.5
   h# = 70.0
   for j = 2001 to 2301
      clone object j,2000
      color object j,rgb(rnd(255),rnd(255),rnd(255))
      scale object j,125,125,125
      h# = h# + 1.0
      temp_x# = sin(ang#)*radius#
      temp_z# = cos(ang#)*radius#
      position object j,temp_x#,h#,temp_z#
      phy make rigid body dynamic box j,3
      ang# = wrapvalue(ang#)+angstep#
   next j
return




`PLAY_SIMULATION ==============================================================
play_simulation:
   repeat
      phy update
      sync
   until spacekey() = 1
return

` this example demonstrates the use of kinematic objects

` set up the program
sync on
sync rate 60
phy start
autocam off
position camera -20,20,-25
point camera 0,10,0
make light 1
set directional light 1, -5,-5,5

` create the background
load image "stripe5.png",1000
make object sphere 1000,400,48,48
texture object 1000,1000
scale object texture 1000,6,6
set object cull 1000,0
rotate object 1000,0,0,90

` make the floor
load image "stripe6.png", 3
make object box 1,40,1,40
phy make rigid body static box 1
texture object 1, 3

` create first dynamic box
make object box 2,5,5,5
position object 2,-12,3,0
phy make rigid body dynamic box 2

` create second dynamic box
make object box 3,5,5,5
position object 3,12,3,0
phy make rigid body dynamic box 3

` create third dynamic box and make this one kinematic
make object box 4,5,5,5
position object 4,0,6,0
phy make rigid body dynamic box 4
phy set rigid body kinematic 4, 1

` create fourth dynamic box
make object box 5,5,5,5
position object 5,0,24,0
phy make rigid body dynamic box 5

` colour all of our objects
for i = 2 to 6
   if object exist ( i )
      color object i, rgb ( rnd ( 255 ), rnd ( 255 ), rnd ( 255 ) )
      set object specular i, rgb ( rnd ( 255 ), rnd ( 255 ), rnd ( 255 ) )
      set object specular power i, 255
      set object ambient i,0
   endif
next i

` display the Dark Physics logo
load image "logo.png", 10000
sprite 1, 0, 600 - 60, 10000

` some variables we use in the main loop
x# = 0
move = 0

` main program loop
do
   ` adjust the position of the kinematic object on the x axis
   if move = 0
      x# = x# - 0.1

      if x# < -10
         move = 1
      endif
   endif

   if move = 1
      x# = x# + 0.1

      if x# > 10
         move = 0
      endif
   endif

   ` control the position of the kinematic object
   phy set rigid body kinematic position 4, x#, 6, 0

   ` rotate the background
   rotate object 1000, 0, object angle y( 1000 ) + 0.3, 0

   ` update the simulation and screen
   phy update
   sync
loop

` show how mass settings alter behaviours of rigid bodies

` program set up
phy start
autocam off
sync on
sync rate 60
color backdrop 0
position camera 0, 20, -100

` create background sphere
load image "stripe5.png",8
make object sphere 800,400,48,48
texture object 800,8
scale object texture 800,6,6
set object cull 800,0

x# = -100

make object box 1, 80, 1, 50
texture object 1, 1
phy make rigid body static box 1
texture object 1, 8

` create rigid body with mass on left
make object box 2, 50, 5, 5
position object 2, -26, 10, 0
phy make rigid body dynamic box 2
phy set rigid body mass offset local 2, -50, 0, 0

` create rigid body with mass in centre ( default )
make object box 3, 50, 5, 5
position object 3, 26, 10, 0
phy make rigid body dynamic box 3

` the dark physics logo is loaded and displayed with a sprite
load image "logo.png", 100000
sprite 1, 0, 600 - 60, 100000

` now we get to our main program loop
do
   set cursor 0, 0
   print ""
   print "Demonstrates how the position of mass in a rigid body alters its behaviour"
   print "Object on left has its centre of mass on its far left side"
   print "Object on right has its centre of mass in the centre of the box"

   ` now we update the physics simulation and the screen
   phy update
   sync
loop

` demonstrates how to move an object around a scene

` we begin by starting the physics process and setting some initial
` properties of the application, such as sync rate and camera position
phy start
autocam off
sync on
sync rate 60
color backdrop 0
position camera 0, 20, -100

rem stripe textures
load image "stripe5.png",8
make object sphere 8,400,48,48
texture object 8,8
scale object texture 8,6,6
set object cull 8,0
load image "stripe6.png",1

` a box is made to represent our floor object
make object box 1, 150, 1, 150
texture object 1,1
phy make rigid body static box 1

` a cube is created and positioned on top of the floor over to the left
make object cube 2, 10
position object 2, 0, 10, 0
phy make rigid body dynamic box 2
phy set rigid body gravity 2, 0

` the dark physics logo is loaded and displayed with a sprite
load image "logo.png", 100000
sprite 1, 0, 600 - 60, 100000

position camera 0, 180, 0
rotate camera 90, 0, 0

` now we get to our main program loop
do
   set cursor 0, 0
   print "Demonstration of controlling rigid bodies movement"
   print "Move the rigid body box around with the arrow keys"

   ` turn left
   if leftkey ( ) = 1
      phy set rigid body angular velocity 2, 0, -1.0, 0
   endif

   ` turn right
   if rightkey ( ) = 1
      phy set rigid body angular velocity 2, 0, 1.0, 0
   endif

   ` apply force
   if upkey ( ) = 1
      phy add rigid body local force 2, 1000, 0, 0, 5
   endif

   ` stop linear momentum
   phy set rigid body linear momentum 2, 0.0, 0.0, 0.0

   ` now we update the physics simulation and the screen
   phy update

   ` reset angular velocity
   phy set rigid body angular velocity 2, 0.0, 0.0, 0.0

   sync
loop

`xDarkPhysics Demo / Example Code.x
`xXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXx





`### prepare the display for use
backdrop on
color backdrop rgb(0,0,0)
fog on
fog distance 750.0
fog color rgb(0,0,0)
autocam off
sync on
sync rate 60


`### prepare the camera
position camera 0.0,35.0,-40.0
point camera 0.0,10.0,0.0


`### prepare the lighting
set directional light 0,-1,-1,1


`### load any textures needed
load image "medialogo.png",1
load image "mediaskydome.png",2
load image "mediafloor.png",3
load object "mediapencil.X",30002
load object "mediatumbler.x",30003
position object 30002,1000,1000,1000
hide object 30002

disable object zwrite 30003
ghost object on 30003
fade object 30003,250
set sphere mapping on 30003,3
set object smoothing 30003,75

`### make a skydome or skysphere (non physics)
make object sphere 30000,1000,48,48
texture object 30000,2
scale object texture 30000,6,6
set object cull 30000,0
fade object 30000,250.0
set sphere mapping on 30000,2



`### start the physics engine
phy start
phy set gravity 0.0,-27.0,0.0


`### define physics materials
phy make material 1,"hardrubber"
phy set material static friction 1,0.25
phy set material dynamic friction 1,0.25
phy set material restitution 1,0.5
phy build material 1

phy make material 2,"hardwood"
phy set material static friction 2,0.4
phy set material dynamic friction 2,0.4
phy set material restitution 2,0.2
phy build material 2

phy make material 3,"concrete"
phy set material static friction 3,0.75
phy set material dynamic friction 3,0.75
phy set material restitution 3,0.1
phy build material 3


`### make the ground object (physics object)
make object box 30001,100.0,2.0,100.0
position object 30001,0.0,-1.0,0.0
texture object 30001,3
scale object texture 30001,3,3
phy make rigid body static box 30001,1

offset limb 30003, 1, 0.0, 11.0, 0.0
phy make rigid body static mesh 30003,3




`### build the demo scene
demo_quit = 0

f_pencil = 100

for j = 1 to 100
   clone object f_pencil+j,30002
   position object f_pencil+j,rnd(25)-12,rnd(100)+25,rnd(25)-12
   rotate object f_pencil+j,rnd(10),rnd(10),rnd(10)
   phy make rigid body dynamic capsule f_pencil+j,1
   phy set rigid body max angular velocity f_pencil,2.0
next j



load image "logo.png", 100000
sprite 1, 0, 600 - 60, 100000



`the demo main loop
repeat
   turn object left 30000,0.25
   phy update
   sync
until quit_demo = 1

` in this program we look at the process of loading static meshes
` and how this can benefit from using a pre process step of saving
` data to file and then reloading

` start the simulation and set the sync ratr
phy start
backdrop off

` load our dbo model
set dir "cave"
load object "cavelit.dbo", 1
set dir ".."

` create a regular static mesh and take note of the time
cls
print "We are going to create a static mesh by calling the"
print "command 'phy make rigid body static mesh' and passing"
print "in the ID number from our level model which is 1"

time = timer ( )
phy make rigid body static mesh 1
newtime = timer ( )
attempt1 = newtime - time

print ""
print "This process has taken " + str$ ( attempt1 ) + " ms"
print ""
print "Press any key to continue..."
phy delete rigid body 1
wait key

` this time save the rigid body mesh
cls
print "We are going to create a static mesh by calling the"
print "command 'phy make rigid body static mesh' with the"
print "difference being this time we will pass in a filename"
print "which will save out the mesh data"

time = timer ( )
phy make rigid body static mesh 1, "cave.mesh"
newtime = timer ( )
attempt2 = newtime - time

print ""
print "This process has taken " + str$ ( attempt2 ) + " ms"
print ""
print "Press any key to continue..."
phy delete rigid body 1
wait key

` now that the data has been saved we can load it in
cls
print "As the mesh data has been saved out to file we can"
print "load it in. This will be significantly faster. We"
print "use the command 'phy load rigid body static mesh'"
print "for this and pass in the filename of the file that"
print "has just been saved"

time = timer ( )
phy load rigid body static mesh 1, "cave.mesh"
newtime = timer ( )
attempt3 = newtime - time

print ""
print "This process has taken " + str$ ( attempt3 ) + " ms"
print ""
print "Press any key to continue..."
phy delete rigid body 1
wait key

` lets recap on all the data
cls
print "We have seen three methods of making static meshes"
print "The first approach was to make a regular static mesh"
print "The second approach was to make a mesh and save the data"
print "The third approach was to load the saved data"
print ""
print "Method 1 took " + str$ ( attempt1 ) + " ms"
print "Method 2 took " + str$ ( attempt2 ) + " ms"
print "Method 3 took " + str$ ( attempt3 ) + " ms"
print ""
print "What this demonstrates is that by pre processing meshes"
print "you can reduce the loading time significantly"
print ""
print "It is recommended to save out mesh data first while"
print "developing and then when your mesh is final simply"
print "load the file each time instead of recalculating it"
print ""
print "Press any key to end the demo..."
wait key

` in this example we look at how to remove objects from
` the simulation for a short while, this can be useful
` for many scenarios

phy start
autocam off
sync on
sync rate 60
color backdrop 0
position camera 0, 20, -100

` create background sphere
load image "stripe5.png",8
make object sphere 800,400,48,48
texture object 800,8
scale object texture 800,6,6
set object cull 800,0

` ground object
make object box 1, 50, 1, 50
texture object 1, 1
phy make rigid body static box 1
texture object 1, 8

` make the first row of cubes
x# = -100

for i = 2 to 100
   make object cube i, 5
   position object i, x#, 40, 0
   color object i, rgb ( rnd ( 255 ), rnd ( 255 ), rnd ( 255 ) )
   set object specular i, rgb ( rnd ( 255 ), rnd ( 255 ), rnd ( 255 ) )
   set object specular power i, 255
   set object ambient i, 0
   phy make rigid body dynamic box i
   phy set rigid body mass i, 0.00001
   x# = x# + 5
next i

x# = -100

` make the second row of cubes higher up
for i = 101 to 200
   make object cube i, 5
   position object i, x#, 60, 0
   phy make rigid body dynamic box i
   x# = x# + 5
next i

` color all objects
for i = 1 to 200
   color object i, rgb ( rnd ( 255 ), rnd ( 255 ), rnd ( 255 ) )
   set object specular i, rgb ( rnd ( 255 ), rnd ( 255 ), rnd ( 255 ) )
   set object specular power i, 255
   set object ambient i, 0
next i

` display Dark Physics logo
load image "logo.png", 100000
sprite 1, 0, 600 - 60, 100000

` disable flag
disable = 1

` now we get to our main program loop
do
   set cursor 0, 0
   print ""
   print "Demonstrates how to temporarily remove objects from the simulation"
   print "The top row is enabled while the bottom row is disabled"
   print "The top row will fall down and go straight through the bottom row"
   print "Press space to enable the bottom row"

   ` make the bottom row go to sleep
   if disable = 1
      for i = 2 to 100
         phy sleep rigid body i
         phy set rigid body group i, 2
         phy set group collision 2, 0, 0
      next i
   endif

   ` wake up the bottom row
   if spacekey ( )
      for i = 2 to 100
         phy wake up rigid body i
         phy set rigid body group i, 0
      next

      disable = 0
   endif

   ` now we update the physics simulation and the screen
   phy update
   sync
loop

` in this example program we see how restitution affects objects

` set up the program
phy start
autocam off
sync on
sync rate 60
color backdrop 0
position camera 0, 20, -70

rem stripe textures
load image "stripe5.png",8
make object sphere 8,400,48,48
texture object 8,8
scale object texture 8,6,6
set object cull 8,0
load image "stripe6.png",1

` create our ground object
make object box 1, 50, 1, 50
texture object 1,1
phy make rigid body static box 1

` make a bouncy material
phy make material 1, "very bouncy"
phy set material restitution 1, 1.0
phy build material 1

` make a less bouncy material
phy make material 2, "less bouncy"
phy set material restitution 2, 0.5
phy build material 2

` and finally a material with no bounce
phy make material 3, "no bounce"
phy set material restitution 3, 0.0
phy build material 3

` create sphere with bouncy material
make object sphere 2, 5
position object 2, -20, 30, 0
phy make rigid body dynamic sphere 2, 1

` create sphere with less bouncy material
make object sphere 3, 5
position object 3, 0, 30, 0
phy make rigid body dynamic sphere 3, 2

` create sphere with no bounce material
make object sphere 4, 5
position object 4, 20, 30, 0
phy make rigid body dynamic sphere 4, 3

` colour all objects
for i = 2 to 4
   color object i, rgb ( rnd ( 255 ), rnd ( 255 ), rnd ( 255 ) )
   set object specular i, rgb ( rnd ( 255 ), rnd ( 255 ), rnd ( 255 ) )
   set object specular power i, 255
   set object ambient i, 0
next i

load image "logo.png", 100000
sprite 1, 0, 600 - 60, 100000

do
   center text object screen x ( 2 ), object screen y ( 2 ) - 40, "very bouncy"
   center text object screen x ( 3 ), object screen y ( 3 ) - 40, "less bouncy"
   center text object screen x ( 4 ), object screen y ( 4 ) - 40, "no bounce"

   phy update
   sync
loop

` in this program we see how to get information
` back from rigid bodies such as their velocity

` set up the program
phy start
autocam off
sync on
sync rate 60
color backdrop 0
position camera 0, 20, -100

rem stripe textures
load image "stripe5.png",8
make object sphere 8,400,48,48
texture object 8,8
scale object texture 8,6,6
set object cull 8,0
load image "stripe6.png",1

` create the ground
make object box 1, 1500, 1, 1500
texture object 1,1
scale object texture 1,8,8
phy make rigid body static box 1

` set up a dynamic sphere
make object sphere 2, 15
position object 2, 0, 15, 0
phy make rigid body dynamic sphere 2

` colour both objects
for i = 2 to 2
   color object i, rgb ( rnd ( 255 ), rnd ( 255 ), rnd ( 255 ) )
   set object specular i, rgb ( rnd ( 255 ), rnd ( 255 ), rnd ( 255 ) )
   set object specular power i, 255
   set object ambient i, 0
next i

` display Dark Physics logo
load image "logo.png", 100000
sprite 1, 0, 600 - 60, 100000

` main program loop
do
   ` add a force when the space key is pressed
   if spacekey ( ) = 1
      phy add rigid body force 2, 1000000, 1000000, 1000000, 0
   endif

   ` display information
   set cursor 0, 0
   print ""
   print "Press the space bar to apply force to the object"
   print ""
   print "Information about object:"
   print ""
   print "Point Velocity   X = " + str$ ( phy get rigid body point velocity x ( 2, object position x ( 2 ), object position y ( 2 ), object position z ( 2 ) ) )
   print "Point Velocity   Y = " + str$ ( phy get rigid body point velocity y ( 2, object position x ( 2 ), object position y ( 2 ), object position z ( 2 ) ) )
   print "Point Velocity   Z = " + str$ ( phy get rigid body point velocity z ( 2, object position x ( 2 ), object position y ( 2 ), object position z ( 2 ) ) )
   print ""
   print "Momentum         X = " + str$ ( phy get rigid body linear momentum x ( 2 ) )
   print "Momentum         Y = " + str$ ( phy get rigid body linear momentum y ( 2 ) )
   print "Momentum         Z = " + str$ ( phy get rigid body linear momentum z ( 2 ) )
   print ""
   print "Angular Velocity X = " + str$ (  phy get rigid body angular velocity x ( 2 ) )
   print "Angular Velocity Y = " + str$ (  phy get rigid body angular velocity y ( 2 ) )
   print "Angular Velocity Z = " + str$ (  phy get rigid body angular velocity z ( 2 ) )
   print ""

   ` update the simulation and screen
   phy update
   sync
loop

` this program demonstrates the differences between convex
` meshes and representing an object with a box

phy start
autocam off
sync on
sync rate 60
color backdrop 0
position camera 0, 20, -50
phy set gravity 0, -9.8 * 3, 0

make object box 1, 150, 1, 150
phy make rigid body static box 1

load image "logo.png", 100000
sprite 1, 0, 0, 100000

load object "convex1.x", 2
position object 2, -10, 5, 0
phy make rigid body static convex 2

load object "convex1.x", 3
position object 3, 10, 5, 0
phy make rigid body static box 3

x# = -8
y# = 30

for i = 4 to 80
   make object sphere i, 2.5
   position object i, x#, y#, 0
   phy make rigid body dynamic sphere i

   if i = 20
      x# = -12
      y# = 30
   endif

   if i = 40
      x# = 8
      y# = 30
   endif

   if i = 60
      x# = 12
      y# = 30
   endif

   y# = y# + 5
next i

set object wireframe 2, 1
set object wireframe 3, 1

for i = 1 to 80
   if object exist ( i )
      color object i, rgb ( rnd ( 255 ), rnd ( 255 ), rnd ( 255 ) )
      set object specular i, rgb ( rnd ( 255 ), rnd ( 255 ), rnd ( 255 ) )
      set object specular power i, 255
      set object ambient i, 0
   endif
next i

load image "stripe5.png",1
make object sphere 600,400,48,48
texture object 600,1
scale object texture 600,6,6
set object cull 600,0

do
   rotate object 600, object angle x ( 600 ) + 0.01, object angle y( 600 ) - 0.05, object angle z ( 600 ) + 0.03

   phy update
   sync
loop

` example of placing dynamic objects inside a dynamic mesh

` set up program
backdrop on
color backdrop rgb(0,0,0)
fog on
fog distance 750.0
fog color rgb(0,0,0)
autocam off
sync on
sync rate 60

`### prepare the camera
position camera 0.0,15,-50.0
point camera 0.0,10.0,0.0

`### prepare the lighting
set directional light 0,-1,-1,1

`### load any textures needed
load image "medialogo.png",1,1
load image "mediaskydome.png",2
load image "mediafloor.png",3
load object "mediahollowtorus.x",30003
position object 30003,0.0,50.0,0.0
disable object zwrite 30003
ghost object on 30003
set sphere mapping on 30003,2
set object smoothing 30003,75.0
set object cull 30003,0
set object wireframe 30003,1

`### make a skydome or skysphere (non physics)
make object sphere 30000,1000,48,48
texture object 30000,2
scale object texture 30000,6,6
set object cull 30000,0
fade object 30000,250.0
set sphere mapping on 30000,2
set object light 30000, 0

`### start the physics engine
phy start
phy set gravity 0.0,-29.4,0.0
phy set continuous cd 1.0

`### define physics materials
phy make material 1,"hardrubber"
phy set material static friction 1,0.25
phy set material dynamic friction 1,0.25
phy set material restitution 1,0.5
phy build material 1

`### make the ground object (physics object)
make object box 30001,100.0,2.0,100.0
position object 30001,0.0,-1.0,0.0
texture object 30001,3
scale object texture 30001,3,3
ghost object on 30001
phy make rigid body static box 30001,1

st# = 15.0
tt# = 0.0

for j = 1 to 40
   make object sphere j,3.0
   position object j,sin(tt#)*10.0,50.0,cos(tt#)*10.0
   color object j, rgb ( rnd ( 255 ), rnd ( 255 ), rnd ( 255 ) )
   set object specular j, rgb ( rnd ( 255 ), rnd ( 255 ), rnd ( 255 ) )
   set object specular power j, 255
   set object ambient j, 0
   tt# = tt# + st#
   phy make rigid body dynamic sphere j,1
next j

` create a dynamic mesh for the torus
phy make rigid body dynamic mesh 30003,1

` spin the torus as it falls
phy set rigid body angular velocity 30003,1.0,1.0,1.0

` display Dark Physics logo
load image "logo.png", 100000
sprite 1, 0, 0, 100000

`the demo main loop
repeat
   turn object left 30000,0.25
   if spacekey()=1
      phy set rigid body linear velocity 30003,0.0,20.0,0.0
   endif
   phy update
   sync
until quit_demo = 1

`DarkPhysics Demo / twistedpipe
`XXXXXXXXXXXXXXXXXXXXXXXXXXXXXX





`### prepare the display for use
`set display mode 800,600,32,1
backdrop off
color backdrop rgb(0,0,0)
draw sprites last
autocam off
sync on
sync rate 60




`### prepare the camera
cam_orbit# = 50.0
cam_position# = 0.0
cam_speed# = 0.25

cam_vorbit# = 25.0
cam_vposition# = 0.0
cam_vspeed# = 0.37




`### load any textures needed
load image "medialogo.png",1,1
load image "mediaskydome.png",2
load image "mediafloor.png",3
load object "mediatwistpipe.x",1000
sprite 1,0,0,1
hide sprite 1





`### make a skydome or skysphere (non physics)
make object sphere 30000,1000,48,48
texture object 30000,2
disable object zwrite 30000
set alpha mapping on 30000,50.0
set object cull 30000,0
fade object 30000,250




`### start the physics engine
phy start
phy set gravity 0.0,-18.8,0.0
phy set continuous cd 1.0




`### define physics materials
phy make material 1,"hardrubber"
phy set material static friction 1,0.75
phy set material dynamic friction 1,0.75
phy set material restitution 1,0.75
phy build material 1

phy make material 2,"glass"
phy set material static friction 2,0.1
phy set material dynamic friction 2,0.1
phy set material restitution 2,0.25
phy build material 2

phy make material 3,"concrete"
phy set material static friction 3,0.75
phy set material dynamic friction 3,0.75
phy set material restitution 3,0.1
phy build material 3




`### build the demo scene
position object 1000,0.0,0.0,0.0
scale object 1000,250.0,250.0,250.0
disable object zwrite 1000
ghost object on 1000
set sphere mapping on 1000,2
set object smoothing 1000,75.0
fade object 1000,250.0
set object cull 1000,0
phy make rigid body static mesh 1000,2

first = 100
max = 150

`spit the ball into the scene one by one seperated by a delay of 6 frames
j = 1
repeat
   gosub update_camera
   if sdelay > 0 : sdelay = sdelay - 1 : endif
   if sdelay = 0
      if t = 0
         make object sphere first+j,6.5
         position object first+j,rnd(2.0)+18.0,200.0,rnd(2.0)+19.0
         texture object first+j,2
         set object specular first+j,rgb(rnd(128)+127,rnd(128)+127,rnd(128)+127)
         set object specular power first+j,255
         set sphere mapping on first+j,3
         fade object first+j,5000.0
         phy make rigid body dynamic sphere first+j,2
      endif
      if t = 1
         make object cube first+j,2.0
         position object first+j,rnd(2.0)+18.0,200.0,rnd(2.0)+19.0
         phy make rigid body dynamic box first+j,2
      endif
      phy set rigid body linear velocity first+j,0.0,-60.0,0.0
      sdelay = 6
      j = j + 1
   endif
   phy update
   sync
until j = max+1









demo_quit = 0
wire = 0


`the demo main loop
repeat
   gosub update_camera
   gosub update_falling_objects
   gosub update_master_object
   phy update
   sync
until quit_demo = 1


`SUBROUTINES ==================================================================


update_camera:
   cam_position# = wrapvalue(cam_position#+cam_speed#)
   cam_vposition# = wrapvalue(cam_vposition#+cam_vspeed#)
   cam_x# = sin(cam_position#)*cam_orbit#
   cam_z# = cos(cam_position#)*cam_orbit#
   cam_y# = sin(cam_vposition#)*cam_vorbit#
   position camera cam_x#,cam_y#,cam_z#
   point camera 0.0,0.0,0.0
return


update_falling_objects:
   for j = 1 to max
      if object position y(first+j) < -300.0
         phy set rigid body position first+j,rnd(2.0)+18.0,j+200.0,rnd(2.0)+19.0
         phy set rigid body linear velocity first+j,0.0,-60.0,0.0
         phy set rigid body angular velocity first+j,0.0,0.0,0.0
      endif
   next j
return


update_master_object:
   if swap_counter > 0 : swap_counter = swap_counter - 1 : endif
   swap_done = 0
   if swap_counter = 0
      if swap_done = 0
         if wire = 0
            set object wireframe 1000,1
            swap_done = 1
            wire = 1
         endif
      endif
      if swap_done = 0
         if wire = 1
            set object wireframe 1000,0
            swap_done = 1
            wire = 0
         endif
      endif
      swap_counter = 240
   endif
return

sync on: sync rate 60
autocam off
position camera 0,1,-12
point camera 0,0,0
phy start

rem Make a Wheel

wheel = 97
wheelmount1 = 98
wheelmount2 = 99
paddle = 100
paddleLen# = 20
paddleWidth# = 4
paddleDepth# = 0.5
steps = 60

make object box wheel, 2,2,20
position object wheel, 0,0,10
phy make rigid body dynamic box wheel
make object box wheelmount1, 1,1,1
position object wheelmount1, 0,0,20.5
phy make rigid body Static box wheelmount1
phy make cylindrical joint wheel, wheel, wheelmount1, object position x(wheelmount1), object position y(wheelmount1), object position z (wheelmount1), 0, 0, 1
make object box wheelmount2, 1,1,1
position object wheelmount2, 0,0,-0.5
phy make rigid body Static box wheelmount2

phy make cylindrical joint wheel+1, wheel, wheelmount2, object position x(wheelmount2), object position y(wheelmount2), object position z (wheelmount2), 0, 0, 1

for n = 0 to 359 step steps
   obj = paddle + (n / steps)
   make object box obj, paddleWidth#, paddleDepth#, PaddleLen#
   position object obj, object position x(wheel) + cos(n) * 4, object position y(wheel) + sin(n) * 4 , 10
   zrotate object obj, n
   phy make rigid body dynamic box obj
   phy make fixed joint obj, obj, wheel
next n

for n = 1000 to 2000
   make object sphere n, (rnd(10) / 10) + 1
   color object n, rgb(rnd(255), rnd(255), rnd(255))
   set object ambient n, 0
   position object n, 4 - (rnd(30) / 10),  20 + rnd(2000) / 10, (rnd(100) / 10)
   phy make rigid body dynamic sphere n
next n

load image "logo.png", 100000
sprite 1, 0, 0, 100000

` set up the background
load image "stripe5.png",1
make object sphere 600,400,48,48
texture object 600,1
scale object texture 600,6,6
set object cull 600,0

` create ground object
make object box 1, 50, 1, 50
position object 1, 0, -20, 0
phy make rigid body static box 1
color object 1, rgb(rnd(255), rnd(255), rnd(255))
set object ambient 1, 0

move camera -10

do
   phy update

   CONTROL CAMERA USING ARROWKEYS 0,0.1,0.1
   sync
loop

` demonstrates simple creation of a vehicle

` set up program
phy enable debug
phy start
autocam off
sync on
sync rate 60
color backdrop 0
make light 1
set directional light 1, -5, -5, 5
position camera -20, 20, -25
point camera 0, 10, 0

` create ground
load image "road2.png", 1
make object box 1, 1000, 1, 1000
texture object 1, 1
phy make rigid body static box 1

` load car
load object "beach.x", 2
load image "beachBu2.tga",2
load image "dbprocubemap.dds",3
texture object 2,2
set blend mapping on 2,1,3,2,16
position object 2, 15, 2, -25
rotate limb 2,0,0,-90,0

` set up vehicle
phy create vehicle 2
phy add vehicle body 2, 2.2, 0.6, 0.75, 0.0, 0.6, 0.0
phy add vehicle wheel 2, 5,  1.5, 0.3,  1.1, 0.6, 0.2, 0, 0
phy add vehicle wheel 2, 7,  1.5, 0.3, -1.1, 0.6, 0.2, 0, 1
phy add vehicle wheel 2, 3, -1.5, 0.3, -1.1, 0.6, 0.2, 1, 0
phy add vehicle wheel 2, 9, -1.5, 0.3,  1.1, 0.6, 0.2, 1, 1
phy set vehicle max motor 2, 200.0
phy set vehicle steering delta 2, 0.1
phy set vehicle max steering angle 2, 0.4
phy set vehicle auto 2, 1
phy set vehicle suspension spring 2,100
phy build vehicle 2

` display image
load image "logo.png", 100000
sprite 1, 0, 600 - 60, 100000

` main loop
do
   ` follow car
   set camera to follow object position x ( 2 ), object position y ( 2 ), object position z ( 2 ), 0, 6, 4, 1, 0

   ` update physics and screen
   phy update
   sync
loop

rem Vehicle Physics

rem Init
phy enable debug
phy start
sync on : sync rate 60
autocam off : color backdrop 0

rem Lights and camera
make light 1 : set directional light 1, -5, -5, 5
position camera -20, 20, -25 : point camera 0, 10, 0
set camera fov 90

rem Load scene
set dir "Scene"
load object "levelbanktestleveluniverse.dbo",1
scale object 1,10,10,10 : phy make rigid body static mesh 1
set dir ".."

rem Load buggy
load object "beach.x", 2
load image "beachBu2.tga",2
load image "dbprocubemap.dds",3
texture object 2,2 : set blend mapping on 2,1,3,2,16
position object 2, 15, 4, -25
offset limb 2,0,0,-0.5,0
rotate limb 2,0,0,-90,0

rem Create vehicle physics body
width# = 0.75
height# = 0.4
length# = 2.2
wheelX# = 1.1
wheelY# = 0.3
wheelZ# = 1.5
radius# = 0.6
wheelHeight# = 0.2

rem Be aware the vehicle width and length orientation
phy create vehicle 2
phy add vehicle body 2, length#, height#, width#, 0.0, height#, 0.0
phy add vehicle body 2, width#, height#, width#, 0.0, height#*2, 0.0
phy add vehicle wheel 2, 5,  wheelZ#, wheelY#,  wheelX#, radius#, wheelHeight#, 0, 0
phy add vehicle wheel 2, 7,  wheelZ#, wheelY#, -wheelX#, radius#, wheelHeight#, 0, 1
phy add vehicle wheel 2, 3, -wheelZ#, wheelY#, -wheelX#, radius#, wheelHeight#, 1, 0
phy add vehicle wheel 2, 9, -wheelZ#, wheelY#,  wheelX#, radius#, wheelHeight#, 1, 1
phy set vehicle max motor 2, 200.0
steeringDelta# = 0.1 : phy set vehicle steering delta 2, steeringDelta#
phy set vehicle max steering angle 2, 0.4
phy set vehicle auto 2, 0
phy set vehicle wheel multiplier 2,0
phy set vehicle suspension spring 2,100
phy build vehicle 2

rem follower object invisible
make object sphere 3,10 : hide object 3

rem Load logo sprite
load image "logo.png", 100000
sprite 1, 0, 600 - 60, 100000

` movement
g_fSpeed# = 0.05
g_fTurn#  = 0.3

rem Main
do
 rem Follow buggy
 position object 3,object position x(2),object position y(2),object position z(2)
 set object to object orientation 3,2
 move object 3,-100
 point object 3,object position x(2),object position y(2),object position z(2)
 dist#=5.0 : high#=2.5 : angle#=object angle y(3)+90
 set camera to follow object position x(2), object position y(2), object position z(2), angle#, dist#, high#, 1, 0
 `
 rem Control buggy
 phy set vehicle motor force 2,0.0
gosub driveCar
 `
 rem Update physics and screen
 phy update
 sync
 `
loop


driveCar:
 `
 rem movement
 key = 0
 if upkey ( ) = 1 then phy set vehicle motor force 2,300 : key = 1 : phy set vehicle wheel multiplier 2,50
 if downkey ( ) = 1 then phy set vehicle motor force 2,-200.0 : key = 1 : phy set vehicle wheel multiplier 2,-50
 if key = 0 then phy set vehicle motor force 2, 0.0
 `
 rem steering
 steeringAngle# = phy get vehicle steering angle ( 2 )
 steeringDelta# = 0.25
 key = 0
 if keystate ( 205 ) = 1
  if steeringAngle# > ( -1.0 + steeringDelta# )
   steeringAngle# = steeringAngle# - ( steeringDelta# / 2 )
  endif
  key = 1
 endif
 if keystate ( 203 ) = 1
  if steeringAngle# < ( 1.0 - steeringDelta# )
   steeringAngle# = steeringAngle# + ( steeringDelta# / 2 )
  endif
  key = 1
 endif
 if key = 0
  if steeringAngle# > 0.0
   steeringAngle# = steeringAngle# - steeringDelta# * 2
   if steeringAngle# < 0
    steeringAngle# = 0.0
   endif
  endif
  if steeringAngle# < 0.0
   steeringAngle# = steeringAngle# + steeringDelta# * 2
   if steeringAngle# > 0
    steeringAngle# = 0.0
   endif
  endif
 endif
 phy set vehicle steering angle 2, steeringAngle#
 phy set vehicle steering value 2, -( steeringAngle# * 45 )
 `
return

` collision feedback

` set up the program
phy start
autocam off
sync on
sync rate 60
color backdrop 0
position camera 0, 20, -40

` create the ground object
make object box 1, 50, 1, 50
phy make rigid body static box 1

` make and position 3 cubes
make object cube 2, 5
make object cube 3, 5
make object cube 4, 5

position object 2, 0, 10, 0
position object 3, 2, 20, 0
position object 4, 3, 30, 0

phy make rigid body static box 2
phy make rigid body dynamic box 3
phy make rigid body dynamic box 4

` display the Dark Physics logo
load image "logo.png", 100000
sprite 1, 0, 600 - 60, 100000

` main program loop
do
   ` display information
   set cursor 0, 0
   print "Example demonstrating how to determine when collisions have taken place"
   print "When objects 3 and 4 collide object 3 will turn red and object 4 will turn green"
   print "When any object hits object 2 it will turn yellow"
   print "When any object hits the floor it will turn blue"

   ` extract collision data
   while phy get collision data ( )
      a = phy get collision object a ( )
      b = phy get collision object b ( )

      ` react when objects 3 and 4 collide
      if a = 3 and b = 4
         color object 3, rgb ( 255, 0, 0 )
         color object 4, rgb ( 0, 255, 0 )
      endif

      ` react when one of the objects hit object 2
      if a = 2 or b = 2
         color object 2, rgb ( 255, 255, 0 )
      endif

      ` react when any of the objects hit the floor
      if a = 1 or b = 1
         color object 1, rgb ( 0, 0, 255 )
      endif
   endwhile

   phy update
   sync
loop