Sorry your browser is not supported!

* Additional Message Commands (for Contacts)
* Ball-in-socket joints
* Hinge joints
* Slider joints
* Fixed joints
* Universal joints
* Hinge2 joints
* Angular motor joints
* Linear motor joints
* PR joints
* PU joints
* Piston joints
* Plane2D joints(not fully implemented, I wouldn't use this
quite yet)
* Additional Parameter for triangle Mesh to use a different
object's data on a different object. Useful for low poly
collision meshes.

---- Update Log ----
--------------------

* Note: I decided to keep an update log starting from v0.3.2, to keep track
of things I changed. Things added before I kept record are the joint functions.

- v0.5.0 -

* Added Static and Dynamic Capsules
* Changed ODE SET BODY MASS to ODE SET BODY TOTAL MASS
* Added extra mass functions, ODE SET BODY MASS CENTER/ROTATION and ODE SET BODY
  MASS BOX/CYLINDER/SPHERE/TRIANGLE MESH/CAPSULE

- v0.5.0 rc3 -

* Organized Code into seperate h/cpp and classes and added seperate configurations
  for future possiblity of compiling it to dgdk/dbc and fpsc (none working yet).
* Added ODE SET WORLD CONTACT SURFACE LAYER and ODE SET AUTO DISABLE Commands.
* Added ODE CREATE STATIC SPHERE and STATIC TRIANGE MESH with optional Geom
  Object parameter.

- v0.5.0 rc2 -

* Added Ode Enable/Disable Body to forcably enable/disable objects. When Objects
  come to a complete rest in ode they auto-disable to save cpu.
* Added Ode Enable/Disable Joint, basically same as above but on joints.

- v0.5.0 rc1 -

* Fixed Ode Attach Joint, now allows 0 in object params which allows dettaching
  from objects (both are 0) and attaching one object to the static environment
  (obj, 0).
* Fixed Ode Get Joint Body so if it is attached to static environment it returns
  0.
* Fixed Ode Plane2D Joint so its useable now.
* Added Joint Motor Params set and get functions for all joints.

- v0.4.0 -

* Fixed Dynamic Cylinder so it rotates and uses the actual Cylinder class rather
  than a Sphere and Cube(Lee's workaround at the time).
* Now uses the Oct '06 DirectX SDK(like DBP) rather than the Aug '07 SDK.
* Added Raycasting support, ODE RAYCAST and a number of supporting get functions.
* Fixed commands returning floats so it returns the correct value (it should at
  least).
* Changed some of the command parameter names (from angle->anum) to more accurately
  show what it wants and/or to be consistant with other commands.

- v0.4.0 rc3 -

* Added four new commands ODE FIND FREE JOINT, ODE FIND FREE JOINT GROUP,
  ODE JOINT EXISTS, and ODE JOINT GROUP EXISTS.
* Fixed a few problems with the keywords file, all commands should highlight
  correctly now.

- v0.4.0 rc2 -

* Fixed Ode Destroy Joint Group & Destroy Joint.
* Fixed the Euler to Matrix internally which should fix a number of functions
  that had problems with rotation such as the reported problem with ode create
  static box.


- v0.4.0 rc1 -

* Updated to latest SVN source (apparently the snapshot version I had was really
  old).
* Added Linear Motors, PR, PU, Piston, and Plane2D Joints(not fully implemented)
  along with their set and get functions.

- v0.3.2 -

* Removed minimum limit of 7 units for bodies.
* Added an overloaded function, ODE CREATE DYNAMIC TRIANGLE MESH Object,[GeomObject].
  This will allow you to specify a different object to act as the Collision model of
  an object.

`
` Ode Ragdoll Demo
` Author: Christian Ang
`

`
` Setup
Sync On
Sync Rate 60
Autocam Off
Disable Escapekey

`
` Ode Start
Ode Start

` Ground
Make Object Box 1,1000,10,1000
Ode Create Static Box 1

Make Object Box 2,100,10,100
Position Object 2,0,300,0
Rotate Object 2,20,45,0
Ode Create Static Box 2

Make Object Box 3,300,10,300
Position Object 3,0,150,50
Rotate Object 3,15,0,30
Ode Create Static Box 3

Make Object Box 4,500,10,500
Position Object 4,0,300,150
Rotate Object 4,90,0,0
Ode Create Static Box 4

Make Object Box 5,200,10,200
Position Object 5,0,200,150
Rotate Object 5,0,0,-45
Ode Create Static Box 5

`
` Create Ragdoll

For i=0 to 60
    makeRagdoll(rnd(1000)-500,rnd(1000),rnd(1000)-500)
Next i

Position Camera -500,400,-500
Point Camera 0,0,0

`
` Main Loop
Repeat

	Text 0,0,"FPS: "+str$(Screen Fps())
	Text 0,20,"Use Arrowkeys to move Around Scene"
	
	Control Camera Using Arrowkeys 0,5,2

` Update Physics
	Ode Update

`Sync
	Sync
Until escapekey()=1

Ode End

End

Function makeRagdoll(offX,offY,offZ)

` Head
	head=Find Free Object()
	Make Object Sphere head,20
	Position Object head,offX,200+offY,offZ
	Ode Create Dynamic Sphere head
	Ode Set Body Mass head,0.5

` Body
	body=Find Free Object()
	Make Object Box body,25,50,25
	Position Object body,offX,160+offY,offZ
	Ode Create Dynamic Box body
	Ode Set Body Mass body,0.5

` Left Upper Arm
	lUarm=Find Free Object()
	Make Object Box lUarm,25,12,12
	Position Object lUarm,-30+offX,185+offY,offZ
	Ode Create Dynamic Box lUarm
	Ode Set Body Mass lUarm,0.5

` Left Lower Arm
	lLarm=Find Free Object()
	Make Object Box lLarm,30,8,8
	Position Object lLarm,-60+offX,185+offY,offZ
	Ode Create Dynamic Box lLarm
	Ode Set Body Mass lLarm,0.5

` Right Upper Arm
	rUarm=Find Free Object()
	Make Object Box rUarm,25,12,12
	Position Object rUarm,30+offX,185+offY,offZ
	Ode Create Dynamic Box rUarm
	Ode Set Body Mass rUarm,0.5

` Right Lower Arm
	rLarm=Find Free Object()
	Make Object Box rLarm,30,8,8
	Position Object rLarm,60+offX,185+offY,offZ
	Ode Create Dynamic Box rLarm
	Ode Set Body Mass rLarm,0.5

` Left Upper Leg
	lUleg=Find Free Object()
	Make Object Box lUleg,12,30,12
	Position Object lUleg,-10+offX,115+offY,offZ
	Ode Create Dynamic Box lUleg
	Ode Set Body Mass lUleg,0.5

` Left Lower Leg
	lLleg=Find Free Object()
	Make Object Box lLleg,8,30,8
	Position Object lLleg,-10+offX,80+offY,offZ
	Ode Create Dynamic Box lLleg
	Ode Set Body Mass lLleg,0.5

` Right Upper Leg
	rUleg=Find Free Object()
	Make Object Box rUleg,12,30,12
	Position Object rUleg,10+offX,115+offY,offZ
	Ode Create Dynamic Box rUleg
	Ode Set Body Mass rUleg,0.5

` Right Lower Leg
	rLleg=Find Free Object()
	Make Object Box rLleg,8,30,8
	Position Object rLleg,10+offX,80+offY,offZ
	Ode Create Dynamic Box rLleg
	Ode Set Body Mass rLleg,0.5
	
`
` Attach Joints
	jG=ODE Find Free Joint Group()
	Ode Create Joint Group jG

` Attach Head to Body
    i=ODE Find Free Joint()
	Ode Create Ball Joint i,jG
	Ode Attach Joint i,head,body
	Ode Set Ball Anchor i,offX,195+offY,offZ

` Attach Upper Arms to Body
    i=ODE Find Free Joint()
	Ode Create Ball Joint i,jG
	Ode Attach Joint i,body,lUarm
	Ode Set Ball Anchor i,-15+offX,185+offY,offZ
	
    i=ODE Find Free Joint()
	Ode Create Ball Joint i,jG
	Ode Attach Joint i,body,rUarm
	Ode Set Ball Anchor i,15+offX,185+offY,offZ

` Attach Lower Arms to Body
    i=ODE Find Free Joint()
	Ode Create Hinge Joint i,jG
	Ode Attach Joint i,lUarm,lLarm
	Ode Set Hinge Anchor i,-48+offX,185+offY,offZ
	Ode set Hinge Axis i,0,1,0
	
    i=ODE Find Free Joint()
	Ode Create Hinge Joint i,jG
	Ode Attach Joint i,rUarm,rLarm
	Ode Set Hinge Anchor i,48+offX,185+offY,offZ
	Ode set Hinge Axis i,0,1,0

` Attach Upper Legs to Body
    i=ODE Find Free Joint()
	Ode Create Ball Joint i,jG
	Ode Attach Joint i,body,lUleg
	Ode Set Ball Anchor i,-10+offX,135+offY,offZ
	
    i=ODE Find Free Joint()
	Ode Create Ball Joint i,jG
	Ode Attach Joint i,body,rUleg
	Ode Set Ball Anchor i,10+offX,135+offY,offZ

` Attach Lower Legs to Body
    i=ODE Find Free Joint()
	Ode Create Hinge Joint i,jG
	Ode Attach Joint i,lUleg,lLleg
	Ode Set Hinge Anchor i,-10+offX,100+offY,offZ
	Ode set Hinge Axis i,1,0,0
	
    i=ODE Find Free Joint()
	Ode Create Hinge Joint i,jG
	Ode Attach Joint i,rUleg,rLleg
	Ode Set Hinge Anchor i,10+offX,100+offY,offZ
	Ode set Hinge Axis i,1,0,0
	
EndFunction

`
` ODE Demo
` Author: Christian Ang
`

`
` Setup
Sync On
Sync Rate 60
Autocam Off

set window on

Make Light 1
Set Directional Light 1,0,5,5

`
` Setup ODE
Ode Start
Ode Set World Gravity 0.0,-9.8,0.0

`
` Ground
Make Object Plain 1,200,200
Xrotate Object 1,90
Color Object 1,rgb(255,255,0)
Ode Create Static Box 1

`
` Create a Complex Structure with Joints
Ode Create Joint Group 1
For x=1 to 8
	For y=1 to 10
	    inc pos,2
		tempobj=Find Free Object()
		Make Object Box tempobj,2,10,2
		Position Object tempobj,-50+x*12,20+y*18,0
		Ode Create Dynamic Box tempobj
		
		tempobj2=Find Free Object()
        Make Object Box tempobj2,2,10,2
        Zrotate Object tempobj2,90
        Position Object tempobj2,-56+x*12,27+y*20,0
        Ode Create Dynamic Box tempobj2
            
		Ode Create Hinge Joint pos,1
		Ode Attach Joint pos,tempobj,tempobj2
	    Ode Set Hinge Anchor pos,-50+x*12,27+y*20,0
        Ode Set Hinge Axis pos,0,1,0
		
        Ode Create Hinge Joint pos-1,1
        Ode Attach Joint pos-1,tempobj-20,tempobj2
        Ode Set Hinge Anchor pos-1,-50+(x-1)*12,27+y*18,0
        Ode Set Hinge Axis pos-1,0,1,0
		  
		If y > 1
			Ode Create Hinge Joint pos+1,1
			Ode Attach Joint pos+1,tempobj-1,tempobj
			Ode Set Hinge Anchor pos+1,-50+x*12,27+(y-1)*20,0
			Ode Set Hinge Axis pos+1,0,1,0
			inc pos
		Endif
		
	Next y
Next x

` Move the camera to get a better view
Position Camera 0,100,-500

`
` Main Loop
Do

	Control Camera Using Arrowkeys 0,5,2
	
`Update ODE
    for i=2 to Find Free Object()-1
        Ode Set Angular Velocity i,0,45,0
    next i
	ODE Update

`Sync
    Sync
Loop

`
` ODE Demo
` Author: Christian Ang
`

`
` Setup
Sync On
Sync Rate 60
Autocam Off
Set Camera Range 0.1,5000

set window on

Make Light 1
Set Directional Light 1,0,5,5

`
` Setup ODE
Ode Start
Ode Set World Gravity 0.0,-9.8,0.0

`
` Ground
Make Object box 1,2000,100,2000
`Xrotate Object 1,90
Color Object 1,rgb(255,255,0)
Ode Create Static Box 1

`
` Create a Complex Structure with Joints
Ode Create Joint Group 1
For x=1 to 8
	For y=1 to 6
	    inc pos,2
		tempobj=Find Free Object()
		Make Object Box tempobj,20,100,20
		Position Object tempobj,-500+x*120,130+y*180,0
		Ode Create Dynamic Box tempobj
		
		Ode Set Body Mass tempobj,20
		Ode Set Contact Fdir1 tempobj,50

		tempobj2=Find Free Object()
        Make Object Box tempobj2,20,100,20
        Zrotate Object tempobj2,90
        Position Object tempobj2,-560+x*120,200+y*200,0
        Ode Create Dynamic Box tempobj2
		
		Ode Set Body Mass tempobj2,20
		Ode Set Contact Fdir1 tempobj2,50
            
		Ode Create Hinge Joint pos,1
		Ode Attach Joint pos,tempobj,tempobj2
	    Ode Set Hinge Anchor pos,-500+x*120,200+y*200,0
        Ode Set Hinge Axis pos,0,1,0
		
        Ode Create Hinge Joint pos-1,1
        Ode Attach Joint pos-1,tempobj-20,tempobj2
        Ode Set Hinge Anchor pos-1,-500+(x-1)*120,200+y*180,0
        Ode Set Hinge Axis pos-1,0,1,0
		  
		If y > 1
			Ode Create Hinge Joint pos+1,1
			Ode Attach Joint pos+1,tempobj-1,tempobj
			Ode Set Hinge Anchor pos+1,-500+x*120,200+(y-1)*200,0
			Ode Set Hinge Axis pos+1,0,1,0
			inc pos
		Endif
		
	Next y
Next x

tempobj=Find Free Object()
Make Object Box tempobj,20,400,20
Position Object tempobj,0,1500,0
Ode Create Dynamic Box tempobj
		
Ode Set Body Mass tempobj,20
Ode Set Contact Fdir1 tempobj,50

tempobj2=Find Free Object()
Make Object Sphere tempobj2,200
Position Object tempobj2,0,1900,0
Ode Create Dynamic Box tempobj2

Ode Set Body Mass tempobj2,20
Ode Set Contact Fdir1 tempobj2,50

tempobj3=Find Free Object()
Make Object Box tempobj3,20,20,20
Position Object tempobj3,0,1250,0
Ode Create Dynamic Box tempobj3

Ode Set Body Mass tempobj3,20
Ode Set Contact Fdir1 tempobj3,50

Ode Create Fixed Joint pos+1,1
Ode Attach Joint pos+1,tempobj,tempobj3
Ode Set Fixed pos+1
`Ode Set Ball Anchor pos+1,0,1500,0

Ode Create Ball Joint pos+2,1
Ode Attach Joint pos+2,tempobj,tempobj2
Ode Set Ball Anchor pos+2,0,2000,0

` Move the camera to get a better view
Position Camera 0,500,-2500

`
` Main Loop
Do
	Text 0,0,str$(Screen FPS())
	
	Ode Set Linear Velocity tempobj3,0.0,-Ode Get Body Linear Velocity Y(tempobj),0.0
	Ode Set Angular Velocity tempobj3,10.0,0.0,0.0

	Control Camera Using Arrowkeys 0,50,2
	
`Update ODE
	ODE Update

`Sync
    Sync
Loop

sync on
sync rate 60
autocam off
set display mode 1024,768,32
ode start

`floor
make object box 100,1000,10,1000
position object 100,0,-5,0
color object 100,rgb(80,120,80)
ode create static box 100
ode set contact fdir1 100,50

`wall
make object box 101,1000,200,10
position object 101,10,100,500
color object 101,rgb(80,120,80)
ode create static box 101
ode set contact fdir1 101,50

`left leg
make object box 1,8,50,8
position object 1,-7.5,25,0
ode create dynamic box 1
ode set body mass 1,2
ode set contact fdir1 1,50

`right leg
make object box 2,8,50,8
position object 2,7.5,25,0
ode create dynamic box 2
ode set body mass 2,2
ode set contact fdir1 2,50

`body
make object box 3,25,36,10
position object 3,0,72,0
ode create dynamic box 3
ode set body mass 3,30
ode set contact fdir1 3,50

`left arm
make object box 4,7,47,7
position object 4,-20,62,0
ode create dynamic box 4
ode set body mass 4,2
ode set contact fdir1 4,50

`right arm
make object box 5,7,47,7
position object 5,20,62,0
ode create dynamic box 5
ode set body mass 5,2
ode set contact fdir1 5,50

`head
make object box 6,12,20,10
position object 6,0,102,0
ode create dynamic box 6
ode set body mass 6,2
ode set contact fdir1 6,50

ode create joint group 1

ode create hinge joint 1,1
ode create hinge joint 2,1
ode create hinge joint 3,1
ode create hinge joint 4,1
ode create hinge joint 5,1

ode attach joint 1,1,3
ode attach joint 2,2,3
ode attach joint 3,4,3
ode attach joint 4,5,3
ode attach joint 5,6,3

ode set hinge anchor 1,-12,50,0
ode set hinge anchor 2,12,50,0

ode set hinge anchor 3,-15,80,0
ode set hinge anchor 4,15,80,0

ode set hinge anchor 5,0,98,0

position camera -120,100,-200
point camera 0,30,0
ball=200
t=0
do
   set cursor 0,0
   print "Hit Space to throw balls, move camera with arrowkeys"
    control camera using arrowkeys 0,2,1

    if spacekey()=1 and timer()>t
       inc ball
       make object sphere ball,20
       position object ball,0,100,-250
       ode create dynamic sphere ball
       ode set linear velocity ball,0,0,100
       t=timer()+300
    endif
    ode update
    sync
loop

sync on
sync rate 60
autocam off
set display mode 1024,768,32
set window size 1024,768

ode start

`make the floor
make object box 1,150,10,100
ode create static box 1

position camera 0,8,-100
point camera 0,5,0

obj=1
do
   set cursor 0,0
   print "Hit Space to drop cubes, red cubes (size 4) left hanging in the air"
   print "but green cubes (size 7) hit correctly the floor"
   if spacekey() and timer()>ti
      inc obj
      c=rnd(1)
      if c=0 then make object cube obj,7:color object obj,rgb(0,255,0) `green cube size 7
      if c=1 then make object cube obj,4:color object obj,rgb(255,0,0) `red cube size 4
      position object obj,rnd(40)-20,100,0
      ode create dynamic box obj
      ti=timer()+300
   endif
   ode update
   sync
loop

end

sync on
sync rate 60
autocam off
set display mode 1024,768,32
set window size 1024,768

ode start

`make the floor
make object box 1,100,10,100
rotate object 1,0,0,10  `tilt the floor 10 degrees to left
ode create static box 1

position camera 0,60,-200
point camera 0,0,0

ball=1
do
   set cursor 0,0
   print "Test 1 - Hit Space to drop balls, which bounce to right even the floor is tilted to left"
   if spacekey() and timer()>ti
      inc ball
      make object sphere ball,10
      position object ball,0,100,0
      ode create dynamic sphere ball
      ti=timer()+500
   endif
   ode update
   sync
loop

end

sync on
sync rate 60
autocam off
set display mode 1024,768,32
set window size 1024,768

ode start

`make the floor
make object box 1,100,10,100
rotate object 1,0,0,-10  `tilt the floor first 10 degrees to opposite direction
ode create static box 1
rotate object 1,0,0,10 `and then to left

position camera 0,60,-200
point camera 0,0,0

ball=1
do
   set cursor 0,0
   print "Test 2 - Hit Space to drop balls, which now bounce to left as expected"
   if spacekey() and timer()>ti
      inc ball
      make object sphere ball,10
      position object ball,0,100,0
      ode create dynamic sphere ball
      ti=timer()+500
   endif
   ode update
   sync
loop

end