Sorry your browser is not supported!

`   'Aargh - not another Pong Clone!' by Ric.

if check display mode(1024,768,32)=1 then set display mode 1024,768,32
hide mouse
sync on
sync rate 50
autocam off
hide light 0
color backdrop rgb(0,0,0)
set ambient light 80
make light 1
position light 1,100,100,20
set light range 1,100000
color light 1,rgb(255,220,180)

fog on
fog color 0
fog distance 1000

`create green texture
for x=0 to 100
   for y=0 to 100
      ink rgb(0,x+y,0),0
      dot x,y
   next y
next x
get image 103,0,0,100,100

cls

`create purple texture
for x=0 to 100
   for y=0 to 100
      ink rgb(x+y,0,x+y),0
      dot x,y
   next y
next x
get image 102,0,0,100,100

cls

`create blue texture
for x=0 to 100
   for y=0 to 100
      ink rgb(0,0,x+y),0
      dot x,y
   next y
next x
get image 101,0,0,100,100

`create star texture
for x=0 to 100
for y=0 to 100
d=rnd(20)
ink rgb(100+rnd(100),100+rnd(100),rnd(100)+100),0
if d=1 then dot x,y
next y
next x
get image 1,0,0,100,100

`create tile texture
cls
ink rgb(0,0,255),0
box 0,0,10,10
box 10,10,20,20
get image 2,0,0,20,20

set text font "sf automaton_mod"
set text size 25

`create starsphere
make object sphere 1000,-1000,50,50
texture object 1000,1
scale object texture 1000,5,5
xrotate object 1000,-90

`player paddle
make object sphere 1,20,20,20
scale object 1,100,400,100
ghost object on 1
texture object 1,102
set object emissive 1,rgb(200,200,200)
set object specular 1,rgb(250,250,250)
set object specular power 1,10
set object fog 1,0
set object collision on 1
set object collision to boxes 1


`reflection of player paddle
clone object 302,1 `top
scale object 302,100,400,100
fade object 302,90
clone object 303,1 `bottom
scale object 303,100,400,100
fade object 303,90

`computer paddle
make object sphere 2,20,20,20
scale object 2,100,400,100
ghost object on 2
texture object 2,103
set object emissive 2,rgb(200,200,200)
set object specular 2,rgb(250,250,250)
set object specular power 2,10
set object fog 2,0
set object collision on 2
set object collision to boxes 2

`reflection of computer paddle
clone object 304,2 `top
scale object 304,100,400,100
fade object 304,90
clone object 305,2 `bottom
scale object 305,100,400,100
fade object 305,90

`ball
make object sphere 3,20,40,40
texture object 3,101
set object specular 3,rgb(200,200,200)
set object specular power 3,15
set object emissive 3,rgb(150,150,100)
set object ambient 3,0
set object collision on 3
set object fog 3,0

`reflection of ball
clone object 300,3 `top reflection
fade object 300,50
clone object 301,3 `bottom reflection
fade object 301,50

`bottom wall
make object plain 4,500,800
xrotate object 4,90
set object collision on 4
texture object 4,2
scale object texture 4,5,5
set object transparency 4,1

`top wall
make object plain 5,500,800
xrotate object 5,90
set object collision on 5
texture object 5,2
scale object texture 5,5,5
set object transparency 5,1

`back wall
make object plain 6,500,100
texture object 6,101
scale object texture 6,2,10
set object texture 6,2,0
set object transparency 6,1
set object fog 6,0
ghost object on 6

`position walls
position object 4,0,-150,100
position object 5,0,150,100
position object 6,0,0,300

`restart point for new game (the goto command is not dead yet!)
newgame:

for object=300 to 305
hide object object
next object

`zoom in
paddlex#=0
position object 1,-paddlex#,0,0
position object 2,paddlex#,0,0
position object 3,0,0,0


zrotate camera 0
camz#=-2000.0
position camera 0,0,0,camz#
while camz#<-500.0
inc camz#,5
position camera 0,0,camz#
sync
endwhile
position camera 0,0,0,-500

`set paddle positions

while paddlex#<180
inc paddlex#
position object 1,-paddlex#,0,0
position object 2,paddlex#,0,0
sync
endwhile



do
text screen width()/2-100,200,"Gravity on? (y/n)"
if inkey$()="y" then gravity=1:exit
if inkey$()="n" then gravity=0:exit
sync
loop

text screen width()/2-70,240,"GET READY!"
sync
wait 600

for object=300 to 305
show object object
next object

`set initial variables
level=1
pscore=0
cscore=0
pv#=10 `player paddle velocity
bvx#=10 `ball velocity
if gravity=1
cv#=3.5 `computer paddle velocity
g#=0.5
else
cv#=2
g#=0
endif

`restart point for new serve or new level
restart:
randomize timer()
wait 800
py#=-10+rnd(20) `player's initial y position
cy#=-10+rnd(20)           `computer's initial y position
bx#=0           `ball x
by#=0           `ball y
bvy#=1.5+rnd(10)/10          `ball direction (in degrees:- horizontal=0)
bvx#=abs(bvx#)
`main loop

do

text 0,0,str$(screen fps())

`player input
remstart
if upkey()>0 and object collision (1,5)=0
   py#=py#+pv#
endif

if downkey()>0 and object collision (1,4)=0
   py#=py#-pv#
endif
remend


py#=py#-mousemovey()
if py#>110 then py#=110
if py#<-110 then py#=-110

`move player paddle
position object 1,-180,py#,100
position object 302,-180,-py#-300,100
position object 303,-180,-py#+300,100
`position object 401,-180,py#,100

`ball motion
bvy#=bvy#+g#
bx#=bx#+bvx#
by#=by#-bvy#

`collision with court
if by#>140
by#=by#-10
bvy#=bvy#*-1
endif

if by#<-140
by#=by#+10
bvy#=bvy#*-1
endif

`collision with player paddle
if object collision (3,0)=1
  bvx#=bvx#*-1 `reverse velocity
  bx#=-150 `prevent embedding
`measure offset between player paddle and ball and adjust direction
    po#=by#-py#
    bvy#=bvy#-po#*0.15
endif

`and same for computer paddle.....
if object collision (3,0)=2
  bvx#=bvx#*-1
  bx#=150
    co#=by#-cy#
    bvy#=bvy#-co#*0.15
endif

if bvy#>15.0 then bvy#=15.0
if bvy#<-15.0 then bvy#=-15.0

`new ball position
position object 3,bx#,by#,100
position object 300,bx#,-by#+300,100
position object 301,bx#,-by#-300,100

`computer paddle A.I.

`return to middle
if bvx#<0
  if cy#>2 then a#=-cv#
  if cy#<2 then a#=cv#
  if cy#<=2 and cy#>=-2 then a#=0
  cy#=cy#+a#
endif

`move towards ball
if bvx#>0
  if by#>cy# then a#=cv#
  if by#<cy# then a#=-cv#
  cy#=cy#+a#
endif

position object 2,180,cy#,100
position object 304,180,-cy#+300,100
position object 305,180,-cy#-300,100

`win or lose
if object position x(3) < -250
   cscore=cscore+1
   vb#=vb#*-1
   goto restart
endif

if object position x(3) > 250
  pscore = pscore +1
  goto restart
endif

`print score
text screen width()/2-20,screen height()/2-12,str$(pscore)+" : "+str$(cscore)

`goto next level, increase difficulty and reset scores
if pscore>2
   bv#=bv#+1
   pv#=pv#+0.3
   cv#=cv#+0.5
   level=level+1
   pscore=0
   cscore=0
   goto restart
endif

`display level
text screen width()/2-40,screen height()/2-100,"Level "+str$(level)


`game over text
if cscore>2
set text font "impact"
ink rgb(0,200,0),0
text screen width()/2-50,screen height()/2+200,"Game Over"
text screen width()/2-80,screen height()/2+250,"You reached level "+str$(level)
text screen width()/2-100,screen height()/2+280,"Press any key to restart"
sync
wait key
set text font "sf automaton_mod"
ink rgb(0,0,255),0
goto newgame
endif

if inkey$()="q" then goto restart

if level>3
  `scroll textures
  scroll object texture 1000,0,-0.014
  scroll object texture 4,0,0.08
  scroll object texture 5,0,0.08

  if clockwise=1 then roll camera right 0.1
  if camera angle z()>30 then clockwise=0:turn camera left 0.1
  if clockwise=0 then roll camera left 0.1
  if camera angle z()<-30 then clockwise=1:turn camera right 0.1

else

 `scroll textures
  scroll object texture 1000,0,-0.004
  scroll object texture 4,0,0.004
  scroll object texture 5,0,0.004

endif

sync
loop

remstart
   Info on type _Bot:

   x#: X Position
   y#: Y Position
   team: Bot's team number
   aim#: Aiming direction
   walk#: Walking direction
   score: Player score
   life: Bot's life amount left
   t: Bot's target: 0 for main target, greater than 0 for another bot's ID
   tb: If target is main target, tb is main target's ID
   rstart: Time (in milisec) when reload started.
   bullets: Number of bullets in magazine.
   shoot: Time shot started.
   mode: 0 for attacking, 1 for defending.
remend

remstart
   Info on type _Team:

   color: Team's color
   score: Team's total score
   x#: Team base X position
   y#: Team base Y position
   Bots#: Number of team's bots; Float value because it's needed for later calculations.
   time: Value of timer when started (if 0, then no timer)
remend

type _Bot
   x#=0
   y#=0
   team=1
   aim#=0
   walk#=0
   score=0
   life=100
   t=0
   tb=0
   rstart=0
   bullets=10
   shoot=0
   mode=0
endtype

type _Team
   color=0
   score=0
   x#=0
   y#=0
   Bots#=6
   time=0
   BotCam=0
endtype

global l_team=1
global cam_team=1 :`Current team for cam 1
global _cam=0 :`Current camera
global l_cam=0 :`Last camera - used for camera changing
global r_wait=2000 :`Time to wait to finish reloading (in milisec)
global top_min=4 :`Bitmap minimize factor
global _top_h,_top_w,_top_x,_top_y,_m=1
global key_min=0,key_plus=0
global dim Bots(12) as _Bot
global dim Teams(2) as _Team

set display mode 800,600,16
if check display mode(1024,768,16)=1
   set display mode 1024,768,32
else
   if check display mode(800,600,16)=1
      set display mode 800,600,16
   else
      if check display mode(640,480,16)=1
         set display mode 640,480,16
      endif
   endif
endif

sync on : sync rate 100
backdrop on
color backdrop rgb(200,200,200)
hide mouse

set text font "arial"
set text size 14
set text to bold
set text transparent

sync : center text screen width()/2, screen height()/2,"Loading..." : sync

set text size 20

set current camera 0
autocam off

gosub _load
gosub _setup

do
   gosub _ai_calc
   gosub _check_keyboard
   gosub _render_fps
   gosub _render_topview
   sync
loop

end

_ai_calc:

   for i=1 to array count(Bots(0))
      if Bots(i).life>0
         if Bots(i).t>0 :`Target is another bot
            if Bots(Bots(i).t).team=Bots(i).team :`Check target is within the other team
               Bots(i).t=0
            else
               Bots(i).aim#=GetAngle(Bots(i).x#,Bots(i).y#,Bots(Bots(i).t).x#,Bots(Bots(i).t).y#)
               Bots(i).walk#=Bots(i).aim#
               dist#=GetDist(Bots(i).x#,Bots(i).y#,Bots(Bots(i).t).x#,Bots(Bots(i).t).y#)
               if dist#<70
                  Bots(i).walk#=wrapvalue(Bots(i).walk#)
                  Advance(i,2)
                  if Bots(i).bullets>0
                     if timer()>Bots(i).rstart+r_wait
                        Shoot(i,t)
                     endif
                  else
                     Bots(i).rstart=timer()
                     Bots(i).bullets=10
                  endif
               else
                  if dist#>80
                     Advance(i,2)
                     if Bots(i).bullets>0
                        if timer()>Bots(i).rstart+r_wait
                           Shoot(i,t)
                        endif
                     else
                        Bots(i).rstart=timer()
                        Bots(i).bullets=10
                     endif
                  else
                     Bots(i).walk#=wrapvalue(Bots(i).walk#+90)
                     Advance(i,2)
                     Bots(i).walk#=wrapvalue(Bots(i).walk#-90)
                     if Bots(i).bullets>0
                        if timer()>Bots(i).rstart+r_wait
                           Shoot(i,t)
                        endif
                     else
                        Bots(i).rstart=timer()
                        Bots(i).bullets=10
                     endif
                  endif
               endif
            endif
         else :`Target is main target
            t=Bots(i).tb
            Bots(i).aim#=GetAngle(Bots(i).x#,Bots(i).y#,Teams(t).x#,Teams(t).y#)
            Bots(i).walk#=Bots(i).aim#
            dist#=GetDist(Bots(i).x#,Bots(i).y#,Teams(t).x#,Teams(t).y#)
            if dist#<16 :`Bot touches target
               Teams(t).time=timer()
            else
               Advance(i,2)
               mindist#=0
               for j=1 to array count(Bots(0))
                  if Bots(i).team<>Bots(j).team and Bots(j).life>0
                     a#=GetAngle(Bots(i).x#,Bots(i).y#,Bots(j).x#,Bots(j).y#)
                     dist#=GetDist(Bots(i).x#,Bots(i).y#,Bots(j).x#,Bots(j).y#)
                     if (a#>Bots(i).aim#-45 and a#<Bots(i).aim#+45) :`Check if bot is in FOV
                        if (dist#<mindist# or mindist#=0) and dist#<300
                           mindist#=0
                           Bots(i).t=j
                        endif
                     endif
                  endif
               next j
            endif
         endif
      endif
   next i

   return

_check_keyboard:

   l_team=cam_team
   l_cam=_cam

   if keystate(74)=1 :`Numpad minus key
      if top_min<8 and key_min=0
         inc top_min
         gosub _set_bitmap_pos
      endif
      key_min=1
   else
      key_min=0
   endif

   if keystate(78)=1 :`Numpad plus key
      if top_min>1 and key_plus=0
         dec top_min
         gosub _set_bitmap_pos
      endif
      key_plus=1
   else
      key_plus=0
   endif

   if keystate(11)=1 :`0 key
      if l_cam<>0
         l_cam=_cam
         _cam=0
      endif
   endif
   if keystate(2)=1 :`1 key
      if l_cam<>1
         l_cam=_cam
         _cam=1
      endif
      cam_team=1
      if l_team=cam_team
         inc Teams(1).BotCam
         if Teams(1).BotCam>int(Teams(1).Bots#) then dec Teams(1).BotCam,int(Teams(1).Bots#)
      endif
   endif
   if keystate(3)=1 :`2 key
      if l_cam<>1
         l_cam=_cam
         _cam=1
      endif
      cam_team=2
      if l_team=cam_team
         inc Teams(2).BotCam
         if Teams(2).BotCam>int(Teams(2).Bots#) then dec Teams(2).BotCam,int(Teams(2).Bots#)
      endif
   endif
   `Print FPS rate
   ink rgb(0,0,128),0
   text 10,10,"FPS: "+str$(screen fps())

   for i=1 to array count(Bots(0))
      if timer()<Bots(i).rstart+r_wait
         r_str$="  [ Reloading ]"
      else
         r_str$=""
      endif
      text 10,50+i*15, "Bot "+str$(i)+": "+str$(Bots(i).life)+r_str$
   next i

   return
_render_topview:

   for i=1 to array count(Teams(0))
      ink Teams(i).color,Teams(i).color
      box _top_x+(int(Teams(i).x#)-16)/top_min,_top_y+(int(Teams(i).y#)-16)/top_min,_top_x+(int(Teams(i).x#)+16)/top_min,_top_y+(int(Teams(i).y#)+16)/top_min
   next i

   for i=1 to array count(Bots(0))
      if Bots(i).life>0
         ink Teams(Bots(i).team).color,Teams(Bots(i).team).color
         circle _top_x+(int(Bots(i).x#))/top_min,_top_y+(int(Bots(i).y#))/top_min,16/top_min
         line _top_x+(int(Bots(i).x#))/top_min,_top_y+(int(Bots(i).y#))/top_min,_top_x+(int(Bots(i).x#+cos(Bots(i).aim#)*16))/top_min,_top_y+(int(Bots(i).y#+sin(Bots(i).aim#)*16))/top_min
      endif
   next i

   return

_render_fps:
   for i=1 to array count(Bots(0))
      if Bots(i).life>0 then position object i,Bots(i).x#,16,Bots(i).y#
   next i

   for i=1 to array count(Teams(0))
      j=array count(Bots(0))+i
      position object j,Teams(i).x#,16,Teams(i).y#
   next i

   if _cam=1
      __retry_bot:
      b=Teams(cam_team).BotCam
      if Bots(b).life<=0
         inc Teams(cam_team).BotCam
         if Teams(cam_team).BotCam>int(Teams(cam_team).Bots#) then dec Teams(cam_team).BotCam,int(Teams(cam_team).Bots#)
         goto __retry_bot
      endif
      position camera 0,Bots(b).x#+cos(Bots(b).aim#-180)*100,16,Bots(b).y#+sin(Bots(b).aim#-180)*100
      rotate camera 0,0,wrapvalue(90-Bots(b).aim#),0
   else
      if _cam<>l_cam
         offsetxz=100
         offsety=80
         position camera -1*offsetxz,offsety,-1*offsetxz
         xzdist#=sqrt(2*offsetxz^2)
         yrotate camera 0,45
         xrotate camera 0,-1*int(atan( -1*offsety/(sqrt( (screen width())^2 + (screen height())^2 )+xzdist#) ))
      endif
   endif
   return

_setup:
   offsetxz=100
   offsety=80
   set camera range 0,0.1,screen width() * 2
   position camera -1*offsetxz,offsety,-1*offsetxz
   xzdist#=sqrt(2*offsetxz^2)
   yrotate camera 0,45
   xrotate camera 0,-1*int(atan( -1*offsety/(sqrt( (screen width())^2 + (screen height())^2 )+xzdist#) ))

   Teams(1).color=rgb(0,0,255)
   Teams(1).x#=(screen width())-128
   Teams(1).y#=128
   Teams(1).Bots#=6
   Teams(1).BotCam=1
   Teams(2).color=rgb(255,0,0)
   Teams(2).x#=128
   Teams(2).y#=(screen height())-128
   Teams(2).Bots#=6
   Teams(2).BotCam=7
   cteam=1
   j#=1
   a#=1

   for i=1 to array count(Teams(0))
      j=array count(Bots(0))+i
      CheckDelObj(j)

      make object cube j,32
      set object cull j,0
      color object j,Teams(i).color
      position object j,Teams(i).x#,16,Teams(i).y#
   next i

   for i=1 to array count(Bots(0))
      if j#>Teams(cteam).Bots#
         inc cteam
         j#=1
      endif
      a#=j#/(Teams(cteam).Bots#)*360.0
      Bots(i).team=cteam
      Bots(i).x#=Teams(cteam).x#+cos(a#)*64
      Bots(i).y#=Teams(cteam).y#+sin(a#)*64
      Bots(i).t=0
      Bots(i).tb=3-cteam `Set to other team
      Bots(i).life=100

      CheckDelObj(i)

      make object sphere i,32
      set object cull i,0
      color object i,Teams(Bots(i).team).color
      position object i,Bots(i).x#,16,Bots(i).y#
      inc j#
   next i

   return

_load:
   gosub _set_bitmap_pos
   make matrix _m,screen width(),screen height(),screen width()/10,screen height()/10:`,screen width()/40,screen height()/40
   sync
   return

_set_bitmap_pos:

   _top_w=screen width()/top_min
   _top_h=screen height()/top_min
   _top_x=0
   _top_y=screen height()-_top_h

   return

function CheckDelObj(id)
   if object exist(id)=1 then delete object id
endfunction

function GetAngle(x1#,y1#,x2#,y2#)
   a#=90-atanfull(x2#-x1#,y2#-y1#)
endfunction a#

function GetDist(x1#,y1#,x2#,y2#)
   d#=sqrt((x1#-x2#)^2+(y1#-y2#)^2)
endfunction d#

function Advance(n,d#)
   Bots(n).x#=Bots(n).x#+cos(Bots(n).walk#)*d#
   Bots(n).y#=Bots(n).y#+sin(Bots(n).walk#)*d#
endfunction

function Shoot(n,t)
   if timer()<Bots(n).shoot+500 then exitfunction
   dec Bots(t).life,8
   dec Bots(n).bullets
   Bots(n).shoot=timer()
   if Bots(t).life<0 then Bots(t).life=0
endfunction

Sync On
Sync Rate 60

Autocam off
Global Circ as Float
Global Spring as Float
Circ=1
Spring=1

Make Object Sphere 1,20
Position Object 1,0,10,200
Make Object Sphere 2,1,10,10
Hide Object 2
For i = 1001 to 4000
   Make Object Sphere i,5,8,8
Next i

Do
   Select MouseClick()
      Case 1
         Move Object Down 1,MouseMoveY()
         Move Object Right 1,MouseMoveX()
         Circ=Circ+(MouseMoveZ()/100)
      Endcase
      Case 2
         Roll Object Right 1,MouseMoveX()
         Pitch Object Down 1,MouseMoveY()
         Spring = Spring+(MouseMoveZ()/100)
      Endcase
      Case Default
         x=MouseMoveX()
         y=MouseMoveY()
      EndCase
   Endselect
   If Spacekey() Then Point Camera Object Position X(1),Object Position Y(1),Object Position Z(1)
   Set Cursor 0,0
   Print Screen FPS()
   Drawstuff(1)
   Sync
Loop




Function Drawstuff(ObjectID)
Position Object 2, Object Position X(ObjectID),Object Position Y(ObjectID),Object Position Z(ObjectID)
Set Object To Object Orientation 2,1
lx=Object Screen X(2):ly=Object Screen Y(2)
For i = 1 to 3000
   Move Object 2,4.5
   Turn Object Left 2,Circ
   Pitch Object Up 2,1
   Roll Object RIght 2,Spring
   Position Object 1000+i, Object Position X(2),Object Position Y(2),Object Position Z(2)
Next i
Endfunction

`sets up initial program status
set display mode 1024,768,16
sync on
sync rate 60
hide mouse
autocam off
randomize timer()
set camera range 1,10000
color backdrop 0

`makes the ground texture
ink 0,0
box 0,0,64,64
ink rgb(25,25,25),0
box 1,1,63,63
ink rgb(50,50,50),0
box 2,2,62,62
ink rgb(75,75,75),0
box 3,3,61,61
ink rgb(100,100,100),0
box 4,4,60,60
ink rgb(125,125,125),0
box 5,5,59,59
ink rgb(150,150,150),0
box 6,6,58,58
ink rgb(175,175,175),0
box 7,7,57,57
get image 1,0,0,64,64
cls

`texture for box attack
ink rgb(100,80,0),0
box 0,0,64,64
ink rgb(130,120,0),0
box 5,5,59,59

ink rgb(80,70,0),0
box 15,15,49,49

get image 2,0,0,64,64

`makes level
make matrix 1,6000,6000,10,10
prepare matrix texture 1,1,1,1

`makes player
make object cone 3,40
xrotate object 3,90
fix object pivot 3
set object cull 3,0

`makes outside walls
make object cube 1,6000
texture object 1,1
scale object texture 1,10,10
set object 1,1,1,0,1,0
position object 1,3000,0,3000

`makes AI character
make object cone 2,40
xrotate object 2,90
fix object pivot 2
position object 2,3000,20,3000
color object 2,rgb(200,200,200)
set object cull 2,0

`players shadow
make object sphere 7,40
scale object 7,100,2,100
color object 7,rgb(0,0,0)
set object ambient 7,0

`players attack shadow
make object cube 8,50
scale object 8,100,2,100
color object 8,rgb(0,0,0)
hide object 8

`makes AI's shadow
make object sphere 5,40
scale object 5,100,2,100
color object 5,rgb(40,40,40)
set object ambient 5,0

`makes AI attack object
make object cube 4,5
scale object 4,40,200,300
color object 4,rgb(0,0,0)

`makes player's attack object
make object cube 6,50
scale object 6,100,50,100
texture object 6,2

`makes 5 randomly placed mp heals
mp1x#=rnd(5800)+100
mp1z#=rnd(5800)+100
mp2x#=rnd(5800)+100
mp2z#=rnd(5800)+100
mp3x#=rnd(5800)+100
mp3z#=rnd(5800)+100
mp4x#=rnd(5800)+100
mp4z#=rnd(5800)+100
mp5x#=rnd(5800)+100
mp5z#=rnd(5800)+100

for healer=10 to 14
   make object cone healer,150
   xrotate object healer,180
   set object cull healer,0
next healer

color object 10,rgb(255,100,100)
color object 11,rgb(255,100,100)
color object 12,rgb(255,100,100)

color object 13,rgb(100,255,100)
color object 14,rgb(100,255,100)

position object 10,mp1x#,get ground height(1,mp1x#,mp1z#),mp1z#
position object 11,mp2x#,get ground height(1,mp2x#,mp2z#),mp2z#
position object 12,mp3x#,get ground height(1,mp3x#,mp3z#),mp3z#
position object 13,mp4x#,get ground height(1,mp4x#,mp4z#),mp4z#
position object 14,mp5x#,get ground height(1,mp5x#,mp5z#),mp5z#

set ambient light 0

`AI ENEMY STATS
`health
enemy_hp=1200
enemy_maxhp=1200
`magic points
enemy_mp=120
enemy_maxmp=120
`damage dealt on normal attack
enemy_strength=10

`sets AI reaction and movement variables
aware=0
`the distance infront of the enemy used for his sight, same effects as hearing.
sight_distance#=750
`a distance around the enemy used for hearing. if you step within it, the enemy will become aware of your presence.
hearing_distance#=300
`the distance at which the enemy stops following you (gives up)
max_range#=1000
AI_attacktime=10
AI_weight=5
AI_walkingspeed=7

`AI healing ability
enemy_heal_effect=45
enemy_heal_mpuse=20
enemy_heal_speed=100

`PLAYER STATS
`health
hp=1000
maxhp=1000
`magic points
mp=150
maxmp=150
`damage dealt on normal attack
strength=15

`character variables
`how fast the player walks
player_walkingspeed=10
weight=5
`how high player jumps
player_jumpforce=23
`how fast the players attack is
player_attacktime=20

`player healing ability
`how many points to heal
heal_effect=50
`how much mp used
heal_mpuse=20
`how long it takes
heal_speed=60


`action shortcuts
stand=0
jump=1
walk=2
heal=3
attack=4
limit=5


`sets gravity
gravity=-5
lcount=-100

`text color
ink rgb(200,50,50),0

position object 3,0,0,0




do
gosub player_movement
gosub AI_player
gosub healers
gosub debug_info
gosub rules
`gets distance between player and AI player
distance#=sqrt((object position x(3)-object position x(2))^2+(object position y(3)-object position y(2))^2+(object position z(3)-object position z(2))^2)
sync
loop



debug_info:
ink 0,0
box 3,1,152,187
box 893,1,1007,72

ink rgb(100,100,100),0
box 5,3,150,185
box 895,3,1005,70

ink rgb(255,255,255),0
text 10,5,"-Player Stats-"
text 10,20,"Hp:"+str$(hp)+"/"+str$(maxhp)
text 10,35,"Mp:"+str$(mp)+"/"+str$(maxmp)

if action=0 then text 10,50,"Action:Standing"
if action=1 then text 10,50,"Action:Jumping"
if action=2 then text 10,50,"Action:Walking"
if action=3 then text 10,50,"Action:Healing"
if action=4 then text 10,50,"Action:Attacking"

text 900,2,"-Enemy Stats-"
text 900,20,"Hp:"+str$(enemy_hp)+"/"+str$(enemy_maxhp)
text 900,35,"Mp:"+str$(enemy_mp)+"/"+str$(enemy_maxmp)

if goal=0
   if eaction=0 then text 900,50,"Action:Standing"
   if eaction=1 then text 900,50,"Action:Jumping"
   if eaction=2 and emovement_action=1 then text 900,50,"Action:Following"
   if eaction=2 and emovement_action=0 then text 900,50,"Action:Escaping"
   if eaction=3 then text 900,50,"Action:Healing"
   if eaction=4 then text 900,50,"Action:Attacking"
else
   text 900,50,"Action:Patrol"
endif


text 10,80,"-Player Controls-"
text 10,95,"Mouse:Turn"
text 10,110,"Mousebuttons:Move"
text 10,125,"Spacebar:Jump"
text 10,140,"Enter:Attack"
text 10,155,"Control:Heal"
text 10,170,"Shift:Limit"
return



player_movement:

`gets players old values
oldx#=x#
oldy#=y#
oldz#=z#

`movement and rotation
if action=stand or action=walk or action=jump
   if upkey()=1
      move object 3,player_walkingspeed
      if action=0 then action=2
   endif

   if downkey()=1
      move object 3,-1*player_walkingspeed
      if action=0 then action=2
   endif
   if upkey()=0 and downkey()=0 and action=2 then action=0
endif

`turning player
if action<>attack
   if leftkey()=1 then yrotate object 3,wrapvalue(object angle y(3)-5)
   if rightkey()=1 then yrotate object 3,wrapvalue(object angle y(3)+5)
endif

`gets camera variables
x#=object position x(3)
y#=object position y(3)
z#=object position z(3)
yr#=object angle y(3)

camyr#=wrapvalue(curveangle(yr#,camera angle y(),12.0))
camx#=newxvalue(x#,wrapvalue(camyr#+180),300)
camz#=newzvalue(z#,wrapvalue(camyr#+180),300)

camy#=get ground height(1,camx#,camz#)+200

if camx#>5900 then camx#=5900
if camx#<100 then camx#=100
if camz#>5900 then camz#=5900
if camz#<100 then camz#=100
if camy#>2800 then camy#=2800

position camera camx#,camy#,camz#
point camera x#,y#,z#
yrotate camera wrapvalue(camyr#)



`calculates standing and jumping
if action=stand or action=walk then y#=get ground height(1,x#,z#)+20
`jump with out flying
if action=jump then y#=oldy#:gravity_force=gravity_force+(gravity/10):y#=y#+gravity_force+vertforce

`starting an attack
if returnkey()=1
   if action=stand or action=walk then action=attack
endif

`starting a heal
if controlkey()=1 and mp=>heal_mpuse
   if action=stand or action=walk then action=heal
endif

`starting a limit break
if shiftkey()=1 and mp>20
   if action=stand or action=walk then action=limit
endif

`going to various abilities
gosub attack
gosub heal
gosub limit

`sliding collision with walls and roof
if x#>5900 then x#=5900
if x#<100 then x#=100
if z#>5900 then z#=5900
if z#<100 then z#=100
if y#>2800 then y#=2800

`jumping, gravity and staying on the ground
if vertforce>0 then dec vertforce
if y#<get ground height(1,x#,z#)+20 then action=stand

`starting a jump
if spacekey()=1
   if action=stand or action=walk
      vertforce=player_jumpforce
      action=jump
      gravity_force=gravity
   endif
endif

`sliding collision with AI player
dx#=object position x(3)-object position x(2)
dz#=object position z(3)-object position z(2)
`moving player away
if dx#<25 and dx#>0 and dy#>-25 and dy#<20 and z#>az#-25 and z#<az#+25 then x#=ax#+25
if dx#>-25 and dx#<0 and dy#>-25 and dy#<20 and z#>az#-25 and z#<az#+25 then x#=ax#-25
if dz#<25 and dz#>0 and dy#>-25 and dy#<20 and x#>ax#-25 and x#<ax#+25 then z#=az#+25
if dz#>-25 and dz#<0 and dy#>-25 and dy#<20 and x#>ax#-25 and x#<ax#+25 then z#=az#-25

`positioning camera in final position
position object 3,x#,y#,z#

`positions players shadow
position object 7,x#,get ground height(1,x#,z#)+1,z#

return






AI_player:
`gets the AI player's current position into variables.
ax#=object position x(2)
ay#=object position y(2)
az#=object position z(2)
ary#=object angle y(2)

`stores old AI positions
oldax#=ax#
olday#=ay#
oldaz#=az#

`makes enemy patrol if it is unaware that you are around, and if its hp is less than 50% it will heal.
if aware=0
   if enemy_hp>enemy_maxhp/2
      gosub enemy_patrol
   else
      if enemy_mp=>enemy_heal_mpuse
         eaction=heal
      gosub enemy_heal
      else
         gosub enemy_patrol
      endif
   endif
endif


`things to do if the AI player is aware that the main player exists.
if aware=1
   `points and AI object towards player if it is aware, and moves it if it's not in attack range.
   point object 2,x#,y#,z#
   goal=0
   if eaction=walk or eaction=stand
      `enemy will run away if it's hp is less than 25%, if not it will keep chasing you
      if enemy_hp>enemy_maxhp*0.30
         if range=0 then emovement_action=1:eaction=walk
      else
         emovement_action=0:eaction=walk
      endif
      gosub enemy_follow
      gosub enemy_escape
   endif

   if range=1
   `attacks player if it is aware, in range, and facing the right angle
   if eaction=stand or eaction=walk
      if enemy_hp>enemy_maxhp*0.30 then eaction=attack
   endif
   endif
   `makes enemy unaware when it is past it's max range, so it won't chase you forever.
   if distance#>max_range# then aware=0
endif

`enemy heals itself
if enemy_hp<enemy_maxhp*0.3
   if distance#>500
      if eaction<>jump and enemy_mp=>enemy_heal_mpuse then eaction=heal
   endif
endif

`goes to ability code and checks the eaction
gosub enemy_attack
gosub enemy_heal

`if Ai player hears the main player then it is aware
if distance#<hearing_distance# then aware=1:text 200,30,"You are in AI player's hearing range!"

`if AI player sees the main player then it is aware.
if distance#<sight_distance#
   position camera ax#,ay#,az#
   yrotate camera ary#
   if object in screen(3)=1 then aware=1:text 200,45,"You are in AI player's seeing range!"
   position camera camx#,camy#,camz#
   yrotate camera camyr#
endif

`checks to see if player and enemy are in range
if distance#<=50
   range=1
else
   range=0
endif

`sliding collision with walls and roof
if ax#>5900 then ax#=5900
if ax#<100 then ax#=100
if az#>5900 then az#=5900
if az#<100 then az#=100
if ay#>2800 then ay#=2800

`poisitons and rotates enemy and it's shadow
position object 2,ax#,ay#,az#
yrotate object 2,ary#
position object 5,ax#,get ground height(1,ax#,az#)+1,az#

return


`a healing ability that takes mp - used by the enemy
enemy_heal:
if enemy_mp+enemy_heal_mpuse=>enemy_heal_mpuse
   if eaction=heal and ehealcount=0 then dec enemy_mp,enemy_heal_mpuse:ehealcount=enemy_heal_speed
   if ehealcount>0
      color object 2,rgb(rnd(100)+100,rnd(100)+100,rnd(100)+100)
      eaction=heal
      scale object 2,100,ehealcount*3+100,100
      dec ehealcount
      if ehealcount=0
         inc enemy_hp,enemy_heal_effect
         if enemy_hp>enemy_maxhp then enemy_hp=enemy_maxhp
         color object 2,rgb(100,100,100)
         eaction=stand
      endif
   endif
else
   scale object 2,100,100,100
endif
return


`a healing ability that takes mp - used by player
heal:
if mp+heal_mpuse=>heal_mpuse
   if action=heal and healcount=0 then dec mp,heal_mpuse:healcount=heal_speed
   if healcount>0
      color object 3,rgb(rnd(100)+100,rnd(100)+100,rnd(100)+100)
      scale object 3,healcount*2+100,healcount*2+100,healcount*2+100
      action=heal
      dec healcount
      if healcount=0
         scale object 3,100,100,100
         color object 3,rgb(200,200,200)
         inc hp,heal_effect
         if hp>maxhp then hp=maxhp
         action=stand
      endif
   endif
endif
return


`a normal attack by the enemy
enemy_attack:
if eaction=attack and eattackcount=0 then eattackcount=AI_attacktime
if eattackcount>0
   eaction=attack
   `dealing damage
   if eattackcount=1 and distance#<55 then dec hp,enemy_strength
   show object 4
   position object 4,ax#,ay#+eattackcount*4-15,az#
   yrotate object 4,ary#
   move object 4,20
   color object 2,rgb(255,100,100)
   dec eattackcount
   if eattackcount=0 then eaction=stand:color object 2,rgb(100,100,100)
else
   hide object 4
endif
return


`a normal attack by the player
attack:
if action=attack and attackcount=0 then attackcount=player_attacktime
if attackcount>0
   action=attack
   show object 6
   show object 8
   position object 6,x#,y#+(attackcount*5),z#
   position object 8,x#,get ground height(1,x#,z#)+1,z#
   yrotate object 6,yr#
   yrotate object 8,yr#
   move object 6,50
   move object 8,50
   dec attackcount
   `dealing damage and ending attack
   if attackcount=0
      if distance#<70 and object in screen(2)=1 then dec enemy_hp,strength
      action=stand
   endif
else
   hide object 6
   hide object 8
endif
return


enemy_patrol:
if goal=0
goalx#=rnd(5800)+100
goalz#=rnd(5800)+100
goal=1
endif
if goal=1
   point object 2,goalx#,get ground height(1,goalx#,goalz#),goalz#
   move object 2,AI_walkingspeed
   ax#=object position x(2)
   ay#=get ground height(1,ax#,az#)+20
   az#=object position z(2)
   ary#=object angle y(2)

for check=10 to 14
   if object exist(check)=1
      if goalx#=object position x(check)
         if goalz#=object position x(check) then goto noheal
      endif
   endif
next check

for check=10 to 14
   if object exist(check)=1
   if ax#>object position x(check)-1000 and ax#<object position x(check)+1000 and az#>object position z(check)-1000 and az#<object position z(check)+1000
      if check<13 and check>9
         if enemy_hp<enemy_maxhp/2
            goalx#=object position x(check)
            goalz#=object position z(check)
         endif
      else
         if enemy_mp<enemy_maxmp/2
            goalx#=object position x(check)
            goalz#=object position z(check)
         endif
      endif
   endif
   endif
next check
noheal:
   `it gets to its goal
   if ax#>goalx#-10 and ax#<goalx#+10 and az#>goalz#-10 and az#<goalz#+10
      goal=0
   endif
endif
return



`the enemy's movement to follow you
enemy_follow:
if emovement_action=1 and eaction=walk
   move object 2,AI_walkingspeed
   ax#=object position x(2)
   ay#=get ground height(1,ax#,az#)+20
   az#=object position z(2)
   ary#=object angle y(2)
endif
return


`the enemy's movement to run away from you
enemy_escape:
if emovement_action=0 and eaction=walk
   yrotate object 2,wrapvalue(object angle y(2)-180)
   move object 2,AI_walkingspeed
   ax#=object position x(2)
   ay#=get ground height(1,ax#,az#)+20
   az#=object position z(2)
   ary#=object angle y(2)
   if distance#>max_range#-100 then aware=0:
   if needheal=1 and distance#>400 then eaction=heal
endif
return


healers:
for healer=10 to 14
if object exist(healer)=0 then goto nexthealplayer
if object position x(3)>object position x(healer)-40 and object position x(3)<object position x(healer)+40
if object position z(3)>object position z(healer)-40 and object position z(3)<object position z(healer)+40
if healer<13 then inc hp,maxhp/4 else inc mp,maxmp/4
delete object healer
endif
endif
nexthealplayer:
next healer
for healer=10 to 14
if object exist(healer)=0 then goto nexthealenemy
if object position x(2)>object position x(healer)-40 and object position x(2)<object position x(healer)+40
if object position z(2)>object position z(healer)-40 and object position z(2)<object position z(healer)+40
if healer<13 then inc enemy_hp,enemy_maxhp/4 else inc enemy_mp,enemy_maxmp/4
delete object healer
endif
endif
nexthealenemy:
next healer
return


rules:
if enemy_hp>enemy_maxhp then enemyhp=enemy_maxhp
if enemy_mp>enemy_maxmp then enemy_mp=enemy_maxmp

if hp>maxhp then hp=maxhp
if mp>maxmp then mp=maxmp

if enemy_hp<1 then goto victory
if hp<1 then goto gameover
return


victory:
text object screen x(2),object screen y(2),"You win!!"
ghost object on 2
sync
wait 500
for explosion=1 to 30
   make object sphere explosion+20,50
   position object explosion+20,ax#,ay#,az#
   yrotate object explosion+20,wrapvalue(explosion*36)
next explosion
delete object 2
delete object 4
delete object 5
delete object 6
a=100
do
a=a+2
for move_explosion=1 to 30
   move object move_explosion+20,1
   color object move_explosion+20,rgb(rnd(100)+100,rnd(100)+100,rnd(100)+100)
next move_explosion
set gamma a,a,a
if a=500 then exit
sync
loop
goto ending


limit:
if action=limit and lcount=-100
for crates=1 to 10
   make object cube crates+100,rnd(15)+40
   texture object crates+100,2
next crates
make object cylinder 111,150
color object 111,rgb(255,255,180)
ghost object on 111
scale object 111,100,500,100
oldmp=mp
lcount=200
endif
if lcount>-100
   action=limit
   if lcount<50 and mp>0 then dec mp:dec enemy_hp,6

   if lcount>0
      for position=1 to 10
         position object position+100,ax#+rnd(4)-2,ay+(lcount*3)-position*50,az#+rnd(4)-2
      next position
      position object 111,ax#,ay#,az#
      position camera camera position x()+rnd(10),camera position y()+rnd(10),camera position z()+rnd(10)
   endif
   dec lcount
   if lcount<0
      scale object 111,lcount+100,500,lcount+100
   endif
   `dealing damage and ending attack
   if lcount=-100
      for decrates=1 to 11
         delete object decrates+100
      next decrates
      dec enemy_hp,mp
      action=stand
   endif
endif
return

gameover:
a=255
do
move camera rnd(5)-2.5
rotate camera wrapvalue(camera angle x()+rnd(5)-2.5),wrapvalue(camera angle y()+rnd(5)-2.5),wrapvalue(camera angle z()+rnd(5)-2.5)
if camera position x()<100 then position camera 100,camera position y(),camera position z()
if camera position x()>900 then position camera 900,camera position y(),camera position z()
if camera position z()<100 then position camera camera position x(),camera position y(),100
if camera position z()>900 then position camera camera position x(),camera position y(),900
if camera position y()<get ground height(1,camera position x(),camera position z() )+10 then position camera camera position x(),get ground height(1,camera position x(),camera position z() )+10,camera position z()
set gamma a,a,a
dec a,2
if a<=5 then exit
sync
loop
wait 500
set gamma 255,255,255

ending:

remstart
   Info on type _Bot:

   x#: X Position
   y#: Y Position
   team: Bot's team number
   aim#: Aiming direction
   walk#: Walking direction
   score: Player score
   life: Bot's life amount left
   t: Bot's target: 0 for main target, greater than 0 for another bot's ID
   tb: If target is main target, tb is main target's ID
   rstart: Time (in milisec) when reload started.
   bullets: Number of bullets in magazine.
   shoot: Time shot started.
   mode: 0 for attacking, 1 for defending.
   offset#: Angle offset when walking and turning arround in defend mode.

   Info on type _Team:

   color: Team's color
   score: Team's total score
   x#: Team base X position
   y#: Team base Y position
   Bots#: Number of team's bots; Float value because it's needed for later calculations.
   time: Value of timer when started (if 0, then no timer)
remend

type _Bot
   x#=0
   y#=0
   team=1
   aim#=0
   walk#=0
   score=0
   life=100
   t=0
   tb=0
   rstart=0
   bullets=10
   shoot=0
   mode=0
   offset#=0
endtype

type _Team
   color=0
   score=0
   x#=0
   y#=0
   Bots#=6
   time=0
   BotCam=0
endtype

global win_delay=5, attacking_team=1
global l_team=1
global cam_team=1 :`Current team for cam 1
global _cam=0 :`Current camera
global l_cam=0 :`Last camera - used for camera changing
global r_wait=2000 :`Time to wait to finish reloading (in milisec)
global top_min=4 :`Bitmap minimize factor
global _top_h,_top_w,_top_x,_top_y,_m=1
global key_min=0,key_plus=0,key_tab=0
global dim key_num(3)
global dim Bots(12) as _Bot
global dim Teams(2) as _Team

set display mode 800,600,16
if check display mode(1024,768,16)=1
   set display mode 1024,768,32
else
   if check display mode(800,600,16)=1
      set display mode 800,600,16
   else
      if check display mode(640,480,16)=1
         set display mode 640,480,16
      endif
   endif
endif

sync on : sync rate 100
backdrop on
color backdrop rgb(200,200,200)
hide mouse

set text font "arial"
set text size 14
set text to bold
set text transparent

sync : center text screen width()/2, screen height()/2,"Loading..." : sync

set text size 20

set current camera 0
autocam off

gosub _load
gosub _setup

do
   gosub _ai_calc
   gosub _check_keyboard
   gosub _print_stats
   gosub _render_fps
   gosub _render_topview
   sync
loop

end

_ai_calc:

   for i=1 to array count(Bots(0))
      if Bots(i).life>0
         if Bots(i).t>0 :`Target is another bot
            if Bots(Bots(i).t).team=Bots(i).team :`Check target is within the other team
               Bots(i).t=0
            else
               if Bots(Bots(i).t).life>0
                  ChaseBot(i,Bots(i).t)
               else
                  Bots(i).t=0
               endif
            endif
         else :`Target is main target
            AdvanceToMainTarget(i)
         endif
      endif
   next i
   CheckTimer()

   return

_check_keyboard:

   l_team=cam_team
   l_cam=_cam

   if keystate(15)=1 :`Tab key
      if key_tab=0
         attacking_team=3-attacking_team :`Swap teams
         Teams(1).time=0
         Teams(2).time=0
         gosub _setup
      endif
      key_tab=1
   else
      key_tab=0
   endif

   if keystate(74)=1 :`Numpad minus key
      if top_min<8 and key_min=0
         inc top_min
         gosub _set_bitmap_pos
      endif
      key_min=1
   else
      key_min=0
   endif

   if keystate(78)=1 :`Numpad plus key
      if top_min>1 and key_plus=0
         dec top_min
         gosub _set_bitmap_pos
      endif
      key_plus=1
   else
      key_plus=0
   endif

   if keystate(11)=1 :`0 key
      if l_cam<>0 and key_num(1)=0
         l_cam=_cam
         _cam=0
      endif
      key_num(1)=1
   else
      key_num(1)=0
   endif
   if keystate(2)=1 :`1 key
      if key_num(2)=0
         if l_cam<>1
            l_cam=_cam
            _cam=1
         endif
         cam_team=1
         if l_team=cam_team
            inc Teams(1).BotCam
            if Teams(1).BotCam>int(Teams(1).Bots#) then dec Teams(1).BotCam,int(Teams(1).Bots#)
         endif
      endif
      key_num(2)=1
   else
      key_num(2)=0
   endif
   if keystate(3)=1 :`2 key
      if key_num(3)=0
         if l_cam<>1
            l_cam=_cam
            _cam=1
         endif
         cam_team=2
         if l_team=cam_team
            inc Teams(2).BotCam
            if Teams(2).BotCam>int(Teams(2).Bots#) then dec Teams(2).BotCam,int(Teams(2).Bots#)
         endif
      endif
      key_num(3)=1
   else
      key_num(3)=0
   endif

   return

_print_stats:

   `Print FPS rate
   ink rgb(0,0,128),0
   text 10,10,"FPS: "+str$(screen fps())

   for i=1 to array count(Bots(0))
      if timer()<Bots(i).rstart+r_wait
         r_str$="  [ Reloading ]"
      else
         r_str$=""
      endif
      text 10,50+i*15, "Bot "+str$(i)
      text 70,50+i*15, "Life: "+str$(Bots(i).life)
      text 150,50+i*15, "Target: "+str$(Bots(i).t)
      text 230,50+i*15, r_str$
   next i

   return
_render_topview:

   for i=1 to array count(Teams(0))
      ink Teams(i).color,Teams(i).color
      box _top_x+(int(Teams(i).x#)-16)/top_min,_top_y+(int(Teams(i).y#)-16)/top_min,_top_x+(int(Teams(i).x#)+16)/top_min,_top_y+(int(Teams(i).y#)+16)/top_min
   next i

   for i=1 to array count(Bots(0))
      if Bots(i).life>0
         ink Teams(Bots(i).team).color,Teams(Bots(i).team).color
         circle _top_x+(int(Bots(i).x#))/top_min,_top_y+(int(Bots(i).y#))/top_min,16/top_min
         line _top_x+(int(Bots(i).x#))/top_min,_top_y+(int(Bots(i).y#))/top_min,_top_x+(int(Bots(i).x#+cos(Bots(i).aim#)*16))/top_min,_top_y+(int(Bots(i).y#+sin(Bots(i).aim#)*16))/top_min
      endif
   next i

   return

_render_fps:
   for i=1 to array count(Bots(0))
      if Bots(i).life>0
         position object i,Bots(i).x#,16,Bots(i).y#
         if object visible(i)=0 then show object i
      else
         if object visible(i)=1 then hide object i
      endif
   next i

   for i=1 to array count(Teams(0))
      j=array count(Bots(0))+i
      position object j,Teams(i).x#,16,Teams(i).y#
   next i

   if _cam=1
      CamFollowBot()
   else
      if _cam<>l_cam
         ResetCam()
      endif
   endif
   return

_setup:
   ResetCam()
   randomize timer()
   Teams(1).color=rgb(0,0,255)
   Teams(1).x#=(screen width())-128
   Teams(1).y#=rnd((screen height())-128*2)+128
   Teams(1).Bots#=6
   Teams(1).BotCam=1
   Teams(2).color=rgb(255,0,0)
   Teams(2).x#=128
   Teams(2).y#=(screen height())-Teams(1).y#
   Teams(2).Bots#=6
   Teams(2).BotCam=7
   cteam=1
   j#=1
   a#=1

   for i=1 to array count(Teams(0))
      j=array count(Bots(0))+i
      CheckDelObj(j)

      make object cube j,32
      set object cull j,0
      color object j,Teams(i).color
      position object j,Teams(i).x#,16,Teams(i).y#
   next i

   for i=1 to array count(Bots(0))
      if j#>Teams(cteam).Bots#
         inc cteam
         j#=1
      endif
      a#=j#/(Teams(cteam).Bots#)*360.0
      Bots(i).team=cteam
      Bots(i).x#=Teams(cteam).x#+cos(a#)*64
      Bots(i).y#=Teams(cteam).y#+sin(a#)*64
      Bots(i).t=0
      Bots(i).mode=(cteam=3-attacking_team)
      Bots(i).tb=3-attacking_team
      Bots(i).life=100

      CheckDelObj(i)

      make object sphere i,32
      set object cull i,0
      color object i,Teams(Bots(i).team).color
      position object i,Bots(i).x#,16,Bots(i).y#
      inc j#
   next i

   return

_load:
   gosub _set_bitmap_pos
   create bitmap 1,10,10
   set current bitmap 1
   ink 0,0
   box 1,1,5,5
   box 6,6,10,10
   ink rgb(255,255,255),0
   box 6,1,10,5
   box 1,6,5,10
   get image 1,1,1,10,10
   set current bitmap 0
   make matrix _m,screen width(),screen height(),10,10
   prepare matrix texture _m,1,1,1
   delete bitmap 1
   sync
   return

_set_bitmap_pos:

   _top_w=screen width()/top_min
   _top_h=screen height()/top_min
   _top_x=0
   _top_y=screen height()-_top_h

   return

function ResetCam()
   scr#=sqrt( (screen width()/2)^2 + (screen height()/2)^2 )
   offsetxz=100
   offsety=80
   position camera -1*offsetxz,offsety,-1*offsetxz
   xzdist#=sqrt(2*offsetxz^2)
   yrotate camera 0,45
   xrotate camera 0,-1*int(atan( -1*offsety/(scr#+xzdist#) ))
endfunction

function CamFollowBot()
__retry_bot:
   b=Teams(cam_team).BotCam
   if Bots(b).life<=0
      inc Teams(cam_team).BotCam
      if Teams(cam_team).BotCam>int(Teams(cam_team).Bots#) then dec Teams(cam_team).BotCam,int(Teams(cam_team).Bots#)
      goto __retry_bot
   endif
   position camera 0,Bots(b).x#+cos(Bots(b).aim#-180)*100,16,Bots(b).y#+sin(Bots(b).aim#-180)*100
   rotate camera 0,0,wrapvalue(90-Bots(b).aim#),0
endfunction

function CheckDelObj(id)
   if object exist(id)=1 then delete object id
endfunction

function GetAngle(x1#,y1#,x2#,y2#)
   a#=90-atanfull(x2#-x1#,y2#-y1#)
endfunction a#

function GetDist(x1#,y1#,x2#,y2#)
   d#=sqrt((x1#-x2#)^2+(y1#-y2#)^2)
endfunction d#

function Advance(n,d#)
   lx#=Bots(n).x#
   ly#=Bots(n).y#
   Bots(n).x#=Bots(n).x#+cos(Bots(n).walk#)*d#
   Bots(n).y#=Bots(n).y#+sin(Bots(n).walk#)*d#
   BotCollision(n)
   `BoxCollision(n)
   WallCollision(n)
endfunction

function BotCollision(n)
   for i=1 to array count(Bots(0))
      if i<>n and Bots(i).life>0 and GetDist(Bots(n).x#,Bots(n).y#,Bots(i).x#,Bots(i).y#)<32 :`Collision found
         a#=GetAngle(Bots(i).x#,Bots(i).y#,Bots(n).x#,Bots(n).y#)
         d#=32-GetDist(Bots(n).x#,Bots(n).y#,Bots(i).x#,Bots(i).y#)
         Bots(n).x#=Bots(n).x#+cos(a#)*d#
         Bots(n).y#=Bots(n).y#+sin(a#)*d#
      endif
   next i
endfunction

function BoxCollision(n)
   x#=Bots(n).x#
   y#=Bots(n).y#
   for i=1 to array count(Teams(0))
      tx#=Teams(i).x#
      ty#=Teams(i).y#
      if GetDist(tx#,ty#,x#,y#)<(16/cos(GetAngle(tx#,ty#,x#,y#)))+16 :`Collision between circle and box
         if x#<tx#+16+16 :`Right side of box
            d#=tx#-x#+16+16
            a#=180.0
         endif
         if x#>tx#-16-16 :`Left side
            d#=x#-tx#+16+16
            a#=0.0
         endif
         if y#<ty#+16+16 :`Bottom side
            d#=ty#-y#+16+16
            a#=270.0
         endif
         if y#>ty#-16-16 :`Top side
            d#=y#-ty#+16+16
            a#=90.0
         endif
         Bots(n).x#=Bots(n).x#+cos(a#)*d#
         Bots(n).y#=Bots(n).y#+sin(a#)*d#
      endif
   next i
endfunction

function WallCollision(n)
   col=0
   x#=Bots(n).x#
   y#=Bots(n).y#
   if x#<16 :`Collision with left wall
      d#=x#-16
      a#=180.0
      col=1
   endif
   if x#>(screen width())-16 :`Right wall
      d#=(screen width())-x#-16
      a#=0.0
      col=1
   endif
   if y#<16 :`Top wall
      d#=y#-16
      a#=270.0
      col=1
   endif
   if y#>(screen height())-16 :`Bottom wall
      d#=(screen height())-y#-16
      a#=90.0
      col=1
   endif
   if col=1
      Bots(n).x#=Bots(n).x#+cos(a#)*d#
      Bots(n).y#=Bots(n).y#+sin(a#)*d#
   endif
endfunction

function Shoot(n,t)
   if timer()<Bots(n).shoot+500 then exitfunction
   l=8
   if Bots(n).mode=1 then l=10 :`If in defend mode, set bullets to be more powerful
   dec Bots(t).life,l
   dec Bots(n).bullets
   Bots(n).shoot=timer()
   if Bots(t).life<0 then Bots(t).life=0
endfunction

function TryToShoot(n,t)
   if Bots(n).bullets>0
      if timer()>Bots(n).rstart+r_wait
         Shoot(n,t)
      endif
   else
      Bots(n).rstart=timer()
      Bots(n).bullets=10
   endif
endfunction

function LookForTarget(n)
   mindist#=0
   for i=1 to array count(Bots(0))
      if Bots(n).team<>Bots(i).team and Bots(i).life>0
         a#=GetAngle(Bots(n).x#,Bots(n).y#,Bots(i).x#,Bots(i).y#)
         dist#=GetDist(Bots(n).x#,Bots(n).y#,Bots(i).x#,Bots(i).y#)
         if (a#>Bots(n).aim#-45 and a#<Bots(n).aim#+45) :`Check if bot is in FOV
            if (dist#<mindist# or mindist#=0) and dist#<300
               mindist#=dist#
               Bots(n).t=i
            endif
         endif
      endif
   next i
endfunction

function AimTo(n,x#,y#)
   Bots(n).aim#=GetAngle(Bots(n).x#,Bots(n).y#,x#,y#)
   Bots(n).walk#=Bots(n).aim#
endfunction

function ChaseBot(n,t)
   AimTo(n,Bots(t).x#,Bots(t).y#)
   dist#=GetDist(Bots(n).x#,Bots(n).y#,Bots(t).x#,Bots(t).y#)
   if dist#<70
      Bots(n).walk#=wrapvalue(Bots(n).walk#)
      Advance(n,2)
      TryToShoot(n,t)
   else
      if dist#>80
         Advance(n,2)
         TryToShoot(n,t)
      else
         Bots(n).walk#=wrapvalue(Bots(n).walk#+90)
         Advance(n,2)
         Bots(n).walk#=wrapvalue(Bots(n).walk#-90)
         TryToShoot(n,t)
      endif
   endif
endfunction

function AdvanceToMainTarget(n)
   if Bots(n).mode=0
      AdvanceAndAttack(n)
   else
      AdvanceAndDefend(n)
   endif
endfunction

function AdvanceAndAttack(n)
   t=Bots(n).tb
   AimTo(n,Teams(t).x#,Teams(t).y#)
   dist#=GetDist(Bots(n).x#,Bots(n).y#,Teams(t).x#,Teams(t).y#)
   if dist#<16 :`Bot touches target
      if Teams(t).time+win_delay*1000<timer() then Teams(t).time=timer()
   else
      Advance(n,2)
      LookForTarget(n)
   endif
endfunction

function AdvanceAndDefend(n)
   t=Bots(n).tb
   tx#=Teams(t).x#
   ty#=Teams(t).y#
   dist#=GetDist(Bots(n).x#,Bots(n).y#,tx#,ty#)
   AimTo(n,tx#,ty#)
   Bots(n).aim#=wrapvalue(Bots(n).aim#+180)
   if dist#<120
      if dist#<110
         Bots(n).walk#=Bots(n).aim#
      else
         Bots(n).walk#=wrapvalue(Bots(n).walk#+90)
      endif
   endif
   Advance(n,2)
   Bots(n).aim#=wrapvalue(Bots(n).aim#+Bots(n).offset#)
   inc Bots(n).offset#,10
   LookForTarget(n)
endfunction

function CheckTimer()
   for i=1 to array count(Teams(0))
      if Teams(i).time>0
         center text screen width()/2,20,"Time left: "+str$(win_delay-int((timer()-Teams(i).time)/1000))
         t_timeleft=timer()
         if Teams(i).time+win_delay*1000+200>=timer()
            Teams(i).time=0
            attacking_team=3-attacking_team :`Swap teams
            gosub _setup
         endif
      endif
   next i
endfunction

Rem Project: connect four
Rem Created: 1/26/2005 3:48:41 PM
Rem authored by Coding Fodder
Rem ***** Main Source File *****
sync on:sync rate 0
set window title "Connect Four by Daniel Wigton"
dim board(7,5,2)
dim column_importance(7)
dim move_list(18,2)
dim player_name$(2)
global Player_turn
global unit#
global downhold
global difficulty
dim rec_risk(10)

setup_board()
sync
ink rgb(255,255,255),rgb(0,0,255)
set cursor 1,1
input "Player 1 Name ",player1$
player_name$(1)=player1$
Print "Select player 2 type"
Print "(1) Human:"
Print "(2) computer:"
Print "(3) Net Player:"
sync
repeat
select inkey$()
   case "1":player_type=1:out=1:endcase
   case "2":player_type=2:player_name$(2)="AI Bob":out=1:endcase
   case "3":player_type=3:out=1:endcase
endselect
until out=1
Rem currently only difficulties 0-2 are supported. use 0 only if you want to play a mindless monkey
difficulty=2

DO
   setup_board()
   player_turn=1
   ink rgb(255,255,255),rgb(0,0,255)
   sync
   gosub main
LOOP

MAIN:
   turns_taken=0
DO
   inc turns_taken
   if turns_taken>35
      print "Its a tie"
      input "Would you like to play agian? y/n ",ans$
      if ans$="y" or ans$="Y" then return
      sync
      end
      return
   endif

   box 0,0,100,screen height(),rgb(0,0,255),rgb(0,0,255),rgb(0,0,255),rgb(0,0,255)
   set cursor 1,1
   print player_name$(player_turn)
   if player_turn=1
      Human_select(1):  REM you may set either player to Human or AI by changing the function call
   else
      AI_select(2)
   endif
   swap_players()

   if check_for_winner(1)>0
      Print player_name$(check_for_winner(1))+" Wins"
      input "Would you like to play agian? y/n ",ans$
      if ans$="y" or ans$="Y" then return
      sync
      end
   endif

   sync
LOOP
RETURN

function AI_select(player)
   lowest_risk=30
   for i=1 to 7
      for j= 1 to 5
         board(i,j,2)=board(i,j,1)
      next j
   next i
   for i=1 to 7
      r_num=1
      prediction(player,i,r_num)
      column_importance(i)=rec_risk(1)
      if column_importance(i)<lowest_risk then lowest_risk=column_importance(i)
      `if column_importance(i)=18
      `   add_chip(player,i)
      `   prediction(player,i,r_num)
      `   plan=rec_risk(1)
      `   if plan=2 then column_importance=17
      `   remove_chip()
      `endif
   next i

   randomize timer()
   selection_num=rnd(6)
   counter1=selection_num
   repeat
      inc counter1
      if counter1>7 then counter1=1
      if column_importance(counter1)<=lowest_risk then this=make_play(player,counter1)
   until this=1

endfunction

REM Prediction is a semi-recursive function. treat with care.
function prediction(player,col,r_num)
   write_risk(r_num,18)                :rem Write_risk and Read_risk are needed because DB does not really support recursion

   if r_num>difficulty then exitfunction

   if full(col)=1
      write_risk(r_num,31)
      exitfunction
   endif

      add_chip(player,col)
      outcome=check_for_winner(2)
      if outcome=player
         write_risk(r_num,1)
         remove_chip()
         exitfunction
      endif
      NoNo=0
      for j=1 to 7
         if full(j)=0
            add_chip(other_player(player),j)
            outcome=check_for_winner(2)
            if outcome=other_player(player)
               write_risk(r_num,28)
               NoNo=1
            else
               if NoNo=0 and r_num<difficulty
                  winning=0
                  losing=0
                  for g=1 to 7
                     prediction(player,g,r_num+1)
                     result=read_risk(r_num+1)
                     if result=1 then inc winning
                     if result>27 then inc losing
                  next g
                  if losing>6 then write_risk(r_num,28-r_num)
                  if winning>r_num then write_risk(r_num,r_num+1)
               endif
            endif
            remove_chip()
         endif
      next j
      remove_chip()
endfunction

function write_risk(r_num,value)
   rec_risk(r_num)=value
endfunction

function read_risk(r_num)
   out=rec_risk(r_num)
endfunction out

function full(column)
   out=0
   if board(column,5,2)>0 then out=1
endfunction out

function other_player(player)
   if player=1
      player_other=2
   else
      player_other=1
   endif
endfunction player_other

function add_chip(player,column)
   if column>0 and column<8
   for i=1 to 5
      if board(column,i,2)=0
         board(column,i,2)=player
         for j=18 to 2 step -1
            move_list(j,1)=move_list(j-1,1)
            move_list(j,2)=move_list(j-1,2)
         next j
         move_list(1,1)=column
         move_list(1,2)=i
         exitfunction
      endif
   next i
   endif
endfunction

function remove_chip()
   board(move_list(1,1),move_list(1,2),2)=0
   for j=1 to 17
      move_list(j,1)=move_list(j+1,1)
      move_list(j,2)=move_list(j+1,2)
   next j
   move_list(18,1)=0
   move_list(18,2)=0
endfunction

function check_for_winner(bd)
   for i=1 to 7
      for j=1 to 5
         if board(i,j,bd)>0
            if check_across(board(i,j,bd),i,j,bd)=1 then win=board(i,j,bd)
            if check_down(board(i,j,bd),i,j,bd)=1 then win=board(i,j,bd)
            if check_diagonal_down(board(i,j,bd),i,j,bd)=1 then win=board(i,j,bd)
            if check_diagonal_up(board(i,j,bd),i,j,bd)=1 then win=board(i,j,bd)
         endif
      next j
   next i
endfunction win

function check_diagonal_down(player,x,y,bd)
   yup=1
   howmany=1
   for i=x-1 to 1 step -1
      j=y+(x-i)
      if i>0 and j<6
         if board(i,j,bd)=player and yup=1
            inc howmany
         else
            yup=0
         endif
      endif
   next i

   yup=1
   for i=x+1 to 7
      j=y+(x-i)
      if i<8 and j>0
         if board(i,j,bd)=player and yup=1
            inc howmany
         else
            yup=0
         endif
      endif
   next i
   if howmany>3 then output=1
endfunction output

function check_diagonal_up(player,x,y,bd)
   yup=1
   howmany=1
   for i=x-1 to 1 step -1
      j=y+(i-x)
      if i>0 and j>0
         if board(i,j,bd)=player and yup=1
            inc howmany
         else
            yup=0
         endif
      endif
   next i

   yup=1
   for i=x+1 to 7
      j=y+(i-x)
      if i<8 and j<6
         if board(i,j,bd)=player and yup=1
            inc howmany
         else
            yup=0
         endif
      endif
   next i
   if howmany>3 then output=1
endfunction output

function check_down(player,x,y,bd)
   yup=1
   howmany=1
   for i=y-1 to 1 step -1
      if i>0
         if board(x,i,bd)=player and yup=1
            inc howmany
         else
            yup=0
         endif
      endif
   next i

   yup=1
   for i=y+1 to 5
      if i<6
         if board(x,i,bd)=player and yup=1
            inc howmany
         else
            yup=0
         endif
      endif
   next i
   if howmany>3 then output=1
endfunction output

function check_across(player,x,y,bd)
   yup=1
   howmany=1
   for i=x-1 to 1 step -1
      if i>0
         if board(i,y,bd)=player and yup=1
            inc howmany
         else
            yup=0
         endif
      endif
   next i

   yup=1
   for i=x+1 to 7
      if i<8
         if board(i,y,bd)=player and yup=1
            inc howmany
         else
            yup=0
         endif
      endif
   next i
   if howmany>3 then output=1
endfunction output

function human_select(player)
   curcolumn=1
   repeat
      if leftkey()=1
         lefthold=1
      else
         if lefthold=1
            if curcolumn>1 then dec curcolumn
            lefthold=0
         endif
      endif

      if rightkey()=1
         righthold=1
      else
         if righthold=1
            if curcolumn<7 then inc curcolumn
            righthold=0
         endif
      endif

      box unit#*2,screen height()-unit#*7,screen width()-unit#*2,screen height()-unit#*6,rgb(0,0,255),rgb(0,0,255),rgb(0,0,255),rgb(0,0,255)
      solid_circle(unit#*(curcolumn+2),screen height()-unit#*6.5,unit#*0.4,rgb(255*(player-2)*(-1),0,0))
      ready=0

      if downkey()=1
         downhold=1
      else
         if downhold=1
            column=curcolumn
            if make_play(player_turn,column)=1 then ready=1
            downhold=0
         endif
      endif

      sync
   until ready=1
endfunction

function swap_players()
   if player_turn=1
      player_turn=2
   else
      player_turn=1
   endif
endfunction

function make_play(player,column)
   if column>0 and column<8
   for i=1 to 5
      if board(column,i,1)=0
         board(column,i,1)=player
         solid_circle(unit#*(column+2),unit#*(6-i)+screen height()-unit#*6,unit#*0.4,rgb(255*(player-2)*(-1),0,0))
         exitfunction 1
      endif
   next i
   endif
endfunction 0

function setup_board()
   for bdnum=1 to 2
      for i=1 to 7
         for j=1 to 5
            board(i,j,bdnum)=0
         next j
      next i
   next bdnum
   cls
   box 0,0,screen width(),screen height(),rgb(0,0,255),rgb(0,0,255),rgb(0,0,255),rgb(0,0,255)
   unit#=screen width()/12.0
   box unit#*2,screen height()-unit#*6,screen width()-unit#*2,screen height(),rgb(255,255,0),rgb(255,255,0),rgb(255,255,0),rgb(255,255,0)
   for i=1 to 7
      for j=1 to 5
         solid_circle(unit#*(i+2),unit#*j+screen height()-unit#*6,unit#*0.4,rgb(0,0,255))
      next j
   next i
endfunction

function solid_circle(x,y,radius,color)
lock pixels
ptr=get pixels pointer()
this=get pixels pitch()
that =bitmap depth()/8
for i=1 to radius*2
   for j=1 to radius*2
      pointer=ptr+((y+j-radius)*this)+(x-radius+i)*that
      if (radius-i)^2+(radius-j)^2<=radius^2 then *pointer=color
   next j
next i
unlock pixels
endfunction

sync on

dim player$(10)
dim reply$(10)

do
gosub playerinput
if nextgo=1 then gosub ai_process
sync
cls
loop

playerinput:
playerin$=playerin$+entry$()
clear entry buffer
if asc(right$(playerin$,1))=13 then nextgo=1
ink rgb(0,255,0),0
print playerin$
print "_"
for s=1 to 10
   ink rgb(0,255,0),0
   print player$(s)
   ink rgb(0,0,255),0
   print reply$(s)
next s
return

ai_process:
use$=upper$(playerin$)
if question=1
   if feelx=1
      if word_inline(use$,"YOU")=1
         reply$="Aww, how sweet..."
      else
         reply$="Fair enough."
      endif
      feelx=0
      question=0
   endif
   if feel=1
      reply$="Dont lie, I know how you feel about me."
      feel=0
      question=0
   endif
   if nexname=1
      myname$=playerin$+"ey"
      reply$="I'll call you "+myname$+". What's on your mind, "+myname$+"?"
      nexname=0
      feelx=1
   endif
else
   if word_inline(use$,"HOW")=1 and word_inline(use$,"WHY")=1 and word_inline(use$,"WHO")=1 and reply$=""
      reply$="Slow down mate..."
   endif
   if word_inline(use$,"HELLO")=1 or word_inline(use$,"HI")=1 or word_inline(use$,"HIYA")=1 or word_inline(use$,"HEY")=1
      if greeting=0
         reply$="Hello, lowlife human phreak. What is your name?"
         nexname=1:question=1
         greeting=1
      else
         reply$="You've already greeted me..."
      endif
   endif
   if word_inline(use$,"HOW")=1 and word_inline(use$,"ARE")=1 and word_inline(use$,"?")=1 and reply$=""
      if word_inline(use$,"YOU")=1
         reply$="Im feeling great actually! Yourself?"
         feel=1
         question=1
      else
         reply$="They're not working right..."
      endif
   else
      if word_inline(use$,"HOW")=1 and word_inline(use$,"?")=1 and reply$=""
         re=rnd(1)
         select re
            case 0:reply$="Using my arms.":endcase
            case 1:reply$="Pretty easily..!":endcase
         endselect
      endif
   endif
   if word_inline(use$,"WHO")=1 and word_inline(use$,"?")=1 and reply$=""
      if word_inline(use$,"PROGRAMMED")=1 or word_inline(use$,"TAUGHT")=1
         reply$="Myself. I taught myself how to talk like this."
      else
         reply$="T'was Jesus."
      endif
   endif
   if word_inline(use$,"WHAT")=1 and word_inline(use$,"?")=1 and reply$=""
      reply$="Whatever..."
      if word_inline(use$,"ARE")=1
         reply$="I am an artificial intelligence bot. The others don't concern me."
      endif
      if word_inline(use$,"IS")=1
         if word_inline(use$,"NAME")=1
            reply$="My name is NathbotV1.0 - And this is all just your illusion."
         else
            reply$="Well, its mainly made of plastic. But the side thingy is metal."
         endif
      endif
      if word_inline(use$,"DID")=1
         reply$="Started destroying continents..."
      endif
      if word_inline(use$,"WAS")=1
         reply$="Get over it."
      endif
   endif
   if word_inline(use$,"DID")=1 and word_inline(use$,"?")=1 and reply$=""
      reply$="Yes, pretty much. But it was hard."
   endif
   if word_inline(use$,"WHEN")=1 and word_inline(use$,"?")=1 and reply$=""
      reply$="About two days ago actually."
   endif
   if word_inline(use$,"WHERE")=1 and word_inline(use$,"?")=1
      if myname$=""
         reply$="Do I even know you!?"
      else
         reply$="Ugh, next to that pizza place. Like y'know, whatever..."
      endif
   endif
endif
nextgo=0
player$(1)=playerin$
reply$(1)=reply$
for pls=10 to 1 step -1
   player$(pls)=player$(pls-1)
   reply$(pls)=reply$(pls-1)
next pls
playerin$=""
reply$=""
return

function word_inline(string$,section$)
`checks if the section$ string is anywhere in the string$ string.
allsize=len(string$)
sectsize=len(section$)
for c=1 to allsize
   if current<sectsize
      if current=0
         if mid$(string$,c)=mid$(section$,current+1) then inc current
      else
         if mid$(string$,c)=mid$(section$,current+1) then inc current else current=0
      endif
   endif
next c
if current=sectsize then result=1
endfunction result

remstart
   Info on type _Bot:

   x#: X Position
   y#: Y Position
   team: Bot's team number
   aim#: Aiming direction
   walk#: Walking direction
   score: Player score
   life: Bot's life amount left
   t: Bot's target: 0 for main target, greater than 0 for another bot's ID
   tb: If target is main target, tb is main target's ID
   rstart: Time (in milisec) when reload started.
   bullets: Number of bullets in magazine.
   shoot: Time shot started.
   mode: 0 for attacking, 1 for defending.
   offset#: Angle offset when walking and turning arround in defend mode.
   form: Formation mode - 0=none, 1=leader of formation, 2=in formation, but not the leader
   formx#: If 'form' is set to 2, then 'formx#' is bot's X position in the formation.
   formy#: If 'form' is set to 2, then 'formy#' is bot's Y position in the formation.
   leader: If 'form' is set to 2, then 'leader' is bot's formation leader.
   skill#: When a bot hits its target, his skill is growing. It is used as a factor when calculating if shot will hit or not.

   Info on type _Team:

   color: Team's color
   score: Team's total score
   x#: Team base X position
   y#: Team base Y position
   Bots#: Number of team's bots; Float value because it's needed for later calculations.
   time: Value of timer when started (if 0, then no timer)
remend

type _Bot
   x#=0
   y#=0
   team=1
   aim#=0
   walk#=0
   score=0
   life=100
   t=0
   tb=0
   rstart=0
   bullets=10
   shoot=0
   mode=0
   offset#=0
   form=0
   formx#=0
   formy#=0
   leader=0
   skill#=1
endtype

type _Team
   color=0
   score=0
   x#=0
   y#=0
   Bots#=6
   time=0
   BotCam=0
endtype

global win_delay=5, attacking_team=1, formation=0
global l_team=1
global cam_team=1 :`Current team for cam 1
global _cam=0 :`Current camera
global l_cam=0 :`Last camera - used for camera changing
global r_wait=2000 :`Time to wait to finish reloading (in milisec)
global top_min=4 :`Bitmap minimize factor
global _top_h,_top_w,_top_x,_top_y,_m=1
global key_min=0,key_plus=0,key_tab=0
global dim key_num(3)
global dim Bots(12) as _Bot
global dim Teams(2) as _Team

set display mode 800,600,16
if check display mode(1024,768,16)=1
   set display mode 1024,768,32
else
   if check display mode(800,600,16)=1
      set display mode 800,600,16
   else
      if check display mode(640,480,16)=1
         set display mode 640,480,16
      endif
   endif
endif

sync on : sync rate 100
backdrop on
color backdrop rgb(200,200,200)
hide mouse

set text font "arial"
set text size 14
set text to bold
set text transparent

sync : center text screen width()/2, screen height()/2,"Loading..." : sync

set text size 20

set current camera 0
autocam off

gosub _load
gosub _setup

do
   gosub _ai_calc
   gosub _check_keyboard
   gosub _print_stats
   gosub _render_fps
   gosub _render_topview
   sync
loop

end

_ai_calc:

   for i=1 to array count(Bots(0))
      if Bots(i).life>0
         if Bots(i).t>0 :`Target is another bot
            if Bots(Bots(i).t).team=Bots(i).team :`Check target is within the other team
               Bots(i).t=0
            else
               if Bots(Bots(i).t).life>0
                  if mode=0
                     ChaseBot(i,Bots(i).t)
                  else
                     if GetDist(Bots(Bots(i).t).x#,Bots(Bots(i).t).y#,Teams(Bots(i).tb).x#,Teams(Bots(i).tb).y#)<300
                        xm#=(Bots(Bots(i).t).x#+Teams(Bots(i).tb).x#)/2
                        ym#=(Bots(Bots(i).t).y#+Teams(Bots(i).tb).y#)/2
                        if Bots(i).x#>xm#-16 and Bots(i).x#<xm#+16 and Bots(i).y#>ym#-16 and Bots(i).y#<ym#+16
                           ChaseBot(i,Bots(i).t)
                        else
                           AdvancePos(i,xm#,ym#)
                        endif
                     else
                        ChaseBot(i,Bots(i).t)
                     endif
                  endif
               else
                  Bots(i).t=0
               endif
            endif
         else :`Target is main target
            AdvanceToMainTarget(i)
         endif
      endif
   next i
   CheckTimer()

   return

_check_keyboard:

   l_team=cam_team
   l_cam=_cam

   if keystate(15)=1 :`Tab key
      if key_tab=0
         attacking_team=3-attacking_team :`Swap teams
         Teams(1).time=0
         Teams(2).time=0
         gosub _setup
      endif
      key_tab=1
   else
      key_tab=0
   endif

   if keystate(74)=1 :`Numpad minus key
      if top_min<8 and key_min=0
         inc top_min
         gosub _set_bitmap_pos
      endif
      key_min=1
   else
      key_min=0
   endif

   if keystate(78)=1 :`Numpad plus key
      if top_min>1 and key_plus=0
         dec top_min
         gosub _set_bitmap_pos
      endif
      key_plus=1
   else
      key_plus=0
   endif

   if keystate(11)=1 :`0 key
      if l_cam<>0 and key_num(1)=0
         l_cam=_cam
         _cam=0
      endif
      key_num(1)=1
   else
      key_num(1)=0
   endif
   if keystate(2)=1 :`1 key
      if key_num(2)=0
         if l_cam<>1
            l_cam=_cam
            _cam=1
         endif
         cam_team=1
         if l_team=cam_team
            inc Teams(1).BotCam
            if Teams(1).BotCam>int(Teams(1).Bots#) then dec Teams(1).BotCam,int(Teams(1).Bots#)
         endif
      endif
      key_num(2)=1
   else
      key_num(2)=0
   endif
   if keystate(3)=1 :`2 key
      if key_num(3)=0
         if l_cam<>1
            l_cam=_cam
            _cam=1
         endif
         cam_team=2
         if l_team=cam_team
            inc Teams(2).BotCam
            if Teams(2).BotCam>int(Teams(2).Bots#) then dec Teams(2).BotCam,int(Teams(2).Bots#)
         endif
      endif
      key_num(3)=1
   else
      key_num(3)=0
   endif

   return

_print_stats:

   `Print FPS rate
   ink rgb(0,0,128),0
   text 10,10,"FPS: "+str$(screen fps())

   for i=1 to array count(Teams(0))
      ink Teams(i).color,0
      text 10,screen height()-20-(array count(Teams(0))-i)*15,"Team "+str$(i)+": "+str$(Teams(i).score)
   next i
   ink rgb(0,0,128),0
   for i=1 to array count(Bots(0))
      if timer()<Bots(i).rstart+r_wait
         r_str$="  [ Reloading ]"
      else
         r_str$=""
      endif
      text 10,50+i*15, "Bot "+str$(i)
      text 70,50+i*15, "Life: "+str$(Bots(i).life)
      text 150,50+i*15, "Target: "+str$(Bots(i).t)
      text 230,50+i*15, r_str$
   next i

   return
_render_topview:

   for i=1 to array count(Teams(0))
      ink Teams(i).color,Teams(i).color
      box _top_x+(int(Teams(i).x#)-16)/top_min,_top_y+(int(Teams(i).y#)-16)/top_min,_top_x+(int(Teams(i).x#)+16)/top_min,_top_y+(int(Teams(i).y#)+16)/top_min
   next i

   for i=1 to array count(Bots(0))
      if Bots(i).life>0
         ink Teams(Bots(i).team).color,Teams(Bots(i).team).color
         circle _top_x+(int(Bots(i).x#))/top_min,_top_y+(int(Bots(i).y#))/top_min,16/top_min
         line _top_x+(int(Bots(i).x#))/top_min,_top_y+(int(Bots(i).y#))/top_min,_top_x+(int(Bots(i).x#+cos(Bots(i).aim#)*16))/top_min,_top_y+(int(Bots(i).y#+sin(Bots(i).aim#)*16))/top_min
      endif
   next i

   return

_render_fps:
   for i=1 to array count(Bots(0))
      if Bots(i).life>0
         position object i,Bots(i).x#,16,Bots(i).y#
         if object visible(i)=0 then show object i
      else
         if object visible(i)=1 then hide object i
      endif
   next i

   for i=1 to array count(Teams(0))
      j=array count(Bots(0))+i
      position object j,Teams(i).x#,16,Teams(i).y#
   next i

   if _cam=1
      CamFollowBot()
   else
      if _cam<>l_cam
         ResetCam()
      endif
   endif
   return

_setup:
   ResetCam()
   randomize timer()
   Teams(1).color=rgb(0,0,255)
   Teams(1).x#=(screen width())-128
   Teams(1).y#=rnd((screen height())-128*2)+128
   Teams(1).Bots#=6
   Teams(1).BotCam=1
   Teams(2).color=rgb(255,0,0)
   Teams(2).x#=128
   Teams(2).y#=(screen height())-Teams(1).y#
   Teams(2).Bots#=6
   Teams(2).BotCam=7
   cteam=1
   j#=1
   a#=1

   for i=1 to array count(Teams(0))
      j=array count(Bots(0))+i
      CheckDelObj(j)

      make object cube j,32
      set object cull j,0
      color object j,Teams(i).color
      position object j,Teams(i).x#,16,Teams(i).y#
   next i

   for i=1 to array count(Bots(0))
      if j#>Teams(cteam).Bots#
         inc cteam
         j#=1
      endif
      a#=j#/(Teams(cteam).Bots#)*360.0
      Bots(i).team=cteam
      Bots(i).x#=Teams(cteam).x#+cos(a#)*64
      Bots(i).y#=Teams(cteam).y#+sin(a#)*64
      Bots(i).t=0

      Bots(i).mode=(cteam=3-attacking_team)
      Bots(i).tb=3-attacking_team
      Bots(i).life=100
      if cteam=attacking_team
         if int(j#)=1 then Bots(i).form=1 else Bots(i).form=2
      endif

      CheckDelObj(i)

      make object sphere i,32
      set object cull i,0
      color object i,Teams(Bots(i).team).color
      position object i,Bots(i).x#,16,Bots(i).y#
      inc j#
   next i

   randomize timer()
   formation=rnd(1)
   SwitchLeader(1)

   return

_load:
   gosub _set_bitmap_pos
   create bitmap 1,10,10
   set current bitmap 1
   ink 0,0
   box 1,1,5,5
   box 6,6,10,10
   ink rgb(255,255,255),0
   box 6,1,10,5
   box 1,6,5,10
   get image 1,1,1,10,10
   set current bitmap 0
   make matrix _m,screen width(),screen height(),10,10
   prepare matrix texture _m,1,1,1
   delete bitmap 1
   sync
   return

_set_bitmap_pos:

   _top_w=screen width()/top_min
   _top_h=screen height()/top_min
   _top_x=0
   _top_y=screen height()-_top_h

   return

function ResetCam()
   scr#=sqrt( (screen width()/2)^2 + (screen height()/2)^2 )
   offsetxz=100
   offsety=80
   position camera -1*offsetxz,offsety,-1*offsetxz
   xzdist#=sqrt(2*offsetxz^2)
   yrotate camera 0,45
   xrotate camera 0,-1*int(atan( -1*offsety/(scr#+xzdist#) ))
endfunction

function CamFollowBot()
__retry_bot:
   b=Teams(cam_team).BotCam
   if Bots(b).life<=0
      inc Teams(cam_team).BotCam
      if Teams(cam_team).BotCam>int(Teams(cam_team).Bots#) then dec Teams(cam_team).BotCam,int(Teams(cam_team).Bots#)
      goto __retry_bot
   endif
   position camera 0,Bots(b).x#+cos(Bots(b).aim#-180)*100,16,Bots(b).y#+sin(Bots(b).aim#-180)*100
   rotate camera 0,0,wrapvalue(90-Bots(b).aim#),0
endfunction

function CheckDelObj(id)
   if object exist(id)=1 then delete object id
endfunction

function GetAngle(x1#,y1#,x2#,y2#)
   a#=90-atanfull(x2#-x1#,y2#-y1#)
endfunction a#

function GetDist(x1#,y1#,x2#,y2#)
   d#=sqrt((x1#-x2#)^2+(y1#-y2#)^2)
endfunction d#

function AdvancePos(n,x#,y#)
   Bots(n).walk#=GetAngle(Bots(n).x#,Bots(n).y#,x#,y#)
   Bots(n).aim#=GetAngle(Bots(n).x#,Bots(n).y#,x#,y#)
   Advance(n,2)
   TryToShoot(n,Bots(n).t)
endfunction

function Advance(n,d#)
   lx#=Bots(n).x#
   ly#=Bots(n).y#
   Bots(n).x#=Bots(n).x#+cos(Bots(n).walk#)*d#
   Bots(n).y#=Bots(n).y#+sin(Bots(n).walk#)*d#
   BotCollision(n)
   `BoxCollision(n)
   WallCollision(n)
endfunction

function BotCollision(n)
   for i=1 to array count(Bots(0))
      if i<>n and Bots(i).life>0 and GetDist(Bots(n).x#,Bots(n).y#,Bots(i).x#,Bots(i).y#)<32 :`Collision found
         a#=GetAngle(Bots(i).x#,Bots(i).y#,Bots(n).x#,Bots(n).y#)
         d#=32-GetDist(Bots(n).x#,Bots(n).y#,Bots(i).x#,Bots(i).y#)
         Bots(n).x#=Bots(n).x#+cos(a#)*d#
         Bots(n).y#=Bots(n).y#+sin(a#)*d#
      endif
   next i
endfunction

function BoxCollision(n)
   x#=Bots(n).x#
   y#=Bots(n).y#
   for i=1 to array count(Teams(0))
      tx#=Teams(i).x#
      ty#=Teams(i).y#
      if GetDist(tx#,ty#,x#,y#)<(16/cos(GetAngle(tx#,ty#,x#,y#)))+16 :`Collision between circle and box
         if x#<tx#+16+16 :`Right side of box
            d#=tx#-x#+16+16
            a#=180.0
         endif
         if x#>tx#-16-16 :`Left side
            d#=x#-tx#+16+16
            a#=0.0
         endif
         if y#<ty#+16+16 :`Bottom side
            d#=ty#-y#+16+16
            a#=270.0
         endif
         if y#>ty#-16-16 :`Top side
            d#=y#-ty#+16+16
            a#=90.0
         endif
         Bots(n).x#=Bots(n).x#+cos(a#)*d#
         Bots(n).y#=Bots(n).y#+sin(a#)*d#
      endif
   next i
endfunction

function WallCollision(n)
   col=0
   x#=Bots(n).x#
   y#=Bots(n).y#
   if x#<16 :`Collision with left wall
      d#=x#-16
      a#=180.0
      col=1
   endif
   if x#>(screen width())-16 :`Right wall
      d#=(screen width())-x#-16
      a#=0.0
      col=1
   endif
   if y#<16 :`Top wall
      d#=y#-16
      a#=270.0
      col=1
   endif
   if y#>(screen height())-16 :`Bottom wall
      d#=(screen height())-y#-16
      a#=90.0
      col=1
   endif
   if col=1
      Bots(n).x#=Bots(n).x#+cos(a#)*d#
      Bots(n).y#=Bots(n).y#+sin(a#)*d#
   endif
endfunction

function Shoot(n,t)
   if timer()<Bots(n).shoot+500 then exitfunction
   l=8
   if Bots(n).mode=1 then l=10 :`If in defend mode, set bullets to be more powerful
   randomize timer()
   if rnd(int(GetDist(Bots(n).x#,Bots(n).y#,Bots(t).x#,Bots(t).y#)/40/Bots(n).skill#))=0 :`Closer than 40 will always hit
      dec Bots(t).life,l
      inc Bots(n).skill#,0.08
   endif
   dec Bots(n).bullets
   Bots(n).shoot=timer()
   if Bots(t).life<0 then Bots(t).life=0
endfunction

function TryToShoot(n,t)
   if Bots(n).bullets>0
      if timer()>Bots(n).rstart+r_wait
         Shoot(n,t)
      endif
   else
      Bots(n).rstart=timer()
      Bots(n).bullets=10
   endif
endfunction

function LookForTarget(n)
   t=FindNearestEnemy(n,250)
   if t>0 then Bots(n).t=t
endfunction

function FindNearestEnemy(n,range#)
   mindist#=0
   t=0
   for i=1 to array count(Bots(0))
      if Bots(n).team<>Bots(i).team and Bots(i).life>0
         a#=GetAngle(Bots(n).x#,Bots(n).y#,Bots(i).x#,Bots(i).y#)
         dist#=GetDist(Bots(n).x#,Bots(n).y#,Bots(i).x#,Bots(i).y#)
         if (a#>Bots(n).aim#-45 and a#<Bots(n).aim#+45) :`Check if bot is in FOV
            if (dist#<mindist# or mindist#=0) and dist#<range#
               mindist#=dist#
               t=i
            endif
         endif
      endif
   next i
endfunction t

function AimTo(n,x#,y#)
   Bots(n).aim#=GetAngle(Bots(n).x#,Bots(n).y#,x#,y#)
   Bots(n).walk#=Bots(n).aim#
endfunction

function ChaseBot(n,t)
   AimTo(n,Bots(t).x#,Bots(t).y#)
   dist#=GetDist(Bots(n).x#,Bots(n).y#,Bots(t).x#,Bots(t).y#)
   if dist#<70
      Bots(n).walk#=wrapvalue(Bots(n).walk#)
      Advance(n,2)
      TryToShoot(n,t)
   else
      if dist#>80
         Advance(n,2)
         TryToShoot(n,t)
      else
         Bots(n).walk#=wrapvalue(Bots(n).walk#+90)
         Advance(n,2)
         Bots(n).walk#=wrapvalue(Bots(n).walk#-90)
         TryToShoot(n,t)
      endif
   endif
endfunction

function AdvanceToMainTarget(n)
   if Bots(n).mode=0
      AdvanceAndAttack(n)
   else
      AdvanceAndDefend(n)
   endif
endfunction

function AdvanceAndAttack(n)
   t=Bots(n).tb
   AimTo(n,Teams(t).x#,Teams(t).y#)
   dist#=GetDist(Bots(n).x#,Bots(n).y#,Teams(t).x#,Teams(t).y#)
   if dist#<16 :`Bot touches target
      if Teams(t).time+win_delay*1000<timer() then Teams(t).time=timer()
   else
      adv#=2
      if Bots(n).form=2
         if Bots(Bots(n).leader).life<40
            SwitchLeader(Bots(i).team)
         else
            dist#=GetDist(Bots(n).x#,Bots(n).y#,Bots(n).formx#,Bots(n).formy#)
            if dist#>10 then AimTo(n,Bots(n).formx#,Bots(n).formy#)
         endif
      endif
      if Bots(n).form=1
         bots$=""
         for i=(n+1) to (n+int(Teams(Bots(n).team).Bots#)-1)
            bots$=bots$+chr$(i)
         next i
         if FindNearestEnemy(n,320)>0 :`Can see enemy
            LineFormation(n,bots$)
         else
            if formation=1
               CircleFormation(n,bots$)
            else
               VFormation(n,bots$)
            endif
         endif
         if BotsInFormation(n,bots$)=0 then adv#=1.0
      endif
      Advance(n,adv#)
      LookForTarget(n)
   endif
endfunction

function AdvanceAndDefend(n)
   t=Bots(n).tb
   tx#=Teams(t).x#
   ty#=Teams(t).y#
   dist#=GetDist(Bots(n).x#,Bots(n).y#,tx#,ty#)
   AimTo(n,tx#,ty#)
   Bots(n).aim#=wrapvalue(Bots(n).aim#+180)
   if dist#<120
      if dist#<110
         Bots(n).walk#=Bots(n).aim#
      else
         Bots(n).walk#=wrapvalue(Bots(n).walk#+90)
      endif
   endif
   Advance(n,2)
   Bots(n).aim#=wrapvalue(Bots(n).aim#+Bots(n).offset#)
   inc Bots(n).offset#,10
   LookForTarget(n)
endfunction

function CheckTimer()
   dim t(array count(Teams(0)))
   for i=1 to array count(Teams(0))
      t(i)=1
      if Teams(i).time>0
         center text screen width()/2,20,"Time left: "+str$(win_delay-int((timer()-Teams(i).time)/1000))
         t_timeleft=timer()
         if Teams(i).time+win_delay*1000+200>=timer()
            WinGame(3-i)
         endif
      endif
   next i
   j=0
   cteam=1
   for i=1 to array count(Bots(0))
      inc j
      if j>int(Teams(cteam).Bots#)
         j=1
         inc cteam
      endif
      t(cteam)=(t(cteam) and (Bots(i).life<=0))
   next i
   for i=1 to array count(Teams(0))
      Teams(i).time=0
      if t(i)=1
         WinGame(3-i)
      endif
   next i
endfunction

function WinGame(n)
   Teams(n).time=0
   inc Teams(n).score
   attacking_team=3-attacking_team :`Swap teams
   gosub _setup
endfunction

function VFormation(leader,bots$)
   Bots(leader).form=1
   for i=1 to len(bots$)
      n=asc(left$(mid$(bots$,i),1))
      Bots(n).form=2
      Bots(n).leader=leader
      if i mod 2=0
         a#=135
      else
         a#=225
      endif
      a#=a#+Bots(leader).walk#
      Bots(n).formx#=Bots(leader).x#+cos(a#)*64*((i+(i mod 2))/2)
      Bots(n).formy#=Bots(leader).y#+sin(a#)*64*((i+(i mod 2))/2)
      Bots(n).aim#=Bots(leader).aim#
   next i
   if (len(bots$) mod 2)=1
      n=asc(right$(bots$,1))
      a#=180+Bots(leader).walk#
      Bots(n).formx#=Bots(leader).x#+cos(a#)*64
      Bots(n).formy#=Bots(leader).y#+sin(a#)*64
   endif
endfunction

function CircleFormation(leader,bots$)
   Bots(leader).form=1
   i#=0
   for i=1 to len(bots$)
      inc i#
      n=asc(left$(mid$(bots$,i),1))
      Bots(n).form=2
      Bots(n).leader=leader
      a#=i#/len(bots$)*360.0
      Bots(n).formx#=Bots(leader).x#+cos(a#)*64
      Bots(n).formy#=Bots(leader).y#+sin(a#)*64
      Bots(n).aim#=a#
   next i
endfunction

function LineFormation(leader,bots$)
   Bots(leader).form=1
   for i=1 to len(bots$)
      n=asc(left$(mid$(bots$,i),1))
      Bots(n).form=2
      Bots(n).leader=leader
      if i mod 2=0
         a#=-1
      else
         a#=1
      endif
      a#=a#*90+Bots(leader).walk#
      Bots(n).formx#=Bots(leader).x#+cos(a#)*64*((i+(i mod 2))/2)
      Bots(n).formy#=Bots(leader).y#+sin(a#)*64*((i+(i mod 2))/2)
      Bots(n).aim#=Bots(leader).aim#
   next i
endfunction

function BotsInFormation(leader,bots$)
   for i=1 to len(bots$)
      n=asc(left$(mid$(bots$,i),1))
      dist#=GetDist(Bots(n).x#,Bots(n).y#,Bots(n).formx#,Bots(n).formy#)
      if dist#>17 then exitfunction 0
   next i
endfunction 1

function SwitchLeader(t)
   max=0
   for i=1 to array count(Bots(0))
      if Bots(i).team=t and Bots(i).life>=40 and Bots(i).life>max
         max=Bots(i).life
         l=i
      endif
   next i
   Bots(l).form=1
   Bots(l).leader=0
   for i=1 to array count(Bots(0))
      if Bots(i).team=t and Bots(i).life>=40 and i<>l
         Bots(i).form=2
         Bots(i).leader=l
      endif
   next i
endfunction

`Bill Robinson
`Coding Challenge - AI
`2-16-0`
sync on:sync rate 60
set display mode 1024,768,32
hide mouse
set ambient light 20

dim ball#(200,10)

global leftwall=0
global rightwall=1000
global backwall=1000
global floor=0
global gravity#=0
global ballcount=0
global newballflag=1
global width
global height
global paddlewidth=200
global paddleheight=100
global px
global py
global pa#
global pscore
global cscore
global level
global numtargets=8
global targetsleft
global leveldone=0
global specialtarget

global compwidth=100
global compheight=100
global compx#
global compy#
global comp_xinc#

get image 1,1,1,100,100,1

make object plain 101,1000,1000     :`leftwall
yrotate object 101,-90
position object 101,0,500,500
color object 101,rgb(255,0,0)
set object emissive 101,rgb(100,0,0)

make object plain 102,1000,1000     :`backwall
position object 102,500,500,1000
color object 102,rgb(0,255,0)
set object emissive 102,rgb(0,70,0)

make object plain 103,1000,1000     :`rightwall
yrotate object 103,-90
position object 103,1000,500,500
color object 103,rgb(0,0,255)
set object emissive 103,rgb(0,0,150)

make object plain 104,1000,1000     :`floor
xrotate object 104,-90
position object 104,500,0,500
color object 104,rgb(100,100,0)

make object plain 105,paddlewidth,paddleheight     :`My Paddle
color object 105,rgb(0,100,100)
fade object 105,70
ghost object on 105
set object emissive 105,rgb(0,150,150)
set object collision on 105

make object plain 106,paddlewidth,1                :`My Paddle Shadow
color object 106,rgb(1,1,1)

make object plain 110,compwidth,compheight         :`Computer Paddle
color object 110,rgb(200,0,200)
set object emissive 110,rgb(255,0,255)

make object plain 111,compwidth,2               :`Computer Shadow
color object 111,rgb(1,1,1)

for i=1 to numtargets                           :`Targets
   make object plain 150+i,90,90
   set object collision on 150+i
next i

for i=1 to 2
   make object sphere i,30             :`ball#1
   make object sphere 50+i,30          :`ball#1 Shadow
   set object collision on i
   scale object 50+i,100,1,100
   color object 50+i,rgb(1,1,1)
   _init_ball(i)
next i

width=screen width()
height=screen height()

position camera 0,500,300,-550
xrotate camera 0,0
px1=paddlewidth/2
px2=950                            :`rightwall-padddlewidth
py1=paddleheight
py2=height-paddleheight/2
comp_xinc#=3.0
level=1

startnewlevel:
gosub _setuptargets
pa#=0
targetsleft=numtargets
do
   set cursor 1,1:print screen fps()
   score$="Level:"+str$(level)+"   Player:"+str$(pscore)+"   Computer:"+str$(cscore)
   center text 500,10,score$
   text$="Use Z and X keys to AIM PADDLE"
   center text 500,30,text$
   if ballcount=0
      center text 500,300,"Press <space> to fire ball"
   endif
   if keystate(57)=1 then if newballflag>0 then gosub _fire_new_ball:wait 100
   if keystate(44) then if pa#>-35 then dec pa#,2:yrotate object 105,pa#:yrotate object 106,pa#
   if keystate(45) then if pa#<35 then inc pa#,2:yrotate object 105,pa#:yrotate object 106,pa#
   if keystate(42) then pa#=0:yrotate object 105,pa#:yrotate object 106,pa#
   if leveldone=1 then gosub _endlevel:goto startnewlevel

   px=mousex():py=height-mousey()
   if px<px1 then px=px1
   if px>px2 then px=px2
   if py<py1 then py=py1
   if py>py2 then py=py2
   position object 105,px,py1,100
   position object 106,px,1,100

   position object 110,compx#,py1,800

   position object 111,compx#,2,800
   gosub _move_balls
   gosub _comp_paddle
`   gosub _debug
   sync
loop

`------------------------
_debug:
set cursor 1,100:print "ballcount=";ballcount
set cursor 1,110:print "hitnum=";hitnum
set cursor 1,120:print "specialtarget=";specialtarget
return

`------------------------
_endlevel:
text$="You Finished Level: "+str$(level)
center text 500,200,text$
text$="Press any key for next level"
center text 500,240,text$
sync
for i=1 to ballcount
   ball#(i,1)=0
   _init_ball(i)
next i
leveldone=0
inc level
inc comp_xinc#,0.2
newballflag=1
ballcount=0
wait key
return

`------------------------
_setuptargets:
specialtarget=rnd(7)+151
for i=1 to numtargets
   if i+150=specialtarget
      color object 150+i,rgb(255,255,0)
      set object emissive 150+i,rgb(100,100,0)
   else
      color object 150+i,rgb(255,0,0)
      set object emissive 150+i,rgb(100,0,0)
   endif
   position object 150+i,i*120-50,100,backwall-10
   show object 150+i
   set object collision on 150+i
next i
return

`------------------------
`computer paddle follows ball
_comp_paddle:
b1x=ball#(1,2):b1y=ball#(1,3):b1z=object position z(1)
b2x=ball#(2,2):b2y=ball#(2,3):b2z=object position z(2)
if b1z>b2z
   if compx#<b1x then inc compx#,comp_xinc#
   if compx#>b1x then dec compx#,comp_xinc#
else
   if compx#<b2x then inc compx#,comp_xinc#
   if compx#>b2x then dec compx#,comp_xinc#
endif
return

`------------------------
function _init_ball(ptr)
ball#(ptr,1)=0      :`active? 1=yes
ball#(ptr,2)=900    :`x
ball#(ptr,3)=200    :`y
ball#(ptr,4)=-100   :`z
ball#(ptr,5)=-2     :`xdir
ball#(ptr,6)=0      :`ydir
ball#(ptr,7)=10     :`zdir
position object ptr,ball#(ptr,2),ball#(ptr,3),ball#(ptr,4)
position object 50+ptr,ball#(ptr,2),ball#(ptr,3),ball#(ptr,4)
endfunction

`------------------------
_move_balls:
if ballcount>0
for i=1 to 2
   if ball#(i,1)=1
      hitnum=object collision(i,0)
      if hitnum=105                             :`Hit PLAYER paddle
         if ball#(i,7)<0
            if pa#=0
               ball#(i,7)=ball#(i,7)*-1
               ball#(i,4)=ball#(i,4)+ball#(i,7)
            endif
            if pa#>0
               ball#(i,5)=pa#/5
               ball#(i,7)=ball#(i,7)*-1
               ball#(i,4)=ball#(i,4)+ball#(i,7)
            endif
            if pa#<0
               ball#(i,5)=pa#/5
               ball#(i,7)=ball#(i,7)*-1
               ball#(i,4)=ball#(i,4)+ball#(i,7)
            endif
         endif
      endif

      if hitnum=110                             :`Hit COMPUTER paddle
         if ball#(i,7)>0
            ball#(i,7)=ball#(i,7)*-1
            ball#(i,4)=ball#(i,4)+ball#(i,7)
         endif
      endif

      if hitnum>150 and hitnum<=160             :`Hit TARGET
         hide object hitnum
         set object collision off hitnum
         inc pscore
         dec targetsleft
         if targetsleft=0 then leveldone=1
         if targetsleft>0 and hitnum=specialtarget
            gosub _fire_new_ball
         endif
      endif

      bx#=ball#(i,2)+ball#(i,5)
      by#=ball#(i,3)+ball#(i,6)-gravity#
      bz#=ball#(i,4)+ball#(i,7)

      if bx#<leftwall+10 or bx#>rightwall-10
         ball#(i,5)=ball#(i,5)*-1
         bx#=bx#+ball#(i,5)
      endif
      if by#<floor
         ball#(i,6)=ball#(i,6)*-1
         by#=by#+ball#(i,6)
      endif
      if bz#>backwall
         ball#(i,7)=ball#(i,7)*-1
         bz#=bz#+ball#(i,7)
      endif
      if bz#<-200
         _init_ball(i)
         ball#(i,1)=0
         hide object i
         dec ballcount
         newballflag=1
         inc cscore
      endif

      position object i,bx#,100,bz#
      position object i+50,bx#,2,bz#
      ball#(i,2)=bx#
      ball#(i,3)=by#
      ball#(i,4)=bz#
   endif
next i
endif
return

`------------------------
_fire_new_ball:
   ballcount=ballcount+1
   ball#(ballcount,1)=1
   position object ballcount,ball#(ballcount,2),ball#(ballcount,3),ball#(ballcount,4)
   show object ballcount
   newballflag=0
return
end

DesertEagle (team bots AI):
1) Multiple AI's
2) AI works as intended
3) Human-like qualities

Ric (pong):
1) I believe this award was unanimous.

NathF (arena cone combat):
1) Multiple AI techniques displayed.
2) AI worked as intended
3) Challenging, but not unbeatable
4) Human-like qualities

sync on
Enemy=1000
Enemyx#=-20
Enemyz#=-40
Enemya#=0
viewangle#=140
EnemyStatus$="Idle"
EnemyAttackDistance=4
pathstacksize=0
Dim Pathstack(10)

Gosub _BuildWalls
Gosub _BuildPaths
x#=0
z#=40
Me=999
make object cone enemy,5
make object sphere me,4

do
   set cursor 0,0
   Print "Enemy Status: "+EnemyStatus$
   gosub _EnemyUpdate
   gosub _getControls
   gosub _PostionObjects:
   sync
loop

_PostionObjects:
   tempx#=x#:tempz#=z#
      Gosub _SlideCollision
   x#=tempx#:z#=tempz#
   position object me,x#,2,z#
   cam#=wrapvalue(cam#+.1)
   position camera 0,100,-10
   point camera 0,0,0
   tempx#=enemyx#:tempz#=enemyz#
      Gosub _SlideCollision
   enemyx#=tempx#:enemyz#=tempz#
   position object enemy,enemyx#,2,enemyz#
   rotate object enemy,90,enemya#,0
Return

_SlideCollision:
   col_dist=2
   for i=1 to walls
      maxtemp#=0
      for j=0 to 360 step 45
         temp#=intersect object (i,tempx#,2,tempz#,newxvalue(tempx#,j,col_dist),2,newzvalue(tempz#,j,col_dist))
         if temp#>maxtemp#
            maxtemp#=temp#
            maxangle#=j
         endif
      next j
      if maxtemp#>0
         tempx#=newxvalue(tempx#,maxangle#,maxtemp#-col_dist)
         tempz#=newzvalue(tempz#,maxangle#,maxtemp#-col_dist)
      endif
   next i
Return


_EnemyUpdate:
   angletoplayer#=wrapvalue(atanfull(x#-enemyx#,z#-enemyz#))
   if wrapvalue(enemya#-angletoplayer#+viewangle#*.5)<viewangle#
      distancetoplayer#=sqrt((x#-enemyx#)*(x#-enemyx#)+(z#-enemyz#)*(z#-enemyz#))
      cansee=1
      for i=1 to walls
         temp#=intersect object (i,enemyx#,2,enemyz#,x#,2,z#)
         if temp#>0 and temp#<distancetoplayer# then cansee=0
      next i
      if cansee=1
         enemystatus$="CloseIn"
         newx#=x#
         newz#=z#
         print "Attack Attack!"
      else
         print "No body there"
      endif
   else
      print "out of view field"
   endif

   If EnemyStatus$="CloseIn"
      enemyangle#=atanfull(newx#-enemyx#,newz#-enemyz#)
      if wrapvalue(enemyangle#-enemya#)>180
         enemya#=wrapvalue(enemya#-1)
      else
         enemya#=wrapvalue(enemya#+1)
      endif
      tempdist#=sqrt((newx#-enemyx#)*(newx#-enemyx#)+(newz#-enemyz#)*(newz#-enemyz#))
      if tempdist#<2 then EnemyStatus$="Scouting3"
      enemyx#=newxvalue(enemyx#,enemyangle#,.1)
      enemyz#=newzvalue(enemyz#,enemyangle#,.1)
   endif

   if EnemyStatus$="Idle"
      if rnd(1000)>997 then EnemyAngle#=(rnd(360)-180)*.001
      enemya#=wrapvalue(enemya#+EnemyAngle#)
   endif

   if EnemyStatus$="Tracking"
      if rnd(1000)>980 then TrackingAngle#=(rnd(10)-5)*.3
      if rnd(1000)>990 then scounting3=0:EnemyStatus$="Scouting3"
      enemya#=wrapvalue(enemya#+TrackingAngle#)
   endif

   if EnemyStatus$="Scouting3"
      if scouting3=0
         gosub _UpdatePathStack
         scouting3=1
      endif
      if scouting3=1
         old2location=oldlocation
         oldlocation=newlocation
         newlocation=int(rnd(pathstacksize-.5))
         if newlocation=oldlocation then newlocation=int(rnd(pathstacksize-.5))
         if newlocation=old2location then newlocation=int(rnd(pathstacksize-.5))
         newx#=pathpos#(pathstack(newlocation),0)
         newz#=pathpos#(pathstack(newlocation),1)
         Enemystatus$="CloseIn"
         scouting3=0
      endif
   endif

   _GetControls:
   if upkey()=1 then z#=z#+.1
   if downkey()=1 then z#=z#-.1
   if leftkey()=1 then x#=x#-.1
   if rightkey()=1 then x#=x#+.1
   if spacekey()=1 then tempx#=x#:tempz#=z#:gosub _UpdatePathStack
Return

_BuildWalls:
   For i=1 to 5
      read x#,z#,xp#,zp#
      make object box i,x#,10,z#
      position object i,xp#,5,zp#
   next i
   walls=i-1
   data 20,2,0,10
   data 2,20,-10,0
   data 20,2,0,-10
   data 20,2,10,0
   data 2,20,20,-10
Return

_BuildPaths:
   numpaths=8
   Dim PathPos#(numpaths,1)
   for i=0 to numpaths
      read PathPos#(i,0),PathPos#(i,1)
   next i
   data 17,-11
   data 15,25
   data 25,25
   data -15,15
   data -5,5
   data 15,5
   data -5,-5
   data 25,-5
   data -12,-20
Return

_UpdatePathStack:
   pathstacksize=0
   for j=0 to numpaths
      cansee=1
      for i=1 to walls
         tempscan#=intersect object (i,tempx#,2,tempz#,pathpos#(j,0),2,pathpos#(j,1))
         if tempscan#>0 then cansee=0
      next i
      if cansee=1 then pathstack(pathstacksize)=j:pathstacksize=pathstacksize+1
   next j
Return