Sorry your browser is not supported!

`initialise screen
set display mode 640,480,32
autocam off

`declare variable for camera angle

angle=225

`reset object number
a=1

`create board

make object cube 1601,100

`stretch board
scale object 1601,500,10,500

`position board
position object 1601,0,0,0

`create pins
For y = 1 to 40
For x = 1 to 40

`create object
Make object cube a,10
scale object a,100,2000,100

`position object
Position object a,(x*12)-240,(sin((9.0*x)+t#)+cos((9.0*y)+t#))*40.0,(y*12)-240

`increment object number
Inc a

Next x
Next y

`main loop
Do

a=1

For y = 1 to 40
For x = 1 to 40

`reposition dependant on sine wave function and time
Position object a,(x*12)-240,(sin((9.0*x)+t#)+cos((9.0*y)+t#))*40.0,(y*12)-240

Inc a

Next x
Next y

`increment time
inc t#

set cursor 0,0

`display info
print "Pin Pression simulation by calcyman"
print "Press Left and right arrowkeys to rotate simulation"


`position camera dependant on angle, and point towards centre of simulation
Position camera 600*SIN(angle),400,600*COS(angle)
point camera 0,0,0

`change angle dependant on user input
If leftkey()=1 then dec angle,5
If rightkey()=1 then inc angle,5

`repeat loop
Loop

//Image All's Pinpression thingy that has the thing under it and go whee

sync on : sync rate 60 : hide mouse
disable escapekey : autocam off : randomize timer( )

//Pinpression variables
    type pos
        x as float
        y as float
        z as float
    endtype
    
    type pin
        id as integer
        pos as pos
    endtype
    
    type base
        id as integer
        pos as pos
    endtype
    
    #CONSTANT MAX_PINS 600
    
    global pinpressionbase as base
    global MasterPin as integer
    global dim pinpression(MAX_PINS) as pin
    


//Construct the pinpression
    MasterPin=freeObject( )
    make object box MasterPin, 0.35, 5.0, 0.35
    hide object MasterPin
    
    for x=1 to 20
        for y=1 to 30
            i=((30*(x-1))+y)
            pinpression(i).id=freeObject( )
            clone object pinpression(i).id, MasterPin
            pinpression(i).pos.x=((x*0.50)-5.25)
            pinpression(i).pos.y=0.00
            pinpression(i).pos.z=((y*0.50)-7.75)
        next y
    next x
    
    pinpressionbase.id=freeObject( )
    make object box pinpressionbase.id, 10.25, 1.50, 15.25
    set object diffuse pinpressionbase.id, 0x000088
    pinpressionbase.pos.x=0.0
    pinpressionbase.pos.y=10.0
    pinpressionbase.pos.z=0.0



//Build a random object for the Pinpression
    global Subject as integer
    Subject=constructRandomObject( 5, 2.0, 5.0 )
    
    



position camera 8, 15, -17.50
point camera 0, 0, 0

//Main Loop
while escapekey( )=0
    text 5,5,"Move the mouse forward and back to elevate the Pinpression"
    text 5,25,"Move the mouse left and right to rotate the objects below"

    ymove#=mousemovey( )*0.02
    inc pinpressionbase.pos.y, ymove#
    if pinpressionbase.pos.y<=2.75 then pinpressionbase.pos.y=2.75
    
    xmove#=mousemovex( )*0.04
    yrotate object Subject, object angle y( Subject )+xmove#
    
    for i=1 to MAX_PINS
        pinpression(i).pos.y=pinpressionbase.pos.y-1.5
            x#=pinpression(i).pos.x
            y1#=100.0
            y2#=pinpressionbase.pos.y-4.0
            z#=pinpression(i).pos.z
        ray#=intersect object( Subject, x#,y1#,z#, x#,y2#,z# )
        if ray#>0.0
            pinpression(i).pos.y=(100-ray#)+2.5
        endif
    next i    
        
    readyGameObjects( )
    
    sync
    
endwhile

cls
center text screen width( )/2, screen height( )/2, "exiting..." : sync
deleteGameObjects( )
end






//Function Declarations

function freeObject( )
    obj=0
    repeat
        inc obj, 1
    until object exist( obj )=0
endfunction obj

function constructRandomObject( limbs as integer, size# as float, radius# as float )
    object=freeObject( )
    make object sphere object, size#*2
    for i=1 to limbs
        limb=freeObject( )
        otype=rnd(2)
        select otype
        case 1
            make object sphere limb, size#*1.5
        endcase
        case 2
            make object cube limb, size#*2
        endcase
        case 0
            make object cone limb, size#*2
        endcase
        endselect
        make mesh from object 1, limb
        add limb object, i, 1
        delete mesh 1
        delete object limb
        offset limb object, i, rnd(radius#*2)-radius#, 0, rnd(radius#*2)-radius#
    next i
endfunction object       

function readyGameObjects( )
    base=pinpressionbase.id
    x1#=pinpressionbase.pos.x
    y1#=pinpressionbase.pos.y
    z1#=pinpressionbase.pos.z
    position object base, x1#, y1#, z1#
    
    for i=1 to MAX_PINS
        obj=pinpression(i).id
        x#=pinpression(i).pos.x
        y#=pinpression(i).pos.y
        z#=pinpression(i).pos.z
        position object obj, x#+x1#, y#, z#+z1#
    next i
endfunction

function deleteGameObjects( )
    failures=0
    objects=1
    do
        if object exist( objects )=1
            delete object objects
            inc objects, 1
        else
            inc failures, 1
        endif
        
        if failures=20
            exit
                endif
    loop
endfunction

set display mode 640,480,0

DIM CirclePos(5,3)

`This keeps data for each of the five balls
`1 is the X Pos, 2 is the Y Pos, and 3 is the X Pos of the point the ball swivels around
CirclePos(1,1)=240
CirclePos(2,1)=280
CirclePos(3,1)=320
CirclePos(4,1)=360
CirclePos(5,1)=400
CirclePos(1,2)=300
CirclePos(2,2)=300
CirclePos(3,2)=300
CirclePos(4,2)=300
CirclePos(5,2)=300
CirclePos(1,3)=240
CirclePos(2,3)=280
CirclePos(3,3)=320
CirclePos(4,3)=360
CirclePos(5,3)=400

DO
cls rgb(70,150,220)

`Draw the circles
ink rgb(21,20,201),rgb(70,150,220)
Circle CirclePos(1,1),CirclePos(1,2),20
Circle CirclePos(2,1),CirclePos(2,2),20
Circle CirclePos(3,1),CirclePos(3,2),20
Circle CirclePos(4,1),CirclePos(4,2),20
Circle CirclePos(5,1),CirclePos(5,2),20

`Draw the strings
ink rgb(100,100,100),rgb(70,150,220)
line 0,100,screen width(),100
line CirclePos(1,1),CirclePos(1,2),240,100
line CirclePos(2,1),CirclePos(2,2),280,100
line CirclePos(3,1),CirclePos(3,2),320,100
line CirclePos(4,1),CirclePos(4,2),360,100
line CirclePos(5,1),CirclePos(5,2),400,100

if mouseclick()=1
   for c=1 to 5 `See which ball the player has clicked on
      if mousex()>CirclePos(c,1)-20 and mousex()<CirclePos(c,1)+20 and mousey()>CirclePos(c,2)-20 and mousey()<CirclePos(c,2)+20
         no=c
      endif
   next c
   if no>0
      gosub MoveIt `Allow the player to drag the ball along its curve
   endif
endif
if mouseclick()=0 then no=0

text 0,0,str$(no)
LOOP



MoveIt:
newposx=CirclePos(no,1)+mousemovex()

for y=1 to screen height()
   if SQRT((newposx-CirclePos(no,3))^2+(y-100)^2)<=140
      record1=y
   endif
   if SQRT((newposx-CirclePos(no,3))^2+(y-100)^2)>140
      recordP=record1
   endif
next y

CirclePos(no,2)=recordP
recordP=0
record1=0
return

`initialise screen
set display mode 640,480,32
autocam off

`declare variable for camera angle

angle=225

`reset object number
a=1

`create board
make object cube 1601,100

`create pin
make object cylinder 65000,10
scale object 65000,100,2000,100
make object sphere 65001,12
make mesh from object 65001,65001
delete object 65001
add limb 65000,1,65001
offset limb 65000,1,0,5,0
scale limb 65000,1,100,5,100
make mesh from object 65002,65000
delete object 65000



`stretch board
scale object 1601,500,10,500

`position board
position object 1601,0,0,0

`create pins
For y = 1 to 40
For x = 1 to 40

`create object
Make object a,65002,0
`scale object a,100,2000,100

`position object
Position object a,(x*12)-240,(sin((9.0*x)+t#)+cos((9.0*y)+t#))*40.0,(y*12)-240

`increment object number
Inc a

Next x
Next y

`main loop
Do

a=1

For y = 1 to 40
For x = 1 to 40

`reposition dependant on sine wave function and time
Position object a,(x*12)-240,(sin((9.0*x)+t#)+cos((9.0*y)+t#))*40.0,(y*12)-240

Inc a

Next x
Next y

`increment time
inc t#

set cursor 0,0

`display info
print "Pin Pression simulation by calcyman"
print "Press Left and right arrowkeys to rotate simulation"


`position camera dependant on angle, and point towards centre of simulation
Position camera 600*SIN(angle),400,600*COS(angle)
point camera 0,0,0

`change angle dependant on user input
If leftkey()=1 then dec angle,5
If rightkey()=1 then inc angle,5

`repeat loop
Loop

`initialise screen
`set display mode 640,480,32
set display mode 1024,768,32
autocam off
sync on
sync rate 0

`declare variable for camera angle

angle=225

`reset object number
a=1

`create board
make object cube 1601,100

`create pin
make object cylinder 65000,10
scale object 65000,100,2000,100
make object sphere 65001,12,8,8
make mesh from object 65001,65001
delete object 65001
add limb 65000,1,65001
offset limb 65000,1,0,5,0
scale limb 65000,1,100,5,100
make mesh from object 65002,65000
delete object 65000



`stretch board
scale object 1601,500,10,500

`position board
position object 1601,0,0,0

`create pins
For y = 1 to 40
For x = 1 to 40

`create object
Make object a,65002,0
`scale object a,100,2000,100

`position object
Position object a,(x*12)-240,(sin((9.0*x)+t#)+cos((9.0*y)+t#))*40.0,(y*12)-240

`increment object number
Inc a

Next x
Next y

`main loop
Do

a=1

For y = 1 to 40
For x = 1 to 40

`reposition dependant on sine wave function and time
Position object a,(x*12)-240,(sin((9.0*x)+t#)+cos((9.0*y)+t#))*40.0,(y*12)-240

Inc a

Next x
Next y

`increment time
inc t#

set cursor 0,0

`display info
print "Pin Pression simulation by calcyman"
print "Press Left and right arrowkeys to rotate simulation"


`position camera dependant on angle, and point towards centre of simulation
Position camera 600*SIN(angle),400,600*COS(angle)
point camera 0,0,0

`change angle dependant on user input
If leftkey()=1 then dec angle,5
If rightkey()=1 then inc angle,5

`repeat loop
`set cursor 0,100
print screen fps()
sync
Loop

set display mode 1024,768,32
hide mouse
backdrop on
color backdrop 0
sync on

rem Create waypoints for movement of escalator
dim ramp1_y#(20)
dim ramp1_z#(20)
dim ramp1_a#(20)
dim Oramp(4)
dim Oleg(4)
dim Opad(10)
dim pad_pos(10)
rem Define Object numbers
temp=1
Oramp(1)=2
Oramp(2)=3
Oramp(3)=4
Oramp(4)=5
Oball=6
Oleg(1)=7
Oleg(2)=8
Oleg(3)=9
Oleg(4)=10
Obase=11
rem Define segments of escalator
obj=12
for x=1 to 10
  Opad(x)=obj
  inc obj
next x
Oramp1=22
Opost=23
global Oswing=24
Obox=25

rem Define Mesh numbers
Mboard=2
Mrampend=3
Mrampcyl=4
Mboxseg=5
Mball=6
Mswingarm=7

rem Define Image numbers
Iboard=2
Iball=3
Ibase=4
Instructions=5

rem Define textures
Tramp1_x#=0.0
Tramp1_y#=0.0

gosub make_objects        rem Create and build all the objects
gosub get_elevator        rem Get the waypoints for the escalator movement

position camera 0,30,-100
point camera 0,30,0

rem Set up the marble movements parameters
ball_x_start#=0.03        rem Starting speed for rolling marble
ball_x#=ball_x_start#
xaccel#=0.0002            rem Rate of acceleration for the marble on the ramps
xmax#=0.4                 rem Maximum speed of the marble on the ramps
ball_y#=0.0               rem Marble speed for other axes
ball_z#=0.0
ball_z_start#=2.75        rem Marble position on the ramps
gravity#=0.008            rem Acceleration due to gravity
dir#=1.0                  rem Direction of roll of the marble
mag#=0.6                  rem Magnitude of force when collision with escalator
pmag#=0.8                 rem Magnitude of force when collision with escalator paddles
rem Set up the swing arm movements
sdir#=1.0                 rem Direction of swing
smax#=0.3                 rem Maximum speed of the swing
sv#=0.0                   rem Swing velocity
sa#=0.01                  rem Acceleration of the swing velocity
sangle#=10.0              rem Starting angle of the swing arm
rangle#=-95.0             rem Limit of the swing arm motion
swingfull=0               rem Swing arm box has the marble 0=no, 1=yes
rem Define activity identifiers for collision detection and physics
ramps=1
escalator=2
swingarm=3
outofbox=4
activity=ramps            rem Start the marble on the ramps

gosub position_objects    rem Place all objects in the scene
gosub instructions

while not escapekey()
  rem Move the camera around the object using the arrow keys
  move_camera()
  rem Animate the escalator
  gosub move_ramp
  rem Animate the swing arm
  gosub move_swing

  rem Get the current position of the marble
  Oball_x#=object position x(Oball)
  Oball_y#=object position y(Oball)
  Oball_z#=object position z(Oball)

  rem Calculate which ramp the marble is on based on the marble's height
  effective_ramp=int(Oball_y#/20)+1
  if effective_ramp>4 then effective_ramp=4
  if effective_ramp<1 then effective_ramp=1

  rem Move the marble horizontally
  Oball_x#=Oball_x#+ball_x#*dir#
  ball_x#=ball_x#+xaccel#
  if ball_x#>xmax# then ball_x#=xmax# rem Limit the top speed of the marble
  rem Apply gravity to the marble
  ball_y#=ball_y#+gravity#
  position object Oball,Oball_x#,Oball_y#-ball_y#,Oball_z#-ball_z#

  if object position z(Oball)=ball_z_start# and effective_ramp>1
    if activity=swingarm then activity=ramps
    rem Check for collision of the marble with the ramp
    if object collision(Oramp(effective_ramp),Oball)
      if effective_ramp && 1 = 1 rem Check which direction to marble should be rolling on the ramp
        if dir#=1.0
          ball_x#=ball_x_start# rem Set starting speed of the marble if it landed on a new ramp
        endif
        dir#=-1.0
      else
        if dir#=-1.0
          ball_x#=ball_x_start# rem Set starting speed of the marble if it landed on a new ramp
        endif
        dir#=1.0
      endif
      position object Oball,object position x(Oball),object position y(Oball)+ball_y#,object position z(Oball)
      ball_y#=ball_y#*-0.5 rem Apply bounce friction to the marble
    endif
    rem Roll the marble in the direction of motion
    zrotate object Oball,object angle z(Oball)-ball_x#*12.0*dir#
  else
    if object position z(Oball)<=76 and activity<>swingarm rem Marble is on escalator
      if activity=ramps then activity=escalator
      if activity=escalator
        if object position x(Oball)>=ramp1_x#
          dir#=0.0  rem Stop the marble in the center of the escalator
        else
          dir#=1.0  rem Keep the marble rolling until it reaches the center of the escalator
        endif
        rem Check for collision of the marble with the escalator paddles
        found=0
        for i=1 to 10
          if object collision(Opad(i),Oball) then found=i
        next i
        if found>0
          rem Calculate the direction of force on the marble and apply to the marble
          ydir#=cos(object angle x(Opad(found))+90)*pmag#
          zdir#=sin(object angle x(Opad(found))+90)*pmag#
          position object Oball,object position x(Oball),object position y(Oball)+ydir#,object position z(Oball)+zdir#
        endif
        rem Check for collision of the marble with the escalator
        if object collision(Oramp1,Oball)
          if object position z(Oball)<64
            temp#=ball_y#*mag#
            ball_y#=ball_z#*mag#
            ball_z#=temp#
          else
            ball_y#=-0.05
            ball_z#=0.1
          endif
          rem Apply collision force to the marble
          position object Oball,object position x(Oball),object position y(Oball)-ball_y#,object position z(Oball)-ball_z#
        endif
      endif
    else
      if activity=escalator then activity=swingarm
      if activity=swingarm
        ball_z#=0.0             rem Make ball fall straight down
        if swingfull=0          rem Ball has not made contact with box yet
          if object collision(Obox,Oball)  rem If ball has landed in the box
            position object Oball,limb position x(Oswing,Lhorzarm),object position y(Oball)-ball_y#,limb position z(Oswing,Lhorzarm)
            swingfull=1         rem Swing the arm with the ball in the box
          endif
        else
          rem Keep the ball in the box using the hidden limb on the swing arm
          position object Oball,limb position x(Oswing,Lballholder),limb position y(Oswing,Lballholder),limb position z(Oswing,Lballholder)
        endif
      endif
    endif
  endif
  if activity=outofbox  rem Ball is falling out of the box onto the ramp
    position object Oball,object position x(Oball),object position y(Oball)-ball_y#,object position z(Oball)-0.1
    if object position z(Oball)<ball_z_start#   rem When ball reaches the center of the ramp, keep it in the center
      position object Oball,object position x(Oball),object position y(Oball)-ball_y#,ball_z_start#
      activity=ramps
    endif
  endif
  sync
endwhile
end

move_swing:
  if activity=swingarm and swingfull=1  rem If ball is in the box, swing the arm
    sv#=sv#-sa#           rem Accelerate the swing arm for realistic physics
    if abs(sv#)>smax# then sv#=sv#+sa#  rem Limit the speed of the swing arm
    rem Swing the arm
    rotate object Oswing,object angle y(Oswing)/2.2,object angle y(Oswing)+sv#,object angle z(Oswing)
    rem Pivot the joint holding the box
    rotate limb Oswing,Lvertjoint,0,object angle y(Oswing)*-1.0+10.0,0
    rem Rotate the box to stay in position with the end of the swing arm
    yrotate object Obox,limb angle y(Oswing,Lvertjoint)
    rem Swing arm reaches limit to dump marble onto ramp
    if object angle y(Oswing)<= rangle#
      swingfull=0
      sv#=0.0
      activity=outofbox
      ball_y#=0.0
      ball_x#=ball_X_start#
    endif
  else    rem Swing arm back into starting position
    sv#=sv#+sa#   rem Accelerate the swing arm for realistic physics
    if abs(sv#)>smax# then sv#=sv#-sa#  rem Limit the speed of the swing arm
    rem Swing the arm
    rotate object Oswing,object angle y(Oswing)/2.2,object angle y(Oswing)+sv#,object angle z(Oswing)
    rem Pivot the joint holding the box
    rotate limb Oswing,Lvertjoint,0,object angle y(Oswing)*-1.0+10.0,0
    rem Rotate the box to stay in position with the end of the swing arm
    yrotate object Obox,limb angle y(Oswing,Lvertjoint)
    rem Swing arm reaches starting position
    if object angle y(Oswing)>= sangle#
      yrotate object Oswing,object angle y(Oswing)-sv#
      sv#=sv#*-0.5      rem Bounce the arm for realistic physics
    endif
  endif
return

move_ramp:
  for i=1 to 10
    rem Get position of the escalator segment
    y#=object position y(Opad(i))
    z#=object position z(Opad(i))
    rem Check its distance to the next waypoint
    dist#=sqrt((ramp1_y#(pad_pos(i))-y#)^2+(ramp1_z#(pad_pos(i))-z#)^2)
    rem If it is close enough to the next waypoint
    if dist#<0.5
      rem Place the segment at the waypoint
      position object Opad(i),ramp1_x#,ramp1_y#(pad_pos(i)),ramp1_z#(pad_pos(i))
      rem Correctly orient the segment rotation to the waypoint
      xrotate object Opad(i),ramp1_a#(pad_pos(i))
      rem Point at the next waypoint
      dec pad_pos(i)
      if pad_pos(i)<1 then pad_pos(i)=20
    else
      rem Calculate the step of motion to move the segment towards the next waypoint
      ydir#=(ramp1_y#(pad_pos(i))-y#)/dist#*0.2
      zdir#=(ramp1_z#(pad_pos(i))-z#)/dist#*0.2
      position object Opad(i),ramp1_x#,y#+ydir#,z#+zdir#
      rem Slowly adjust the segment rotation to move towards the waypoint orientation
      if object angle x(Opad(i))<>ramp1_a#(pad_pos(i))
        angle#=ramp1_a#(pad_pos(i))-7*dist#
        xrotate object Opad(i),angle#
      endif
    endif
  next i
return

make_objects:
rem Make a board mesh for use with the ramp object
make object box temp,60,2,5
make mesh from object Mboard,temp
delete object temp

rem Make a wood texture for use with the objects
create bitmap temp,32,32
ink rgb(120,38,0),0
box 0,0,31,31
ink rgb(180,60,0),0
for x=1 to 50
  dot rnd(31),rnd(31)
next x
get image Iboard,0,0,31,31
delete bitmap temp

rem Make ramps
make object Oramp(1),Mboard,Iboard
add limb Oramp(1),1,Mboard
offset limb Oramp(1),1,0,2,5
rotate limb Oramp(1),1,-45,0,0
texture limb Oramp(1),1,Iboard
xrotate object Oramp(1),22.5
fix object pivot Oramp(1)
set object collision to polygons Oramp(1)
instance object Oramp(2),Oramp(1)
instance object Oramp(3),Oramp(1)
instance object Oramp(4),Oramp(1)
set object collision to polygons Oramp(2)
set object collision to polygons Oramp(3)
set object collision to polygons Oramp(4)

rem Make marble
create bitmap temp,256,256
ink rgb(192,192,192),0
box 0,0,255,255
ink rgb(64,64,64),0
for x=1 to 500
  dot rnd(255),rnd(255)
next x
get image Iball,0,0,255,255
delete bitmap temp
set current bitmap 0
make object sphere Oball,9,20,20
texture object Oball,Iball
set object Oball, 1,1,1,2,1,0,1
yrotate object Oball, 180
set object collision to spheres Oball

rem Make legs
make object cylinder Oleg(1),60
texture object Oleg(1),Iboard
instance object Oleg(2),Oleg(1)
instance object Oleg(3),Oleg(1)
instance object Oleg(4),Oleg(1)
scale object Oleg(1),3,100,3
scale object Oleg(2),3,100,3
scale object Oleg(3),3,120,3
scale object Oleg(4),3,120,3

rem Make base
size=1023
create bitmap 1,size+1,size+1
ink rgb(64,64,64),0
box 0,0,size,size
ink rgb(128,128,128),0
for x=0 to size step 3
  line x,0,rnd(size),size
  line 0,x,size,rnd(size)
next x
get image Ibase,0,0,size,size
delete bitmap 1
make object box Obase,70,5,50
texture object Obase,Ibase

rem Make escalator
make object box Opad(1),10,10,2
texture object Opad(1),Iboard
offset limb Opad(1),0,0,5,0
set object collision to polygons Opad(1)
rem Make all escalator segments
for x=2 to 10
  instance object Opad(x),Opad(1)
  offset limb Opad(x),0,0,5,0
  set object collision to polygons Opad(x)
next x
rem Make escalator centre (base)
make object cylinder temp,10
scale object temp,140,100,140
make mesh from object Mrampend,temp
delete object temp
make object sphere temp,14
scale object temp,1,100,100
make mesh from object Mrampcyl,temp
delete object temp
make object box Oramp1,10,14,90
add limb Oramp1,1,Mrampend
offset limb Oramp1,1,0,0,45
rotate limb Oramp1,1,0,0,90
add limb Oramp1,2,Mrampend
offset limb Oramp1,2,0,0,-45
rotate limb Oramp1,2,0,0,90
add limb Oramp1,3,Mrampcyl
offset limb Oramp1,3,5,0,-45
add limb Oramp1,4,Mrampcyl
offset limb Oramp1,4,-5,0,-45
add limb Oramp1,5,Mrampcyl
offset limb Oramp1,5,5,0,45
add limb Oramp1,6,Mrampcyl
offset limb Oramp1,6,-5,0,45
texture object Oramp1,Iboard
xrotate object Oramp1,135
set object collision to polygons Oramp1

rem Make swing post
make object cylinder Opost,30
scale object Opost,8,100,8
texture object Opost,Iboard

rem Make swing
rem Define limbs
Lmainjoint=1
Lvertjoint=2
Lvertarm=3
Lboxjoint=4
Lhorzarm=5
Lballholder=6
make object cylinder temp,60
scale object temp,5,100,5
make mesh from object Mswingarm,temp  rem create a mesh from the scaled object so that the scaling
delete object temp                    rem       does not apply to limbs of the object
make object Oswing,Mswingarm,0        rem remake the object from the mesh of the scaled object
offset limb Oswing,0,0,30,0           rem Shift the main object so that it rotates from its end, not its middle
texture object Oswing,Iboard
make object sphere temp,10,20,20      rem Create object for use with making ball joints
make mesh from object Mball,temp      rem Create mesh to use with add limb command
delete object temp
add limb Oswing,Lmainjoint,Mball        rem Add the main joint for the swing arm
texture limb Oswing,Lmainjoint,Iball
add limb Oswing,Lvertjoint,Mball        rem Add the joint for the vertical arm
scale limb Oswing,Lvertjoint,50,50,50   rem Shrink the vertical joint by half
offset limb Oswing,Lvertjoint,0,60,0    rem Position the vertical joint at the end of the main arm
texture limb Oswing,Lvertjoint,Iball
add limb Oswing,Lvertarm,Mswingarm      rem Add the vertical arm
scale limb Oswing,Lvertarm,100,50,100   rem Shorten the vertical arm to the correct length
rotate limb Oswing,Lvertarm,0,0,90      rem Orient the vertical arm to vertical
offset limb Oswing,Lvertarm,15,0,0     rem Position the vertical arm at the vertical joint
texture limb Oswing,Lvertarm,Iboard
link limb Oswing,Lvertjoint,Lvertarm
add limb Oswing,Lboxjoint,Mball         rem Add the joint for the horizontal arm
scale limb Oswing,Lboxjoint,100,200,100    rem Shrink the horizontal joint by half
offset limb Oswing,Lboxjoint,0,-25,0    rem Position the horizontal joint at the end of the horizontal arm
texture limb Oswing,Lboxjoint,Iball
link limb Oswing,Lvertarm,Lboxjoint
add limb Oswing,Lhorzarm,Mswingarm      rem Add the horizontal arm
scale limb Oswing,Lhorzarm,100,10,100   rem Shorten the horizontal arm to the correct length
rotate limb Oswing,Lhorzarm,90,0,0      rem Orient the horizontal arm
offset limb Oswing,Lhorzarm,0,0,-5      rem Position the horizontal arm at the horizontal joint
texture limb Oswing,Lhorzarm,Iboard
link limb Oswing,Lboxjoint,Lhorzarm
add limb Oswing,Lballholder,Mball       rem Add an invisible limb to hold the marble
offset limb Oswing,Lballholder,0,-150,0   rem Position the invisible limb
link limb Oswing,Lhorzarm,Lballholder
hide limb Oswing,Lballholder
rem Make swingarm catcher box
make object box temp,12,1,12            rem Make a side of the box
make mesh from object temp,temp         rem Create a mesh to be used for all sides of the box
delete object temp
make object Obox,temp,0                 rem Start building the box with one side
add limb Obox,1,temp                    rem Add one side to the box
add limb Obox,2,temp                    rem Add one side to the box
add limb Obox,3,temp                    rem Add one side to the box
add limb Obox,4,temp                    rem Add one side to the box
offset limb Obox,0,0,-3,0             rem Position a side of the box
offset limb Obox,1,5.5,3,0            rem Position a side of the box
offset limb Obox,2,0,3,5.5            rem Position a side of the box
offset limb Obox,3,-5.5,3,0           rem Position a side of the box
offset limb Obox,4,0,3,-5.5           rem Position a side of the box
rotate limb Obox,1,0,0,90               rem Orient the side of the box
rotate limb Obox,2,90,0,0               rem Orient the side of the box
rotate limb Obox,3,0,0,90               rem Orient the side of the box
rotate limb Obox,4,90,0,0               rem Orient the side of the box
make mesh from object temp,Obox         rem Create a mesh so that object can be created with no limbs
delete object Obox
make object Obox,temp,Iboard            rem Create box from mesh so it has no limbs
offset limb Obox,0,0,5,0                rem Change its axis of rotation position
xrotate object Obox,270                 rem Point to open end of the box up
glue object to limb Obox,Oswing,Lhorzarm,1    rem Attach box to the swing arm
rotate object Oswing,90,0,0             rem Orient the entire swing arm obect to sit on the swing pole
fix object pivot Oswing                 rem Define the current orientation of the swing arm as absolute
set object collision to polygons Obox
return

get_elevator:
rem Get the waypoints for the escalator animation
ramp1_x#=35.0
for i=1 to 20
  read ramp1_y#(i),ramp1_z#(i),ramp1_a#(i)
  ramp1_y#(i)=ramp1_y#(i)-20.0
next i
return

position_objects:
hide object Oramp(1)    rem Original design had 4 ramps, bottom ramp was removed so marble would fall onto escalator
position object Oramp(1),10,0,0
position object Oramp(2),-10,20,0
position object Oramp(3),10,40,0
position object Oramp(4),-10,60,0
zrotate object Oramp(1),5
zrotate object Oramp(2),-5
zrotate object Oramp(3),5
zrotate object Oramp(4),-5
position object Oleg(1),15,28,-3
position object Oleg(2),15,28,8.5
position object Oleg(3),-41,32,-2
position object Oleg(4),-41,32,7.5
position object Obase,-15,-5,0
position object Oball, -35,69,ball_z_start#
rem Place escalator paddles along top and bottom of the escalator
for x=1 to 5
  position object Opad(x),ramp1_x#,ramp1_y#(1)+(x-1)*15,ramp1_z#(1)+(x-1)*15
  xrotate object Opad(x),ramp1_a#(1)
  pad_pos(x)=1
next x
for x=6 to 10
  position object Opad(x),ramp1_x#,ramp1_y#(11)-(x-6)*15,ramp1_z#(11)-(x-6)*15
  xrotate object Opad(x),ramp1_a#(11)
  pad_pos(x)=11
next x
position object Oramp1,ramp1_x#,25,35
position object Opost,10,10,20
position object Oswing,10,25,20
return

instructions:
rem Draw cursor key buttons and label with instructions for camera movement
x=0:y=40
create bitmap temp,256,256
ink 0,0
box 0,0,255,255
ink rgb(128,255,128),0
box x,y+1,x+12,y+15
box x+244,y+1,x+255,y+15
box x,y+23,x+12,y+37
box x+244,y+23,x+255,y+37
box x,y+43,x+41,y+57
box x+43,y+43,x+55,y+57
box x+200,y+43,x+241,y+57
box x+243,y+43,x+255,y+57
set cursor x+15,y+0
print "move left"
set cursor x+155,y+0
print "move right"
set cursor x+15,y+22
print "zoom in"
set cursor x+155,y+22
print "zoom out"
set cursor x+70,y+43
print "up"
set cursor x+153,y+43
print "down"
set cursor 50,0
print "CAMERA CONTROLS"
ink 0,0
line x+1,y+8,x+6,y+3:line x+2,y+8,x+7,y+3
line x+1,y+8,x+6,y+13:line x+2,y+8,x+7,y+13
line x+1,y+8,x+11,y+8
line x+254,y+8,x+249,y+3:line x+253,y+8,x+248,y+3
line x+254,y+8,x+249,y+13:line x+253,y+8,x+248,y+13
line x+254,y+8,x+244,y+8
line x+6,y+25,x+3,y+28:line x+6,y+26,x+3,y+29
line x+6,y+25,x+10,y+29:line x+6,y+26,x+10,y+30
line x+6,y+25,x+6,y+35
line x+250,y+35,x+247,y+32:line x+250,y+34,x+247,y+31
line x+250,y+35,x+254,y+31:line x+250,y+34,x+254,y+30
line x+250,y+25,x+250,y+35
line x+50,y+45,x+47,y+48:line x+50,y+46,x+47,y+49
line x+50,y+45,x+54,y+49:line x+50,y+46,x+54,y+50
line x+50,y+45,x+50,y+55
set cursor x,y+43
print "SHIFT"
line x+250,y+55,x+247,y+52:line x+250,y+54,x+247,y+51
line x+250,y+55,x+254,y+51:line x+250,y+54,x+254,y+50
line x+250,y+45,x+250,y+55
set cursor x+200,y+43
print "SHIFT"

rem Convert instructions bitmap into a sprite for display on the screen
get image Instructions,0,0,256,256
delete bitmap temp
sprite 1,0,0,Instructions
return

rem Waypoints for escalator movement
data 10,10,135,70,70,135,72,71,115,75,72,95,77.5,71.5,75,79,70.5,55,80.5,69,35,81.7,67,15,82,65,355,81.5,62.5,335,80,60,315,20,0,315,17.9,-1.4,295,15,-2,275,12.5,-1.5,255,10.8,-0.6,235,9.4,0.8,215,8.3,2.9,195,8,5,175,8.5,7.5,155

function move_camera()
  if leftkey()
    turn camera left 90.0
    move camera 1.0
    point camera 0,30,0
  endif
  if rightkey()
    turn camera right 90.0
    move camera 1.0
    point camera 0,30,0
  endif
  if upkey()
    if not shiftkey()
      move camera 0.5
    else
      position camera camera position x(),camera position y()+1.0,camera position z()
      point camera 0,30,0
    endif
  endif
  if downkey()
    if not shiftkey()
      move camera -0.5
    else
      position camera camera position x(),camera position y()-1.0,camera position z()
      point camera 0,30,0
    endif
  endif
endfunction

...a lava lamp! 

REM ===========SETUP==========
`Setup sync(-rate) etc.
sync on : sync rate 60
hide mouse : autocam off
set display mode 800,600,32

`Number of balls in lamp
#constant C_num 5

`random global color of the light and balls
global color : color=rgb(rnd(255),rnd(255),rnd(255))

`background color will be grey
bgcolor=rgb(127,127,127)



REM ==========IMAGES==========

`make image for metal above and below the glas, black will be invisible
cls                        `clear to make sure its all black
ink rgb(120,120,120),0        `grey-metallic color
box 0,0,512,150            `  "     "     box at the top..
box 0,320,512,512          `...and bottom of the image
get image 1,0,0,512,512    `get the image

`make image for the stand, just the top will be visible so we'll keep everything below blsck
cls                        `erase old boxes from screen
box 0,0,512,200            `a box, just at the top
get image 2,0,0,512,512    `finally get the image




REM ==========OBJECTS=========

`glas
make object sphere 1,5,32,32     `make a sphere...
scale object 1,25,100,25         `...stretch it...
ghost object on 1,2              `...ghost it so it looks like glas, ghost mode 2 is perfect...
set alpha mapping on 1,25        `...and then make it 75% transparent

`metal
make object sphere 2,5.05,32,32  `nearly same size...
scale object 2,25,100,25         `...as the glas , just a little bit bigger
texture object 2,1               `texture it with image 1
set object transparency 2,1      `hide black parts, there the glas will be visible

`stand
make object sphere 3,5,32,32     `again, same size...
scale object 3,30,75,30          `but different scale
texture object 3,2               `texture with img 2
set object transparency 3,1      `and hide lower part
move object down 3,3             `its the stand/base isnt it? so it has be at the top, yeah...

`balls
for ball=11 to 10+C_num          `as 1 to 3 are already used the balls will be 10+1 to 10+number of balls
   new_ball(ball)                `creates a new ghosted ball at the bottom of the lamp (explained in the function itself)
   move object up ball,rnd(5)    `as they'll move with same speed they have to be "spawned" random
next ball                        `or they'll be on the same height all the time



REM =========LIGHTS===========

`light from inside the stand/base, colored with the random 'color' defined earlier
make light 1
set directional light 1,5,1000,5
color light 1,color

set normalization on `this will smooth lighting

REM ======CAMERA-SETUP========
position camera 25,5,25  `position it outside the lamp
color backdrop bgcolor   `color the backdrop with background-color (grey)


REM ======MAIN_LOOP====>>>>>>>
do

   gosub Camera

   `control lava-balls
   for ball=11 to 10+C_num
      `slowly move them up
      move object up ball,lavaspeed#/1000.0

      `if it is at the top it will "respawn" at the bottom lol *unrealistic*
      if object position y(ball) >= 1.5-object size(ball)/2.0
         `just delete...
         delete object ball
         `...and make a new one
         new_ball(ball)
      endif
   next ball

   `if speed of the balls is lower than 5...
   if lavaspeed#<5
      `... then slowly increase it
      inc lavaspeed#,0.01
   endif

   `print FPS
   set cursor 0,0 : print screen fps()

   `update screen
   sync

loop
REM <<<<<<=========


REM ==========SUBS===========
Camera:

   if spacekey()
      `move camera forward and backward with arrowkeys
      move camera upkey()-downkey()
      `rotate it with the mouse
      rotate camera camera angle x()+mousemovey(),camera angle y()+mousemovex(),0

   else

      `if space is not pressed:

      `rotate camera nearly 90° ...
      rotate camera camera angle x()-5,camera angle y()+87.5,0
      `... move it to that direction ...
      move camera 0.5
      `... and turn it back to face the lamp
      point camera 0,0,0

      `this way it will move around the lamp (i know its not very exact but it was easy to code :p )
   endif

return


REM ========FUNCTIONS===========
function new_ball(num)
   make object sphere num,(1+rnd(2))/5.0,32,32      `make random-sized new sphere, with 32 rows and columns so it'll be smooth
   ghost object on num,2                            `ghost it
   set alpha mapping on num,60+rnd(40)              `random transparency between 0% and 40%
   local x# : local y# : local z#                   `local vars for the position
   x#=(rnd(5)-rnd(5))/25.0                          `random x position between -0.2 and +0.2
   y#=-1.0+object size(num)/2.0                     `       y position at the bottom
   z#=(rnd(5)-rnd(5))/25.0                          `random z position between -0.2 and +0.2
   position object num,x#,y#,z#                     `position it now
   color object num,color                           `color it (with the global random 'color')
   disable object zdepth num                        `always draw in front, or it will be sometimes hidden by glas
endfunction

REM Project: knick-knack
REM Created: 11/7/2007 7:39:47 PM
REM
REM ***** Main Source File *****
REM
sync on:sync rate 60:sync

#constant MaxSwing = 45
#constant SwingSpeed = 3

make camera 1

move camera 1,-10

make object cylinder 1,1 `Makes center shaft
make mesh from object 2,1 `Makes a mesh of a cylinder for later limb use
scale limb 1,0,5,500,5   `Scales the shaft to make it long

`Makes a sphere mesh
make object sphere 2,.5
make mesh from object 1,2
delete object 2

`Makes a cylinder with two balls
add limb 1,1,1
add limb 1,2,1

scale limb 1,2,150,150,150 `Makes the bottom ball bigger

`Puts the balls at either end
offset limb 1,1,0,2.5,0
offset limb 1,2,0,-2.5,0

`Makes the first horizontal cross shaft
add limb 1,3,2
scale limb 1,3,10,250,10
rotate limb 1,3,0,0,90

`Makes the first sticking out shaft
add limb 1,4,2
scale limb 1,4,10,150,10
rotate limb 1,4,90,0,0
offset limb 1,4,-.75,0,-.75

`Makes the second sticking out shaft
add limb 1,5,2
scale limb 1,5,10,150,10
rotate limb 1,5,90,0,0
offset limb 1,5,.75,0,.75

`Makes annother shaft
add limb 1,6,2
scale limb 1,6,10,75,10
rotate limb 1,6,0,0,90
offset limb 1,6,-.375,0,-1.5

`Makes the shaft opposite the above shaft
add limb 1,7,2
scale limb 1,7,10,75,10
rotate limb 1,7,0,0,90
offset limb 1,7,.375,0,1.5

`Makes annother shaft
add limb 1,8,2
scale limb 1,8,10,100,10
rotate limb 1,8,90,0,0
offset limb 1,8,0,0,1.5

`Makes the one of the four final balls
add limb 1,9,1

`Makes the oposite ball
add limb 1,10,1

link limb 1,8,9
scale limb 1,9,1000,100,1000
offset limb 1,9,0,.5,0

link limb 1,8,10
scale limb 1,10,1000,100,1000
offset limb 1,10,0,-.5,0

`Makes the shaft opposite the above shaft
add limb 1,11,2
scale limb 1,11,10,100,10
rotate limb 1,11,90,0,0
offset limb 1,11,0,0,-1.5

`Makes the second to last ball
add limb 1,12,1

`Makes the final ball
add limb 1,13,1

link limb 1,11,12
scale limb 1,12,1000,100,1000
offset limb 1,12,0,-.5,0

link limb 1,11,13
scale limb 1,13,1000,100,1000
offset limb 1,13,0,.5,0

make object box 5,3,.2,5

move object down 5,3

make object cylinder 6,1
scale object 6,25,300,25
position object 6,-1.25,-1.5,0
make object cylinder 7,1
scale object 7,25,300,25
position object 7,1.25,-1.5,0




swing = 1

d1 = 1
d2 = 1

do
   sync

   angx = object angle x(1)

   if angx > MaxSwing or angx < -MaxSwing
      swing = -1*swing
   endif

   xrotate object 1,angx+SwingSpeed*swing



   rotate limb 1,8,limb angle x(1,8)+SwingSpeed*d1,0,0
   rotate limb 1,11,limb angle x(1,11)+SwingSpeed*d2,0,0

   wrap = wrapvalue(limb angle x(1,8))

   if wrap=90 or wrap = 270
      d1 = rnd(1)
      if d1 = 0
         d1 = -1
      endif
   endif

   wrap = wrapvalue(limb angle x(1,11))

   if wrap=90 or wrap = 270
      d2 = rnd(1)
      if d2 = 0
         d2 = -1
      endif
   endif

   if rightkey()
      turn camera left 1,90
      move camera 1,-1
      turn camera right 1,84.3
   endif
   if leftkey()
      turn camera right 1,90
      move camera 1,-1
      turn camera left 1,84.3
   endif
loop

`Newton's Cradle by Ric

set_display()
make_ground()
make_cradle()

do

  move_cradle()
  move_camera()
  sync

loop


function free_image()

  `find a spare image number
  repeat
    inc n
  until image exist(n)=0

endfunction n

function free_object()

  `find a spare object number
  repeat
    inc n
  until object exist(n)=0

endfunction n

function set_display()

  `set the display mode, sync rate and lighting
  set display mode 1024,768,32
  sync on
  sync rate 60
  color backdrop 0
  autocam off
  hide mouse
  make light 1
  position light 1,30,10,-10
  set light range 1,100

endfunction

function make_ground()

  `make a checked texture for the ground
  groundimage=free_image()
  create bitmap 1,99,99
  ink rgb(10,10,10),0
  box 0,0,99,99
  ink rgb(100,100,255),0
  box 0,0,49,49
  box 50,50,99,99
  get image groundimage,0,0,99,99,1
  delete bitmap 1

  `make a translucent plane for the ground and texture it with our image
  ground=free_object()
  make object plain ground,100,100
  texture object ground,groundimage
  scale object texture ground,10,10
  pitch object down ground,90
  set alpha mapping on ground,90

endfunction

function make_cradle()

  `make a texture for applying sphere mapping to the balls
  reflection=free_image()
  create bitmap 1,99,99
  box 0,0,99,30,rgb(100,100,100),rgb(50,50,50),rgb(100,100,100),rgb(50,50,50)
  box 0,30,99,99,rgb(200,200,220),rgb(100,100,100),rgb(200,200,220),rgb(100,100,100)
  get image reflection,0,0,99,99,1
  delete bitmap 1

  `make a grey texture for the wires
  grey=free_image()
  create bitmap 1,10,10
  ink rgb(80,80,80),0
  box 0,0,10,10
  get image grey,0,0,10,10,1
  delete bitmap 1

  `make the frame and its reflection out of boxes
  beam=free_object()
  make object box beam,30,0.5,0.5
  position object beam,0,25.75,-10
  beam=free_object()
  make object box beam,30,0.5,0.5
  position object beam,0,25.75,10
  beam=free_object()
  make object box beam,30,0.5,0.5
  position object beam,0,-25.75,-10
  beam=free_object()
  make object box beam,30,0.5,0.5
  position object beam,0,-25.75,10
  post=free_object()
  make object box post,0.5,26,0.5
  position object post,-15,13,-10
  post=free_object()
  make object box post,0.5,26,0.5
  position object post,15,13,-10
  post=free_object()
  make object box post,0.5,26,0.5
  position object post,-15,13,10
  post=free_object()
  make object box post,0.5,26,0.5
  position object post,15,13,10
  post=free_object()
  make object box post,0.5,26,0.5
  position object post,-15,-13,-10
  post=free_object()
  make object box post,0.5,26,0.5
  position object post,15,-13,-10
  post=free_object()
  make object box post,0.5,26,0.5
  position object post,-15,-13,10
  post=free_object()
  make object box post,0.5,26,0.5
  position object post,15,-13,10
  base=free_object()
  make object box base,0.5,0.5,20
  position object base,-15,0.25,0
  base=free_object()
  make object box base,0.5,0.5,20
  position object base,15,0.25,0

  `make some arrays
  dim pivot(5)
  dim ball(5)
  dim reflection(5)

  `repeat everything five times for five balls
  for n=1 to 5
    `the pivots, which are hidden, act as the point of rotation.
    `the wires and balls will be glued to the pivots, so that when
    `the pivots are rotated, the wires and balls move accordingly
    pivot(n)=free_object()
    make object cube pivot(n),1
    hide object pivot(n)
    position object pivot(n),5*(n-1)-10,26,0
    `first set of wires
    wire=free_object()
    make object box wire,0.1,20,0.1
    texture object wire,grey
    position object wire,0,-9,-5
    xrotate object wire,-30
    glue object to limb wire,pivot(n),0
    `second set of wires
    wire=free_object()
    make object box wire,0.1,20,0.1
    texture object wire,grey
    position object wire,0,-9,5
    xrotate object wire,30
    glue object to limb wire,pivot(n),0
    `balls
    ball(n)=free_object()
    make object sphere ball(n),5,30,30
    set sphere mapping on ball(n),reflection
    set object specular ball(n),-1
    set object specular power ball(n),100
    position object ball(n),0,-20,0
    glue object to limb ball(n),pivot(n),0
    `copy of each ball, for reflection
    reflection(n)=free_object()
    instance object reflection(n),ball(n)
  next n

endfunction

function move_cradle()

  if 0 `funny bit of code which allows you to globalise a variable from within a function
    global theta#
  endif

  `calculate the angle of the pendulum, which increases by a small amount, theta, each loop
  inc theta#,3
  angle#=30*sin(theta#)

  `if the angle is negative, apply it to the leftmost pendulum
  if angle#<0
    zrotate object pivot(1),angle#
    zrotate object pivot(5),0
  endif

  `if the angle is positive, apply it to the right most pendulum
  if angle#>=0
    zrotate object pivot(1),0
    zrotate object pivot(5),angle#
  endif

  `position the ball reflections at the same position as the ball, but with a negative
  `y-value.  Because the balls are glued to limbs, using 'object position' gives a relative
  `rather than an absolute amount - so we use limb position 0 instead.
  for n=1 to 5
    position object reflection(n),limb position x(ball(n),0),-limb position y(ball(n),0),limb position z(ball(n),0)
  next n
endfunction

function move_camera()

  `moves the camera in a circle
  camradius#=50

  if 0
    global camangle#
  endif

  inc camangle#,0.1

  camx#=camradius#*cos(camangle#)
  camz#=camradius#*sin(camangle#)
  camy#=50
  position camera camx#,camy#,camz#
  point camera 0,0,0

endfunction

`Entry - with added colours (but not flavours)

`initialise screen
set display mode 640,480,32
autocam off

`declare variable for camera angle

angle=225

`reset object number
a=1

`create board
make object cube 1601,100

`create pin
make object cylinder 65000,10
scale object 65000,100,2000,100
make object sphere 65001,20
make mesh from object 65001,65001
delete object 65001
add limb 65000,1,65001
offset limb 65000,1,0,5,0
scale limb 65000,1,100,5,100
make mesh from object 65002,65000
delete object 65000



`stretch board
scale object 1601,500,10,500

`position board
position object 1601,0,0,0

`create pins
For y = 1 to 40
For x = 1 to 40

`create object
Make object a,65002,0
`scale object a,100,2000,100

`position object
Position object a,(x*12)-240,(sin((9.0*x)+t#)+cos((9.0*y)+t#))*40.0,(y*12)-240

`increment object number
Inc a

Next x
Next y

zoom#=600

`main loop
Do

a=1

For y = 1 to 40
For x = 1 to 40

`reposition dependant on sine wave function and time
Position object a,(x*12)-240,(sin((9.0*x)+t#)+cos((9.0*y)+t#))*40.0,(y*12)-240
color object a,RGB(pulsate(255,0,10,t#),pulsate(255,0,10,t#+12+(10*SIN(x))),pulsate(255,0,10,t#+12+(10*COS(y))))
Inc a

Next x
Next y

`increment time
inc t#

ink 0xffffffff,0

set cursor 0,0
`display info
print "Pin Pression simulation by calcyman"
print "Press Left and right arrowkeys to rotate simulation"
print "Press Up and Down to zoom in/out"
print "polies: ";STATISTIC(1)




`position camera dependant on angle, and point towards centre of simulation
Position camera zoom#*SIN(angle),(zoom#*2.0)/3.0,zoom#*COS(angle)
point camera 0,0,0

`change angle dependant on user input
If leftkey()=1 then dec angle,5
If rightkey()=1 then inc angle,5
If upkey()=1 then dec zoom#,10
IF downkey()=1 then inc zoom#,10

`repeat loop

Loop

function pulsate(maximum as double float,minimum as double float,speed as double float, time as double float)

value as double float
value=((maximum+minimum)/2.0)+(((maximum-minimum)/2.0)*SIN(speed*time))

endfunction value

autocam off
position light 0,70,50,100

`Make the 5 main balls
for sph=1 to 5
   Make object sphere sph,2
   color object sph,rgb(150,150,160)
   set shadow shading on sph
next sph

`Make the strings
for scl=6 to 10
   Make object cylinder scl,1
   color object scl,rgb(40,40,40)
   scale object scl,10,1300,10
   xrotate object scl,30
next scl
for scl=11 to 15
   Make object cylinder scl,1
   color object scl,rgb(40,40,40)
   scale object scl,10,1300,10
   xrotate object scl,-30
next scl

`Make the frame
for bar=16 to 17
   Make object cylinder bar,1
   zrotate object bar,90
   scale object bar,60,1500,60
   color object bar,rgb(30,30,30)
next
for bar2=18 to 21
   Make object cylinder bar2,1
   scale object bar2,60,1200,60
   yrotate object bar2,90
   color object bar2,rgb(30,30,30)
next bar2

position object 18,-7.5,4.7,6
position object 19,-7.5,4.7,-6
position object 20,7.5,4.7,-6
position object 21,7.5,4.7,6
make mesh from object 10,18

position object 16,0,object position y(18)+(object size y(18)/2),6
position object 17,0,object position y(18)+(object size y(18)/2),-6

for c=26 to 29
   make object sphere c,object size x(18)
   color object c,rgb(30,30,30)
next c

position object 26,object position x(18),object position y(16),object position z(18)
position object 27,object position x(19),object position y(16),object position z(19)
position object 28,object position x(20),object position y(17),object position z(20)
position object 29,object position x(21),object position y(17),object position z(21)

`Add limb 16,1,11
`Add limb 16,2,11
`Offset limb 16,1,0,0,6
`Offset limb 16,1,0,0,-6
`link limb 16,0,1
`link limb 16,0,2

position object 6,-4,5,3
position object 7,-2,5,3
position object 8,0,5,3
position object 9,2,5,3
position object 10,4,5,3

position object 11,-4,5,-3
position object 12,-2,5,-3
position object 13,0,5,-3
position object 14,2,5,-3
position object 15,4,5,-3

position object 1,-4,0,0
position object 2,-2,0,0
position object 3,0,0,0
position object 4,2,0,0
position object 5,4,0,0

`Make the platform the thing stands on
Make object box 45,20,0.5,20
Make object box 46,18,0.5,18
position object 45,0,-2,0
position object 46,0,-1.5,0
color object 45,rgb(40,10,14)
color object 46,rgb(40,10,14)

`Make mesh from object 35,45

remstart
`Put the platform together
Add limb 46,1,35
Delete object 45
Link limb 46,0,1
scale limb 46,1,6,100,4
scale limb 46,0,100,100,70
Offset Limb 46,1,0,-0.5,0
color limb 46,0,rgb(20,5,7)
color limb 46,1,rgb(20,5,7)
position object 46,0,-1.5,0
`Add the corner poles
for c=2 to 5
   Add limb 46,c,10
   link limb 46,0,c
   scale limb 46,c,20,100,20
next
offset limb 46,2,-7.5,3.2,6
offset limb 46,2,-7.5,3.2,-6
offset limb 46,2,7.5,3.2,-6
offset limb 46,2,7.5,3.2,6
remend

position camera 30,10,-30
point camera 0,0,0
wait key

It was so difficult, I picked two:
Spopovich's Knick-knack - nice movement with plenty of camera control
calcyman's Pin Pression Adaptation - very mesmerising and calming motion.

Acelepage's Ball Machine - The ball and machine movement were very realistic.

sync on : sync rate 0
hide mouse

make object sphere 1, 5
set object cull 1, 0

type pos
    x# as float
    y# as float
    z# as float
endtype

`Store inital positions
lock vertexdata for limb 1, 0
    vd = get vertexdata index count()
    dim vd(vd) as pos
    for i = 0 to vd
        vd(i).x# = get vertexdata position x(i)
        vd(i).y# = get vertexdata position y(i)
        vd(i).z# = get vertexdata position z(i)
    next i
unlock vertexdata

`Vector
r = make vector3(1)

`Cursor
make object cube 2, 1
color object 2, rgb(255, 255, 255)

`constants
#constant g 0.5
#constant m1 2
#constant m2 2

dist# = 20.0
angley# = 180
anglex# = 45
position camera sin(angley#) * cos(anglex#) * dist#, sin(anglex#) * dist#, cos(angley#) * cos(anglex#) * dist#
point camera 0, 0, 0

do

    `Editing
    px# = object position x(2)
    py# = object position y(2)
    pz# = object position z(2)
    
    lock vertexdata for limb 1, 0
    for i = 0 to vd
            
        `Get initial vertex data
        vx# = vd(i).x#
        vy# = vd(i).y#
        vz# = vd(i).z#
            
        `Calculate gravity force
        set vector3 1, px# - vx#, py# - vy#, pz# - vz#
        l# = length vector3(1)
        grav# = g * (m1 * m2)/(l#^2)
        multiply vector3 1, grav#
        
        set vertexdata position i, vx# + x vector3(1), vy# + y vector3(1), vz# + z vector3(1)

    next i
    unlock vertexdata

    `Position cursor
    position object 2, px# + mousemovex()*0.01, py# - mousemovey()*0.01, pz# + mousemovez()*0.01

    if mouseclick() = 2
        repeat
            angley# = wrapvalue(angley# + mousemovex())
            anglex# = wrapvalue(anglex# + mousemovey())
            dist# = dist# + mousemovez() * 0.1
            position camera sin(angley#) * cos(anglex#) * dist#, sin(anglex#) * dist#, cos(angley#) * cos(anglex#) * dist#
            point camera 0, 0, 0
            sync
        until mouseclick() = 0
    endif

    sync
loop

REM Projekt: Morph_me
REM erstellt: 20.11.2007 14:33:54
REM
REM ***** Haupt-Quelldatei *****
REM

REM STANDARD SETUP
autocam off : sync on : sync rate 60 : sync sleep 0 : sync mask 0x0000000F : color backdrop rgb(0,0,128) : hide mouse
disable escapekey

global frame as byte : frame=1
up=1 : down=0 : speed=5 : size=1

rem w000t thats a long string, four lines in one and a crypted name XD
info$=" box circle morph by "+chr$(82)+chr$(101)+chr$(100)+chr$(70)+chr$(108)+chr$(97)+chr$(109)+chr$(101)+chr$(115)+chr$(10)+chr$(13)+"  left/right = modify speed"+chr$(10)+chr$(13)+"  up/down = modify size"+chr$(10)+chr$(13)+"  click to morph"

REM MAIN LOOP
do
cls

   gosub controls

   ink rgb(250,250,250),0
   set cursor 0,0
   print screen fps()
   print "   current frame: #";frame
   print "number of frames: ";max_frame
   print "    current size: ";size
   print "   current speed: ";speed
   ink rgb(123,177,255),0
   set cursor screen width()/4,5
   print info$

   REM CALL EXIT-FUNCTION ON ESC
   if escapekey() then esc()

   REM UPDATE
   sync
loop

controls:
   max_frame=draw_frame(mousex(),mousey(),size)
   if mouseclick() and clicktimer<=0
      if up then inc frame
      if down then dec frame
      clicktimer=speed
   endif
   dec clicktimer
   if up and frame=max_frame then up=0 : down=1
   if down and frame=1 then up=1 : down=0
   if sizetimer<=0 and (upkey() or downkey()) then inc size,upkey()-downkey() : sizetimer=10
   dec sizetimer
   if speedtimer<=0 and (leftkey() or rightkey()) then inc speed,leftkey()-rightkey() : speedtimer=10
   dec speedtimer
return


REM EXIT-FUNCTION
function esc()
   end
endfunction

function draw_frame(px,py,scale)
   restore morph
   while num<>frame*10
      read num
   endwhile
   while x<17 and y<17
      read x
      read y
      if x<17 and y<17
         dot x*scale+px,y*scale+py,rgb(255,255,255)
      endif
   endwhile
   num=11
endfunction num



morph:
data 10,1,4,1,5,2,3,2,6,3,2,3,7,4,1,4,8,5,1,5,8,6,2,6,7,7,3,7,6,8,4,8,5
data 20,1,4,1,5,2,3,2,6,3,2,3,7,4,1,4,8,5,1,5,8,6,2,6,7,7,3,7,6,8,4,8,5
data 30,1,4,1,5,2,2,2,3,2,6,3,1,3,7,4,1,4,8,5,1,5,8,6,2,6,8,7,3,7,6,7,7,8,4,8,5
data 40,1,4,1,5,2,2,2,3,2,6,2,7,3,1,3,8,4,1,4,8,5,1,5,8,6,1,6,8,7,2,7,3,7,6,7,7,8,4,8,5
data 50,1,3,1,4,1,5,2,2,2,6,2,7,3,1,3,8,4,1,4,8,5,1,5,8,6,1,6,8,7,2,7,3,7,7,8,4,8,5,8,6
data 60,1,3,1,4,1,5,1,6,2,2,2,7,3,1,3,8,4,1,4,8,5,1,5,8,6,1,6,8,7,2,7,7,8,3,8,4,8,5,8,6
data 70,1,3,1,4,1,5,1,6,1,7,2,2,2,8,3,1,3,8,4,1,4,8,5,1,5,8,6,1,6,8,7,1,7,7,8,2,8,3,8,4,8,5,8,6
data 80,1,2,1,3,1,4,1,5,1,6,1,7,2,1,2,8,3,1,3,8,4,1,4,8,5,1,5,8,6,1,6,8,7,1,7,8,8,2,8,3,8,4,8,5,8,6,8,7
data 90,1,2,1,3,1,4,1,5,1,6,1,7,2,1,2,8,3,1,3,8,4,1,4,8,5,1,5,8,6,1,6,8,7,1,7,8,8,2,8,3,8,4,8,5,8,6,8,7,1,1,8,8
data 100,1,2,1,3,1,4,1,5,1,6,1,7,2,1,2,8,3,1,3,8,4,1,4,8,5,1,5,8,6,1,6,8,7,1,7,8,8,2,8,3,8,4,8,5,8,6,8,7,8,1,1,8,1,1,8,8
data 110,1,2,1,3,1,4,1,5,1,6,1,7,2,1,2,8,3,1,3,8,4,1,4,8,5,1,5,8,6,1,6,8,7,1,7,8,8,2,8,3,8,4,8,5,8,6,8,7,8,1,1,8,1,1,8,8
data 120

sync on : sync rate 50

`Constants
#constant sph 1
#constant cub 2

#constant s 2.5

`Types
type pos
    x# as float
    y# as float
    z# as float
endtype

`Make the object
make object sphere 1, 2*s, 24, 24
set object wireframe 1, 1
set object cull 1, 0

`Get number of verteces and store it in an array
global vd as integer
lock vertexdata for limb 1, 0
    vd = get vertexdata index count()
    dim vert(vd) as pos
    for v = 0 to vd
        vert(v).x# = get vertexdata position x(v)
        vert(v).y# = get vertexdata position y(v)
        vert(v).z# = get vertexdata position z(v)
    next v
unlock vertexdata

`Distance vector
r = make vector3(1)

`Global
global t as integer
t = sph
do

    `Toggle
    if upkey() = 1 and hold = 0
        hold = 1
        inc t
    endif
    if downkey() = 1 and hold = 0
        hold = 1
        dec t
    endif
    if downkey() + upkey() = 0 then hold = 0

    `Change type
    if t = sph
    
        `Edit to a sphere
        lock vertexdata for limb 1, 0
        
            `Run through all verteces
            for v = 0 to vd
            
                `Get vertex data
                vx# = get vertexdata position x(v)
                vy# = get vertexdata position y(v)
                vz# = get vertexdata position z(v)
                
                `Get target values
                tx# = vert(v).x#
                ty# = vert(v).y#
                tz# = vert(v).z#
            
                `Get distance to position
                set vector3 1, tx# - vx#, ty# - vy#, tz# - vz#
                d# = length vector3(1)
            
                `Change to new vertex data
                multiply vector3 1, 0.5
                set vertexdata position v, vx# + x vector3(1), vy# + y vector3(1), vz# + z vector3(1)
            
            next v
        unlock vertexdata
    endif
    if t = cub
    
        `Edit to a cube
        lock vertexdata for limb 1, 0
        
            `Run through all verteces
            for v = 0 to vd
            
                `Get vertex data
                vx# = get vertexdata position x(v)
                vy# = get vertexdata position y(v)
                vz# = get vertexdata position z(v)
            
                `Get origin data
                ox# = vert(v).x#
                oy# = vert(v).y#
                oz# = vert(v).z#
                
                `Based on the origin data from in the sphere, assign target position
                set vector3 1, ox#, oy#, oz#
                if ox# <> 0.0
                    multiply vector3 1, s / ab(ox#)
                    if ab(y vector3(1)) > s
                        set vector3 1, ox#, oy#, oz#
                        multiply vector3 1, s / ab(oy#)
                        if ab(z vector3(1)) > s
                            set vector3 1, ox#, oy#, oz#
                            multiply vector3 1, s / ab(oz#)
                        endif
                    else
                        if ab(z vector3(1)) > s
                            set vector3 1, ox#, oy#, oz#
                            multiply vector3 1, s / ab(oz#)
                        endif
                    endif
                else
                    multiply vector3 1, s / ab(oy#)
                    if ab(z vector3(1)) > s
                        set vector3 1, ox#, oy#, oz#
                        multiply vector3 1, s / ab(oz#)
                    endif
                endif
                tx# = x vector3(1)
                ty# = y vector3(1)
                tz# = z vector3(1)
                
                `scale vector
                set vector3 1, tx# - vx#, ty# - vy#, tz# - vz#
                multiply vector3 1, 0.5
                
                `position
                set vertexdata position v, vx# + x vector3(1), vy# + y vector3(1), vz# + z vector3(1)
            
            next v
        unlock vertexdata
    endif

    `Position camera
    angle# = wrapvalue(angle# + rightkey() - leftkey())
    position camera cos(angle#)*10, 10, sin(angle#) * 10
    point camera 0, 0, 0

    sync
loop

function ab(nr#)
    if nr# < 0 then exitfunction -nr#
endfunction nr#