Sorry your browser is not supported!

set display mode 1280, 1024, 32
sync on
sync rate 0
randomize timer()
backdrop on
color backdrop 0


type psuedoPoint
   x#
   y#
endtype

type psuedoLine
   p as psuedoPoint
endtype

type Asteroid
   x#
   y#
   speedX#
   speedY#
   rotSpeed#
   angle#

   cX#
   cY#

   imgId
   size
   radiusSquared
endtype




#constant ASTEROID_POINTS 12
#constant ASTEROID_COUNT 6

Dim Asteroids(ASTEROID_COUNT) as Asteroid

`Lines
Dim psuedoLineArray(ASTEROID_COUNT, ASTEROID_POINTS) as psuedoLine


`Make 'ASTEROID_COUNT' asteroids
for j = 1 to ASTEROID_COUNT
   `Asteroid size (width and height)
   ASTEROID_SIZE = 128 + rnd(128)

   `Center point
   cP# = ASTEROID_SIZE * 0.5

   `reset the angle to 0
   angle# = 0.0

   `Make a colour
   col as dword

   select rnd(7)
      case 0 : col = rgb(255, 128, 128) : endcase
      case 1 : col = rgb(128, 255, 128) : endcase
      case 2 : col = rgb(128, 128, 255) : endcase
      case 3 : col = rgb(255, 255, 128) : endcase
      case 4 : col = rgb(255, 128, 255) : endcase
      case 5 : col = rgb(128, 255, 255) : endcase
      case 6 : col = rgb(255, 255, 255) : endcase
      case 7 : col = rgb(128, 128, 128) : endcase
   endselect
   inc col,(128 << 24) && 0xFFFFFFFF

   `Used for getting center average point
   tX# = 0
   tY# = 0

   for i = 0 to ASTEROID_POINTS
      if i < ASTEROID_POINTS
         `Get the angle
         angle# = 360.0 * i / (ASTEROID_POINTS * 1.0)

         `Distance is currently 95% of the radius (distance from edge to middle) - this SHOULD make a "circle"
         dist# = (cP# * 0.95) * (rnd(60) + 40) * 0.01

         `Create a point based on the current angle, above distance and the center point.
         psuedoLineArray(j, i).p.x# = (cos(angle#) * dist#) + cP#
         psuedoLineArray(j, i).p.y# = (sin(angle#) * dist#) + cP#
      else
         psuedoLineArray(j, ASTEROID_POINTS).p.x# = psuedoLineArray(j, 0).p.x#
         psuedoLineArray(j, ASTEROID_POINTS).p.y# = psuedoLineArray(j, 0).p.y#
      endif

      inc tX#, psuedoLineArray(j, i).p.x#
      inc tY#, psuedoLineArray(j, i).p.y#
   next i

   Asteroids(j).cX# = tX# / (ASTEROID_POINTS * 1.0)
   Asteroids(j).cY# = tY# / (ASTEROID_POINTS * 1.0)
   Asteroids(j).size = ASTEROID_SIZE
   Asteroids(j).radiusSquared = (ASTEROID_SIZE * 0.5) * (ASTEROID_SIZE * 0.5)


   make memblock 1, 12 + (ASTEROID_SIZE * ASTEROID_SIZE * 4)
   write memblock dword 1, 0, ASTEROID_SIZE
   write memblock dword 1, 4, ASTEROID_SIZE
   write memblock dword 1, 8, 32


   `CODE HERE BASED ON: http://astronomy.swin.edu.au/~pbourke/geometry/insidepoly/
   p as psuedoPoint
   `p1 as psuedoPoint
   `p2 as psuedoPoint
   for y = 0 to ASTEROID_SIZE - 1
      for x = 0 to ASTEROID_SIZE - 1
         pos = 12 + ((y * ASTEROID_SIZE) + x) * 4

         p.x# = x
         p.y# = y

         if PointInAsteroid(p, j) = 0
            `outside
            write memblock dword 1, pos, 0
         else
            `inside
            write memblock dword 1, pos, col
         endif
      next x
   next y
   make image from memblock j, 1

   delete memblock 1

   sprite j, 0, 0, j
`   offset sprite j, ASTEROID_SIZE * 0.5, ASTEROID_SIZE * 0.5
   offset sprite j, Asteroids(j).cX#, Asteroids(j).cY#

   Asteroids(j).x# = rnd(screen width())
   Asteroids(j).y# = rnd(screen height())

   Asteroids(j).speedX# = rnd(25) + 25 : if rnd(1) then Asteroids(j).speedX# = Asteroids(j).speedX# * -1
   Asteroids(j).speedY# = rnd(25) + 25 : if rnd(1) then Asteroids(j).speedY# = Asteroids(j).speedY# * -1
   Asteroids(j).rotSpeed# = rnd(40) + 20 : if rnd(1) then Asteroids(j).rotSpeed# = Asteroids(j).rotSpeed# * -1
   Asteroids(j).angle# = 0.0

   Asteroids(j).imgId = j : `Temp - will allow multiple asteroids for randomness
next j





global frameTime#
frameTime# = 1.0
startTime = timer()
do
   frameTime# = (frameTime# * 0.8) + ((timer() - startTime) * 0.2)
   startTime = timer()

   `paste image 100, 0, 0, 0
   moveAsteroids()

   for i = 1 to ASTEROID_COUNT
         p as psuedoPoint
         p.x# = mousex() - (Asteroids(i).x# - Asteroids(i).cX#)
         p.y# = mousey() - (Asteroids(i).y# - Asteroids(i).cY#)

         if p.x# >= 0 AND p.x# <= Asteroids(i).size AND p.y# >= 0 AND p.y# <= Asteroids(i).size
            pia = PointInAsteroid(p, i)
            if pia = 0
               text 20, i*10, str$(i) + ": Inside box..."
            else
               text 20, i*10, str$(i) + ": Inside asteroid..."
            endif
         else
            text 20, i * 10, str$(i) + ": Outside box..."
         endif

      text Asteroids(i).x#, Asteroids(i).y#, str$(i)
   next i


   text 0, screen height() - 20, "FPS: " + str$(screen fps())
   sync
loop
end


function PointInAsteroid(p as psuedoPoint, j)
   `Check if point p is within asteroid 'j'
   p1 as psuedoPoint
   p2 as psuedoPoint
   counter = 0

   p1 = psuedoLineArray(j, 0).p
   for i = 1 to ASTEROID_POINTS
      p2 = psuedoLineArray(j, i MOD ASTEROID_POINTS).p

      if p.y# > MIN(p1.y#, p2.y#)
         if p.y# <= MAX(p1.y#, p2.y#)
            if p.x# <= MAX(p1.x#, p2.x#)
               if p1.y# <> p2.y#
                  xinters# = (p.y# - p1.y#) * (p2.x# - p1.x#) / (p2.y# - p1.y#) + p1.x#
                  if p1.x# = p2.x# OR p.x# <= xinters# then inc counter
               endif
            endif
         endif
      endif

      p1 = p2
   next i

   result = counter MOD 2
endfunction result













function moveAsteroids()
   for j = 1 to ASTEROID_COUNT
      inc Asteroids(j).x#, Asteroids(j).speedX# * frameTime# * 0.001
      inc Asteroids(j).y#, Asteroids(j).speedY# * frameTime# * 0.001
      `inc Asteroids(j).angle#, Asteroids(j).rotSpeed# * frameTime# * 0.001
      `rotate sprite j, Asteroids(j).angle#

      sprite j, Asteroids(j).x#, Asteroids(j).y#, Asteroids(j).imgId

      if Asteroids(j).x# < ASTEROID_SIZE * 0.5
         `Paste a duplicate on the other side
         paste sprite j, Asteroids(j).x# + screen width(), Asteroids(j).y#
         `If off screen - move to the other side
         if Asteroids(j).x# < 0 then if Asteroids(j).speedX# < 0 then Asteroids(j).x# = Asteroids(j).x# + screen width()
      else
         if Asteroids(j).x# > screen width() - (ASTEROID_SIZE * 0.5)
            `Paste a duplicate on the other side
            paste sprite j, Asteroids(j).x# - screen width(), Asteroids(j).y#
            `If off screen - move to the other side
            if Asteroids(j).x# > screen width() then if Asteroids(j).speedX# > 0 then Asteroids(j).x# = Asteroids(j).x# - screen width()
         endif
      endif



      if Asteroids(j).y# < ASTEROID_SIZE * 0.5
         `Paste a duplicate on the other side
         paste sprite j, Asteroids(j).x#, Asteroids(j).y# + screen height()
         `If off screen - move to the other side
         if Asteroids(j).y# < 0 then if Asteroids(j).speedY# < 0 then Asteroids(j).y# = Asteroids(j).y# + screen height()
      else
         if Asteroids(j).y# > screen height() - (ASTEROID_SIZE * 0.5)
            `Paste a duplicate on the other side
            paste sprite j, Asteroids(j).x#, Asteroids(j).y# - screen height()
            `If off screen - move to the other side
            if Asteroids(j).y# > screen height() then if Asteroids(j).speedY# > 0 then Asteroids(j).y# = Asteroids(j).y# - screen height()
         endif
      endif
   next j
endfunction


















function MIN(a#, b#)
   if a# < b# then r# = a# else r# = b#
endfunction r#

function MAX(a#, b#)
   if a# > b# then r# = a# else r# = b#
endfunction r#

850mhz PIII
100mhz fsb
384mb ram
geforce2 mx400 64mb card (agp 2x)

`Challenge Compo - Asteroids Game
`by Bill Robinson
`due: 2-25-06

`@Kimosabi - you do NOT have rights to use this program as your own.
`And you never should have used Ric's pong game as your own, on your web sight!
`
`Use 'Z' and 'X' to rotate ship, leftarrow and rightarrow work too
`Use comma ',' to fire, period '.' to thrust
`Use 'Space' to Hyperspace to a new position
`
`Using Hyperspace FREEZES TIME while your ship is in hyperspace traveling to new location.
`If ship traveling through Hyperspace lands on an asteroid,
`you have a brief moment to engage Hyperspace again to save your ship
`Hyperspace will also bring your moving ship to a stop
`
set display mode 1024,768,32
autocam off
sync on
sync rate 60
Hide Mouse
Backdrop on
Color Backdrop 0
set ambient light 15
set camera range 1,5000
randomize timer()

`--- Game Setup ---
#constant MAX_ASTEROIDS 100
global GREEN
GREEN=rgb(0,255,0)
global level
global newlevel
global score
global targetsleft
global numasteroids

`--- Player ---
global ship_x#
global ship_y#
global ship_z#=0
global shipangle#
global shipthrust#
global shipmass#
global explode_object=0
global expdone=0
global exparrayindex=1
global expparticleindex=1
global numhits
global playerdeadtime
global velx#=0
global vely#=0
global incx#=0
global incy#=0

`--- asteroids ---
`1=active, 2=size, 3=x, 4=y, 5=z, 6=xinc, 7=yinc, 8=zinc, 9=xrot,10=yrot, 11=zrot, 12=color
dim ast_info#(MAX_ASTEROIDS,15)
` highest number of vertexes = 200 for now
global vcount=200
dim vertex_count(100)
dim v_pos_x#(100,vcount)
dim v_pos_y#(100,vcount)
dim v_pos_z#(100,vcount)

`--- explosion particles ---
rem Arrays for position, velocity and life of each explosion particle
dim partx#(300)
dim party#(300)
dim partz#(300)
dim partxvel#(300)
dim partyvel#(300)
dim partzvel#(300)
dim partlife(300)
dim explosion(10,10)
global start_time=0
global inten#=60.0
global max=200


`--- Shots Fired ---
dim shots(100,4)
global shotptr
global shotspeed#
global lastshot
global shottime
global shotpause
global hitnum
global maxshots
global numshots

`--- Players shots getting made ---
for i=400 to 410
   make object sphere i,30,3,3
   xrotate object i,90
   color object i,rgb(255,255,255)
   scale object i,20,20,100
   set object collision off i
   hide object i
next i

`--- hyperspace ships ---
global numhyper=5
dim hyperinfo#(numhyper,6)
color=GREEN
for i=1 to numhyper
   obnum=1020+i
   make object cone obnum, 20

   color object obnum,color
   ghost object on obnum
   hide object obnum
next i

`------------------------
screen_xmax=screen width()
screen_ymax=screen height()
screen_center=screen_xmax/2

`--- make cone for ship ---
make object cone 1000,20
color object 1000,rgb(0,255,0)
set object collision on 1000
set object collision to spheres 1000
fix object pivot 1000

`make object box 999,2,2,2
`color object 999,rgb(255,255,0)
`glue object to limb 999,1000,0
`offset limb 999,0,0,-15,0

`--- make explosion pieces ---
color=rgb(255,255,255)
for i=1 to max
   obnum=100+i
   make object plain obnum,6,6
   color object obnum,color
   hide object obnum
next i

_reset_vars()
_make_stars()

`--- setup starfield in background ---
make object plain 998,1300,1000
texture object 998, 1
position object 998,0,0,200

`--- debug limits of screen, for wrap-around of objects ---
global lwall=-480
global rwall=480
global twall=360
global bwall=-360

position object 1000, 0,0,0
position camera 0,0,-600
point camera 0,0,0

do
   set object collision on 1000

   if newlevel=1 then _new_level()
   if targetsleft=0 then newlevel=1

   for i=1 to numasteroids
      pitch object down i,ast_info#(i,9)           :`tumble asteroids in all three axis
      turn object right i,ast_info#(i,10)
      roll object right i,ast_info#(i,11)

      inc ast_info#(i,3),ast_info#(i,6)
      inc ast_info#(i,4),ast_info#(i,7)
      `--- wrap asteroids around screen if needed -----
      ast_info#(i,3)=_asteroid_screen_wrapx(ast_info#(i,3),ast_info#(i,2))    :`returns a screen wrap coord if object x-value went off screen
      ast_info#(i,4)=_asteroid_screen_wrapy(ast_info#(i,4),ast_info#(i,2))    :`returns a screen wrap coord if object y-value went off screen
      position object i,ast_info#(i,3),ast_info#(i,4),ast_info#(i,5)          :`position asteroid in new location
   next i
   `explosion 1=active flag, 2=object, 3=#particles, 4=intensity, 5=particle life, 6=particle start num, 7=color
   if keystate(48)=1                            :`b key - self destruct
      _set_explosion(1000,50,30,100,GREEN)
      playerdeadtime=200
   endif

   if leftkey()=1 then inc shipangle#,3         :`left arrow key
   if rightkey()=1 then dec shipangle#,3        :`right arrow key
   if keystate(44)=1 then inc shipangle#,3      :`z key
   if keystate(45)=1 then dec shipangle#,3      :`x key
   if keystate(29)=1 then _fire_missle()        :`ctrl key
   if keystate(57)=1                            :`space key
      _hyperspace()
      velx#=0:vely#=0:incx#=0:incy#=0
   endif

   if keystate(51)=1 and numshots<maxshots then _shoot()
   if keystate(52)=1
      incx#=-sin(shipangle#)*shipthrust#
      incy#=cos(shipangle#)*shipthrust#
   else
      incx#=0
      incy#=0
   endif

   `calc ship velocity
   deltax#=incx#/shipmass#
   deltay#=incy#/shipmass#
   inc velx#,deltax#
   inc vely#,deltay#

   inc ship_x#,velx#
   inc ship_y#,vely#

   shipangle#=wrapvalue(shipangle#)

`   exhaust#=thrust#
`   dec exhaust#, 1
`   if exhaust#<0 then exhaust#=0

   ship_x#=_ship_screen_wrapx(ship_x#)             :`wrap players ship around screen if needed
   ship_y#=_ship_screen_wrapy(ship_y#)

   zrotate object 1000,shipangle#                  :`rotate players ship
   position object 1000,ship_x#,ship_y#,ship_z#    :`position ship on screen

`----------------------------This is messy code----may just post it this way for now--------
   for ex=1 to 10
      if explosion(ex,1)=1
         ex#=object position x(explosion(ex,2))
         ey#=object position y(explosion(ex,2))
         ez#=object position z(explosion(ex,2))
         if expparticleindex+explosion(ex,3)>=200
            expparticleindex=1
         endif
         explosion(ex,6)=expparticleindex
         inc expparticleindex,explosion(ex,3)
   `explosion() 1=active flag, 2=object, 3=#particles, 4=intensity, 5=particle life, 6=particle start num, 7=color
         _request_explosion(ex#,ey#,ez#,explosion(ex,3),explosion(ex,4),explosion(ex,5),explosion(ex,6),explosion(ex,7))
         start_time=1

         hide object explosion(ex,2)               :`was explode_object
         set object collision off explosion(ex,2)  :`was explode_object
         explosion(ex,1)=2
      endif
   next ex

   _check_hits()           :`check for player hits from shots
   _check_playerhit()
   _move_shots()           :`move player shots
   _continue_explosion()     :`continue to explode pieces

   if playerdeadtime>0
      dec playerdeadtime
      if playerdeadtime=0
         velx#=0:vely#=0:incx#=0:incy#=0
         _hyperspace()
         set object collision on 1000
      endif
   endif

   if expdone=1
      explode_object=0
      start_time=0
      expdone=0
   endif

   set cursor 1,1
   print screen fps()
   center text screen_center,10,"Level: "+str$(level)+"     Targets Left: "+str$(targetsleft)+"     Score: "+str$(score)
   sync
loop

`--- array entry for another explosion ---
function _set_explosion(object,numparticles,intensity,particlelife,color)
explosion(exparrayindex,1)=1                 :`explosion flag 1=on 0=off
explosion(exparrayindex,2)=object            :`object to explode
explosion(exparrayindex,3)=numparticles      :`number of particles
explosion(exparrayindex,4)=intensity         :`intensity
explosion(exparrayindex,5)=particlelife      :`particle life
explosion(exparrayindex,7)=color             :`color of particles
inc exparrayindex
if exparrayindex>10 then exparrayindex=1
endfunction


`--- builds new level ---
function _new_level()
inc level
set text size 24
sync
center text screen_center,10,"Level:"+str$(level)
sync
set text size 12
wait 1000
numasteroids=0
newasteroids=7+level
for i=1 to 99
   if object exist(i)=1
      delete object i
   endif
next i
if level<10
   size=3
   _add_asteroids(newasteroids,size,0)
   newlevel=0
endif
ship_x#=0
ship_y#=0
endfunction


function _check_playerhit()
hnum=object collision(1000,0)
   if hnum>0
      if hnum<100
         inc numhits
         if numhits>50
`           hide object objnum                           :`hide shot
`           set object collision off objnum
`           position object objnum,-3000,-3000,-3000     :`just move offscreen

            hide object 1000                           :`hide player ship
            set object collision off 1000
            position object 1000,-2000,-2000,-2000     :`just move offscreen
            _set_explosion(1000,50,30,100,GREEN)
            numhits=0
            playerdeadtime=250
`            set object collision on 1000
`            show object 1000
`            position object 1000,ship_x#,ship_y#,ship_z#
         endif
      endif
   endif
endfunction


function _check_hits()
sync rate 0
for i=1 to 10
   if shots(i,1)=1
      objnum=shots(i,2)
      hitnum=object collision(objnum,0)
      if hitnum>0
         if hitnum<100
            hide object objnum                           :`hide shot
            set object collision off objnum
            position object objnum,-3000,-3000,-3000     :`just move offscreen

            hide object hitnum                           :`hide asteroid
            set object collision off hitnum
            position object hitnum,-2000,-2000,-2000     :`just move offscreen

            inc score,10
            dec targetsleft
            size=ast_info#(hitnum,2)                     :`size of the hit asteroid
            if size>1
               _add_asteroids(2,size-1,hitnum)

            endif
            _set_explosion(hitnum,10,3*size,20,ast_info#(hitnum,12))
         endif
      endif
   endif
next i
sync rate 60
endfunction


`--- Player Shots - 1=active, 2=obnum, 3=shotlife, ---
function _shoot()
shottime=timer()-lastshot
if shottime<shotpause then exitfunction
   position object shotptr,ship_x#,ship_y#,0
   show object shotptr
   zrotate object shotptr,shipangle#
   set object collision on shotptr
   set object collision to spheres shotptr
   shots(shotptr-399,1)=1
   shots(shotptr-399,2)=shotptr
   shots(shotptr-399,3)=500
   inc shotptr
   if shotptr>=410 then shotptr=400
   lastshot=timer()
   inc numshots
endfunction


function _move_shots()
   for i=1 to 10
      if shots(i,1)=1
         obnum=shots(i,2)
         move object obnum,-shotspeed#
         posx#=object position x(obnum)
         posy#=object position y(obnum)
         posx#=_ship_screen_wrapx(posx#)
         posy#=_ship_screen_wrapy(posy#)
         position object obnum,posx#,posy#,0
         dec shots(i,3),shotspeed#
         if shots(i,3)<=0 then _remove_shot(obnum):shots(i,1)=0
      endif
   next i
endfunction


function _remove_shot(obnum)
set object collision off obnum
position object shotptr,-2000,-2000,-2000    :`just move offscreen
hide object obnum
dec numshots
endfunction


function _fire_missle()

endfunction


function _asteroid_screen_wrapx(x#,size#)
limit#=490+size#*15.0
if x#>limit# then x#=-limit#
if x#<-limit# then x#=limit#
endfunction x#


function _asteroid_screen_wrapy(y#,size#)
limit#=380+size#*15.0
if y#>limit# then y#=-limit#
if y#<-limit# then y#=limit#
endfunction y#


function _ship_screen_wrapx(x#)
if x#>500 then x#=-500
if x#<-500 then x#=500
endfunction x#


function _ship_screen_wrapy(y#)
if y#>380 then y#=-380
if y#<-380 then y#=380
endfunction y#


function _make_stars()
ink rgb(255,255,255),0
for x=1 to 250
   dot rnd(1024),rnd(768)
next x
get image 1,0,0,1024,768,1
endfunction


function _reset_vars()
`   thrust#=0
`   exhaust#=1
`   vel#=0
   level=0
   newlevel=1
   targetsleft=0
   numasteroids=0

   ship_y#=0
   ship_x#=0
   shipthrust#=3.0
   shipmass#=50.0

   expdone=0
   exparrayindex=1
   expparticleindex=1
   shotptr=400
   shotspeed#=4
   shotpause=150
   maxshots=5
   numshots=0

   fusetime#=1
   fuselength=1
   boomflag=0
endfunction


`--------DB demo routines for explosions--------
function _request_explosion(ex#,ey#,ez#,particles,intensity#,life,partindex,color)
`t=0:p=0
`repeat
`   t=t+1
for i=partindex to partindex+particles
`   if partlife(t)=0
`      p=p+1
      partlife(i)=life + rnd(life/5)
      partx#(i)=ex#
      party#(i)=ey#
      partz#(i)=ez#
      partyvel#(i)=rnd(intensity#)-(intensity#/2)
      partxvel#(i)=rnd(intensity#)-(intensity#/2)
      partzvel#(i)=rnd(intensity#)-(intensity#/2)
      show object 100+i           :`100+t
      color object 100+i,color    :`100+t,color
`   endif
`   if p>=particles then exit
`until t>=100
next i
endfunction


`explosion 1=active flag, 2=object, 3=#particles, 4=intensity, 5=particle life, 6=particle start num, 7=
function _continue_explosion()
for ex=1 to 10
   if explosion(ex,1)=2
      for t=explosion(ex,6) to explosion(ex,6)+explosion(ex,3)
         if partlife(t)>1
            dec partlife(t)
            position object 100+t,partx#(t),party#(t),partz#(t)
            partxvel#(t)=partxvel#(t)*0.98                 :`was 0.95
            partyvel#(t)=partyvel#(t)*0.98
`           partzvel#(t)=partzvel#(t)*0.95                 :`particles slow down from air friction
            partzvel#(t)=0.0
`           partyvel#(t)=partyvel#(t)-0.5                  :`particles effected by gravity
            inc partx#(t),partxvel#(t)
            inc party#(t),partyvel#(t)
            inc partz#(t),partzvel#(t)
`           if party#(t)<=0 then partyvel#(t)=partyvel#(t)*-0.7     :`particles bounce on the ground
            rotate object t+100,wrapvalue(object angle x(t+100)+rnd(50)),wrapvalue(object angle y(t+100)+rnd(100)),0
         endif
         if partlife(t)=1
            partlife(t)=0
            hide object 100+t
            start_time=0
            expdone=1
`            explosion(ex,1)=0
         endif
      next t
   endif
next ex
endfunction


function _add_asteroids(num,size,hitnum)
sync rate 0
for i=1 to num
   astnum=numasteroids+1
`   size=rnd(2)+1
   _make_asteroids(astnum,size)

   set object smoothing astnum,0
   set object collision on astnum
   set object collision to spheres astnum
`1=active, 2=size, 3=x, 4=y, 5=z, 6=xinc, 7=yinc, 8=zinc, 9=xrot,10=yrot, 11=zrot, 12=color
   ast_info#(astnum,1)=1
   ast_info#(astnum,2)=size
   if hitnum>0
      ast_info#(astnum,3)=ast_info#(hitnum,3)     :`use larger asteroid location
      ast_info#(astnum,4)=ast_info#(hitnum,4)
   else
      ast_info#(astnum,3)=rnd(1200)-600           :`random location
      ast_info#(astnum,4)=rnd(1200)-600
   endif
   ast_info#(astnum,5)=0

   v#=(rnd(3)+0.8)/(rnd(10)+1.0)       :`generate a motion value
   d=rnd(10):if d>5 then v#=v#*-1.0    :`decide whether a positive or negative motion
   ast_info#(astnum,6)=v#

   v#=(rnd(3)+0.8)/(rnd(10)+1.0)       :`generate a motion value
   d=rnd(10):if d>5 then v#=v#*-1.0    :`decide whether a positive or negative motion
   ast_info#(astnum,7)=v#

   ast_info#(astnum,8)=0

   v#=rnd(3)/(rnd(10)+1.0)             :`generate a rotation value
   d=rnd(10):if d>5 then v#=v#*-1.0    :`decide whether a positive or negative rotation
   ast_info#(astnum,9)=v#

   v#=rnd(3)/(rnd(10)+1.0)
   d=rnd(10):if d>5 then v#=v#*-1.0
   ast_info#(astnum,10)=v#

   v#=rnd(3)/(rnd(10)+1.0)
   d=rnd(10):if d>5 then v#=v#*-1.0
   ast_info#(astnum,11)=v#

   if hitnum>0
      color=ast_info#(hitnum,12)     :`use larger asteroid color
   else
      color=rgb(rnd(255),rnd(255),rnd(255))  :`use random color
   endif
   ast_info#(astnum,12)=color
   color object astnum,ast_info#(astnum,12)
   position object astnum,ast_info#(astnum,3),ast_info#(astnum,4),ast_info#(astnum,5)
   show object astnum

   inc numasteroids
   inc targetsleft
next i
sync rate 60
endfunction


` ----- Make Asteroids --- Trying vertex commands for the first time! -----
function _make_asteroids(num,size)
objs=num
make object sphere objs,60
if size=2 then scale object objs,70,70,70
if size=1 then scale object objs,30,30,30

` get vertex data
ob=objs
make mesh from object 1,ob
lock vertexdata for mesh  1
vertex_count(ob)=(GET VERTEXDATA VERTEX COUNT()-1)
for v=0 to vertex_count(ob)
   v_pos_x#(ob,v)=GET VERTEXDATA POSITION X(v)+object position x(ob)
   v_pos_y#(ob,v)=GET VERTEXDATA POSITION y(v)+object position y(ob)
   v_pos_z#(ob,v)=GET VERTEXDATA POSITION z(v)+object position z(ob)
next v
unlock vertexdata
delete mesh 1

` deform vertices 4-10 times for jagged look
for deftimes=1 to (rnd(6)+4)
   make mesh from object 1,ob
   lock vertexdata for mesh  1
   for i=0 to vertex_count(ob)
      xdir=rnd(10):if xdir>5 then xdir=1 else xdir=-1
      ydir=rnd(10):if ydir>5 then ydir=1 else ydir=-1
      zdir=rnd(10):if zdir>5 then zdir=1 else zdir=-1
      inc v_pos_x#(ob,i),rnd(5)*xdir
      inc v_pos_y#(ob,i),rnd(5)*ydir
      inc v_pos_z#(ob,i),rnd(5)*zdir
      SET VERTEXDATA POSITION i, v_pos_x#(ob,i),v_pos_y#(ob,i),v_pos_z#(ob,i)
   next i
   unlock vertexdata
   make object 5000,1,0
   delete mesh 1
   delete object ob
   clone object ob,5000
   delete object 5000
next deftimes
endfunction


` ----- Hyperspace ship to new location --- This was interesting to work out -----
function _hyperspace()
sync rate 0
hyperflag=1
numslices=3
destx#=rnd(850)-425
desty#=rnd(650)-325
hide object 1000

for i=1 to numhyper
   hyperinfo#(i,1)=ship_x#
   hyperinfo#(i,2)=ship_y#
   obnum=1020+i
   xrotate object obnum,object angle x(1000)
   yrotate object obnum,object angle y(1000)
   zrotate object obnum,object angle z(1000)
   position object obnum,hyperinfo#(i,1), hyperinfo#(i,2), 0
   show object obnum
next i

hyperinfo#(1,1)=destx#
hyperinfo#(1,2)=desty#
position object 1021,hyperinfo#(1,1), hyperinfo#(1,2), 0

count=0
while hyperflag=1
   for i=2 to numhyper
      hyperinfo#(i,3)=(hyperinfo#(i-1,1)-hyperinfo#(i,1))/numslices
      hyperinfo#(i,4)=(hyperinfo#(i-1,2)-hyperinfo#(i,2))/numslices
      inc hyperinfo#(i,1),hyperinfo#(i,3)
      inc hyperinfo#(i,2),hyperinfo#(i,4)
      position object 1020+i,hyperinfo#(i,1), hyperinfo#(i,2), 0
      sync
   next i
   inc count
   if count>=numhyper*numslices*2 then hyperflag=0
endwhile
ship_x#=destx#
ship_y#=desty#
box_xdir#=0
box_ydir#=0
position object 1000,ship_x#,ship_y#,ship_z#
show object 1000

for i=1 to numhyper
   hide object 1020+i
next i
sync
sync rate 60
endfunction

`----- builds each level -----
function _next_level()

endfunction


remstart
function _rocket_thrust()
`thrust ,1=active, 2=x, 3=y, 4=xinc, 5=yinc
for i=1 to numthrust
   if thrust(i,1)=1
      thnum=2000+i
      inc thrust(i,2),thrust(i,4)
      inc thrust(i,3),thrust(i,5)
      position object thnum,thrust(i,2),thrust(i,3),0
   endif
next i
endfunction
remend

set display mode 1280, 1024, 32
sync on
sync rate 0
randomize timer()
backdrop on
color backdrop 0


type psuedoPoint
   x#
   y#
endtype

type psuedoLine
   p as psuedoPoint
endtype

type Asteroid
   x#
   y#
   speedX#
   speedY#
   rotSpeed#
   angle#

   cX#
   cY#

   imgId
   size
   radiusSquared
endtype




#constant ASTEROID_POINTS 12
#constant ASTEROID_COUNT 6
#constant ASTEROID_MIN_RADIUS_FACTOR 0.40
#constant ASTEROID_MAX_RADIUS_FACTOR 0.99

Dim Asteroids(ASTEROID_COUNT) as Asteroid

`Lines
Dim psuedoLineArray(ASTEROID_COUNT, ASTEROID_POINTS) as psuedoLine


`Make 'ASTEROID_COUNT' asteroids
for j = 1 to ASTEROID_COUNT
   `Asteroid size (width and height)
   ASTEROID_SIZE = 128 + rnd(128)

   `Make a colour
   col as dword

   select rnd(7)
      case 0 : col = rgb(255, 128, 128) : endcase
      case 1 : col = rgb(128, 255, 128) : endcase
      case 2 : col = rgb(128, 128, 255) : endcase
      case 3 : col = rgb(255, 255, 128) : endcase
      case 4 : col = rgb(255, 128, 255) : endcase
      case 5 : col = rgb(128, 255, 255) : endcase
      case 6 : col = rgb(255, 255, 255) : endcase
      case 7 : col = rgb(128, 128, 128) : endcase
   endselect
   inc col,(128 << 24) && 0xFFFFFFFF


   for i = 0 to ASTEROID_POINTS
      if i < ASTEROID_POINTS
         `Get the angle
         angle# = 360.0 * i / (ASTEROID_POINTS * 1.0)

         `Distance is currently 95% of the radius (distance from edge to middle) - this SHOULD make a "circle"
         dist# = (ASTEROID_SIZE * ASTEROID_MIN_RADIUS_FACTOR)   +   (rnd(ASTEROID_SIZE * 100.0 * (ASTEROID_MAX_RADIUS_FACTOR - ASTEROID_MIN_RADIUS_FACTOR)) * 0.01)
         dist# = dist# * 0.5

         `Create a point based on the current angle, above distance. This is from the origin; 0,0
         psuedoLineArray(j, i).p.x# = (cos(angle#) * dist#) `+ cP#
         psuedoLineArray(j, i).p.y# = (sin(angle#) * dist#) `+ cP#
      else
         psuedoLineArray(j, ASTEROID_POINTS).p.x# = psuedoLineArray(j, 0).p.x#
         psuedoLineArray(j, ASTEROID_POINTS).p.y# = psuedoLineArray(j, 0).p.y#
      endif
   next i

   Asteroids(j).cX# = ASTEROID_SIZE * 0.5
   Asteroids(j).cY# = ASTEROID_SIZE * 0.5
   Asteroids(j).size = ASTEROID_SIZE
   Asteroids(j).radiusSquared = (ASTEROID_SIZE * 0.5) * (ASTEROID_SIZE * 0.5)


   make memblock 1, 12 + (ASTEROID_SIZE * ASTEROID_SIZE * 4)
   write memblock dword 1, 0, ASTEROID_SIZE
   write memblock dword 1, 4, ASTEROID_SIZE
   write memblock dword 1, 8, 32


   p as psuedoPoint
   for y = 0 to ASTEROID_SIZE - 1
      for x = 0 to ASTEROID_SIZE - 1
         pos = 12 + ((y * ASTEROID_SIZE) + x) * 4

         p.x# = x - (ASTEROID_SIZE * 0.5)
         p.y# = y - (ASTEROID_SIZE * 0.5)

         if PointInAsteroid(p, j, 0.0) = 0
            `outside
            write memblock dword 1, pos, 0
         else
            `inside
            write memblock dword 1, pos, col
         endif
      next x
   next y
   make image from memblock j, 1

   delete memblock 1

   sprite j, 0, 0, j
   offset sprite j, Asteroids(j).cX#, Asteroids(j).cY#

   Asteroids(j).x# = rnd(screen width())
   Asteroids(j).y# = rnd(screen height())

   Asteroids(j).speedX# = rnd(25) + 25 : if rnd(1) then Asteroids(j).speedX# = Asteroids(j).speedX# * -1
   Asteroids(j).speedY# = rnd(25) + 25 : if rnd(1) then Asteroids(j).speedY# = Asteroids(j).speedY# * -1
   Asteroids(j).rotSpeed# = rnd(40) + 20 : if rnd(1) then Asteroids(j).rotSpeed# = Asteroids(j).rotSpeed# * -1
   Asteroids(j).angle# = 0.0

   Asteroids(j).imgId = j : `Temp - will allow multiple asteroids for randomness
next j





global frameTime#
frameTime# = 1.0
startTime = timer()
do
   frameTime# = (frameTime# * 0.8) + ((timer() - startTime) * 0.2)
   startTime = timer()

   moveAsteroids()
   checkAsteroids()

   text 0, screen height() - 20, "FPS: " + str$(screen fps())
   sync
loop
end


exitfunction
function checkAsteroids()
   for i = 1 to ASTEROID_COUNT
      for j = i+1 to ASTEROID_COUNT
         `Check squared distance between asteroids... Quicker check to see if we need to check points
         dx# = Asteroids(i).x# - Asteroids(j).x#
         dy# = Asteroids(i).y# - Asteroids(j).y#
         radiussum# = (Asteroids(i).size * 0.5) + (Asteroids(j).size * 0.5)

         if (dx#*dx#)+(dy#*dy#) <= radiussum#*radiussum#
            `Compare asteroid i to j. This loop structure should stop comparing A to B then B to A...
            ap as psuedoPoint
            angle# = Asteroids(i).angle#
            for k = 1 to ASTEROID_POINTS
               ap.x# = (psuedoLineArray(i, k).p.x# * cos(angle#)) - (psuedoLineArray(i, k).p.y# * sin(angle#))
               ap.y# = (psuedoLineArray(i, k).p.x# * sin(angle#)) + (psuedoLineArray(i, k).p.y# * cos(angle#))

               inc ap.x#, dx#
               inc ap.y#, dy#

               `Point p is now 1 vertice of asteroid 'i'. See if this point is in asteroid 'j'
               if PointInAsteroid(ap, j, Asteroids(j).angle#) = 1 then text 400, 400, "ASTEROID COLLISION!!!"
            next k
         endif
      next j
   next i
endfunction







`CODE HERE BASED ON: http://astronomy.swin.edu.au/~pbourke/geometry/insidepoly/
function PointInAsteroid(p as psuedoPoint, j, angle#)
   `Check if point p is within asteroid 'j'
   p1 as psuedoPoint
   p2 as psuedoPoint
   counter = 0


   `Angle is zero, no need to rotate!
   if angle# = 0.0
      p1 = psuedoLineArray(j, 0).p
   else
      p1.x# = (psuedoLineArray(j, 0).p.x# * cos(angle#)) - (psuedoLineArray(j, 0).p.y# * sin(angle#))
      p1.y# = (psuedoLineArray(j, 0).p.x# * sin(angle#)) + (psuedoLineArray(j, 0).p.y# * cos(angle#))
   endif


   for i = 1 to ASTEROID_POINTS
      if angle# = 0.0
         p2 = psuedoLineArray(j, i MOD ASTEROID_POINTS).p
      else
         iMODap = i MOD ASTEROID_POINTS
         p2.x# = (psuedoLineArray(j, iMODap).p.x# * cos(angle#)) - (psuedoLineArray(j, iMODap).p.y# * sin(angle#))
         p2.y# = (psuedoLineArray(j, iMODap).p.x# * sin(angle#)) + (psuedoLineArray(j, iMODap).p.y# * cos(angle#))
      endif



      if p.y# > MIN(p1.y#, p2.y#)
         if p.y# <= MAX(p1.y#, p2.y#)
            if p.x# <= MAX(p1.x#, p2.x#)
               if p1.y# <> p2.y#
                  xinters# = (p.y# - p1.y#) * (p2.x# - p1.x#) / (p2.y# - p1.y#) + p1.x#
                  if p1.x# = p2.x# OR p.x# <= xinters# then inc counter
               endif
            endif
         endif
      endif

      p1 = p2
   next i

   result = counter MOD 2
endfunction result








function moveAsteroids()
   for j = 1 to ASTEROID_COUNT
      inc Asteroids(j).x#, Asteroids(j).speedX# * frameTime# * 0.001
      inc Asteroids(j).y#, Asteroids(j).speedY# * frameTime# * 0.001
      inc Asteroids(j).angle#, Asteroids(j).rotSpeed# * frameTime# * 0.001
      rotate sprite j, Asteroids(j).angle#

      `Check for horizontal bounds
      if Asteroids(j).speedX# < 0
         `going left, are we too far?
         if Asteroids(j).x# + Asteroids(j).Size * 0.5 < 0 then inc Asteroids(j).x#, screen width() + Asteroids(j).Size
      else
         `going right, are we too far?
         if Asteroids(j).x# - Asteroids(j).Size * 0.5 > screen width() then dec Asteroids(j).x#, screen width() + Asteroids(j).Size
      endif



      `Check for vertical bounds
      if Asteroids(j).speedY# < 0
         `going up, are we too far?
         if Asteroids(j).y# + Asteroids(j).Size * 0.5 < 0 then inc Asteroids(j).y#, screen height() + Asteroids(j).Size
      else
         `going right, are we too far?
         if Asteroids(j).y# - Asteroids(j).Size * 0.5 > screen height() then dec Asteroids(j).y#, screen height() + Asteroids(j).Size
      endif

      sprite j, Asteroids(j).x#, Asteroids(j).y#, Asteroids(j).imgId
   next j
endfunction





function MIN(a#, b#)
   if a# < b# then r# = a# else r# = b#
endfunction r#

function MAX(a#, b#)
   if a# > b# then r# = a# else r# = b#
endfunction r#

type Thingies
   Thingy1 As Integer
   Thingy2 As Integer
endtype

type Tooties
   Tootie1 As Thingies
   Tootie2 As Thingies
endtype

dim Array(10) As Tooties

`now I can access stuff :D

Array(1).Tootie1.Thingy1 = 21

`------------------------------------------
`Bomb Functions
`------------------------------------------

Function Create_Bomb(Moving, X#, Y#, Z#)
	Add to queue Bombs(0)
	BNum = Array Count(Bombs(0))
	
	Bombs(BNum).X = X#
	`Declare all other variables to do with this bomb, as well as create object etc.
endfunction
 
Function Destroy_Bomb(BNum)
	Delete Object Bombs(BNum).Num
	Array Delete Element Bombs(0), BNum
endfunction

Bombs(BNum).MemoryLocation = Make Memory(Size)

type PointsArray
   p1 as PsuedoPoint
   p2 as PsuedoPoint
   p3 as PsuedoPoint
   p4 as PsuedoPoint
   p5 as PsuedoPoint
   p6 as PsuedoPoint
   p7 as PsuedoPoint
   p8 as PsuedoPoint
endtype

Function ReadInteger(Pointer As Dword)
	Remstart 
	This function just reads an integer from memory using a pointer number.
	
	***Special Thanks to IanM and all kinds of other people who wrote great
	posts that helped me understand this stuff!***
	Remend
	
	Local Value As Integer
	Value = *Pointer
endfunction Value


Function WriteInteger(Pointer As DWord, Value As Integer)
	Remstart
	This function writes an integer to a specific block of memory using a pointer number.
	
	***Special Thanks to IanM and all kinds of other people who wrote great
	posts that helped me understand this stuff!***
	Remend
	
	*Pointer = Value
endfunction

Function WriteFloat(Pointer As DWord, Value As Float)
	Remstart
	This function writes an float to a specific block of memory using a pointer number.
	Note: This function works ONLY in conjunction with my ReadFloat function.
	
	***Special Thanks to IanM and all kinds of other people who wrote great
	posts that helped me understand this stuff!***
	Remend
	
	*Pointer = Value
endfunction

Function ReadFloat(Pointer As Dword)
	Remstart 
	This function just reads an integer from memory using a pointer number, and
	then converts it to a decimal number using the integer's binary number.
	
	**Note: IanM's DLL functions (Peek and Poke) work CrAzIllY Faster than this
	one. Use only when those are not available.**	
	
	***Special Thanks to IanM and all kinds of other people who wrote great
	posts that helped me understand this stuff!***
	Remend
	
	Local Value As Integer  `This is the value that is retrieved from memory
	Local Number As Float   `This is the value to be exported
	Local Mantissa As Float `Base number in scientific notation
	Local Exponent As Float `Exponent in scientific notation
	Local Sign As Float: Sign = 1.0 `Positive or negative? (default positive)
		
	Value = *Pointer

	binary$ = bin$(Value)
	If Mid$(binary$,2) = "1" Then Sign = -1.0
	Exponent = BinaryToBase10(ExpandMid$(binary$,3,8))-127
	Mantissa = 1.0+((0.0+BinaryToBase10(ExpandMid$(binary$,11,23)))/8388608)
	Number = Sign*(2^Exponent)*Mantissa 
endfunction Number


Function ExpandMid$(astr$,start,number)
	For x = 0 To Number-1
		returnvar$ = returnvar$ + Mid$(astr$,start+x)		
	next x
endfunction returnvar$
 
Function BinaryToBase10(BinaryNumber$)
	Remstart
	This function simply takes a binary number (in the form of a string) and
	exports a base 10 number in the form of an integer.
	
	***Special thanks to Narf the Mouse of the Darkbasic Forums who wrote a 
	similar function from which this function was inspired.***
	Remend
	
	Local Base As Integer: Local Number As Integer
	Base = 1: Number = 0
	For x = Len(BinaryNumber$) To 1 Step -1
		If Mid$(BinaryNumber$,x) = "1" Then Number = Number + Base
		Base = Base*2		
	next x
endfunction Number

start:
cls
randomize timer()
`write 5 floats (4 * 5 = 20bytes)
ptr as DWORD
ptr = make memory (20)

for i = 0 to 4
   f# = (rnd(1000000) / 1000000.0) + rnd(100) - 50
   print " INPUT (" + str$(i) + ") : " + str$(f#)
   writeFloat(ptr + (i*4),  f#)
next i
print ""
print ""

for i = 0 to 4
   f# = readFloat(ptr + (i*4))
   print "OUTPUT(" + str$(i) + ") : " + str$(f#)
next i




wait key
delete memory ptr
goto start


function writeFloat(ptr as DWORD, value as float)
   *ptr = value
endfunction

function readFloat(ptr as DWORD)
   `Value directly from the pointer
   Result as integer
   Result = *ptr

   `the "fun" parts
   local Number as float
   local Exponent as float
   local Mantissa as float
   local Sign as float

   `Check the if left most bit is set using a mask
   if Result && %10000000000000000000000000000000 then Sign = -1.0 else Sign = 1.0

   `Check the exponent by shifting everything across 23 bits and masking for the right 8 bits only.
   Exponent = ((Result >> 23) && %00000000000000000000000011111111) - 127

   `Get the mantissa - basically, everything to the right of the exponent with some other jiggerypokery to make it a decimal.
   Mantissa = ((Result && %00000000011111111111111111111111) / 8388608.0) + 1.0

   `Put it all in a pot and stir for 20 mins until simmering... Et voila!
   Number = Sign * (2^Exponent) * Mantissa

endfunction Number

Function Convert_Float_to_DWord(f as Float)
   m=Free_Memblock()
   Make Memblock m,4
   Write Memblock Float m,0,f
   d as DWord
   d=Memblock DWord m,0
   Delete Memblock m
Endfunction d

Function Convert_Dword_to_Float(d as DWord)
   m=Free_Memblock()
   Make Memblock m,4
   Write Memblock DWord m,0,d
   f as float
   f=Memblock Float m,0
   Delete Memblock m
Endfunction f


Function Free_Memblock()
   i=1
   While Memblock Exist(i)=1
      Inc i
   Endwhile
Endfunction i

sync on : sync rate 50 : hide mouse
autocam off : randomize timer()

`d2l3=1
`load music "d2l3.mid",d2l3
`loop music d2l3

stars=1
for i=0 to 10000
   dot rnd(screen width()),rnd(screen height()),rgb(255,255,255)
next i
get image stars,0,0,screen width(),screen height(),0
make object plain stars,120,120
xrotate object stars,-90
texture object stars,stars
position object stars,0,-10,0
set object cull stars,0

global Plr=2
global Plrx#=0.0
global Plrz#=0.0
global Plrs#=0.0
global Plra#=0.0
global Fire
global Gun=2
global Score=0
global Lives=3
global SpawnTime
Fire=timer()
SpawnTime=timer()

make object cone Plr,5
scale object Plr,100,100,30
make object cone 3,5
scale object 3,150,90,30
make mesh from object 1,3
delete object 3
add limb Plr,1,1
delete mesh 1
offset limb Plr,1,0,-2,-0.5
color object Plr,rgb(0,0,255)
color limb Plr,1,rgb(50,255,50)
make object cylinder 3,5
scale object 3,12,60,12
make mesh from object 1,3
make mesh from object 2,3
delete object 3
add limb Plr,2,1
add limb Plr,3,2
delete mesh 1
delete mesh 2
offset limb Plr,2,2,-1,0
offset limb Plr,3,-2,-1,0
color limb Plr,2,rgb(100,100,100)
color limb Plr,3,rgb(100,100,100)
set object cull Plr,0
xrotate object Plr,90
fix object pivot Plr
set object collision on Plr

make object sphere 3,6
scale object 3,100,150,50
xrotate object 3,90
fix object pivot 3
color object 3,rgb(0,255,0)
ghost object on 3,4
hide object 3

position camera 0,50,0
point camera 0,0,0

do
   if rnd(30)=1 then MakeFreakAsteroid(rnd(360),rnd(7)+3)
   if mouseclick()=2 then inc Plrs#,0.05
   if mouseclick()<>2 then dec Plrs#,0.025
   if Plrs# >= 1.0 then Plrs#=1.0
   if Plrs# <= 0 then Plrs#=0
   Plra#=wrapvalue(Plra#+(mousemovex()*0.2))
   inc Plrx#,sin(Plra#)*Plrs#
   inc Plrz#,cos(Plra#)*Plrs#
   if mouseclick()=1 and timer()-Fire >= 200 then MakeFreakBullet() : Fire=timer()
   if mouseclick()=3
      inc Plrs#,0.05
      if timer()-Fire >= 200 then MakeFreakBullet() : Fire=timer()
   endif
   if timer()-SpawnTime >= 2000 then hide object 3
   if timer()-SpawnTime < 2000 then show object 3
   for i=4 to 1000 : ControlTehAsteroids(i) : next i
   for i=1001 to 2000 : ControlTehBullets(i) : next i
   CheckPlayerDeath()
   WrapPlayerPosition()
   position object Plr,Plrx#,0,Plrz#
   position object 3,Plrx#,0,Plrz#
   yrotate object Plr,Plra#
   yrotate object 3,Plra#
   yrotate object stars,object angle y(stars)+0.5
   text screen width()-text width("Score: "+str$(Score))-5,5,"Score: "+str$(Score)
   for i=1 to Lives : circle i*20,20,10 : next i
   sync
loop

function MakeFreakAsteroid(angle,size)
   Asteroid=3
   while object exist(Asteroid)=1
      inc Asteroid,1
   endwhile
   make object sphere Asteroid,size
   yrotate object Asteroid,angle
   if angle >= 45 and angle < 135 then x=-object size x(1) : y=rnd(object size y(1))-object size y(1)/2
   if angle >= 135 and angle < 225 then x=rnd(object size x(1))-object size x(1)/2 : y=-object size y(1)
   if angle >= 225 and angle < 315 then x=object size x(1) : y=rnd(object size y(1))-object size y(1)/2
   if angle >= 315 or angle < 45 then x=rnd(object size x(1))-object size x(1)/2 : y=object size y(1)
   position object Asteroid,x,0,y
   color object Asteroid,rgb(150,0,0)
   set object collision to spheres Asteroid
endfunction

function ControlTehAsteroids(Asteroid)
   newx=0
   newy=0
   change=0
   if object exist(Asteroid)=1
      move object Asteroid,0.3
      if object position x(Asteroid) > 50 then newx=-49 : change=1
      if object position x(Asteroid) < -50 then newx=49 : change=1
      if object position z(Asteroid) > 40 then newy=-39 : change=1
      if object position z(Asteroid) < -40 then newy=39 : change=1
      if change=1
         if newx<>0 then position object Asteroid,newx,0,object position z(Asteroid)
         if newy<>0 then position object Asteroid,object position x(Asteroid),0,newy
      endif
   endif
endfunction

function MakeFreakBullet()
   Flack=1001
   while object exist(Flack)=1
      inc Flack,1
   endwhile
   make object sphere Flack,0.3
   scale object Flack,100,100,1000
   set object diffuse Flack,rgb(255,0,0)
   set object specular Flack,rgb(255,150,150)
   set object emissive Flack,rgb(255,0,0)
   position object Flack,limb position x(Plr,Gun),0,limb position z(Plr,Gun)
   yrotate object Flack,Plra#
   set object collision to spheres Flack
   Gun=(-Gun)+5
endfunction

function ControlTehBullets(Flack)
   if object exist(Flack)=1
      move object Flack,1.2
      if object position x(Flack) < -object size x(1)/2 or object position x(Flack) > object size x(1)/2 or object position z(Flack) < -object size y(1)/2 or object position z(Flack) > object size y(1)/2 then delete object Flack : exitfunction
      if object collision(Flack,0)<>0 and object collision(Flack,0)<>Plr and object collision(Flack,0)<>1 and object collision(Flack,0)<>3
         delete object object collision(Flack,0)
         inc Score,1
         delete object Flack
         exitfunction
      endif
   endif
endfunction

function CheckPlayerDeath()
   if object collision(Plr,0)<>0 and object collision(Plr,0)<>3 and object collision(Plr,0)<1001
      if timer()-SpawnTime >= 2000
         if Lives>0
            hide object Plr
            ink rgb(200,200,200),0
            center text screen width()/2,screen height()/2,"YOU DIED" : sync
            suspend for key
            ink rgb(255,255,255),0
            dec Lives
            Plrx#=0.0
            Plrz#=0.0
            Plra#=0.0
            Plrs#=0.0
            delete object object collision(Plr,0)
            for i=1 to 50 : if object collision(3,0)<>0 and object collision(3,0)<>Plr and object collision(3,0)<>1 then delete object object collision(3,0)
            next i
            show object Plr
            SpawnTime=timer()
         else
            hide object Plr
            ink rgb(200,200,200),0
            center text screen width()/2,screen height()/2,"GAME OVER" : sync
            suspend for key
            ink rgb(255,255,255),0
            Lives=3
            Score=0
            Plrx#=0.0
            Plrz#=0.0
            Plra#=0.0
            Plrs#=0.0
            delete object object collision(Plr,0)
            for i=1 to 50 : if object collision(3,0)<>0 and object collision(3,0)<>Plr and object collision(3,0)<>1 then delete object object collision(3,0)
            next i
            show object Plr
            SpawnTime=timer()
         endif
      endif
   endif
endfunction

function WrapPlayerPosition()
   if Plrx# < -50 then Plrx#=49
   if Plrx# > 50 then Plrx#=-49
   if Plrz# < -40 then Plrz#=39
   if Plrz# > 40 then Plrz#=-39
endfunction

Sync On:Sync Rate 0:Autocam Off
Set Camera Range .01,500
Color Backdrop 0

null=Make Vector3(1)

Type vectors
   x as float
   y as float
   z as float
Endtype

Type attributes
   p as vectors
   a as vectors
   v as vectors
   s as vectors
Endtype

Global temp as attributes
Dim Roid(50) as attributes

Splotch(150,20)
Ink Rgb(0,0,200),0
Box 0,0,256,256
Sprite 1,0,0,1
Lock Pixels
For i = 1 to 100
   Rotate Sprite 1,rnd(360)
   Set Sprite Diffuse 1,0,rnd(100)+50,0
   Paste Sprite 1,rnd(256),rnd(256)
Next i
Unlock Pixels
Get Image 1,0,0,256,256,1
Ink Rgb(255,255,255),0

Make Object Sphere 1,380,80,80
Texture Object 1,1

Make Object Sphere 100,4,6,6
Make Mesh From Object 1,100
Delete Object 100
Make Object triangle 100,0,0,0,0,.01,0,0,0,0
Add Limb 100,1,1
Offset Limb 100,1,0,200,0
Rotate Object 100,Rnd(360),Rnd(360),Rnd(360)

For i = 1 to 49
   Clone Object 100+i,100
   Rotate Object 100+i,Rnd(360),Rnd(360),Rnd(360)
Next i

Make Object triangle 2,0,0,0,0,.01,0,0,0,0
Make Mesh From Object 1,2
Add Limb 2,1,1
Offset Limb 2,1,0,200,0
Hide Object 2


Do
   Pitch Object Down 2,(Upkey())*.05
   Turn Object Left 2,(LeftKey()-RightKey())*.3
   Position Camera LPosX (2,1), LPosY (2,1), LPosZ (2,1)
   Rotate Camera LAngX (2,1), LAngY (2,1), LAngZ (2,1)
   For i = 0 to 49
      Pitch Object Down 100+i,.02
   Next i
   Sync
Loop







Function Record_Rotation(ObjectID)
   temp.a.x = AngX (ObjectID)
   temp.a.y = AngY (ObjectID)
   temp.a.z = AngZ (ObjectID)
Endfunction

Function Record_Position(ObjectID)
   temp.p.x = PosX (ObjectID)
   temp.p.y = PosY (ObjectID)
   temp.p.z = PosZ (ObjectID)
Endfunction

Function Record_Camera_Rotation()
   temp.a.x = CAngX ()
   temp.a.y = CAngY ()
   temp.a.z = CAngZ ()
Endfunction

Function Record_Camera_Position()
   temp.p.x = CPosX ()
   temp.p.y = CPosY ()
   temp.p.z = CPosZ ()
Endfunction


Function Get_Planet_Distance(ObjectID)
   Set Vector3 1,PosX (ObjectID)- PosX (1),PosY (ObjectID)-PosY (1),PosZ (ObjectID)-PosZ (1)
   d#=Length Vector3(1)
Endfunction d#


Function Splotch(h,s)
   Lock Pixels
   Ink 0,0
   Box 200,200,230+s,230+s
   c=rnd(7)+h-3
   Ink Rgb(c,c,c),0
   r=rnd(s/2)+s/4
   For i# = 0.0 to 360.0 step 2
      x=sin(i#)*r+215+s/2
      y=cos(i#)*r+215+s/2
      line 207+s/2,207+s/2,x,y
      r=r+(rnd(2)-1)
      if r>s+15 then r=s+15
      m=s-15:If m<2 then m=2
      if rthen r=m
   Next i#
   Unlock Pixels
   Get Image 1,200,200,230+s,230+s
Endfunction



#Constant PosX Object Position X
#Constant PosY Object Position Y
#Constant PosZ Object Position Z

#Constant AngX Object Angle X
#Constant AngY Object Angle Y
#Constant AngZ Object Angle Z

#Constant CPosX Camera Position X
#Constant CPosY Camera Position Y
#Constant CPosZ Camera Position Z

#Constant CAngX Camera Angle X
#Constant CAngY Camera Angle Y
#Constant CAngZ Camera Angle Z

#Constant LPosX Limb Position X
#Constant LPosY Limb Position Y
#Constant LPosZ Limb Position Z

#Constant LAngX Limb Direction X
#Constant LAngY Limb Direction Y
#Constant LAngZ Limb Direction Z

Sync On:Sync Rate 60:Autocam Off
Set Camera Range .01,3000
`Color Backdrop 0

null=Make Vector3(1)

Type vectors
   x as float
   y as float
   z as float
Endtype

Type attributes
   p as vectors
   a as vectors
   v as vectors
   s as vectors
Endtype

Global temp as attributes
Dim Roid(500) as attributes

Splotch(150,20)
Ink Rgb(0,0,200),0
Box 0,0,256,256
Sprite 1,0,0,1
Lock Pixels
For i = 1 to 200
   Rotate Sprite 1,rnd(360)
   Set Sprite Diffuse 1,0,rnd(100)+50,0
   Paste Sprite 1,rnd(256),rnd(150)+43
Next i
Unlock Pixels
Get Image 2,0,0,256,256,1
Ink Rgb(255,255,255),0

Make Object Sphere 1,380,80,80
Texture Object 1,2

Splotch(150,20)
Ink Rgb(0,0,0),0
Box 0,0,256,256
Sprite 1,0,0,1
Lock Pixels
c=rnd(50)+200
Set Sprite Diffuse 1,c,c,c
For i = 1 to 100
   Rotate Sprite 1,rnd(360)
   Paste Sprite 1,rnd(256),rnd(150)+43
Next i
Unlock Pixels
Get Image 3,0,0,256,256,0
Ink Rgb(255,255,255),0

Make Object Sphere 2,382,40,40
Texture Object 2,3
Ghost Object On 2
Set Object Light 2,0
Fade Object 2,90




Splotch(150,20)
Ink Rgb(35,25,15),0
Box 0,0,256,256
Sprite 1,0,0,1
Lock Pixels
For i = 1 to 200
   Rotate Sprite 1,rnd(360)
   c=rnd(50)+25
   Set Sprite Diffuse 1,c+10,c,c-10
   Paste Sprite 1,rnd(256),rnd(150)+43
Next i
Unlock Pixels
Get Image 100,0,0,256,256,1
Ink Rgb(255,255,255),0

Make Object Sphere 100,4,5,5
Make Mesh From Object 1,100
Delete Object 100
Make Object triangle 100,0,0,0,0,.01,0,0,0,0
Add Limb 100,1,1
Offset Limb 100,1,0,200,0
Rotate Object 100,Rnd(360),Rnd(360),Rnd(360)
Roid(0).s.x=(rnd(20.0)/10.0)-1.0
Roid(0).s.y=(rnd(20.0)/10.0)-1.0

Texture Limb 100,1,100

For i = 1 to Array Count(Roid(0))
   Clone Object 100+i,100
   Rotate Object 100+i,Rnd(360),Rnd(360),Rnd(360)
   Roid(i).s.x=(rnd(20.0)/10.0)-1.0
   Roid(i).s.y=(rnd(20.0)/10.0)-1.0
Next i

Make Object triangle 3,0,0,0,0,.01,0,0,0,0
Make Mesh From Object 1,3
Add Limb 3,1,1
Offset Limb 3,1,0,200,0
Hide Object 3

`Lock Pixels
Create Bitmap 1,512,512
Ink 0,0
Box 0,0,512,512
For i = 0 to 2000+rnd(1000)+Rnd(1000)
   ink rgb(rnd(55)+200,rnd(55)+200,rnd(55)+200),0
   Dot rnd(512),Rnd(512)
Next i
`Unlock Pixels
Ink rgb(255,255,255),0
Get Image 1,0,0,512,512,0
Delete Bitmap 1
Set Current Bitmap 0

Make Object Cube 5,1000
Texture Object 5,1
Set Object Light 5,0
Set Object Emissive 5,rgb(100,100,100)
Set Object Cull 5,0


Do
   Pitch Object Down 3,(Upkey())*.05
   Turn Object Left 3,(LeftKey()-RightKey())*2.0
   Position Camera LPosX (3,1), LPosY (3,1), LPosZ (3,1)
   Rotate Camera LDirX (3,1), LDirY (3,1), LDirZ (3,1)
   For i = 0 to Array Count(Roid(0))
      Pitch Object Down 100+i,.01
      Rotate Limb 100+i,1,LAngx (100+i,1)+Roid(i).s.x , LAngY (100+i,1)+Roid(i).s.y , LAngZ (100+i,1)+Roid(i).s.z
   Next i
   Set Cursor 0,0
   Print "FPS: ";Screen FPS()
   Sync
Loop







Function Record_Rotation(ObjectID)
   temp.a.x = AngX (ObjectID)
   temp.a.y = AngY (ObjectID)
   temp.a.z = AngZ (ObjectID)
Endfunction

Function Record_Position(ObjectID)
   temp.p.x = PosX (ObjectID)
   temp.p.y = PosY (ObjectID)
   temp.p.z = PosZ (ObjectID)
Endfunction

Function Record_Camera_Rotation()
   temp.a.x = CAngX ()
   temp.a.y = CAngY ()
   temp.a.z = CAngZ ()
Endfunction

Function Record_Camera_Position()
   temp.p.x = CPosX ()
   temp.p.y = CPosY ()
   temp.p.z = CPosZ ()
Endfunction


Function Get_Planet_Distance(ObjectID)
   Set Vector3 1,PosX (ObjectID)- PosX (1),PosY (ObjectID)-PosY (1),PosZ (ObjectID)-PosZ (1)
   d#=Length Vector3(1)
Endfunction d#


Function Splotch(h,s)
   Lock Pixels
   Ink 0,0
   Box 200,200,230+s,230+s
   c=rnd(7)+h-3
   Ink Rgb(c,c,c),0
   r=rnd(s/2)+s/4
   For i# = 0.0 to 360.0 step 2
      x=sin(i#)*r+215+s/2
      y=cos(i#)*r+215+s/2
      line 207+s/2,207+s/2,x,y
      r=r+(rnd(2)-1)
      if r>s+15 then r=s+15
      m=s-15:If m<2 then m=2
      if rthen r=m
   Next i#
   Unlock Pixels
   Get Image 1,200,200,230+s,230+s
Endfunction



#Constant PosX Object Position X
#Constant PosY Object Position Y
#Constant PosZ Object Position Z

#Constant AngX Object Angle X
#Constant AngY Object Angle Y
#Constant AngZ Object Angle Z

#Constant CPosX Camera Position X
#Constant CPosY Camera Position Y
#Constant CPosZ Camera Position Z

#Constant CAngX Camera Angle X
#Constant CAngY Camera Angle Y
#Constant CAngZ Camera Angle Z

#Constant LPosX Limb Position X
#Constant LPosY Limb Position Y
#Constant LPosZ Limb Position Z

#Constant LDirX Limb Direction X
#Constant LDirY Limb Direction Y
#Constant LDirZ Limb Direction Z

#Constant LAngX Limb Angle X
#Constant LAngY Limb Angle Y
#Constant LAngZ Limb Angle Z

Sync On:Sync Rate 60:Autocam Off
Set Camera Range .01,3000
`Color Backdrop 0

null=Make Vector3(1)

Type vectors
   x as float
   y as float
   z as float
Endtype

Type attributes
   p as vectors
   a as vectors
   v as vectors
   s as vectors
Endtype

Global temp as attributes
Global speed as float
Dim Roid(500) as attributes
speed#=.01

Splotch(150,20)
Ink Rgb(0,0,200),0
Box 0,0,270,270
Sprite 1,0,0,1
Lock Pixels
For i = 1 to 200
   Rotate Sprite 1,rnd(360)
   Set Sprite Diffuse 1,0,rnd(100)+50,0
   Paste Sprite 1,rnd(180)+13,rnd(150)+43
Next i
Unlock Pixels
Blur Bitmap 0,3
Get Image 2,4,4,260,260,1
Ink Rgb(255,255,255),0

Make Object Sphere 1,380,180,180
Texture Object 1,2
Set Object Diffuse 1,Rgb(255,255,255)
Set Object Specular 1,Rgb(255,255,50)
Set Object Specular Power 1,200

Splotch(150,20)
Ink Rgb(0,0,0),0
Box 0,0,270,270
Sprite 1,0,0,1
Lock Pixels
c=rnd(50)+200
Set Sprite Diffuse 1,c,c,c
For i = 1 to 100
   Rotate Sprite 1,rnd(360)
   Paste Sprite 1,rnd(180)+13,rnd(150)+43
Next i
Unlock Pixels
Blur BItmap 0,3
Get Image 3,0,0,256,256,0
Ink Rgb(255,255,255),0

Make Object Sphere 2,382,120,120
Texture Object 2,3
Ghost Object On 2
Set Object Light 2,0
Fade Object 2,90




Splotch(150,20)
Ink Rgb(35,25,15),0
Box 0,0,270,270
Sprite 1,0,0,1
Lock Pixels
For i = 1 to 200
   Rotate Sprite 1,rnd(360)
   c=rnd(50)+25
   Set Sprite Diffuse 1,c+10,c,c-10
   Paste Sprite 1,rnd(256),rnd(150)+43
Next i
Unlock Pixels
Get Image 100,4,4,260,260,0
Ink Rgb(255,255,255),0

Make Object Sphere 100,4,5,5
Make Mesh From Object 1,100
Delete Object 100
Make Object triangle 100,0,0,0,0,.01,0,0,0,0
Add Limb 100,1,1
Offset Limb 100,1,0,200,0
Rotate Object 100,Rnd(360),Rnd(360),Rnd(360)
Roid(0).s.x=(rnd(20.0)/10.0)-1.0
Roid(0).s.y=(rnd(20.0)/10.0)-1.0

Texture Limb 100,1,100
Set Object Diffuse 100,Rgb(200,200,200)
Set Object Ambience 100,Rgb(200,200,180)
Set Object Emissive 100,rgb(25,25,23)
Set Object Specular 100,rgb(50,50,10)
Set Object Specular Power 100,30

For i = 1 to Array Count(Roid(0))
   Clone Object 100+i,100
   Rotate Object 100+i,Rnd(360),Rnd(360),Rnd(360)
   Roid(i).s.x=(rnd(20.0)/10.0)-1.0
   Roid(i).s.y=(rnd(20.0)/10.0)-1.0
Next i

Make Object triangle 3,0,0,0,0,.01,0,0,0,0
Make Mesh From Object 1,3
Add Limb 3,1,1
Offset Limb 3,1,0,200,0
Hide Object 3

`Lock Pixels
Create Bitmap 1,512,512
Ink 0,0
Box 0,0,512,512
For i = 0 to 2000+rnd(1000)+Rnd(1000)
   ink rgb(rnd(55)+200,rnd(55)+200,rnd(55)+200),0
   Dot rnd(512),Rnd(512)
Next i
`Unlock Pixels
Ink rgb(255,255,255),0
Get Image 1,0,0,512,512,0
Delete Bitmap 1
Set Current Bitmap 0

Make Object Cube 5,2000
Texture Object 5,1
Set Object Light 5,0
Set Object Emissive 5,rgb(100,100,100)
Set Object Cull 5,0

Ink Rgb(255,255,0),0
Box 0,0,128,128
Get Image 6,0,0,128,128,0
Ink rgb(255,255,255),0

For i = 6 to 9
   Make Object Sphere i,-540+i*100,12,12
   Texture Object i,6
   Position Object i,500,60,400
   Set Object Emissive i,Rgb(255,255,255)
   Ghost Object On i
   Fade Object i,60-i*2
Next i
Ghost Object Off 6
Set Object Light 6,0
Fade Object 6,255


Hide Light 0


Make Light 1
Color Light 1,255,255,50
Position Light 1,500,60,400
Set Light Range 1,2000
Set Ambient Light 25



click=0
Do
   Turn Object Left 1,.002
   Turn Object Left 2,.005
   Turn Object Right 5,.002
   Pitch Object Down 3,(Upkey())*.05
   Turn Object Left 3,(LeftKey()-RightKey())*1.0
   Position Camera LPosX (3,1), LPosY (3,1), LPosZ (3,1)
   Rotate Camera LDirX (3,1), LDirY (3,1), LDirZ (3,1)
   Move_Asteroids()
   If MouseClick()=1 and click=0
      click = 1
      Make_Bullet()
   Endif
   click=MouseClick()
   Move_Bullets()
   Set Cursor 0,0
   Print "FPS: ";Screen FPS()
   Sync
Loop



Function Move_Asteroids()
   For i = 0 to Array Count(Roid(0))
      If Object Visible(100+i)
         Pitch Object Down 100+i,speed
         Rotate Limb 100+i,1,LAngx (100+i,1)+Roid(i).s.x , LAngY (100+i,1)+Roid(i).s.y , LAngZ (100+i,1)+Roid(i).s.z
      Else
         Pitch Object Down 100+i,speed
         r#=Get_Limb_Distance(100+i,1,3,1)
         If r#>150
            Show Object 100+i
            speed=speed+.0002
         Endif
      Endif
   Next i
Endfunction



Function Record_Rotation(ObjectID)
   temp.a.x = AngX (ObjectID)
   temp.a.y = AngY (ObjectID)
   temp.a.z = AngZ (ObjectID)
Endfunction

Function Record_Position(ObjectID)
   temp.p.x = PosX (ObjectID)
   temp.p.y = PosY (ObjectID)
   temp.p.z = PosZ (ObjectID)
Endfunction

Function Record_Camera_Rotation()
   temp.a.x = CAngX ()
   temp.a.y = CAngY ()
   temp.a.z = CAngZ ()
Endfunction

Function Record_Camera_Position()
   temp.p.x = CPosX ()
   temp.p.y = CPosY ()
   temp.p.z = CPosZ ()
Endfunction


Function Get_Planet_Distance(ObjectID)
   Set Vector3 1,PosX (ObjectID)- PosX (1),PosY (ObjectID)-PosY (1),PosZ (ObjectID)-PosZ (1)
   d#=Length Vector3(1)
Endfunction d#

Function Get_Object_Distance(Obj1,Obj2)
   Set Vector3 1,PosX (Obj1)-PosX (Obj2),PosY (Obj1)-PosY (Obj2),PosZ (Obj1)-PosZ (Obj2)
   d#=Length Vector3(1)
Endfunction d#

Function Get_Limb_Distance(Obj1,L1,Obj2,L2)
   Set Vector3 1,LPosX (Obj1,L1)-LPosX (Obj2,L2),LPosY (Obj1,L1)-LPosY (Obj2,L2),LPosZ (Obj1,L1)-LPosZ (Obj2,L2)
   d#=Length Vector3(1)
Endfunction d#


Function Move_Bullets()
   For i = 1000 to 1200
      If Object Exist(i)
         If Object Visible(i)
            Pitch Object Down i,.3
            For j=0 to Array Count(Roid(0))
               If Object Visible(100+j)=1
                  r#=Get_Limb_Distance(i,1,100+j,1)
                  if r#<2
                     Hide Object 100+j
                     Hide Object i
                     Exit
                  Endif
               Endif
            Next j
         Endif
      Endif
   Next i
Endfunction


Function Make_Bullet()
   b=Free_Bullet()
   if b=0 then exitfunction
   If Object Exist(b)=0
      Make Object triangle b,-.05,0,0,0,0,3,.05,0,0
      Make Mesh From Object 1,b
      Add Limb b,1,1
      Offset Limb b,1,0,199.3,0
      Color Limb b,1,rgb(255,0,0)
      Set Object Emissive b,rgb(200,100,100)
      Set Object Cull b,0
   Else
      Show Object b
   Endif
   Rotate Object b,AngX (3),AngY (3), AngZ (3)
   Pitch Object Down b,.5
Endfunction

Function Free_Bullet()
   flag=0
   For i = 1000 to 1200
      If Object Exist(i)=0
         flag=1
         Exit
      Endif
      If Object Visible(i)=0
         flag=1
         Exit
      Endif
   Next i
   i=i*flag
Endfunction i


Function Splotch(h,s)
   Lock Pixels
   Ink 0,0
   Box 200,200,230+s,230+s
   c=rnd(7)+h-3
   Ink Rgb(c,c,c),0
   r=rnd(s/2)+s/4
   For i# = 0.0 to 360.0 step 2
      x=sin(i#)*r+215+s/2
      y=cos(i#)*r+215+s/2
      line 207+s/2,207+s/2,x,y
      r=r+(rnd(2)-1)
      if r>s+15 then r=s+15
      m=s-15:If m<2 then m=2
      if rthen r=m
   Next i#
   Unlock Pixels
   Get Image 1,200,200,230+s,230+s
Endfunction



#Constant PosX Object Position X
#Constant PosY Object Position Y
#Constant PosZ Object Position Z

#Constant AngX Object Angle X
#Constant AngY Object Angle Y
#Constant AngZ Object Angle Z

#Constant CPosX Camera Position X
#Constant CPosY Camera Position Y
#Constant CPosZ Camera Position Z

#Constant CAngX Camera Angle X
#Constant CAngY Camera Angle Y
#Constant CAngZ Camera Angle Z

#Constant LPosX Limb Position X
#Constant LPosY Limb Position Y
#Constant LPosZ Limb Position Z

#Constant LDirX Limb Direction X
#Constant LDirY Limb Direction Y
#Constant LDirZ Limb Direction Z

#Constant LAngX Limb Angle X
#Constant LAngY Limb Angle Y
#Constant LAngZ Limb Angle Z

rem variables
global time as integer
global stars as integer
global gamelevel as integer : gamelevel=1
global numberofstars as integer : numberofstars=200
global maximumobjects as integer : maximumobjects=1000
global xmid : xmid=int(1024/2)
global ymid : ymid=int(768/2)
global shiprotatespeed as float : shiprotatespeed=0.4
global shipbulletlife as integer : shipbulletlife=1500
global shipsleft as integer : shipsleft=2
global shipfirerate as integer
global shipacceleration as float
global shipmaximumspeed as float
global shipfiretime as integer
global shipscore as integer : shipscore=0



rem setup
sync on
sync rate 50
set display mode 1024,768,32
hide mouse
set text font "microsoft sans serif"
null=make vector2(1)
null=make vector2(2)
sync



rem make the stars
ink rgb(255,255,200),rgb(0,0,0)
for x=1 to numberofstars
   dot rnd(1024),rnd(768)
next x
stars=1 : get image stars,0,0,1024,768
ink rgb(255,255,255),rgb(0,0,0)



rem types and arrays
type pointtype
   x as float
   y as float
   tx as float
   ty as float
endtype
type objecttype
   points as integer
   size as float
   xpos as float
   ypos as float
   rotation as float
   xvel as float
   yvel as float
   spin as float
endtype
type bullettype
   id as integer
   time as integer
endtype
type asteroidtype
   id as integer
   size as integer
endtype
global dim object(maximumobjects) as objecttype
global dim objectpoint(maximumobjects,20) as pointtype
global dim asteroid() as asteroidtype
global dim bullet() as bullettype



rem make the ship
array insert at bottom object(0)
object(0).points=5
object(0).size=10
object(0).xpos=xmid
object(0).ypos=ymid
object(0).rotation=0
object(0).xvel=0
object(0).yvel=0
object(0).spin=0
objectpoint(0,0).x=0
objectpoint(0,0).y=-10
objectpoint(0,1).x=-6
objectpoint(0,1).y=6
objectpoint(0,2).x=0
objectpoint(0,2).y=3
objectpoint(0,3).x=6
objectpoint(0,3).y=6
objectpoint(0,4).x=0
objectpoint(0,4).y=-10



`===========================================================================================



rem load the first level and start the loop
_load_level()
do
   rem get time and paste stars
   time=timer()
   paste image stars,0,0

   rem main routines
   _control_ship()
   _check_bullets()
   _update_objects()

   rem print stats and sync
   set cursor 0,5
   text 10,10,"Level_"+str$(gamelevel)
   text 10,30,"Ships left: "+str$(shipsleft)
   text 10,50,"Score: "+str$(shipscore)
   sync
loop



`==========================================================================================



rem sets up a level
function _load_level()
   object(0).xpos=xmid
   object(0).ypos=ymid
   object(0).rotation=0
   object(0).spin=0
   object(0).xvel=0
   object(0).yvel=0
   inc shipsleft
   shipfirerate=1000-shipscore*4
   shipmaximumspeed=1.5+shipscore*0.005
   shipacceleration=0.1+shipscore*0.0009
   for x=1 to 5
      xpos=rnd(1024) : ypos=rnd(768)
      if xpos>400 and xpos<600 then xpos=600
      if ypos>300 and ypos<500 then ypos=300
      makeasteroid(3,xpos,ypos)
   next x
   paste image stars,0,0
   set text size 40
   center text xmid,ymid-50,"Level_"+str$(gamelevel) : sync
   set text size 20
   wait 3000
endfunction



rem controls the ship
function _control_ship()
   rem rotate the ship
   object(0).spin=mousemovex()*shiprotatespeed
   if leftkey() or keystate(30) then dec object(0).spin,shiprotatespeed*10
   if rightkey() or keystate(32) then inc object(0).spin,shiprotatespeed*10
   rem move the ship
   if keystate(17) or upkey() or mouseclick()=2 or mouseclick()=3
      inc object(0).xvel,sin(object(0).rotation)*shipacceleration
      inc object(0).yvel,cos(object(0).rotation)*shipacceleration
      set vector2 1,object(0).xvel,object(0).yvel
      if length vector2(1)>shipmaximumspeed
         normalize vector2 1,1
         object(0).xvel=x vector2(1)*shipmaximumspeed
         object(0).yvel=y vector2(1)*shipmaximumspeed
      endif
   endif
   rem fire bullets
   if shipfiretime+shipfirerate<time
      if spacekey() or mouseclick()=1 or mouseclick()=3
         shipfiretime=time
         makebullet(object(0).xpos,object(0).ypos,object(0).rotation)
         dec shipscore
         if shipscore<0 then shipscore=0
      endif
   endif
   rem check for asteroid collision
   for x=0 to array count(asteroid(0))
      set vector2 1,object(0).xpos-object(asteroid(x).id).xpos,object(0).ypos-object(asteroid(x).id).ypos
      if length vector2(1)<object(0).size+object(asteroid(x).id).size
         destroyasteroid(x)
         center text xmid,ymid-80,"You were hit!" : sync
         dec shipsleft
         if shipsleft<0
            set text size 40
            center text xmid,ymid-40,"You Lose!"
            center text xmid,ymid,"Your Score: "+str$(shipscore)
            sync
            wait 5000 : end
         endif
         object(0).xpos=xmid
         object(0).ypos=ymid
         object(0).rotation=0
         object(0).spin=0
         object(0).xvel=0
         object(0).yvel=0
         wait 1500
      endif
   next x
   rem check for next level
   if array count(asteroid(0))=-1
      inc gamelevel
      _load_level()
   endif
endfunction



rem draws and updates all objects
function _update_objects()
   for x=0 to maximumobjects
      rem rotation
      dec object(x).rotation,object(x).spin
      for y=0 to object(x).points-1
         objectpoint(x,y).tx=cos(object(x).rotation)*objectpoint(x,y).x+sin(object(x).rotation)*objectpoint(x,y).y
         objectpoint(x,y).ty=cos(object(x).rotation)*objectpoint(x,y).y-sin(object(x).rotation)*objectpoint(x,y).x
      next y
      rem movement
      dec object(x).xpos,object(x).xvel
      dec object(x).ypos,object(x).yvel
      if object(x).xpos<0 then object(x).xpos=1024
      if object(x).ypos<0 then object(x).ypos=768
      if object(x).xpos>1024 then object(x).xpos=0
      if object(x).ypos>768 then object(x).ypos=0
      rem drawing
      for y=0 to object(x).points-2
         line objectpoint(x,y).tx+object(x).xpos,objectpoint(x,y).ty+object(x).ypos,objectpoint(x,y+1).tx+object(x).xpos,objectpoint(x,y+1).ty+object(x).ypos
      next y
   next x
endfunction



rem expolodes asteroids and gets rid of bullets
function _check_bullets()
   while x<=array count(bullet(0))
      bulletobject=bullet(x).id
      collision=0
      for y=0 to array count(asteroid(0))
         asteroidobject=asteroid(y).id
         set vector2 1,object(asteroidobject).xpos-object(bulletobject).xpos,object(asteroidobject).ypos-object(bulletobject).ypos
         if length vector2(1)<object(asteroidobject).size+object(bulletobject).size
            select asteroid(y).size
               case 3
                  for z=1 to (gamelevel+3)*0.5
                     makeasteroid(2,object(asteroidobject).xpos,object(asteroidobject).ypos)
                  next z
                  inc shipscore,1
               endcase
               case 2
                  for z=1 to (gamelevel+3)*0.5
                     makeasteroid(1,object(asteroidobject).xpos,object(asteroidobject).ypos)
                  next z
                  inc shipscore,2
               endcase
               case 1
                  inc shipscore,3
               endcase
            endselect
            destroyasteroid(y)
            collision=1 : exit
         endif
      next y
      if collision or bullet(x).time+shipbulletlife<time
         destroybullet(x)
      else
         inc x
      endif
   endwhile
endfunction



`=========================================================================================



rem makes a new asteroid
function makeasteroid(size,x#,y#)
   num=newobject()
   array insert at bottom asteroid(0)
   asteroid(array count(asteroid(0))).id=num

   direction#=rnd(359)
   speed#=rnd(9*gamelevel)*0.09+0.09*gamelevel
   if rnd(1)
      spin#=rnd(10*gamelevel)*0.1+0.1*gamelevel
   else
      spin#=-1*rnd(10*gamelevel)*0.1+0.1*gamelevel
   endif

   select size
      case 1
         asteroid(array count(asteroid(0))).size=1
         object(num).points=6
         object(num).size=10
         object(num).xpos=x#
         object(num).ypos=y#
         object(num).rotation=0
         object(num).xvel=sin(direction#)*speed#
         object(num).yvel=cos(direction#)*speed#
         object(num).spin=spin#
         objectpoint(num,0).x=0
         objectpoint(num,0).y=-10
         objectpoint(num,1).x=-10+(rnd(6)-3)
         objectpoint(num,1).y=-3+(rnd(6)-3)
         objectpoint(num,2).x=-5+(rnd(6)-3)
         objectpoint(num,2).y=10+(rnd(6)-3)
         objectpoint(num,3).x=5+(rnd(6)-3)
         objectpoint(num,3).y=10+(rnd(6)-3)
         objectpoint(num,4).x=10+(rnd(6)-3)
         objectpoint(num,4).y=-3+(rnd(6)-3)
         objectpoint(num,5).x=0
         objectpoint(num,5).y=-10
      endcase
      case 2
         asteroid(array count(asteroid(0))).size=2
         object(num).points=7
         object(num).size=20
         object(num).xpos=x#
         object(num).ypos=y#
         object(num).rotation=0
         object(num).xvel=sin(direction#)*speed#
         object(num).yvel=cos(direction#)*speed#
         object(num).spin=spin#
         objectpoint(num,0).x=0
         objectpoint(num,0).y=-20
         objectpoint(num,1).x=-20+(rnd(10)-5)
         objectpoint(num,1).y=-10+(rnd(10)-5)
         objectpoint(num,2).x=-20+(rnd(10)-5)
         objectpoint(num,2).y=10+(rnd(10)-5)
         objectpoint(num,3).x=0+(rnd(10)-5)
         objectpoint(num,3).y=20+(rnd(10)-5)
         objectpoint(num,4).x=20+(rnd(10)-5)
         objectpoint(num,4).y=10+(rnd(10)-5)
         objectpoint(num,5).x=20+(rnd(10)-5)
         objectpoint(num,5).y=-10+(rnd(10)-5)
         objectpoint(num,6).x=0
         objectpoint(num,6).y=-20
      endcase
      case 3
         asteroid(array count(asteroid(0))).size=3
         object(num).points=9
         object(num).size=30
         object(num).xpos=x#
         object(num).ypos=y#
         object(num).rotation=0
         object(num).xvel=sin(direction#)*speed#
         object(num).yvel=cos(direction#)*speed#
         object(num).spin=spin#
         objectpoint(num,0).x=0
         objectpoint(num,0).y=-30
         objectpoint(num,1).x=-18+(rnd(12)-6)
         objectpoint(num,1).y=-18+(rnd(12)-6)
         objectpoint(num,2).x=-30+(rnd(12)-6)
         objectpoint(num,2).y=0+(rnd(12)-6)
         objectpoint(num,3).x=-18+(rnd(12)-6)
         objectpoint(num,3).y=18+(rnd(12)-6)
         objectpoint(num,4).x=0+(rnd(12)-6)
         objectpoint(num,4).y=30+(rnd(12)-6)
         objectpoint(num,5).x=18+(rnd(12)-6)
         objectpoint(num,5).y=18+(rnd(12)-6)
         objectpoint(num,6).x=30+(rnd(12)-6)
         objectpoint(num,6).y=0+(rnd(12)-6)
         objectpoint(num,7).x=18+(rnd(12)-6)
         objectpoint(num,7).y=-18+(rnd(12)-6)
         objectpoint(num,8).x=0
         objectpoint(num,8).y=-30
      endcase
   endselect
endfunction



rem gets rid of asteroids
function destroyasteroid(num)
   object(asteroid(num).id).points=0
   array delete element asteroid(0),num
endfunction



rem makes bullets
function makebullet(x#,y#,direction#)
   num=newobject()
   array insert at bottom bullet(0)
   bullet(array count(bullet(0))).id=num
   bullet(array count(bullet(0))).time=time
   object(num).points=5
   object(num).size=2
   object(num).xpos=x#
   object(num).ypos=y#
   object(num).rotation=direction#
   object(num).xvel=sin(direction#)*10.0
   object(num).yvel=cos(direction#)*10.0
   object(num).spin=0
   objectpoint(num,0).x=0
   objectpoint(num,0).y=-2
   objectpoint(num,1).x=-1
   objectpoint(num,1).y=0
   objectpoint(num,2).x=0
   objectpoint(num,2).y=2
   objectpoint(num,3).x=1
   objectpoint(num,3).y=0
   objectpoint(num,4).x=0
   objectpoint(num,4).y=-2
endfunction



rem gets rid of bullets
function destroybullet(num)
   object(bullet(num).id).points=0
   array delete element bullet(0),num
endfunction



rem returns a free object slot
function newobject()
   while object(test).points<>0
      inc test
   endwhile
endfunction test

`Challenge Compo - Asteroids Game
`by Bill Robinson
`due: 2-25-06

`@Kimosabi - you do NOT have rights to use this program as your own.
`And you never should have used Ric's pong game as your own, on your web sight!
`
`Use 'Z' and 'X' to rotate ship, leftarrow and rightarrow work too
`Use comma ',' to fire, period '.' to thrust
`Use 'Space' to Hyperspace to a new position
`Use 'Shift' for shields, you have a limited number of shields per level
`You only get 5 shots on the screen at a time
`
`Using Hyperspace FREEZES TIME while your ship is in hyperspace traveling to new location.
`If ship traveling through Hyperspace lands on an asteroid,
`you have a brief moment to engage Hyperspace again to save your ship
`Hyperspace will also bring your moving ship to a stop
`
set display mode 1024,768,32
autocam off
sync on
sync rate 60
Hide Mouse
Backdrop on
Color Backdrop 0
set ambient light 15
set camera range 1,5000
randomize timer()

`--- Game Setup ---
#constant MAX_ASTEROIDS 100
global GREEN
GREEN=rgb(0,255,0)
global RED
RED=rgb(255,0,0)
global level
global newlevel
global score
global targetsleft
global numasteroids
global lives
global playersafetime
global shields
global syncrate=60

`--- Player ---
global ship_x#
global ship_y#
global ship_z#=0
global shipangle#
global shipthrust#
global shipmass#
global explode_object=0
global expdone=0
global exparrayindex=1
global expparticleindex=1
global numhits
global playerdeadtime
global velx#=0
global vely#=0
global shipincx#=0
global shipincy#=0

`--- enemy ---
`1=active, 2=size, 3=x, 4=y, 5=z, 6=xinc, 7=yinc, 8=zinc, 9=color
dim enemy#(10)
dim eshots#(10)

`--- asteroids ---
`1=active, 2=size, 3=x, 4=y, 5=z, 6=xinc, 7=yinc, 8=zinc, 9=xrot,10=yrot, 11=zrot, 12=color
dim ast_info#(MAX_ASTEROIDS,15)
` highest number of vertexes = 200 for now
global vcount=200
dim vertex_count(100)
dim v_pos_x#(100,vcount)
dim v_pos_y#(100,vcount)
dim v_pos_z#(100,vcount)

`--- explosion particles ---
rem Arrays for position, velocity and life of each explosion particle
dim partx#(300)
dim party#(300)
dim partz#(300)
dim partxvel#(300)
dim partyvel#(300)
dim partzvel#(300)
dim partlife(300)
dim explosion(10,10)
global start_time=0
global inten#=60.0
global max=200

`--- ship thrust ---
dim thrust#(50,10)
global thrustptr

`--- Shots Fired ---
dim shots(100,4)
global shotptr
global shotspeed#
global lastshot
global shottime
global shotpause
global hitnum
global maxshots
global numshots

`--- Players shots getting made ---
for i=400 to 410
   make object sphere i,30,3,3
   xrotate object i,90
   color object i,rgb(255,255,255)
   scale object i,20,20,100
   set object collision off i
   hide object i
next i

`--- hyperspace ships ---
global numhyper=5
dim hyperinfo#(numhyper,6)
color=GREEN
for i=1 to numhyper
   obnum=1020+i
   make object cone obnum, 20

   color object obnum,color
   ghost object on obnum
   hide object obnum
next i

`------------------------
screen_xmax=screen width()
screen_ymax=screen height()
screen_center=screen_xmax/2

`--- make cone for ship ---
make object cone 1000,20
color object 1000,rgb(0,255,0)
set object collision on 1000
set object collision to spheres 1000
fix object pivot 1000

make object sphere 1001,50
color object 1001,rgb(0,255,255)
set object collision off 1001
ghost object on 1001
`set object wireframe 1001,1
set object ambient 1001,0
position object 1001,-2700,-2700,-2700

make object cone 4000,50
scale object 4000,100,50,100
color object 4000,rgb(255,0,0)
set object collision on 4000
set object collision to spheres 4000
position object 4000,-2600,-2600,-2600

`--- make exhaust particles ---
for i=1 to 40
   color=rgb(rnd(55)+200,rnd(55)+200,0)
   obnum=600+i
   make object plain obnum,2,2
   color object obnum,color
   hide object obnum
next i

`--- make explosion pieces ---
color=rgb(255,255,255)
for i=1 to max
   obnum=100+i
   make object plain obnum,6,6
   color object obnum,color
   hide object obnum
next i

_reset_vars()
_make_stars()

`--- setup starfield in background ---
make object plain 998,1300,1000
texture object 998, 1
position object 998,0,0,200

`--- debug limits of screen, for wrap-around of objects ---
global lwall=-480
global rwall=480
global twall=360
global bwall=-360

position object 1000, 0,0,0
position camera 0,0,-600
point camera 0,0,0

do
   set object collision on 1000

   if newlevel=1
      _new_level()
   endif
   if targetsleft=0 then newlevel=1

   `explosion 1=active flag, 2=object, 3=#particles, 4=intensity, 5=particle life, 6=particle start num, 7=color
   if keystate(48)=1                            :`b key - self destruct
      _set_explosion(1000,50,30,100,GREEN)
      playerdeadtime=200
   endif

   if leftkey()=1 then inc shipangle#,3         :`left arrow key
   if rightkey()=1 then dec shipangle#,3        :`right arrow key
   if keystate(44)=1 then inc shipangle#,3      :`z key
   if keystate(45)=1 then dec shipangle#,3      :`x key
   if keystate(29)=1 then _fire_missle()        :`ctrl key
   if keystate(42)=1 or keystate(54)=1 then _raise_shields()
   if keystate(57)=1                            :`space key
      _hyperspace(1)
      velx#=0:vely#=0:shipincx#=0:shipincy#=0
   endif

   if keystate(51)=1 and numshots<maxshots then _shoot()
   if keystate(52)=1
      shipincx#=-sin(shipangle#)*shipthrust#
      shipincy#=cos(shipangle#)*shipthrust#
      _start_thrust()
   else
      shipincx#=0
      shipincy#=0
   endif

   `calc ship velocity
   deltax#=shipincx#/shipmass#
   deltay#=shipincy#/shipmass#
   inc velx#,deltax#
   inc vely#,deltay#

   inc ship_x#,velx#
   inc ship_y#,vely#

   _show_thrust()

   shipangle#=wrapvalue(shipangle#)
   ship_x#=_ship_screen_wrapx(ship_x#)             :`wrap players ship around screen if needed
   ship_y#=_ship_screen_wrapy(ship_y#)

   zrotate object 1000,shipangle#                  :`rotate players ship
   position object 1000,ship_x#,ship_y#,ship_z#    :`position ship on screen
   if playersafetime>0 and playerdeadtime=0
      position object 1001,ship_x#,ship_y#-5,ship_z#    :`safety shield
   else
      position object 1001,-2500,-2500,-2500
   endif

   _check_newexplosions()
   _check_asthits()           :`check for player hits from shots
   _move_shots()              :`move player shots
   _continue_explosion()      :`continue to explode pieces
   _move_asteroids()
   if lives=0 then _game_over()

   if playersafetime>0
      dec playersafetime
   else
      _check_playerhit()
   endif

   if enemy#(1)=0
      _start_enemy()
   else
      _move_enemy()
   endif

`   _check_enemyhit()

   if playerdeadtime>0
      dec playerdeadtime
      if playerdeadtime<200 then center text screen width()/2,300,"GET READY! - For Next Ship"
      if playerdeadtime=0
         velx#=0:vely#=0:shipincx#=0:shipincy#=0
         _hyperspace(2)
         set object collision on 1000
         playersafetime=120
      endif
   endif

   if expdone=1
      explode_object=0
      start_time=0
      expdone=0
   endif

   if numshots<=0 then numshots=0      :`just correcting for a bug I haven't figured out yet

   set cursor 1,1
   print screen fps()
   center text screen_center,10,"Level: "+str$(level)+"      Lives: "+str$(lives)+"      Targets Left: "+str$(targetsleft)+"      Shields: "+str$(shields)+"      Score: "+str$(score)
   sync
loop


function _start_thrust()
thrustlife=10
i=thrustptr
if thrust#(i,1)=0
   thrust#(i,1)=1
   thrust#(i,2)=ship_x#
   thrust#(i,3)=ship_y#
   thrust#(i,4)=-shipincx#-(rnd(3)/4.0)
   thrust#(i,5)=-shipincy#-(rnd(3)/4.0)
   thrust#(i,6)=thrustlife
   inc thrustptr
   if thrustptr>40 then thrustptr=1
   show object 600+i
endif
endfunction


function _show_thrust()
for i=1 to 40
   if thrust#(i,6)>0
      position object 600+i,thrust#(i,2),thrust#(i,3),0
      dec thrust#(i,6)
      inc thrust#(i,2),thrust#(i,4)
      inc thrust#(i,3),thrust#(i,5)
   else
      thrust#(i,1)=0
      hide object 600+i
   endif
next i
endfunction


function _start_enemy()
`1=active, 2=size, 3=x, 4=y, 5=z, 6=xinc, 7=yinc, 8=yloc_change, 9=vis_counter
if enemy#(1)=0
   if enemy#(9)>0
      dec enemy#(9)
   else
      enemy#(1)=1
      enemy#(3)=-500.0
      enemy#(4)=rnd(320)-100
      enemy#(5)=0
      enemy#(6)=(rnd(120)+60)/60.0
      enemy#(7)=0
      enemy#(8)=rnd(100)+50
`      enemy#(9)=rnd(1000)+2000
      position object 4000,enemy#(3),enemy#(4),enemy#(5)
      show object 4000
   endif
endif
endfunction


function _move_enemy()
`1=active, 2=size, 3=x, 4=y, 5=z, 6=xinc, 7=yinc, 8=yloc_change, 9=vis_counter
if enemy#(1)=1
   dec enemy#(8)
   inc enemy#(3),enemy#(6)
   if enemy#(4)<300 and enemy#(4)>-300 then inc enemy#(4),enemy#(7)
   position object 4000,enemy#(3),enemy#(4),enemy#(5)
   if enemy#(8)<0
      enemy#(8)=rnd(50)+50
      enemy#(7)=(rnd(360)-180)/60.0
   endif
   if enemy#(3)>500
      enemy#(1)=0
      position object 4000,-2700,-2700,-2700
      enemy#(8)=rnd(50)+50
      enemy#(9)=rnd(1000)+2000
   endif
endif
endfunction


function _enemy_shots()

endfunction


function _raise_shields()
if shields>=200 and playersafetime=0
   playersafetime=200
   dec shields,200
endif
endfunction


function _check_newexplosions()
  for ex=1 to 10
      if explosion(ex,1)=1
         ex#=object position x(explosion(ex,2))
         ey#=object position y(explosion(ex,2))
         ez#=object position z(explosion(ex,2))
         if expparticleindex+explosion(ex,3)>=200
            expparticleindex=1
         endif
         explosion(ex,6)=expparticleindex
         inc expparticleindex,explosion(ex,3)
   `explosion() 1=active flag, 2=object, 3=#particles, 4=intensity, 5=particle life, 6=particle start num, 7=color
         _request_explosion(ex#,ey#,ez#,explosion(ex,3),explosion(ex,4),explosion(ex,5),explosion(ex,6),explosion(ex,7))
         start_time=1

         hide object explosion(ex,2)               :`was explode_object
         set object collision off explosion(ex,2)  :`was explode_object
         explosion(ex,1)=2
      endif
   next ex
endfunction


`--- move asteroids ---
function _move_asteroids()
for i=1 to numasteroids
   pitch object down i,ast_info#(i,9)           :`tumble asteroids in all three axis
   turn object right i,ast_info#(i,10)
   roll object right i,ast_info#(i,11)

   inc ast_info#(i,3),ast_info#(i,6)
   inc ast_info#(i,4),ast_info#(i,7)
      `--- wrap asteroids around screen if needed -----
   ast_info#(i,3)=_asteroid_screen_wrapx(ast_info#(i,3),ast_info#(i,2))    :`returns a screen wrap coord if object x-value went off screen
   ast_info#(i,4)=_asteroid_screen_wrapy(ast_info#(i,4),ast_info#(i,2))    :`returns a screen wrap coord if object y-value went off screen
   position object i,ast_info#(i,3),ast_info#(i,4),ast_info#(i,5)          :`position asteroid in new location
next i
endfunction


`--- array entry for another explosion ---
function _set_explosion(object,numparticles,intensity,particlelife,color)
explosion(exparrayindex,1)=1                 :`explosion flag 1=on 0=off
explosion(exparrayindex,2)=object            :`object to explode
explosion(exparrayindex,3)=numparticles      :`number of particles
explosion(exparrayindex,4)=intensity         :`intensity
explosion(exparrayindex,5)=particlelife      :`particle life
explosion(exparrayindex,7)=color             :`color of particles
inc exparrayindex
if exparrayindex>10 then exparrayindex=1
endfunction


function _game_over()
do
   center text screen width()/2,10,"Level: "+str$(level)+"     Lives: "+str$(lives)+"    Targets Left: "+str$(targetsleft)+"     Score: "+str$(score)
   center text screen width()/2,300,"GAME OVER - Thanks For Playing!"
   center text screen width()/2,350,"Press escape key to exit"
   _check_newexplosions()
   _continue_explosion()
   _move_asteroids()
   sync
loop
endfunction


`--- builds new level ---
function _new_level()
inc level
set text font "Arial"
set text size 18
sync
center text screen width()/2,300,"Get Ready - For Level "+str$(level)
sync
wait 1000
numasteroids=0
newasteroids=7+level
for i=1 to 99
   if object exist(i)=1
      delete object i
   endif
next i

size=3
_add_asteroids(newasteroids,size,0)
newlevel=0

ship_x#=0
ship_y#=0
playersafetime=200
numshots=0
shields=1000
if level>1 then enemy#(9)=2000          :`reset enemy visible counter
endfunction


function _check_playerhit()
hnum=object collision(1000,0)
   if hnum>0
      if hnum<100
         inc numhits
         if numhits>50
            hide object 1000                           :`hide player ship
            set object collision off 1000
            position object 1000,-2000,-2000,-2000     :`just move offscreen
            _set_explosion(1000,50,30,100,GREEN)
            numhits=0
            playerdeadtime=400
            playersafetime=450
            dec lives
         endif
      endif
   endif
endfunction


function _check_enemyhit()
sync rate 0
for i=1 to 10
   if shots(i,1)=1
      objnum=shots(i,2)
      hitnum=object collision(objnum,0)
      if hitnum>0
         if hitnum=4000
            hide object objnum                           :`hide shot
            set object collision off objnum
            position object objnum,-3000,-3000,-3000     :`just move offscreen

            hide object hitnum                           :`hide asteroid
            set object collision off hitnum
            position object hitnum,-2000,-2000,-2000     :`just move offscreen

            inc score,200
            _remove_shot(objnum)
            shots(i,1)=0
            _set_explosion(hitnum,10,10,20,RED)
         endif
      endif
   endif
next i
sync rate syncrate
endfunction


function _check_asthits()
sync rate 0
for i=1 to 10
   if shots(i,1)=1
      objnum=shots(i,2)
      hitnum=object collision(objnum,0)
      if hitnum>0
         if hitnum<100
            hide object objnum                           :`hide shot
            set object collision off objnum
            position object objnum,-3000,-3000,-3000     :`just move offscreen

            hide object hitnum                           :`hide asteroid
            set object collision off hitnum
            position object hitnum,-2000,-2000,-2000     :`just move offscreen

            inc score,10
            dec targetsleft
            _remove_shot(objnum)
            shots(i,1)=0
            size=ast_info#(hitnum,2)                     :`size of the hit asteroid
            if size>1
               _add_asteroids(2,size-1,hitnum)
            endif
            _set_explosion(hitnum,10,3*size,20,ast_info#(hitnum,12))
         endif
      endif
   endif
next i
sync rate syncrate
endfunction


`--- Player Shots - 1=active, 2=obnum, 3=shotlife, ---
function _shoot()
shottime=timer()-lastshot
if shottime<shotpause then exitfunction
   position object shotptr,ship_x#,ship_y#,0
   show object shotptr
   zrotate object shotptr,shipangle#
   set object collision on shotptr
   set object collision to spheres shotptr
   shots(shotptr-399,1)=1
   shots(shotptr-399,2)=shotptr
   shots(shotptr-399,3)=500
   inc shotptr
   if shotptr>=410 then shotptr=400
   lastshot=timer()
   inc numshots
endfunction


function _move_shots()
   for i=1 to 10
      if shots(i,1)=1
         obnum=shots(i,2)
         move object obnum,-shotspeed#
         posx#=object position x(obnum)
         posy#=object position y(obnum)
         posx#=_ship_screen_wrapx(posx#)
         posy#=_ship_screen_wrapy(posy#)
         position object obnum,posx#,posy#,0
         dec shots(i,3),shotspeed#
         if shots(i,3)<=0
            _remove_shot(obnum)
            shots(i,1)=0
         endif
      endif
   next i
endfunction


function _remove_shot(obnum)
set object collision off obnum
position object shotptr,-2000,-2000,-2000    :`just move offscreen
hide object obnum
dec numshots
endfunction


function _fire_missle()

endfunction


function _asteroid_screen_wrapx(x#,size#)
limit#=490+size#*15.0
if x#>limit# then x#=-limit#
if x#<-limit# then x#=limit#
endfunction x#


function _asteroid_screen_wrapy(y#,size#)
limit#=380+size#*15.0
if y#>limit# then y#=-limit#
if y#<-limit# then y#=limit#
endfunction y#


function _ship_screen_wrapx(x#)
if x#>500 then x#=-500
if x#<-500 then x#=500
endfunction x#


function _ship_screen_wrapy(y#)
if y#>380 then y#=-380
if y#<-380 then y#=380
endfunction y#


function _make_stars()
ink rgb(255,255,255),0
for x=1 to 250
   dot rnd(1024),rnd(768)
next x
get image 1,0,0,1024,768,1
endfunction


function _reset_vars()
   level=0
   newlevel=1
   targetsleft=0
   numasteroids=0
   lives=5
   playersafetime=100

   ship_y#=0
   ship_x#=0
   shipthrust#=3.0
   shipmass#=50.0

   expdone=0
   exparrayindex=1
   expparticleindex=1
   shotptr=400
   shotspeed#=4
   shotpause=150
   maxshots=5
   numshots=0

   fusetime#=1
   fuselength=1
   boomflag=0

   thrustptr=1
endfunction


`--------DB demo routines for explosions--------
function _request_explosion(ex#,ey#,ez#,particles,intensity#,life,partindex,color)
for i=partindex to partindex+particles
   partlife(i)=life + rnd(life/5)
   partx#(i)=ex#
   party#(i)=ey#
   partz#(i)=ez#
   partyvel#(i)=rnd(intensity#)-(intensity#/2)
   partxvel#(i)=rnd(intensity#)-(intensity#/2)
   partzvel#(i)=rnd(intensity#)-(intensity#/2)
   show object 100+i
   color object 100+i,color
next i
endfunction


`explosion 1=active flag, 2=object, 3=#particles, 4=intensity, 5=particle life, 6=particle start num, 7=
function _continue_explosion()
for ex=1 to 10
   if explosion(ex,1)=2
      for t=explosion(ex,6) to explosion(ex,6)+explosion(ex,3)
         if partlife(t)>1
            dec partlife(t)
            position object 100+t,partx#(t),party#(t),partz#(t)
            partxvel#(t)=partxvel#(t)*0.98                 :`was 0.95
            partyvel#(t)=partyvel#(t)*0.98
`           partzvel#(t)=partzvel#(t)*0.95                 :`particles slow down from air friction
            partzvel#(t)=0.0
`           partyvel#(t)=partyvel#(t)-0.5                  :`particles effected by gravity
            inc partx#(t),partxvel#(t)
            inc party#(t),partyvel#(t)
            inc partz#(t),partzvel#(t)
`           if party#(t)<=0 then partyvel#(t)=partyvel#(t)*-0.7     :`particles bounce on the ground
            rotate object t+100,wrapvalue(object angle x(t+100)+rnd(50)),wrapvalue(object angle y(t+100)+rnd(100)),0
         endif
         if partlife(t)=1
            partlife(t)=0
            hide object 100+t
            start_time=0
            expdone=1
`            explosion(ex,1)=0
         endif
      next t
   endif
next ex
endfunction


function _add_asteroids(num,size,hitnum)
sync rate 0
for i=1 to num
   astnum=numasteroids+1
   _make_asteroids(astnum,size)

   set object smoothing astnum,0
   set object collision on astnum
   set object collision to spheres astnum
`1=active, 2=size, 3=x, 4=y, 5=z, 6=xinc, 7=yinc, 8=zinc, 9=xrot,10=yrot, 11=zrot, 12=color
   ast_info#(astnum,1)=1
   ast_info#(astnum,2)=size
   if hitnum>0
      ast_info#(astnum,3)=ast_info#(hitnum,3)     :`use larger asteroid location
      ast_info#(astnum,4)=ast_info#(hitnum,4)
   else
      ast_info#(astnum,3)=rnd(1200)-600           :`random location
      ast_info#(astnum,4)=rnd(1200)-600
   endif
   ast_info#(astnum,5)=0

   v#=(rnd(3)+0.8)/(rnd(8)+size)       :`generate a motion value
   d=rnd(10):if d>5 then v#=v#*-1.0    :`decide whether a positive or negative motion
   ast_info#(astnum,6)=v#

   v#=(rnd(3)+0.8)/(rnd(8)+size)       :`generate a motion value
   d=rnd(10):if d>5 then v#=v#*-1.0    :`decide whether a positive or negative motion
   ast_info#(astnum,7)=v#

   ast_info#(astnum,8)=0

   v#=rnd(3)/(rnd(10)+1.0)             :`generate a rotation value
   d=rnd(10):if d>5 then v#=v#*-1.0    :`decide whether a positive or negative rotation
   ast_info#(astnum,9)=v#

   v#=rnd(3)/(rnd(10)+1.0)
   d=rnd(10):if d>5 then v#=v#*-1.0
   ast_info#(astnum,10)=v#

   v#=rnd(3)/(rnd(10)+1.0)
   d=rnd(10):if d>5 then v#=v#*-1.0
   ast_info#(astnum,11)=v#

   if hitnum>0
      color=ast_info#(hitnum,12)     :`use larger asteroid color
   else
      color=rgb(rnd(255),rnd(255),rnd(255))  :`use random color
   endif
   ast_info#(astnum,12)=color
   color object astnum,ast_info#(astnum,12)
   position object astnum,ast_info#(astnum,3),ast_info#(astnum,4),ast_info#(astnum,5)
   show object astnum

   inc numasteroids
   inc targetsleft
next i
sync rate syncrate
endfunction


` ----- Make Asteroids --- Trying vertex commands for the first time! -----
function _make_asteroids(num,size)
objs=num
make object sphere objs,60
if size=2 then scale object objs,70,70,70
if size=1 then scale object objs,30,30,30

` get vertex data
ob=objs
make mesh from object 1,ob
lock vertexdata for mesh  1
vertex_count(ob)=(GET VERTEXDATA VERTEX COUNT()-1)
for v=0 to vertex_count(ob)
   v_pos_x#(ob,v)=GET VERTEXDATA POSITION X(v)+object position x(ob)
   v_pos_y#(ob,v)=GET VERTEXDATA POSITION y(v)+object position y(ob)
   v_pos_z#(ob,v)=GET VERTEXDATA POSITION z(v)+object position z(ob)
next v
unlock vertexdata
delete mesh 1

` deform vertices 4-10 times for jagged look
for deftimes=1 to (rnd(6)+4)
   make mesh from object 1,ob
   lock vertexdata for mesh  1
   for i=0 to vertex_count(ob)
      xdir=rnd(10):if xdir>5 then xdir=1 else xdir=-1
      ydir=rnd(10):if ydir>5 then ydir=1 else ydir=-1
      zdir=rnd(10):if zdir>5 then zdir=1 else zdir=-1
      inc v_pos_x#(ob,i),rnd(5)*xdir
      inc v_pos_y#(ob,i),rnd(5)*ydir
      inc v_pos_z#(ob,i),rnd(5)*zdir
      SET VERTEXDATA POSITION i, v_pos_x#(ob,i),v_pos_y#(ob,i),v_pos_z#(ob,i)
   next i
   unlock vertexdata
   make object 5000,1,0
   delete mesh 1
   delete object ob
   clone object ob,5000
   delete object 5000
next deftimes
endfunction


` ----- Hyperspace ship to new location --- This was interesting to work out -----
function _hyperspace(source)
sync rate 0
hyperflag=1
numslices=3
destx#=rnd(850)-425
desty#=rnd(650)-325
hide object 1000

for i=1 to numhyper
   if source=2
      ship_x#=1500
      ship_y#=400
   endif
   hyperinfo#(i,1)=ship_x#
   hyperinfo#(i,2)=ship_y#

   obnum=1020+i
   xrotate object obnum,object angle x(1000)
   yrotate object obnum,object angle y(1000)
   zrotate object obnum,object angle z(1000)
   position object obnum,hyperinfo#(i,1), hyperinfo#(i,2), 0
   show object obnum
next i

hyperinfo#(1,1)=destx#
hyperinfo#(1,2)=desty#
position object 1021,hyperinfo#(1,1), hyperinfo#(1,2), 0

count=0
while hyperflag=1
   for i=2 to numhyper
      hyperinfo#(i,3)=(hyperinfo#(i-1,1)-hyperinfo#(i,1))/numslices
      hyperinfo#(i,4)=(hyperinfo#(i-1,2)-hyperinfo#(i,2))/numslices
      inc hyperinfo#(i,1),hyperinfo#(i,3)
      inc hyperinfo#(i,2),hyperinfo#(i,4)
      position object 1020+i,hyperinfo#(i,1), hyperinfo#(i,2), 0
      sync
   next i
   inc count
   if count>=numhyper*numslices*2 then hyperflag=0
endwhile
ship_x#=destx#
ship_y#=desty#
box_xdir#=0
box_ydir#=0
position object 1000,ship_x#,ship_y#,ship_z#
show object 1000

for i=1 to numhyper
   hide object 1020+i
next i
sync
sync rate syncrate
endfunction

`Challenge Compo - Asteroids Game
`by Bill Robinson
`due: 2-25-06

`@Kimosabi - you do NOT have rights to use this program as your own.
`And you never should have used Ric's pong game as your own, on your web sight!
`
`Use 'Z' and 'X' to rotate ship, leftarrow and rightarrow work too
`Use comma ',' to fire, period '.' to thrust
`Use 'Space' to Hyperspace to a new position
`Use 'Shift' for shields, you have a limited number of shields per level
`You only get 5 shots on the screen at a time
`
`Using Hyperspace FREEZES TIME while your ship is in hyperspace traveling to new location.
`If ship traveling through Hyperspace lands on an asteroid,
`you have a brief moment to engage Hyperspace again to save your ship
`Hyperspace will also bring your moving ship to a stop
`
set display mode 1024,768,32
autocam off
sync on
sync rate 60
Hide Mouse
Backdrop on
Color Backdrop 0
set ambient light 15
set camera range 1,5000
randomize timer()

`--- Game Setup ---
#constant MAX_ASTEROIDS 199
global GREEN
GREEN=rgb(0,255,0)
global RED
RED=rgb(255,0,0)
global level
global newlevel
global score
global targetsleft
global numasteroids
global lives
global playersafetime
global shields
global syncrate=60

`--- Player ---
global ship_x#
global ship_y#
global ship_z#=0
global shipangle#
global shipthrust#
global shipmass#
global explode_object=0
global expdone=0
global exparrayindex=1
global expparticleindex=1
global numhits
global playerdeadtime
global velx#=0
global vely#=0
global shipincx#=0
global shipincy#=0

`--- enemy ---
`1=active, 2=size, 3=x, 4=y, 5=z, 6=xinc, 7=yinc, 8=zinc, 9=color
dim enemy#(10)
dim eshots#(10)

`--- asteroids ---
`1=active, 2=size, 3=x, 4=y, 5=z, 6=xinc, 7=yinc, 8=zinc, 9=xrot,10=yrot, 11=zrot, 12=color
dim ast_info#(MAX_ASTEROIDS,15)
` highest number of vertexes = 200 for now
global vcount=200
dim vertex_count(199)
dim v_pos_x#(199,vcount)
dim v_pos_y#(199,vcount)
dim v_pos_z#(199,vcount)

`--- explosion particles ---
rem Arrays for position, velocity and life of each explosion particle
dim partx#(300)
dim party#(300)
dim partz#(300)
dim partxvel#(300)
dim partyvel#(300)
dim partzvel#(300)
dim partlife(300)
dim explosion(10,10)
global start_time=0
global inten#=60.0
global max=200

`--- ship thrust ---
dim thrust#(50,10)
global thrustptr

`--- Shots Fired ---
dim shots(100,4)
global shotptr
global shotspeed#
global lastshot
global shottime
global shotpause
global hitnum
global maxshots
global numshots

`--- Players shots getting made ---
for i=400 to 410
   make object sphere i,30,3,3
   xrotate object i,90
   color object i,rgb(255,255,255)
   scale object i,20,20,100
   set object collision off i
   hide object i
next i

`--- hyperspace ships ---
global numhyper=5
dim hyperinfo#(numhyper,6)
color=GREEN
for i=1 to numhyper
   obnum=1020+i
   make object cone obnum, 20

   color object obnum,color
   ghost object on obnum
   hide object obnum
next i

`------------------------
screen_xmax=screen width()
screen_ymax=screen height()
screen_center=screen_xmax/2

`--- make cone for ship ---
make object cone 1000,20
color object 1000,rgb(0,255,0)
set object collision on 1000
set object collision to spheres 1000
fix object pivot 1000

make object sphere 1001,50
color object 1001,rgb(0,255,255)
set object collision off 1001
ghost object on 1001
`set object wireframe 1001,1
set object ambient 1001,0
position object 1001,-2700,-2700,-2700

make object cone 4000,50
scale object 4000,100,50,100
color object 4000,rgb(255,0,0)
set object collision on 4000
set object collision to spheres 4000
position object 4000,-2600,-2600,-2600

`--- make exhaust particles ---
for i=1 to 40
   color=rgb(rnd(55)+200,rnd(55)+200,0)
   obnum=600+i
   make object plain obnum,2,2
   color object obnum,color
   hide object obnum
next i

`--- make explosion pieces ---
color=rgb(255,255,255)
for i=1 to max
   obnum=199+i
   make object plain obnum,6,6
   color object obnum,color
   hide object obnum
next i

_reset_vars()
_make_stars()

`--- setup starfield in background ---
make object plain 998,1300,1000
texture object 998, 1
position object 998,0,0,200

`--- debug limits of screen, for wrap-around of objects ---
global lwall=-480
global rwall=480
global twall=360
global bwall=-360

position object 1000, 0,0,0
position camera 0,0,-600
point camera 0,0,0

do
   set object collision on 1000

   if newlevel=1
      _new_level()
   endif
   if targetsleft=0 then newlevel=1

   `explosion 1=active flag, 2=object, 3=#particles, 4=intensity, 5=particle life, 6=particle start num, 7=color
   if keystate(48)=1                            :`b key - self destruct
      _set_explosion(1000,50,30,100,GREEN)
      playerdeadtime=200
   endif

   if leftkey()=1 then inc shipangle#,3         :`left arrow key
   if rightkey()=1 then dec shipangle#,3        :`right arrow key
   if keystate(44)=1 then inc shipangle#,3      :`z key
   if keystate(45)=1 then dec shipangle#,3      :`x key
   if keystate(29)=1 then _fire_missle()        :`ctrl key
   if keystate(42)=1 or keystate(54)=1 then _raise_shields()
   if keystate(57)=1                            :`space key
      _hyperspace(1)
      velx#=0:vely#=0:shipincx#=0:shipincy#=0
   endif

   if keystate(51)=1 and numshots<maxshots then _shoot()
   if keystate(52)=1
      shipincx#=-sin(shipangle#)*shipthrust#
      shipincy#=cos(shipangle#)*shipthrust#
      _start_thrust()
   else
      shipincx#=0
      shipincy#=0
   endif

   `calc ship velocity
   deltax#=shipincx#/shipmass#
   deltay#=shipincy#/shipmass#
   inc velx#,deltax#
   inc vely#,deltay#

   inc ship_x#,velx#
   inc ship_y#,vely#

   _show_thrust()

   shipangle#=wrapvalue(shipangle#)
   ship_x#=_ship_screen_wrapx(ship_x#)             :`wrap players ship around screen if needed
   ship_y#=_ship_screen_wrapy(ship_y#)

   zrotate object 1000,shipangle#                  :`rotate players ship
   position object 1000,ship_x#,ship_y#,ship_z#    :`position ship on screen
   if playersafetime>0 and playerdeadtime=0
      position object 1001,ship_x#,ship_y#-5,ship_z#    :`safety shield
   else
      position object 1001,-2500,-2500,-2500
   endif

   _check_newexplosions()
   _check_asthits()           :`check for player hits from shots
   _move_shots()              :`move player shots
   _continue_explosion()      :`continue to explode pieces
   _move_asteroids()
   if lives=0 then _game_over()

   if playersafetime>0
      dec playersafetime
   else
      _check_playerhit()
   endif

   if level>1
      if enemy#(1)=0
         _start_enemy()
      else
         _move_enemy()
      endif
   endif

`   _check_enemyhit()

   if playerdeadtime>0
      dec playerdeadtime
      if playerdeadtime<200 then center text screen width()/2,300,"GET READY! - For Next Ship"
      if playerdeadtime=0
         velx#=0:vely#=0:shipincx#=0:shipincy#=0
         _hyperspace(2)
         set object collision on 1000
         playersafetime=120
      endif
   endif

   if expdone=1
      explode_object=0
      start_time=0
      expdone=0
   endif

   if numshots<=0 then numshots=0      :`just correcting for a bug I haven't figured out yet

   set cursor 1,1
   print screen fps()
   center text screen_center,10,"Level: "+str$(level)+"      Lives: "+str$(lives)+"      Targets Left: "+str$(targetsleft)+"      Shields: "+str$(shields)+"      Score: "+str$(score)
   sync
loop


function _start_thrust()
thrustlife=10
i=thrustptr
if thrust#(i,1)=0
   thrust#(i,1)=1
   thrust#(i,2)=ship_x#
   thrust#(i,3)=ship_y#
   thrust#(i,4)=-shipincx#-(rnd(3)/4.0)
   thrust#(i,5)=-shipincy#-(rnd(3)/4.0)
   thrust#(i,6)=thrustlife
   inc thrustptr
   if thrustptr>40 then thrustptr=1
   show object 600+i
endif
endfunction


function _show_thrust()
for i=1 to 40
   if thrust#(i,6)>0
      position object 600+i,thrust#(i,2),thrust#(i,3),0
      dec thrust#(i,6)
      inc thrust#(i,2),thrust#(i,4)
      inc thrust#(i,3),thrust#(i,5)
   else
      thrust#(i,1)=0
      hide object 600+i
   endif
next i
endfunction


function _start_enemy()
`1=active, 2=size, 3=x, 4=y, 5=z, 6=xinc, 7=yinc, 8=yloc_change, 9=vis_counter
if enemy#(1)=0
   if enemy#(9)>0
      dec enemy#(9)
   else
      enemy#(1)=1
      enemy#(3)=-500.0
      enemy#(4)=rnd(320)-100
      enemy#(5)=0
      enemy#(6)=(rnd(120)+60)/60.0
      enemy#(7)=0
      enemy#(8)=rnd(100)+50
`      enemy#(9)=rnd(1000)+2000
      position object 4000,enemy#(3),enemy#(4),enemy#(5)
      show object 4000
   endif
endif
endfunction


function _move_enemy()
`1=active, 2=size, 3=x, 4=y, 5=z, 6=xinc, 7=yinc, 8=yloc_change, 9=vis_counter
if enemy#(1)=1
   dec enemy#(8)
   inc enemy#(3),enemy#(6)
   if enemy#(4)<300 and enemy#(4)>-300 then inc enemy#(4),enemy#(7)
   position object 4000,enemy#(3),enemy#(4),enemy#(5)
   if enemy#(8)<0
      enemy#(8)=rnd(50)+50
      enemy#(7)=(rnd(360)-180)/60.0
   endif
   if enemy#(3)>500
      enemy#(1)=0
      position object 4000,-2700,-2700,-2700
      enemy#(8)=rnd(50)+50
      enemy#(9)=rnd(1000)+2000
   endif
endif
endfunction


function _enemy_shots()

endfunction


function _raise_shields()
if shields>=200 and playersafetime=0
   playersafetime=200
   dec shields,200
endif
endfunction


function _check_newexplosions()
  for ex=1 to 10
      if explosion(ex,1)=1
         ex#=object position x(explosion(ex,2))
         ey#=object position y(explosion(ex,2))
         ez#=object position z(explosion(ex,2))
         if expparticleindex+explosion(ex,3)>=200
            expparticleindex=1
         endif
         explosion(ex,6)=expparticleindex
         inc expparticleindex,explosion(ex,3)
   `explosion() 1=active flag, 2=object, 3=#particles, 4=intensity, 5=particle life, 6=particle start num, 7=color
         _request_explosion(ex#,ey#,ez#,explosion(ex,3),explosion(ex,4),explosion(ex,5),explosion(ex,6),explosion(ex,7))
         start_time=1

         hide object explosion(ex,2)               :`was explode_object
         set object collision off explosion(ex,2)  :`was explode_object
         explosion(ex,1)=2
      endif
   next ex
endfunction


`--- move asteroids ---
function _move_asteroids()
for i=1 to numasteroids
   pitch object down i,ast_info#(i,9)           :`tumble asteroids in all three axis
   turn object right i,ast_info#(i,10)
   roll object right i,ast_info#(i,11)

   inc ast_info#(i,3),ast_info#(i,6)
   inc ast_info#(i,4),ast_info#(i,7)
      `--- wrap asteroids around screen if needed -----
   ast_info#(i,3)=_asteroid_screen_wrapx(ast_info#(i,3),ast_info#(i,2))    :`returns a screen wrap coord if object x-value went off screen
   ast_info#(i,4)=_asteroid_screen_wrapy(ast_info#(i,4),ast_info#(i,2))    :`returns a screen wrap coord if object y-value went off screen
   position object i,ast_info#(i,3),ast_info#(i,4),ast_info#(i,5)          :`position asteroid in new location
next i
endfunction


`--- array entry for another explosion ---
function _set_explosion(object,numparticles,intensity,particlelife,color)
explosion(exparrayindex,1)=1                 :`explosion flag 1=on 0=off
explosion(exparrayindex,2)=object            :`object to explode
explosion(exparrayindex,3)=numparticles      :`number of particles
explosion(exparrayindex,4)=intensity         :`intensity
explosion(exparrayindex,5)=particlelife      :`particle life
explosion(exparrayindex,7)=color             :`color of particles
inc exparrayindex
if exparrayindex>10 then exparrayindex=1
endfunction


function _game_over()
do
   center text screen width()/2,10,"Level: "+str$(level)+"     Lives: "+str$(lives)+"    Targets Left: "+str$(targetsleft)+"     Score: "+str$(score)
   center text screen width()/2,300,"GAME OVER - Thanks For Playing!"
   center text screen width()/2,350,"Press escape key to exit"
   _check_newexplosions()
   _continue_explosion()
   _move_asteroids()
   sync
loop
endfunction


`--- builds new level ---
function _new_level()
inc level
set text font "Arial"
set text size 18
sync
center text screen width()/2,300,"Get Ready - For Level "+str$(level)
sync
wait 1000
numasteroids=0
newasteroids=7+level
for i=1 to 199
   if object exist(i)=1
      delete object i
   endif
next i

size=3
_add_asteroids(newasteroids,size,0)
newlevel=0

ship_x#=0
ship_y#=0
playersafetime=200
numshots=0
shields=1000
if level>1 then enemy#(9)=2000          :`reset enemy visible counter
endfunction


function _check_playerhit()
hnum=object collision(1000,0)
   if hnum>0
      if hnum<=199
         inc numhits
         if numhits>50
            hide object 1000                           :`hide player ship
            set object collision off 1000
            position object 1000,-2000,-2000,-2000     :`just move offscreen
            _set_explosion(1000,50,30,100,GREEN)
            numhits=0
            playerdeadtime=400
            playersafetime=450
            dec lives
         endif
      endif
   endif
endfunction


function _check_enemyhit()
sync rate 0
for i=1 to 10
   if shots(i,1)=1
      objnum=shots(i,2)
      hitnum=object collision(objnum,0)
      if hitnum>0
         if hitnum=4000
            hide object objnum                           :`hide shot
            set object collision off objnum
            position object objnum,-3000,-3000,-3000     :`just move offscreen

            hide object hitnum                           :`hide asteroid
            set object collision off hitnum
            position object hitnum,-2000,-2000,-2000     :`just move offscreen

            inc score,200
            _remove_shot(objnum)
            shots(i,1)=0
            _set_explosion(hitnum,10,10,20,RED)
         endif
      endif
   endif
next i
sync rate syncrate
endfunction


function _check_asthits()
sync rate 0
for i=1 to 10
   if shots(i,1)=1
      objnum=shots(i,2)
      hitnum=object collision(objnum,0)
      if hitnum>0
         if hitnum<199
            hide object objnum                           :`hide shot
            set object collision off objnum
            position object objnum,-3000,-3000,-3000     :`just move offscreen

            hide object hitnum                           :`hide asteroid
            set object collision off hitnum
            position object hitnum,-2000,-2000,-2000     :`just move offscreen

            inc score,10
            dec targetsleft
            _remove_shot(objnum)
            shots(i,1)=0
            size=ast_info#(hitnum,2)                     :`size of the hit asteroid
            if size>1
               _add_asteroids(2,size-1,hitnum)
            endif
            _set_explosion(hitnum,10,3*size,20,ast_info#(hitnum,12))
         endif
      endif
   endif
next i
sync rate syncrate
endfunction


`--- Player Shots - 1=active, 2=obnum, 3=shotlife, ---
function _shoot()
shottime=timer()-lastshot
if shottime<shotpause then exitfunction
   position object shotptr,ship_x#,ship_y#,0
   show object shotptr
   zrotate object shotptr,shipangle#
   set object collision on shotptr
   set object collision to spheres shotptr
   shots(shotptr-399,1)=1
   shots(shotptr-399,2)=shotptr
   shots(shotptr-399,3)=500
   inc shotptr
   if shotptr>=410 then shotptr=400
   lastshot=timer()
   inc numshots
endfunction


function _move_shots()
   for i=1 to 10
      if shots(i,1)=1
         obnum=shots(i,2)
         move object obnum,-shotspeed#
         posx#=object position x(obnum)
         posy#=object position y(obnum)
         posx#=_ship_screen_wrapx(posx#)
         posy#=_ship_screen_wrapy(posy#)
         position object obnum,posx#,posy#,0
         dec shots(i,3),shotspeed#
         if shots(i,3)<=0
            _remove_shot(obnum)
            shots(i,1)=0
         endif
      endif
   next i
endfunction


function _remove_shot(obnum)
set object collision off obnum
position object shotptr,-2000,-2000,-2000    :`just move offscreen
hide object obnum
dec numshots
endfunction


function _fire_missle()

endfunction


function _asteroid_screen_wrapx(x#,size#)
limit#=490+size#*15.0
if x#>limit# then x#=-limit#
if x#<-limit# then x#=limit#
endfunction x#


function _asteroid_screen_wrapy(y#,size#)
limit#=380+size#*15.0
if y#>limit# then y#=-limit#
if y#<-limit# then y#=limit#
endfunction y#


function _ship_screen_wrapx(x#)
if x#>500 then x#=-500
if x#<-500 then x#=500
endfunction x#


function _ship_screen_wrapy(y#)
if y#>380 then y#=-380
if y#<-380 then y#=380
endfunction y#


function _make_stars()
ink rgb(255,255,255),0
for x=1 to 250
   dot rnd(1024),rnd(768)
next x
get image 1,0,0,1024,768,1
endfunction


function _reset_vars()
   level=0
   newlevel=1
   targetsleft=0
   numasteroids=0
   lives=5
   playersafetime=100

   ship_y#=0
   ship_x#=0
   shipthrust#=3.0
   shipmass#=50.0

   expdone=0
   exparrayindex=1
   expparticleindex=1
   shotptr=400
   shotspeed#=4
   shotpause=150
   maxshots=5
   numshots=0

   fusetime#=1
   fuselength=1
   boomflag=0

   thrustptr=1
endfunction


`--------DB demo routines for explosions--------
function _request_explosion(ex#,ey#,ez#,particles,intensity#,life,partindex,color)
for i=partindex to partindex+particles
   partlife(i)=life + rnd(life/5)
   partx#(i)=ex#
   party#(i)=ey#
   partz#(i)=ez#
   partyvel#(i)=rnd(intensity#)-(intensity#/2)
   partxvel#(i)=rnd(intensity#)-(intensity#/2)
   partzvel#(i)=rnd(intensity#)-(intensity#/2)
   show object 199+i
   color object 199+i,color
next i
endfunction


`explosion 1=active flag, 2=object, 3=#particles, 4=intensity, 5=particle life, 6=particle start num, 7=
function _continue_explosion()
for ex=1 to 10
   if explosion(ex,1)=2
      for t=explosion(ex,6) to explosion(ex,6)+explosion(ex,3)
         if partlife(t)>1
            dec partlife(t)
            position object 199+t,partx#(t),party#(t),partz#(t)
            partxvel#(t)=partxvel#(t)*0.98                 :`was 0.95
            partyvel#(t)=partyvel#(t)*0.98
`           partzvel#(t)=partzvel#(t)*0.95                 :`particles slow down from air friction
            partzvel#(t)=0.0
`           partyvel#(t)=partyvel#(t)-0.5                  :`particles effected by gravity
            inc partx#(t),partxvel#(t)
            inc party#(t),partyvel#(t)
            inc partz#(t),partzvel#(t)
`           if party#(t)<=0 then partyvel#(t)=partyvel#(t)*-0.7     :`particles bounce on the ground
            rotate object t+199,wrapvalue(object angle x(t+199)+rnd(50)),wrapvalue(object angle y(t+199)+rnd(100)),0
         endif
         if partlife(t)=1
            partlife(t)=0
            hide object 199+t
            start_time=0
            expdone=1
`            explosion(ex,1)=0
         endif
      next t
   endif
next ex
endfunction


function _add_asteroids(num,size,hitnum)
sync rate 0
for i=1 to num
   astnum=numasteroids+1
   _make_asteroids(astnum,size)

   set object smoothing astnum,0
   set object collision on astnum
   set object collision to spheres astnum
`1=active, 2=size, 3=x, 4=y, 5=z, 6=xinc, 7=yinc, 8=zinc, 9=xrot,10=yrot, 11=zrot, 12=color
   ast_info#(astnum,1)=1
   ast_info#(astnum,2)=size
   if hitnum>0
      ast_info#(astnum,3)=ast_info#(hitnum,3)     :`use larger asteroid location
      ast_info#(astnum,4)=ast_info#(hitnum,4)
   else
      ast_info#(astnum,3)=rnd(1200)-600           :`random location
      ast_info#(astnum,4)=rnd(1200)-600
   endif
   ast_info#(astnum,5)=0

   v#=(rnd(3)+0.8)/(rnd(8)+size)       :`generate a motion value
   d=rnd(10):if d>5 then v#=v#*-1.0    :`decide whether a positive or negative motion
   ast_info#(astnum,6)=v#

   v#=(rnd(3)+0.8)/(rnd(8)+size)       :`generate a motion value
   d=rnd(10):if d>5 then v#=v#*-1.0    :`decide whether a positive or negative motion
   ast_info#(astnum,7)=v#

   ast_info#(astnum,8)=0

   v#=rnd(3)/(rnd(10)+1.0)             :`generate a rotation value
   d=rnd(10):if d>5 then v#=v#*-1.0    :`decide whether a positive or negative rotation
   ast_info#(astnum,9)=v#

   v#=rnd(3)/(rnd(10)+1.0)
   d=rnd(10):if d>5 then v#=v#*-1.0
   ast_info#(astnum,10)=v#

   v#=rnd(3)/(rnd(10)+1.0)
   d=rnd(10):if d>5 then v#=v#*-1.0
   ast_info#(astnum,11)=v#

   if hitnum>0
      color=ast_info#(hitnum,12)     :`use larger asteroid color
   else
      color=rgb(rnd(255),rnd(255),rnd(255))  :`use random color
   endif
   ast_info#(astnum,12)=color
   color object astnum,ast_info#(astnum,12)
   position object astnum,ast_info#(astnum,3),ast_info#(astnum,4),ast_info#(astnum,5)
   show object astnum

   inc numasteroids
   inc targetsleft
next i
sync rate syncrate
endfunction


` ----- Make Asteroids --- Trying vertex commands for the first time! -----
function _make_asteroids(num,size)
objs=num
make object sphere objs,60
if size=2 then scale object objs,70,70,70
if size=1 then scale object objs,30,30,30

` get vertex data
ob=objs
make mesh from object 1,ob
lock vertexdata for mesh  1
vertex_count(ob)=(GET VERTEXDATA VERTEX COUNT()-1)
for v=0 to vertex_count(ob)
   v_pos_x#(ob,v)=GET VERTEXDATA POSITION X(v)+object position x(ob)
   v_pos_y#(ob,v)=GET VERTEXDATA POSITION y(v)+object position y(ob)
   v_pos_z#(ob,v)=GET VERTEXDATA POSITION z(v)+object position z(ob)
next v
unlock vertexdata
delete mesh 1

` deform vertices 4-10 times for jagged look
for deftimes=1 to (rnd(6)+4)
   make mesh from object 1,ob
   lock vertexdata for mesh  1
   for i=0 to vertex_count(ob)
      xdir=rnd(10):if xdir>5 then xdir=1 else xdir=-1
      ydir=rnd(10):if ydir>5 then ydir=1 else ydir=-1
      zdir=rnd(10):if zdir>5 then zdir=1 else zdir=-1
      inc v_pos_x#(ob,i),rnd(5)*xdir
      inc v_pos_y#(ob,i),rnd(5)*ydir
      inc v_pos_z#(ob,i),rnd(5)*zdir
      SET VERTEXDATA POSITION i, v_pos_x#(ob,i),v_pos_y#(ob,i),v_pos_z#(ob,i)
   next i
   unlock vertexdata
   make object 5000,1,0
   delete mesh 1
   delete object ob
   clone object ob,5000
   delete object 5000
next deftimes
endfunction


` ----- Hyperspace ship to new location --- This was interesting to work out -----
function _hyperspace(source)
sync rate 0
hyperflag=1
numslices=3
destx#=rnd(850)-425
desty#=rnd(650)-325
hide object 1000

for i=1 to numhyper
   if source=2
      ship_x#=1500
      ship_y#=400
   endif
   hyperinfo#(i,1)=ship_x#
   hyperinfo#(i,2)=ship_y#

   obnum=1020+i
   xrotate object obnum,object angle x(1000)
   yrotate object obnum,object angle y(1000)
   zrotate object obnum,object angle z(1000)
   position object obnum,hyperinfo#(i,1), hyperinfo#(i,2), 0
   show object obnum
next i

hyperinfo#(1,1)=destx#
hyperinfo#(1,2)=desty#
position object 1021,hyperinfo#(1,1), hyperinfo#(1,2), 0

count=0
while hyperflag=1
   for i=2 to numhyper
      hyperinfo#(i,3)=(hyperinfo#(i-1,1)-hyperinfo#(i,1))/numslices
      hyperinfo#(i,4)=(hyperinfo#(i-1,2)-hyperinfo#(i,2))/numslices
      inc hyperinfo#(i,1),hyperinfo#(i,3)
      inc hyperinfo#(i,2),hyperinfo#(i,4)
      position object 1020+i,hyperinfo#(i,1), hyperinfo#(i,2), 0
      sync
   next i
   inc count
   if count>=numhyper*numslices*2 then hyperflag=0
endwhile
ship_x#=destx#
ship_y#=desty#
box_xdir#=0
box_ydir#=0
position object 1000,ship_x#,ship_y#,ship_z#
show object 1000

for i=1 to numhyper
   hide object 1020+i
next i
sync
sync rate syncrate
endfunction