Sorry your browser is not supported!

// Project: Tech Demo 
// Created: 2017-03-08

// show all errors
SetErrorMode(2)

// set window properties
SetWindowTitle( "Tech Demo" )
SetWindowSize( 960, 540, 0 )

// set display properties
SetVirtualResolution( 960, 540 )
SetOrientationAllowed( 1, 1, 1, 1 )
SetSyncRate( 60, 0 ) 
UseNewDefaultFonts( 1 )


#include "scraggle_tech_demo.agc"
#include "batvink_tech_demo.agc"
#include "phaelax_tech_demo.agc"


do
    ScraggleTechDemo()
    Clear()
    BatvinkTechDemo()
    Clear()
    PhaelaxTechDemo()
    Clear()
loop


function Clear()
	DeleteAllImages()
	DeleteAllObjects()
	DeleteAllSprites()
	DeleteAllText()
endfunction

Rem fubarpk techDemo
// show all errors
SetErrorMode(2)

// set window properties
SetWindowTitle( "Demo" )
SetWindowSize( xMax, yMax, 0 )

// set display properties
SetVirtualResolution( xMax, yMax )
SetOrientationAllowed( 1, 1, 1, 1 )
SetSyncRate( 60, 0 ) // 
UseNewDefaultFonts( 1 ) // since version 2.0.22 we can use nicer default fonts

rem data dictionary
rem sprites 1 to x is the sprites in the circle
rem sprites (spr) 100 to x is the sprites in the sinewave
rem sprites (spr2) 200 to x falling bouncy balls balls
rem sprites 800 and 801 curtain

#constant xMax=960
#constant yMax=540
#constant Bg=1000 :rem for the rubout sprite
#constant gravity=50 :rem the gravity to set for the physics
angle#=0

rem for falling bouncing balls
type ball
	id as integer
	x as float
	y as float
endtype

rem for circle
type textSpr
	id as integer
	angle as integer
	img as integer
endtype 

rem for sinewave
type myText
	id as integer		:rem id of sprite
	PointX as integer	:rem makes it move
	centreX as integer  :rem centre of sine wave x axis
	yPosition as integer:rem yPosition on y-axis
	amplitude as integer:rem the heaight of the wave
	speedX# as float	:rem how fast sine travels on x-axis
	WaveWidth as integer:rem how wide the sinewave is
	frequency# as float	:rem speed sprite should move up and down (0.0 to 6.0)
	img as integer		:rem holds the image number for the sprite
endtype
do 
	FubarpkTechDemo()
loop	

function FubarpkTechDemo()
//SetPhysicsDebugOn()
SetPhysicsScale( 0.1)
SetPhysicsGravity(0,gravity)
SetPhysicsWallTop(0)
SetPhysicsWallBottom(0)

CreateSprite(800,fubarpkCreateCurtain(1))
//SetSpriteSize(200,10,yMax)
SetSpriteOffset(800,xMax,0)
SetSpriteTransparency(800,0)
SetSpriteDepth(800,0)
SetSpritePositionByOffset(800,0,0)
CreateSprite(801,fubarpkCreateCurtain(2))
//SetSpriteSize(201,10,yMax)
SetSpriteOffset(801,0,0)
SetSpriteTransparency(801,0)
SetSpriteDepth(801,0)
SetSpritePositionByOffset(801,xMax,0)

SetClearColor(0,0,0)

rem the circle text
text$=fubarpkInvertText("2017 Scrolling Mega Demo by fubarpk using AGK "):strlen=len(text$)	
global dim spr[strlen] as textSpr
Rem Move a sprite around a circle
for num = 0 to strlen
	spr[num].id=num+1:rem the id to rotate
	spr[num].img=num+1:rem holds the image
	spr[num].angle=num*8:rem the angle of the rotation(0 - 360)/A point around the circumference(the circle)
	fubarpkCreateTextImage(Mid(text$,num+1,1),spr[num].img)
	CreateSprite(spr[num].id,spr[num].img)
	SetSpriteColor(spr[num].id, Random(1,255),Random(1,255), Random(1,255), 255 ) 
	SetSpriteTransparency(spr[num].id,1)
	SetSpriteGroup(spr[num].id,1)
	SetSpritePhysicsOn(spr[num].id,1)
next num

rem sine text
text$=fubarpkInvertText("Just another sine scrolling text"):strlen2=len(text$)
global dim spr2[strlen2] as myText
for num=1 to strlen2 
	spr2[num].id=num+100:spr2[num].img=num+100
	spr2[num].centreX=xMax/2
	spr2[num].yPosition=yMax/2
	spr2[num].amplitude=20
	spr2[num].speedX#=.51
	spr2[num].WaveWidth=xMax
	spr2[num].frequency#=1.4
	spr2[num].PointX=90-(num*3)
	fubarpkCreateTextImage(Mid(text$,num,1),spr2[num].img)
	createSprite(spr2[num].id,spr2[num].img)
	SetSpriteColor(spr2[num].id, Random(1,255),Random(1,255), Random(1,255), 255 ) 
	SetSpriteTransparency(spr2[num].id,1)
	SetSpriteDepth(spr2[num].id,10)
	SetSpriteGroup(spr2[num].id,1)
	SetSpritePhysicsOn(spr2[num].id,1)
next num 

global dim balls[20] as ball
img=fubarpkCreateEllipse()
fubarpkSetupballs(img)

Rem set up the variables. Variables is used here for explanation and reuseability
rem the diameter of the circle (the width or height)
` using the same value for diameterX and DiameterY will create a circle
` using different values will create an oval
diameterX = 200
diameterY = 200
rem The x Value of the centre of the circle
centreX = xMax/2
 rem The Y Value of the centre of the circle
centreY = yMax/2
Rem Steps is how fast the sprite should move (a Value of 1 draws the sprite at every point around the circle)
steps = -1


iAlpha=0
yFlag=1
fadeFlag=0
flag=1
ResetTimer()
time#=timer()
repeat
	// circle scroller
	if yFlag=1 
		dec diameterY
		if diameterY <=-200 then yFlag=0
	elseif yFlag=0
		inc diameterY
		if diameterY >=200 then yFlag=1
	endif
	
	rem Position the sprite using the math commands Sin and Cos (Sin for x and Cos for y)
	for num = 0 to strlen 
		//setspritePosition(spr[num].id,Sin(spr[num].angle)*diameterX+centreX,Cos(Sin(spr[num].angle)*diameterY+centreY))
		setspritePosition(spr[num].id,Sin(spr[num].angle)*diameterX+centreX,Cos(spr[num].angle)*diameterY+centreY)
		rem check if the sprite has moved full circle (360 degrees) then set it back to zero if it has.
		` Use greater than -360 ( > -360 ) and subtract before steps ( angle - steps ) to move opposite direction
		` It is possible to skip the check for 360 (full circle) and only decreas/increase the angle
		` but then the angle value will decrease or increase forever
		if spr[num].angle < 360
			spr[num].angle = spr[num].angle + steps
		else
			spr[num].angle = 0
		endif
		SetSpriteColorAlpha(spr[num].id,iAlpha)
	next num
	
	//sine scroller
	flag=fubarpkTextScroll(strlen2,flag,iAlpha)
	if fadeFlag=0
		if iAlpha<255 then inc iAlpha
	else
		if iAlpha>1 then dec iAlpha
	endif	
	for num=1 to 20
		if GetSpriteYByOffset(balls[num].id) > yMax
			balls[num].y =-150
			balls[num].x=random(100,xMax-100)
			SetSpriteColor( balls[num].id, Random(1,255),Random(1,255), Random(1,255), 255 ) 
			SetSpriteVisible(balls[num].id,1)
			SetSpritePositionByOffset(balls[num].id,balls[num].x,balls[num].y)
		endif
		
		for hitCheck=1 to strlen
			If GetSpriteCollision(balls[num].id,hitCheck)
				SetSpriteVisible(hitCheck,0):SetSpriteVisible(num,0)
				SetSpriteActive(hitCheck,0):SetSpriteActive(num,0)
				SetSpritePhysicsOff(hitCheck):SetSpritePhysicsOff(num)
				fubarpkSpriteHit(hitCheck,img)
			endif
		next hitCheck
		for hitCheck=1 to strlen2
			If GetSpriteCollision(balls[num].id,hitCheck+100)
				SetSpriteVisible(hitCheck+100,0):SetSpriteVisible(num,0)
				SetSpriteActive(hitCheck+100,0):SetSpriteActive(num,0)
				SetSpritePhysicsOff(hitCheck+100):SetSpritePhysicsOff(num)
				fubarpkSpriteHit(hitCheck+100,img)
			endif
		next hitCheck
	next num
 Sync()
until Timer()-time#>15
fubarpkTheEnd(strlen,strlen2)
end
endfunction

function fubarpkCreateTextImage (myString as string,imgNum as integer)
CreateSprite(bg,0)
SetSpriteSize(bg,150,150)
SetSpriteColor(bg,0,0,0,255)
clearscreen()
CreateText(100,myString)
SetTextSize(100,50)
SetTextPosition(100,0,0)
//drawSprite(100)
//if myString <> 
Render():If GetImageExists(imgNum) then DeleteImage(imgNum)
GetImage(imgNum,0,0,50,50):ClearScreen()
SetImageTransparentColor( imgNum,0,0,0 )
DrawSprite(bg)
ClearScreen()
DeleteText(100):deleteSprite(bg)
endfunction

function fubarpkInvertText(myString as string)
	resultString as string
	for num =len(myString) to 1 step -1
		resultString=resultString+Mid(myString,num,1)
	next num	
endfunction resultString

function fubarpkTextScroll(strlen as integer,flag as integer, iAlpha as integer)
//if delay# > .05 
for num = 1 to strlen
	xWave=Sin(spr2[num].PointX)*(spr2[num].wavewidth/2)+spr2[num].centreX
	yWave=sin(xWave*spr2[num].frequency#)*(spr2[num].amplitude)+spr2[num].yposition
	SetSpritePosition(spr2[num].id,xWave,yWave)
  
	if spr2[num].PointX >-90
		spr2[num].PointX = spr2[num].PointX - spr2[num].speedX#
		if spr2[num].amplitude>=20 and flag=1  
			spr2[num].amplitude=spr2[num].amplitude+2
			if spr2[num].amplitude>=180 then flag=0
		endif
		if spr2[num].amplitude >0 and flag=0 
			spr2[num].amplitude=spr2[num].amplitude-2
			if spr2[num].amplitude<=20 then flag=1
		endif
	else
		spr2[num].PointX = 90
	endif
	SetSpriteColorAlpha(spr2[num].id,iAlpha)
		
	If GetSpriteX(spr2[num].id)<xMax/2 
		SetSpriteDepth(spr2[num].id,15)
	else 
		SetSpriteDepth(spr2[num].id,5)
	endif
next num
endfunction flag

function fubarpkCreateEllipse()
    Render()
    DrawEllipse(50,50,25,25,MakeColor(255,255,255),MakeColor(100,100,100),1)
    Swap()
    img = getimage(0,0,100,100)
    sync()
endfunction img

function fubarpkSetupballs (img as integer)
for num =1 to 20
	balls[num].id=(num-1)+200
	if GetSpriteExists(balls[num].id) then DeleteSprite(balls[num].id)
	CreateSprite(balls[num].id,img)
	SetSpriteColor(balls[num].id, Random(1,255),Random(1,255), Random(1,255), 255 ) 
	SetSpriteOffset(balls[num].id,50,50)
	SetSpritePositionByOffset(balls[num].id,random(100,xMax-100),-random(100,yMax*4))
	SetSpriteShapeCircle(balls[num].id,0,0,25)
	SetSpritePhysicsOn(balls[num].id,2)
	SetSpritePhysicsRestitution(balls[num].id,.75 ) 
	SetSpriteGroup(balls[num].id,2)
	SetSpriteDepth(spr2[num].id,1)

next num 
endfunction

function fubarpkSpriteHit(hit as integer, img as integer)
	//DeleteParticles(hit)
	id=CreateParticles(100,100)
	SetParticlesImage(id,img)
	SetParticlesSize(id,16)
	SetParticlesFrequency(id,10)
	SetParticlesLife(id,2)
	SetParticlesVelocityRange(id,1,10)
	SetParticlesMax(id,15)
	SetParticlesPosition(id,GetSpriteXByOffset(hit),GetSpriteYByOffset(hit))
	AddParticlesColorKeyFrame(id,0,GetSpriteColorRed(hit),GetSpriteColorGreen(hit),GetSpriteColorBlue(hit),255) 
	updateParticles(id,0)
endfunction

function fubarpkCreateCurtain(direction as integer)
ClearScreen() 
Render()
if direction = 1 :rem left curtain
	DrawBox( 0,0,xMax-6,yMax, MakeColor(0,0,0),MakeColor(0,0,0), MakeColor(0,0,0),MakeColor(0,0,0),1 ) 
	DrawBox( xMax-5,0,xMax,yMax, MakeColor(255,255,255),MakeColor(255,255,255), MakeColor(255,255,255),MakeColor(255,255,255),1 ) 
endif
if direction = 2 :rem Right curtain
	DrawBox( 0,0,5,yMax, MakeColor(255,255,255),MakeColor(255,255,255), MakeColor(255,255,255),MakeColor(255,255,255),1 ) 
	DrawBox( 6,0,xMax,yMax, MakeColor(0,0,0),MakeColor(0,0,0), MakeColor(0,0,0),MakeColor(0,0,0),1 ) 
endif
Swap()
img = getimage(0,0,xMax,yMax)
sync()
endfunction img

function fubarpkTheEnd(strlen as integer,strlen2 as integer)
amount=5	
x=0:xx=xMax
w# as float:w#=0
moveIn=1:flag=0

for num=1 to strlen
	if GetSpriteExists(num) then DeleteSprite(num)
next num
for num=1 to strlen2
	if GetSpriteExists(num+100) then DeleteSprite(num+100)
next num

repeat
	//DrawSprite (Bg)
	SetSpritePositionByOffset(800,x,0)
	SetSpritePositionByOffset(801,xx,0)
	if GetSpriteCollision(800,801) = 0 and moveIn=1
		x=x+amount:xx=xx-amount
	else
		moveIn=0
		flag=1	 
	endif
	if flag=1
		EnableClearColor(1)
		DeleteText(999)
		CreateText(999,"THE END")
		SetTextSize(999,150)
		SetTextPosition(999,xMax/2-230,yMax/2-100)
		flag=3
	endif
	if moveIn=0 and x>0
		x=x-amount:xx=xx+amount
	endif
	Sync()
until moveIn=0 and x<=0
ResetTimer()
for num=255 to 0 step -1
	SetTextColorAlpha(999,num)
	time#=timer()
	repeat
		sync()
	until Timer()-time#>.0005
next num
endFunction

Rem fubarpk techDemo
// show all errors
SetErrorMode(2)

// set window properties
SetWindowTitle( "Demo" )
SetWindowSize(1280,720, 0 )

// set display properties
SetVirtualResolution(1280,720)
SetOrientationAllowed( 1, 1, 1, 1 )
SetSyncRate( 60, 0 ) // 
UseNewDefaultFonts( 1 ) // since version 2.0.22 we can use nicer default fonts

Type MyText
	id as integer
	pop as integer
	drop as float
EndType

t as MyText[23]

for i = 0 to t.length-1
	t[i].id = createText("Super awesome ultra 360 hyper Go platinum demo... Gold Edition!")
	setTextSize(t[i].id, 0)
	SetTextAlignment(t[i].id, 1)
next i

f = loadFont("Courier New")
a as MyText[73]
gosub amiga
for i = 0 to a.length-1
	setTextFont(a[i].id, f) 
	setTextSize(a[i].id, 16)
	SetTextAlignment(a[i].id, 1)
next i


timestamp = 0
timestamp1 = 0

phase = 1


amount = 800


colors as integer[108]
colors[0] = makeColor(random(0,255), random(0,255), random(0,255))
colors[35] = makeColor(random(0,255), random(0,255), random(0,255))
colors[71] = makeColor(random(0,255), random(0,255), random(0,255))
colors[107] = makeColor(random(0,255), random(0,255), random(0,255))


for i = 1 to 34
	t#  = i/36.0
	r = getColorRed(colors[0])   + (getColorRed(colors[35])   - getColorRed(colors[0])  ) * t#
	g = getColorGreen(colors[0]) + (getColorGreen(colors[35]) - getColorGreen(colors[0])) * t#
	b = getColorBlue(colors[0])  + (getColorBlue(colors[35])  - getColorBlue(colors[0]) ) * t#
	colors[i] = makeColor(r,g,b)
next i
for i = 36 to 70
	t#  = (i-36)/36.0
	r = getColorRed(colors[35])   + (getColorRed(colors[71])   - getColorRed(colors[35])  ) * t#
	g = getColorGreen(colors[35]) + (getColorGreen(colors[71]) - getColorGreen(colors[35])) * t#
	b = getColorBlue(colors[35])  + (getColorBlue(colors[71])  - getColorBlue(colors[35]) ) * t#
	colors[i] = makeColor(r,g,b)
next i
for i = 72 to 106
	t#  = (i-72)/36.0
	r = getColorRed(colors[71])   + (getColorRed(colors[107])   - getColorRed(colors[71])  ) * t#
	g = getColorGreen(colors[71]) + (getColorGreen(colors[107]) - getColorGreen(colors[71])) * t#
	b = getColorBlue(colors[71])  + (getColorBlue(colors[107])  - getColorBlue(colors[71]) ) * t#
	colors[i] = makeColor(r,g,b)
next i


Type Star
	x as float
	y as integer
EndType


count = 0


stars as Star[200]

for i = 1 to 200
	stars[i].x = random(0,1480)
	stars[i].y = random(0, 360)
next i

RED = MakeColor(255,0,0)
WHITE = MakeColor(255,255,255)




ox1#=0
ox2#=0
drop = 0
gy = 720


shadow = createSprite(createShadow())
ball = createSprite(createBall())
setSpriteDepth(ball, 2)
setSpriteSize(shadow, 130,75)
setSpriteColorAlpha(shadow, 92)
setSpriteVisible(ball, 0)


angle = 0

Type Monkey
	x as integer
	y as integer
	rot as integer
EndType



Type MonkeyArray
	monkey as Monkey[20]
	wave as float
	y as integer
EndType

spacemonkeys as MonkeyArray[5]

for i = 0 to spacemonkeys.length
	spacemonkeys[i].wave = random(0,360)
	spacemonkeys[i].monkey[0].rot = random(0,360)
	spacemonkeys[i].monkey[0].x = random(0,1280)
	spacemonkeys[i].y = random(50,320)
next i


Type Ball
	spr as integer
	x as integer
	y as integer
	z as integer
	shadow as integer
EndType


balls as Ball[20]

balls[1].spr = createSprite(createOrb(100,WHITE,makeColor(110,110,110)))
setSpriteColor(balls[1].spr, random(40,255),random(40,255),random(40,255),255)
balls[1].x = 640 + cos(18)*200
balls[1].y = 360 + sin(18)*100
setSpriteSize(balls[1].spr, 4, 4)
balls[1].shadow = createSprite(createOrb(100,0xFF000000,0xFF000000))
setSpriteDepth(balls[1].shadow, 40)
setSpriteColorAlpha(balls[1].shadow, 30)
setSpriteVisible(balls[1].spr, 0)
	
for i = 2 to 20
	balls[i].spr = cloneSprite(balls[1].spr)
	setSpriteColor(balls[i].spr, random(40,255),random(40,255),random(40,255),255)
	balls[i].x = 640 + cos(i*18)*200
	balls[i].y = 360 + sin(i*18)*100
	setSpriteSize(balls[i].spr, i*4, i*4)
	balls[i].shadow = cloneSprite(balls[1].shadow)
next i

setSpriteColor(balls[1].spr, 255,255,255,255)


phase = 1
bx = -100
ba=0


DO
	render()
		
	
	
	//sinwave
	if phase = 1 then gosub TextStuff
	
	
	if phase = 2
		ms = getMilliseconds()
		if timestamp+100 <= ms
			a[drop].drop = 0.1
			inc drop
			timestamp = ms
			if drop > 73
				phase = 3
				setSpriteVisible(ball, 1)
				for i = 1 to 20
					setSpriteVisible(balls[i].spr, 1)
				next i
			endif
		endif
	endif
	
	

	gosub doColors
	
	
	doStars(stars)

	
	if phase = 3
		gosub Ground
		gosub flyingSpacemonkeys
		gosub MyBalls
		
		// rolling ball
		positionBall(ball, shadow, bx, 450)
		inc bx, 1
		if bx > 1350 then bx = -100
	endif
	



	
	
/*
	if id < t.length-1
		ms = GetMilliseconds()
		if timestamp+60 <= ms
			timestamp = ms
			inc id
			pop(t, id)
		endif
	endif	
*/	
	
	

	dropText(a)
	animatePop(t)
	Render2DFront()
	sync()
LOOP




MyBalls:
	inc ba
	if ba > 359 then ba = 0
	for i = 1 to 20
		ag = i*18+ba
		if ag > 360 then ag = ag - 360
		
		ta = wrapValue(ag+90, 0, 359)		
		d# = (180-abs(ta-180)) / 180.0
		size = 50*d# + 30
		depth = 30 - 20*d#
		
		setSpriteSize(balls[i].spr, size, size)
		setSpriteDepth(balls[i].spr, depth)
		
		
		balls[i].x = 640 + cos(ag)*200
		balls[i].y = 360 + sin(ag)*50
		setSpritePosition(balls[i].spr, balls[i].x, balls[i].y)

		
		setSpriteSize(balls[i].shadow, size, size/2)
		setSpritePosition(balls[i].shadow, balls[i].x, balls[i].y+50)
	next i
RETURN


function wrapValue(v#, min, max)
	v# = mod((mod((v# - min), (max-min)) + (max-min)), (max-min)) + min
endfunction v#



function positionBall(b, s, x, y)
	setSpritePosition(s, x-25, y+20)
	setSpritePosition(b, x, y)
	setSpriteAngle(b, getSpriteAngle(b)+3)
endfunction




function drawSquare(x, y, width, rot, c)
	w = width/2
	s# = sin(rot)
	c# = cos(rot)
	
	x1 = x + (-w * c# - -w*s#)
	y1 = y + (-w * s# + -w*c#)
	x2 = x + (w * c# - -w*s#)
	y2 = y + (w * s# + -w*c#)
	x3 = x + (-w * c# - w*s#)
	y3 = y + (-w * s# + w*c#)
	x4 = x + (w * c# - w*s#)
	y4 = y + (w * s# + w*c#)
	
	drawLine(x1, y1, x2, y2, c,c)
	drawLine(x3, y3, x4, y4, c,c)
	drawLine(x1, y1, x3, y3, c,c)
	drawLine(x2, y2, x4, y4, c,c)	
endfunction


function createOrb(radius, c1, c2)
	render()
	drawEllipse(radius, radius, radius, radius, c1, c2, 1)
	swap()
	img = getImage(0,0,radius*2,radius*2)
	sync()
endfunction img

function createBall()
    Render()
    DrawEllipse(50,50,25,25,MakeColor(255,255,255),MakeColor(100,100,100),1)
    drawEllipse(60,60,5,5,MakeColor(100,100,100),MakeColor(255,255,255), 1)
    Swap()
    img = getimage(0,0,100,100)
    sync()
endfunction img

function createShadow()
    Render()
    DrawEllipse(50,50,25,25,MakeColor(0,0,0),MakeColor(0,0,0),1)
    Swap()
    img = getimage(0,0,100,100)
    sync()
endfunction img



TextStuff:
	dec amount
	ang = ang + 4
	for i = 0 to a.length-1
		if amount <= 0 then phase = 2
		o# = sin(ang+i*10)*amount
		setTextPosition(a[i].id, 640+o#, i*10)
	next i
RETURN



flyingSpacemonkeys:
	
	// update lead monkey, reinitialize if off-screen
	for i = 0 to spacemonkeys.length
		spacemonkeys[i].monkey[0].x   = spacemonkeys[i].monkey[0].x - 4
		spacemonkeys[i].monkey[0].y   = spacemonkeys[i].y +cos(spacemonkeys[i].wave)*50
		spacemonkeys[i].monkey[0].rot = spacemonkeys[i].monkey[0].rot - 6
		
		spacemonkeys[i].wave = spacemonkeys[i].wave + 3
		if spacemonkeys[i].monkey[0].x < -150
			spacemonkeys[i].monkey[0].x = 1300
			spacemonkeys[i].y = random(50,360)
			spacemonkeys[i].wave = random(0,360)
			spacemonkeys[i].monkey[0].rot = random(0,360)
		endif
	next i
	
	
	ms = GetMilliseconds()
	if timestamp1+10 <= ms
		for i = 0 to spacemonkeys.length
			for j = spacemonkeys[i].monkey.length to 1 step -1
				spacemonkeys[i].monkey[j].x   = spacemonkeys[i].monkey[j-1].x
				spacemonkeys[i].monkey[j].y   = spacemonkeys[i].monkey[j-1].y
				spacemonkeys[i].monkey[j].rot = spacemonkeys[i].monkey[j-1].rot
			next j
		next i
		timestamp1 = ms
	endif
	
	for i = 0 to spacemonkeys.length
		for j = spacemonkeys[i].monkey.length to 1 step -1
			size = 40-(spacemonkeys[i].monkey.length-j)*2
			drawSquare(spacemonkeys[i].monkey[j].x, spacemonkeys[i].monkey[j].y, size, spacemonkeys[i].monkey[j].rot, colors[j])
		next j
	next i
RETURN




doColors:
	// color fading
	inc count
	for i = 0 to a.length-1
		setTextColor(a[i].id, getColorRed(colors[i]), getColorGreen(colors[i]), getColorBlue(colors[i]),255)
	next i

	
	for i = 0 to colors.length-2
		colors[i] = colors[i+1]
	next i
	
	if count = 36
		count = 0
		colors[73]  = colors[72]
		colors[108] = makeColor(random(0,255), random(0,255), random(0,255))
		for j = 74 to 107
			t# = (j-73)/35.0
			r = getColorRed(colors[73])   + (getColorRed(colors[108])   - getColorRed(colors[73])  ) * t#
			g = getColorGreen(colors[73]) + (getColorGreen(colors[108]) - getColorGreen(colors[73])) * t#
			b = getColorBlue(colors[73])  + (getColorBlue(colors[108])  - getColorBlue(colors[73]) ) * t#
			colors[j] = makeColor(r,g,b)
		next j
	endif
RETURN



function dropText(t ref as MyText[])
	for i = 0 to t.length-1
		if t[i].drop > 0
			setTextPosition(t[i].id, 640, getTextY(t[i].id)+t[i].drop)
			t[i].drop = t[i].drop + 0.1
		endif
	next i
endfunction


function animatePop(t ref as MyText[])
	for i = 0 to t.length-1
		s = getTextSize(t[i].id)
		if t[i].pop = 1
			if s < 40
				setTextSize(t[i].id, s+3)
			else
				t[i].pop = 2
			endif
		elseif t[i].pop = 2
			if s > 32
				setTextSize(t[i].id, s-1)
			else
				setTextSize(t[i].id, 32)
				t[i].pop = 0
			endif
		endif
	next i
endfunction	
	
	


function pop(t ref as MyText[], r)
	if t[r].pop > 0 then exitfunction
	t[r].pop = 1
	setTextSize(t[r].id, 0)
	setTextPosition(t[r].id, 640, r*32)
endfunction




//sinwave
/*
	a = a + 4
	for i = 0 to t.length-1
		o# = sin(a+i*10)*260
		setTextPosition(t[i].id, 640+o#, i*32)
	next i
	*/


function doStars(stars ref as Star[])
	for i = 1 to 200
		stars[i].x = stars[i].x - 0.25
		c = random(100,255)
		color = makeColor(c,c,c)
		drawBox(stars[i].x,stars[i].y,stars[i].x+1,stars[i].y+1,color,color,color,color,1)
		if stars[i].x < 0
			stars[i].x = random(1280,1480)
			stars[i].y = random(0, 360)
		endif
	next i
endfunction




Ground:
	dec gy, 8
	if gy <= 360 then gy = 360
	
	ox1# = ox1# - 0.25
	ox2# = ox2# - 2
	
	if ox1# = -16 then ox1# = 0
	if ox2# = -128
		ox2# = 0
		flip = 1-flip
	endif
	
	for x = 1 to 100
		x1=640 + (x-50)*16
		`drawLine(x1+ox1#,gy, 640+(x-50)*128+ox2#,720, RED,RED)
		
		if mod(x,2)=flip
			color = RED
		else
			color = WHITE
		endif
		for i = 0 to 127
			f=i/4
			drawLine(x1+ox1#+f,gy, 640+(x-50)*128+ox2#+i,720, color,color)
		next i
	next x
RETURN



amiga:
	a[0].id =createText("                  MMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMM7        ")
	a[1].id =createText("                  MM????????????????ZMM=====================================MMO????????ZM$       ")
	a[2].id =createText("                  MM????????????????ZMM==========================MMMMMMMMM==MMO??????????MM      ")
	a[3].id =createText("                  MM????????????????ZMM==========================MMI777IMM==MMO??????????IMMO    ")
	a[4].id =createText("                  MM????????????????ZMM==========================MM+???+MM==MMO????????????ZMZ . ")
	a[5].id =createText("                  MM????????????????ZMM==========================MM+???+MM==MMO?????????????7MM~.")
	a[6].id =createText("                  MM????????????????ZMM==========================MM+???+MM==MMO???????????????MM7")
	a[7].id =createText("                  MM????????????????ZMM==========================MM+???+MM==MMO????????????????MM")
	a[8].id =createText("                  MM????????????????ZMM==========================MM????+MM==MMO????????????????MM")
	a[9].id =createText("                  MM????????????????ZMM==========================MMI777IMM==MMO????????????????MM")
	a[10].id=createText("                  MM????????????????ZMM==========================MMMMMMMMM==MMO????????????????MM")
	a[11].id=createText("                  MM????????????????ZMM=====================================MMO????????????????MM")
	a[12].id=createText("                  MM????????????????ZMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMO????????????????MM")
	a[13].id=createText("                  MM????????????????IIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIII????????????????MM")
	a[14].id=createText("                  MM???????????????????????????????????????????????????????????????????????????MM")
	a[15].id=createText("                  MM???????????????????????????????????????????????????????????????????????????MM")
	a[16].id=createText("                  MM???????????????????????????????????????????????????????????????????????????MM")
	a[17].id=createText("                  MM???????????????????????????????????????????????????????????????????????????MM")
	a[18].id=createText("                  MM???????????????????????????????????????????????????????????????????????????MM")
	a[19].id=createText("                  MM???????????????????????????????????????????????????????????????????????????MM")
	a[20].id=createText("                  MM???????????????????????????????????????????????????????????????????????????MM")
	a[21].id=createText("                  MM???????????????????????????????????????????????????????????????????????????MM")
	a[22].id=createText("                  MM???????????????????????????????????????????????????????????????????????????MM")
	a[23].id=createText("               .. MM???????????????????????????????????????????????????????????????????????????MM")
	a[24].id=createText("                  MM???????????????????????????????????????????????????????????????????????????MM")
	a[25].id=createText("            .   MMMM??????I+++++M  MMMMMM++++++++++++++++++++++++++++++++++++++++++++++++??????MM")
	a[26].id=createText("            :MMM  MM???????MMMMM       M  MMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMM??????MM")
	a[27].id=createText("           MD. .  MM???????MM ,M       M+,M                                            MM??????MM")
	a[28].id=createText("          ZM=     MM???????MMZM=       M=,M                                            MM??????MM")
	a[29].id=createText("         :MZ .    MM???????MMMMM=      M=,M                                            MM??????MM")
	a[30].id=createText("         IM       MM???????MMMM~M=     M=,M  :I..7I: .III. .I. :I..7III  .IIII         MM??????MM")
	a[31].id=createText("         M        MM?????MMMM..  OMMMMMN.,M  :?. I?....  ? .?..,?.+????I.I+. ?~        MM??????MM")
	a[32].id=createText("        Z7 .      MM????8MMO     ..      ,M  .?==I? .:?==: .+==+?.:I==I:.:?=:?~        MM??????MM")
	a[33].id=createText("       :M+        MM?INMMO.              +8     .I?.. . .       .        . ..?=.       MM??????MM")
	a[34].id=createText("     . M. M       MMMMMMM               ON      . .             .           ... .      MM??????MM")
	a[35].id=createText("    DM   .  MM  ?MMMMM.            .  MM        . .... .   ........ . .    .           MM??????MM")
	a[36].id=createText("  .M, .        MMM7 .               ?M           7I.II.    ?:..I..?7 ~?7 7?.           MM??????MM")
	a[37].id=createText("  M8         ~OMO                . =N..          :?=II ?I :?: .?. ?I ~?=?=?,           MM??????MM")
	a[38].id=createText(" MM.     . .:MM                  .MM            .I..II  I? II .:?I?. ~I...?,           MM??????MM")
	a[39].id=createText(" M        M N. .                M=  .            .  7I+..... . ....  =I . I,           MM??????MM")
	a[40].id=createText("M       MM.                   ,M  .               .... .            . .    .           MM??????MM")
	a[41].id=createText("M      MM                     ,M      ~MMM+ MMM~=MMM~. ~MMMM7MMMMO~M=$MMMMMMM.7MM~     MM??????MM")
	a[42].id=createText("M      :.                     ,M       .8MOOO+. 8?.+MM$..NM,  :M:.NM= OM~ IMOOO?,      MM??????MM")
	a[43].id=createText("M                             ,M       .8N M=  MMM= MM8..M:   M8 IMM=$M   IM  $..      MM??????MM")
	a[44].id=createText("M                             ,M       .8MI     M. :MM, M=   MM?M:NMM+.   IMM~         MM??????MM")
	a[45].id=createText("M                             ,M       .8~      MMM7= 7MMM:=OMM8. NMM$    I+           MM??????MM")
	a[46].id=createText("M                             .8O                                                      MM??????MM")
	a[47].id=createText("M                             .IMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMM")
	a[48].id=createText("M                               M=MM.        . .MMM+     M                                       ")
	a[49].id=createText("M                               M~ MMMM       MMMM      .M                 .           .      .. ")
	a[50].id=createText("M                               MMMM==+M~    8MMM        M       OOOO OOOOO,   OO.      .OZOO:   ")
	a[51].id=createText("M                               MO    ..N= +MMMZ        M,       =MM.  +MZ    OMM      :MMZZMM+  ")
	a[52].id=createText("M                               MO.    ..MMMMM..      .NM.       =MM .MMO..    MM         ..MM   ")
	a[53].id=createText("M                               M: MMM. ZMMMM MMM .   +M         =MM MM        MM     ..  MMM:   ")
	a[54].id=createText("M.                              M~ MMMMMMMMMM  .  M   M.         =MMM?         MM     .$MM  MMM  ")
	a[55].id=createText("MM                              M=       ,MMM  .  .+ MZ         .=MM         .MMMMM.DM   MMMM:  .")
	a[56].id=createText(" M                              M=        :8MZ  .8M MM                                           ")
	a[57].id=createText(" M                              M=         M MMMM MMM                                            ")
	a[58].id=createText(" M                            . M=           MMMM. +                                             ")
	a[59].id=createText(" M                            ,M              . M                                                ")
	a[60].id=createText(" M                     8888888N,               MM                                                ")
	a[61].id=createText(" M                     MM$$$$$  .            :M$                                                 ")
	a[62].id=createText(" M                     MM                   .?N                                                  ")
	a[63].id=createText(" M                     MM                   MZ                                                   ")
	a[64].id=createText(" M                     MM                .7OM:                                                   ")
	a[65].id=createText(" M                     MM              ??MO$..                                                   ")
	a[66].id=createText(" M                     MM            MM:N                                                        ")
	a[67].id=createText(" M                     MM           .MM                                                          ")
	a[68].id=createText(" M                     MM            MM                                                          ")
	a[69].id=createText(" M                     MM            MM                                                          ")
	a[70].id=createText(" M                     MM            MM                                                          ")
	a[71].id=createText(" M.                    MM            MM                                                          ")
	a[72].id=createText(" MMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMM                                                          ")
RETURN

Function rubAwayColor(spr1 as integer,r as integer,g as integer,b as integer)
	rem this function you pass a sprite you wish to use to gradually color the screen in the chosen color
	radiusX as integer
	radiusY as integer
	SetSpriteColor(spr1,r,g,b,255)
	SetSpriteSize(spr1,2,2)
	SetSpriteDepth(spr1,1)
	SetSpritePositionByOffset(spr1,xMax/2,yMax/2)
	repeat 
		inc radiusX:inc radiusY
		SetSpriteSize(spr1,radiusX,radiusY)
		sync()
	until radiusX>xMax and radiusY>yMax
endfunction

Function fadeIn(spr1 as integer,img1 as integer,img2 as integer)
	rem this function fades in the background sprite passed by gradually covering the screen with img2 
	rem could be used to remove splash screens etc and fade in game from behind
	x=(xMax/2)-1
	y=(yMax/2)-1
	width=2:height=2
	
	SetSpriteSize(spr1,width,height)
	SetSpritePositionByOffset(spr1,xMax/2,yMax/2)
	SetSpriteDepth(spr1,1)
	repeat 
		if x>0 
			dec x:width=width+2	
		endif
		if y>0
			dec y:height=height+2
		endif
		img1=copyImage(img2,x,y,width,height)
		SetSpriteImage(spr1,img1)
		SetSpriteSize(spr1,width,height)
		sync()
	until x<=0 and y<=0

endfunction

Function fadeIn2(spr1 as integer,spr2 as integer,img1 as integer,img2 as integer)
	rem this function fades in the background sprite spr2 passed by gradually 
	rem the sprite spr1 with the background image2
	x=(xMax/2)-1
	y=(yMax/2)-1
	width=2:height=2
	SetSpriteSize(spr1,width,height)
	SetSpritePositionByOffset(spr1,xMax/2,yMax/2)
	SetSpriteDepth(spr1,0)
	
	SetSpriteSize(spr2,width,height)
	SetSpritePositionByOffset(spr2,xMax/2,yMax/2)
	SetSpriteDepth(spr2,1)
	repeat 
		if x>0 
			dec x:width=width+2	
		endif
		if y>0
			dec y:height=height+2
		endif
		img1=copyImage(img2,x,y,width,height)
		SetSpriteImage(spr2,img1)
		SetSpriteSize(spr2,width,height)
		SetSpriteSize(spr1,width,width)
		sync()
	until x<=0 and y<=0
endfunction

	
function fadeOut(spr1 as integer,img1 as integer,img2 as integer)
	rem this function fades out the foreground sprite passed by gradually covering the screen with img2
	Rem could be used for end of scene game over etc
	x=1:y=1
	width=xMax-1:height=yMax-1
	
	SetSpriteSize(spr1,width,height)
	SetSpritePositionByOffset(spr1,xMax/2,yMax/2)
	SetSpriteDepth(spr1,1)
	repeat 
		if x>0 
			inc x:
			if width>4 then width=width-2	
		endif
		if y>0
			inc y
			if height>4 then height=height-2
		endif
		img1=copyImage(img2,x,y,width,height)
		SetSpriteImage(spr1,img1)
		SetSpriteSize(spr1,width,height)
		sync()
	until width<=4 and height<=4
	SetSpriteVisible(spr1,0)
endfunction	

#constant xMax=1024
#constant yMax=600

// show all errors
SetErrorMode(2)

// set window properties
SetWindowTitle( "fade in fade out functions" )
SetWindowSize( xMax,yMax,0)
SetWindowAllowResize( 1 ) // allow the user to resize the window

// set display properties
SetVirtualResolution( xMax, yMax ) // doesn't have to match the window
SetOrientationAllowed( 0, 0, 1, 1 ) // allow both portrait and landscape on mobile devices
//SetSyncRate( 30, 0 ) // 30fps instead of 60 to save battery
SetScissor( 0,0,0,0 ) // use the maximum available screen space, no black borders
UseNewDefaultFonts( 1 ) // since version 2.0.22 we can use nicer default fonts

backgroundImg0 = LoadImage ("Background0.png")
backgroundImg1 = LoadImage ("Background1.png")
ellipse=LoadImage ("Ellipse.png")

createSprite(1,0)
SetSpriteDepth(1,1)

createSprite(2,ellipse)
SetSpriteSize(2,2,2)
SetSpriteDepth(2,0)
SetSpritePositionByOffset(2,xMax/2,yMax/2)


createSprite(3,backgroundImg0)
SetSpriteSize(3,xMax,yMax)
SetSpriteDepth(3,2)
SetSpritePositionByOffset(3,xMax/2,yMax/2)


createSprite(4,backgroundImg1)
SetSpritePositionByOffset(4,xMax/2,yMax/2)
SetSpriteDepth(4,3)

rubAwayColor(1,0,0,1)
DeleteSprite(1)
fadeIn(4,backgroundImg0,backGroundImg1)
fadeOut(4,backgroundImg0,backGroundImg1)
fadeIn2(2,3,ellipse,backGroundImg0)

do 
	Print(999)
	sync()

loop

// Project: ManualPhysics 
// Created: 2017-03-29

// show all errors
SetErrorMode(2)

#constant maxplatforms=5
#constant maxballs = 50
#constant width=1024
#constant height=768

// set window properties
SetWindowTitle( "ManualPhysics" )
SetWindowSize( width, height, 0 )
SetWindowAllowResize( 1 ) // allow the user to resize the window

// set display properties
SetVirtualResolution( 1024, 768 ) // doesn't have to match the window
SetOrientationAllowed( 1, 1, 1, 1 ) // allow both portrait and landscape on mobile devices
SetSyncRate( 30, 0 ) // 30fps instead of 60 to save battery
SetScissor( 0,0,0,0 ) // use the maximum available screen space, no black borders
UseNewDefaultFonts( 1 ) // since version 2.0.22 we can use nicer default fonts


type _ball
	image as integer
	x# as float
	y# as float
	speed# as float
	headingx# as float
	headingy# as float
	direction# as float
	angle# as float
	
endtype

type _platforms
	image as integer
	x# as float
	y# as float
	angle# as float
endtype

global platforms as _platforms[maxplatforms]
global balls as _ball[maxballs] 


createballs()

do
    
	for loops=1 to maxballs
		SetSpritePosition(balls[loops].image, balls[loops].x#, balls[loops].y#)
	
// Move directions	
		balls[loops].y#=balls[loops].y#+balls[loops].headingy#
		balls[loops].x#=balls[loops].x#+balls[loops].headingx#
	
// Check direction headings of the boundaries of the windows
		if balls[loops].y#>height-50 or balls[loops].y# < 50 
			balls[loops].headingy#=-balls[loops].headingy#
		endif
		if balls[loops].x#>width-50 or balls[loops].x# < 50 
			balls[loops].headingx#=-balls[loops].headingx#
		endif

	
		balls[loops].angle#=balls[loops].angle# + balls[loops].headingx#

		SetSpriteAngle(balls[loops].image, balls[loops].angle#)
		
// check collisions with other balls
		for loops2 = 1 to maxballs	
			if loops2<>loops
				if GetSpriteCollision(balls[loops2].image, balls[loops].image)
					
	
					if balls[loops].headingx#<0 then balls[loops].headingx# = 0+balls[loops].headingx#
					if balls[loops].headingy#<0 then balls[loops].headingy# = 0+balls[loops].headingy#
					if balls[loops].headingx#=>0 then balls[loops].headingx# = -balls[loops].headingx#
					if balls[loops].headingy#=>0 then balls[loops].headingy# = -balls[loops].headingy#


					if balls[loops2].headingx#<0 then balls[loops2].headingx# = -balls[loops2].headingx#
					if balls[loops2].headingy#<0 then balls[loops2].headingy# = -balls[loops2].headingy#
					if balls[loops2].headingx#=>0 then balls[loops2].headingx# = 0+balls[loops2].headingx#
					if balls[loops2].headingy#=>0 then balls[loops2].headingy# = 0+balls[loops2].headingy#
						
				
					
					
				endif
			
			endif
		next
		
	
	
	next
	
	
	

    Print( ScreenFPS() )
    Sync()
loop




function createballs()
	
	swap()
	DrawEllipse(10,10,10,10,MakeColor(255,255,255), MakeColor(0,0,0), 1)
	Render()
	img = getimage(0,0,20,20)
	

	for loops=1 to maxballs
		balls[loops].image = createsprite(img)
		balls[loops].x#=random(50,width-50)
		balls[loops].y#=random2(50,height-50)
		balls[loops].speed#=3
		balls[loops].headingx#=random2(-4,4)
		balls[loops].headingy#=random2(-4,4)
		balls[loops].direction#=random(1,180) //angle
		
	next
	
endfunction

// Project: Darts 
// Created: 2017-04-01

// show all errors
SetErrorMode(2)

// set window properties
SetWindowTitle( "Darts" )
SetWindowSize( 1024, 768, 0 )
SetWindowAllowResize( 1 ) // allow the user to resize the window

#constant width=1024
#constant height=768

// set display properties
SetVirtualResolution( width, height ) // doesn't have to match the window
SetOrientationAllowed( 1, 1, 1, 1 ) // allow both portrait and landscape on mobile devices
SetSyncRate( 30, 0 ) // 30fps instead of 60 to save battery
SetScissor( 0,0,0,0 ) // use the maximum available screen space, no black borders
UseNewDefaultFonts( 1 ) // since version 2.0.22 we can use nicer default fonts


global dartnumbers as integer[20]= [ 20, 1, 18, 4, 13, 6, 10, 15, 2, 17, 3, 19, 7, 16, 8, 11, 14, 9, 12, 5]
global darttext as integer[20]

for loops=0 to dartnumbers.length-1
	darttext[loops] = createtext(str(dartnumbers[loops]))
	SetTextSize(darttext[loops], 20)
	
	
next	

dartboardsize#=200
angle#=90
do
	c=makecolor(50,50,50)
	green=MakeColor(0,255,0)
	red = MakeColor(255,0,0)
	white=MakeColor(255,255,255)
	DrawEllipse(width/2, height/2, dartboardsize#+10, dartboardsize#+10, c, c, 1)

	DrawEllipse(width/2, height/2, dartboardsize#-30, dartboardsize#-30, c>>2, c>>2, 0)
	DrawEllipse(width/2, height/2, dartboardsize#-40, dartboardsize#-40, c>>2, c>>2, 0)

	DrawEllipse(width/2, height/2, dartboardsize#-90, dartboardsize#-90, c>>2, c>>2, 0)
	DrawEllipse(width/2, height/2, dartboardsize#-100, dartboardsize#-100, c>>2, c>>2, 0)


	DrawEllipse(width/2, height/2, dartboardsize#-180, dartboardsize#-180, green, green, 1)
	DrawEllipse(width/2, height/2, dartboardsize#-190, dartboardsize#-190, red, red, 1)

	
    for loops=0 to dartnumbers.length-1
		x# = width/2  - dartboardsize# * cos(angle#)
		y# = height/2 - dartboardsize# * sin(angle#)
		angle#= angle# + 360 / (dartnumbers.length-1)
		
//		if angle#>360 then angle#=-180
		SetTextPosition(darttext[loops], x#-GetTextTotalWidth(darttext[loops])/2, y#-GetTextTotalHeight(darttext[loops])/2)
		
		lx# = width/2  - (dartboardsize#-30) * cos(angle#+45)
		ly# = height/2 - (dartboardsize#-30) * sin(angle#+45)
		
		DrawLine(lx#,ly#, width/2, height/2,white,white)
		
	
	next




	Render2DFront()
    Print( ScreenFPS() )
    Sync()
loop

// Project: PerPixelCollision 
// Created: 2017-04-01

// show all errors
SetErrorMode(2)

// set window properties
SetWindowTitle( "PerPixelCollision" )
SetWindowSize( 1024, 768, 0 )
SetWindowAllowResize( 1 ) // allow the user to resize the window

// set display properties
SetVirtualResolution( 1024, 768 ) // doesn't have to match the window
SetOrientationAllowed( 1, 1, 1, 1 ) // allow both portrait and landscape on mobile devices
SetSyncRate( 30, 0 ) // 30fps instead of 60 to save battery
SetScissor( 0,0,0,0 ) // use the maximum available screen space, no black borders
UseNewDefaultFonts( 1 ) // since version 2.0.22 we can use nicer default fonts

img=createsprite(createball(makecolor(255,255,255)))
img1=createsprite(createball(makecolor(255,0,0)))

SetSpriteOffset(img,GetSpriteWidth(img)/2,GetSpriteHeight(img)/2)
SetSpriteOffset(img,GetSpriteWidth(img)/2,GetSpriteHeight(img)/2)

randx=400
randy=400

do

// Setup target sprite values	
	boxx=randx-GetSpriteWidth(img)/2
	boxy=randy-GetSpriteHeight(img)/2
    boxxwidth=randx+GetSpriteWidth(img)/2
    boxyheight=randy+GetSpriteHeight(img)/2
    SetSpritePositionByOffset(img, randx,randy)
	
	boxc=MakeColor(100,100,100)
	DrawBox(boxx,boxy,boxxwidth, boxyheight,boxc,boxc,boxc,boxc,0)


//Setup player sprite values
	playerx = GetPointerx()-GetSpriteWidth(img1)/2
	playery = getpointery()-GetSpriteHeight(img1)/2
	playerxwidth=getpointerx()+GetSpriteWidth(img1)/2
	playeryheight=getpointery()+GetSpriteHeight(img1)/2
	
    
    SetSpritePositionByOffset(img1, getpointerx(), getpointery())
	DrawBox(playerx,playery,playerxwidth, playeryheight,boxc,boxc,boxc,boxc,0)
    
// Check collisions per corner
// Top left corner entry
	if playerx>boxx and playery>boxy and playerx<boxxwidth and playery<boxyheight
			
		r=MakeColor(0,255,0)
		drawbox	(boxxwidth,boxyheight,playerx, playery,r,r,r,r,1)
	endif

// top right corner entry
	if playerx>boxx and playeryheight>boxy and playerx<boxxwidth and playeryheight<boxyheight
			
		r=MakeColor(255,255,0)
		drawbox	(boxxwidth,boxy,playerx, playeryheight,r,r,r,r,1)
	endif

//bottom right corner entry
	if playerxwidth>boxx and playeryheight>boxy and playerxwidth<boxxwidth and playeryheight<boxyheight
				
		r=MakeColor(0,0,255)
		drawbox	(boxx,boxy,playerxwidth, playeryheight,r,r,r,r,1)
	endif


//bottom right corner entry
	if playerxwidth>boxx and playery>boxy and playerxwidth<boxxwidth and playery<boxyheight
				
		r=MakeColor(0,255,255)
		drawbox	(boxx,boxyheight,playerxwidth, playery,r,r,r,r,1)
	endif


	

    Print( ScreenFPS() )
    Sync()
loop

function createball(c)

	swap()
	DrawEllipse(50,50,50,50,c,c,1)
	render()
	img=getimage(0,0,100,100)
	
endfunction img

[1,2,3,4,5,6,7] - initial sequence
[1,2,4,5,6,7] => 3 is counted out and goes into the result [3]
[1,2,4,5,7] => 6 is counted out and goes into the result [3,6]
[1,4,5,7] => 2 is counted out and goes into the result [3,6,2]
[1,4,5] => 7 is counted out and goes into the result [3,6,2,7]
[1,4] => 5 is counted out and goes into the result [3,6,2,7,5]
[4] => 1 is counted out and goes into the result [3,6,2,7,5,1]
[] => 4 is counted out and goes into the result [3,6,2,7,5,1,4]

josephus([1,2,3,4,5,6,7],3)==[3,6,2,7,5,1,4]

function josephusPermutation(items as integer[], k as integer)
    result as integer[]
    // your code here
endfunction result

function bitwars(arr as integer[])
    //add code here
endfunction

decimal=3
do
    

    Print( "Binary number of "+str(decimal)+" is " +str(decimalToBinary(decimal)))
    Sync()
loop

/* Function to convert a decimal number to binary number */
function decimalToBinary(n as float) 
remainder as float
binary as integer= 0: i as integer = 10
while(n <> 0) 
	remainder = MOD(n,2.0)
	n = n/2.0
	binary= binary + (remainder*i)
	i = i*10
endwhile
endfunction binary