Sorry your browser is not supported!

`Global rotation functions by Lower Logic

set display mode 1024,768,32
sync on
sync rate 60
autocam off
hide mouse
color backdrop 0
position camera 0,20,-100

`make textures
create bitmap 99,256,256
ink rgb(140,0,0),0
box 0,0,128,128
box 128,128,256,256
ink rgb(200,210,220),0
box 0,128,128,256
box 128,0,256,128
ink rgb(0,0,0),0
for x=126 to 130
line x,0,x,256
line 0,x,256,x
next x
for x=0 to 2
line x,0,x,256
line 0,x,256,x
next x
for x=254 to 256
line x,0,x,256
line 0,x,256,x
next x
get image 99,0,0,256,256,1
delete bitmap 99
create bitmap 1,256,256
ink rgb(140,0,0),0
box 0,0,128,128
box 128,128,256,256
ink rgb(200,210,220),0
box 0,128,128,256
box 128,0,256,128
ink rgb(0,0,0),0
x=128
line x,0,x,256
line 0,x,256,x
x=0
line x,0,x,256
line 0,x,256,x
x=256
line x,0,x,256
line 0,x,256,x
get image 1,0,0,256,256,1
delete bitmap 1

`make ball
make object sphere 99,5,32,32
texture object 99,99
set object specular 99,rgb(230,210,200)
set object specular power 99,50
set object emissive 99,rgb(0,0,10)
set object ambient 99,1
set object collision off 99
set object filter 99,0
disable object zread 99

`shadow
make object sphere 2,5,32,32
scale object 2,130,0.01,130
yrotate object 2,90
fix object pivot 2
color object 2,0
ghost object on 2,1
set object ambient 2,1
set object emissive 2,rgb(0,0,0)
set object specular 2,rgb(0,0,0)
set object specular power 2,100
set object collision off 2

`ground
   `ice
make object plain 3,100,100
pitch object down 3,-90
color object 3,rgb(0,0,0)
set reflection shading on 3
position object 3,0,7.5,50.0
set object transparency 3,5
 `normal
make object plain 6,100,100
pitch object down 6,-90
texture object 6,1
scale object texture 6,0.999,0.999
position object 6,0,0,-50.0
set object specular 6,rgb(230,210,200)
set object specular power 6,50
set object emissive 6,rgb(0,0,10)
set object filter 6,0

`walls
   `north
make object plain 8,100,7.5/2
texture object 8,1
scale object texture 8,1,0.5
position object 8,0,7.5/4,0
set object specular 8,rgb(230,210,200)
set object specular power 8,50
set object emissive 8,rgb(0,0,10)
set object filter 8,0

make object plain 9,100,7.5/2
texture object 9,1
scale object texture 9,-1,0.5
position object 9,0,(7.5/4)*3,0
set object specular 9,rgb(230,210,200)
set object specular power 9,50
set object emissive 9,rgb(0,0,10)
set object filter 9,0
set object collision off 9

make object plain 25,100,7.5
texture object 25,1
scale object texture 25,0.5,1
position object 25,0,10.0,100.0
set object specular 25,rgb(230,210,200)
set object specular power 25,50
set object emissive 25,rgb(0,0,10)
set object filter 25,0
   `south
make object plain 26,100,7.5
texture object 26,1
scale object texture 26,-0.5,-1
position object 26,0,7.5/2,-100.0
set object specular 26,rgb(230,210,200)
set object specular power 26,50
set object emissive 26,rgb(0,0,10)
set object filter 26,0



`jump-pads
make object sphere 11,5,12,12
scale object 11,150,10,150
position object 11,0,7.52,8.0
make object sphere 12,5,12,12
scale object 12,150,10,150
position object 12,-8.0,0.02,-8.0
make object sphere 13,5,12,12
scale object 13,150,10,150
position object 13,8.0,0.02,-8.0

`comic-outline
make object sphere 4,5.2,32,32
color object 4,rgb(0,0,0)
set object ambient 4,0
set object collision off 4

`light
make light 1
color light 1,rgb(255,255,255)
position light 1,5,100,5
set light range 1,200

c_f=10
`background
cls : backdrop off
for x=0 to 32
ink rgb(111-x*c_f,222-x*c_f,255-x*c_f),0
line x,0,x,64
next x
for x=32 to 0 step -1
ink rgb(111-x*c_f,222-x*c_f,255-x*c_f),0
line abs(32-x)+32,0,abs(32-x)+32,64
next x
get image 5,0,0,64,64,4
backdrop on
make object sphere 5,8
scale object 5,4000,4000,4000 : texture object 5,5
scale object texture 5,4,4 : position object 5,0,0,0
`set object 5,1,0,0,0,1,0,1
set object cull 5,0
set object filter 5,0
set object specular 5,rgb(155,205,255)
set object specular power 5,100
set object emissive 5,rgb(10,30,50)
set object collision off 5

`collision ball
make object sphere 7,5.1,32,32
hide object 7
scale object 7,50,100,50



v#=0.01
vr#=0.1
xm#=0.0
zm#=0.0

camd#=30.0
camh#=20.0
cama#=180.0

one=1

r=1 : b=1 : g=1

dim texts$(13)
texts$(1)=" "
texts$(2)=" Use the Arrowkeys to move the Ball"
texts$(3)=" "
texts$(4)=" left-click for free view"
texts$(5)=" "
texts$(6)=" Use the Mousewheel to zoom"
texts$(7)=" "
texts$(8)=" Use Space to reset the ball"
texts$(9)=" "
texts$(10)="left & right mousebutton to change zoom"
texts$(11)=" "
texts$(12)=" Thanks to Lower Logic and Ric"

textx=25
set text font "Lucida Console"
set text size 16
set text to bold

do
remstart
ink rgb(200,210,220),0
set cursor 0,0
print "xm#=";xm#
print "zm#=";zm#
remend
oldx#=x#
oldy#=y#
oldz#=z#

ang#=360*(vr#^2)/2.5

`rotate for wall collision
zrotate object 7,object angle z(7)+90

`inc/dec speed depending on keys (e.g. v#*0=0 / v#*1=v# )
inc xm#,v#*rightkey()
dec xm#,v#*leftkey()
`north wall collision
if object collision(7,0)<>8 and object collision(7,0)<>25 then inc zm#,v#*upkey()
if object collision(7,0)<>26 then dec zm#,v#*downkey()

`wall collision north
if object collision(7,0)=8 or object collision(7,0)=25
   if abs(zm#)<0.05
      dec z#,zm#/10.0
   else
      zm#=zm#*-0.75
   endif
endif

`wall collision south
if object collision(7,0)=26
   if abs(zm#)<0.05
      inc z#,zm#/10.0
   else
      zm#=zm#*-0.75
   endif
endif

`rotate back
zrotate object 7,object angle z(7)-90

`if moving then rotate ball depending on speed
if xm#>0.0 then rotate_gz(99,-ang#*(xm#*10.0))
if xm#<0.0 then rotate_gz(99,ang#*abs(xm#*10.0))
if zm#>0.0 then rotate_gx(99,ang#*(zm#*10.0))
if zm#<0.0 then rotate_gx(99,-ang#*abs(zm#*10.0))


`check different grounds and set resistance factor
`               object   3  =  icy/metal ground
if object collision(4,0)=3
   d#=1.0
else
`                  object   6  =  standard ground
   if object collision(4,0)=6
      d#=5.0
   else
      d#=8.0
   endif
endif

`set ground resistance depending on speed
f#=((xm#*xm#)*100.0+(zm#*zm#)*100.0)/5.0
if f#<d# then f#=d#
f#=10.0-f#
`print f#
`f#=5.0

`decrease speed depending on speed
if xm#<0.0 then inc xm#,v#/f#
if xm#>0.0 then dec xm#,v#/f#
if zm#<0.0 then inc zm#,v#/f#
if zm#>0.0 then dec zm#,v#/f#

`gravity and ground collision
if object collision(7,0)=0
   if jump=0
      y#=y#-0.5
   endif
else
   if object collision(7,0)<>8 and object collision(7,0)<>25 and object collision(7,0)<>26
      y#=object size z(object collision(7,0))/2.0+object position y(object collision(7,0))+2.5
   endif
endif

`jump-pads
if object collision(7,0)>10 and object collision(7,0)<>25 and object collision(7,0)<>26
jump=30
endif

if jump>0 then y#=y#+0.5 : jump=jump-1

`stop if low speed
if abs(xm#)<0.002 then xm#=0.0
if abs(zm#)<0.002 then zm#=0.0

`add movements to position
x#=x#+xm#
z#=z#+zm#

`reset
if spacekey() and time=0 or one then x#=0.0 : y#=15.0 :  z#=50.0 : rotate object 99,rnd(360),rnd(360),rnd(360) : text 50,50,str$( mouseclick()) : one=0 : time=20

`re-position objects
position object 99,x#,y#,z#
position object 4,x#,y#,z#
`position shadow correct
if object collision(7,0)>0 and object collision(7,0)<>8 and object collision(7,0)<>25 and object collision(7,0)<>26
   sy#=object size z(object collision(7,0))/2.0+object position y(object collision(7,0))
else
   if sy#=0 or sy#=0.0
      for for#=1.0 to 100.0
         position object 2,x#,object position y(2)-for#/10.0,z#
         if object collision(2,0)>0 then sy#=for#/10.0 : exit
      next for#
   endif
endif
`fix if falling
if sy#>y#-2.5 then sy#=y#-2.51
position object 2,x#,sy#+0.01,z#
position object 7,x#,y#,z#

`color jumpers
if object collision(7,0)>10 and object collision(7,0)<14 then ru=1 : gu=1 : bu=1 : r=0 : g=0 : b=255
for x=1 to 2
if ru=1 then inc r : if gu=1 then inc g : if bu<1 then inc b
`if ru=0 then dec r : if gu=0 then dec g : if bu<0 then dec b
if r=255 then ru=0 : if g=255 then gu=0 : if b=255 then bu=0
if r=0 then ru=1   : if g=0 then gu=1   : if b=0 then bu=1
next x

for x=11 to 13
if object collision(7,0)=x
   change=x
endif
if change=x
   color object x,rgb(r,g,b)
else
   color object x,rgb(255,255,255)
endif
next x

`if mousebutton 2 pressed -> free cam
if mouseclick()=2
cama#=cama#+mousemovex()/20.0
`if camh#>object position y(1)
   camh#=curvevalue(camh#+mousemovey()/10.0,camh#,10)
`endif
`print camh#
else
cama#=180.0
camh#=20.0
endif
camd#=abs(camd#-mousemovez()/100.0)
if mouseclick()=4 and time<=0
if camd#<>15.0
camd#=15.0
time=50
else
 camd#=30.0 : time=50
 endif
endif

`set cam
chase_cam(0,99,camd#,camh#+y#,cama#)

`rotate bg-sphere
rotate object 5,object angle x(5)+0.1,object angle y(5)+0.1,object angle z(5)+0.1

gosub interface
text 100,500,str$(object collision(7,0))+" "+str$(object size y(7))

if time>0 then dec time

sync
loop



remstart Rotate_GX
   This function rotates the given object around the global (world) x axis by
   the given amount.
   Param    obj      The object to rotate
   Param    amount#  The angle to rotate the object by
remend

function rotate_GX(obj as integer,amount# as float)
   rem get normal vectors for X, Y, and Z axes of the object
   x#=object position x(obj):y#=object position y(obj):z#=object position z(obj)
   move object right obj,1
   xx#=object position x(obj)-x#:xy#=object position y(obj)-y#:xz#=object position z(obj)-z#
   move object left obj,1:move object up obj,1
   yx#=object position x(obj)-x#:yy#=object position y(obj)-y#:yz#=object position z(obj)-z#
   move object down obj,1:move object obj,1
   zx#=object position x(obj)-x#:zy#=object position y(obj)-y#:zz#=object position z(obj)-z#
   move object obj,-1
   rem rotate the vectors
   xx1#=xx#
   xy1#=xy#*cos(amount#)-xz#*sin(amount#)
   xz1#=xz#*cos(amount#)+xy#*sin(amount#)
   zx1#=zx#
   zy1#=zy#*cos(amount#)-zz#*sin(amount#)
   zz1#=zz#*cos(amount#)+zy#*sin(amount#)
   rem calculate angle z
   zr#=atanfull(xy1#,xx1#)
   rem calculate angle y
   xx2#=xx1#*cos(zr#)+xy1#*sin(zr#)
   xy2#=xy1#*cos(zr#)-xx1#*sin(zr#)
   xz2#=xz1#
   zx2#=zx1#*cos(zr#)+zy1#*sin(zr#)
   zy2#=zy1#*cos(zr#)-zx1#*sin(zr#)
   zz2#=zz1#
   yr#=atanfull(xx2#,xz2#)-90
   rem calculate angle x
   zx3#=zx2#*cos(yr#+90)-zz2#*sin(yr#+90)
   zy3#=zy2#
   xr#=atanfull(zy3#,zx3#)+180
   if xr#+1>xr# and yr#+1>yr# and zr#+1>zr#
      rotate object obj,xr#,yr#,zr#
   endif
endfunction


remstart Rotate_GZ
   This function rotates the given object around the global (world) z axis by
   the given amount.
   Param    obj      The object to rotate
   Param    amount#  The angle to rotate the object by
remend
function rotate_GZ(obj,amount#)
   rem Rotating around the global Z axis is trivial
   rem as it is the first rotation anyway in the default ZYX rotation order
   rotate object obj,object angle x(obj),object angle y(obj),object angle z(obj)+amount#
endfunction


function chase_cam(CamNum#,id,camDist,Height#,yAng#)

   `grab the cameras current position
   xPos#=object position x(id)
   yPos#=object position y(id)
   zPos#=object position z(id)

   `work out new position
   xCamPos#=newxvalue(xPos#,yAng#,camDist)
   zCamPos#=newzvalue(zPos#,yAng#,camDist)

   `work out camera height
   yCamPos#=Height#
   if Height#<yPos# then yCamPos#=yPos#

   s=20
   xCamPos#=curvevalue(xCamPos#,camera position x(CamNum#),s)
   yCamPos#=curvevalue(yCamPos#,camera position y(CamNum#),s)
   zCamPos#=curvevalue(zCamPos#,camera position z(CamNum#),s)

   `update camera position
   position camera CamNum#,xCamPos#,yCamPos#,zCamPos#
   point camera CamNum#,xPos#,yPos#,zPos#

endfunction


interface:

   texts$(0)="FPS: "+str$(screen fps())
   for x=0 to array count(texts$(0))
      shadow_text(textx,x*10,texts$(x),rgb(200,210,220))
   next x

return

function shadow_text(x#,y#,text$,color)
ink rgb(10,20,30),0
text x#+1,y#+1,text$
ink color,0
text x#,y#,text$
endfunction

`Global rotation functions by Lower Logic

set display mode 1024,768,32
sync on
sync rate 60
autocam off
hide mouse
fog off
position camera 0,25.0,20.0

`make textures
create bitmap 99,256,256
ink rgb(140,100,0),0
box 0,0,128,128
box 128,128,256,256
ink rgb(220,210,200),0
box 0,128,128,256
box 128,0,256,128
ink rgb(0,0,0),0
for x=126 to 130
line x,0,x,256
line 0,x,256,x
next x
for x=0 to 2
line x,0,x,256
line 0,x,256,x
next x
for x=254 to 256
line x,0,x,256
line 0,x,256,x
next x
get image 99,0,0,256,256,1
delete bitmap 99
create bitmap 1,256,256
ink rgb(20,80,140),0
box 0,0,128,128
box 128,128,256,256
ink rgb(200,210,220),0
box 0,128,128,256
box 128,0,256,128
ink rgb(0,0,0),0
x=128
line x,0,x,256
line 0,x,256,x
x=0
line x,0,x,256
line 0,x,256,x
x=256
line x,0,x,256
line 0,x,256,x
get image 1,0,0,256,256,1
delete bitmap 1

`make ball
make object sphere 99,5,64,64
texture object 99,99
set object specular 99,rgb(250,240,200)
set object specular power 99,25
set object emissive 99,rgb(30,20,0)
set object ambient 99,1
set object collision off 99
set object filter 99,0

`shadow
make object sphere 2,5,32,32
scale object 2,130,0.01,130
yrotate object 2,90
fix object pivot 2
color object 2,0
ghost object on 2,1
set object ambient 2,1
set object emissive 2,rgb(0,0,0)
set object specular 2,rgb(0,0,0)
set object specular power 2,100
set object collision off 2

`ground
   `ice
make object plain 3,100,100
pitch object down 3,-90
color object 3,rgb(0,0,0)
set reflection shading on 3
position object 3,0,7.5,50.0
set object transparency 3,5

 `normal
make object plain 6,100,100
pitch object down 6,-90
texture object 6,1
scale object texture 6,0.999,0.999
position object 6,0,0,-50.0
set object specular 6,rgb(230,210,200)
set object specular power 6,50
set object emissive 6,rgb(0,0,10)
set object filter 6,0

make object plain 45,100,100
position object 45,-100.0,-7.5,-50.0

make object plain 46,100,100
position object 46,-100.0,-17.5,-150.0

make object plain 47,100,5
position object 47,0.0,-17.5,-150.0

make object plain 48,5,50
position object 48,47.5,-17.5,-150.0-27.5

make object plain 49,25,50
position object 49,50.0,-10.0,-175.0-50.0/2.0-50.0

make object plain 50,25,50
position object 50,50.0,-10.0,-175.0-50.0/2.0-120.0

make object plain 51,50,25
position object 51,50.0,-20.0,-370.0

for x=45 to 51
pitch object down x,-90
texture object x,1
set object specular x,rgb(230,210,200)
set object specular power x,50
set object emissive x,rgb(0,0,10)
set object filter x,0
next x

`walls
   `north
make object plain 8,100,7.5/2
texture object 8,1
scale object texture 8,1,0.5
position object 8,0,7.5/4,0
set object specular 8,rgb(230,210,200)
set object specular power 8,50
set object emissive 8,rgb(0,0,10)
set object filter 8,0

make object plain 9,100,7.5/2
texture object 9,1
scale object texture 9,-1,0.5
position object 9,0,(7.5/4)*3,0
set object specular 9,rgb(230,210,200)
set object specular power 9,50
set object emissive 9,rgb(0,0,10)
set object filter 9,0
set object collision off 9

make object plain 25,100,7.5
texture object 25,1
scale object texture 25,0.5,1
position object 25,0,7.5*1.5,100.0

make object plain 29,100,7.5
texture object 29,1
scale object texture 29,-0.5,1
position object 29,-100.0,7.5/-2,0



   `test
make object plain 30,100,25
texture object 30,1
xrotate object 30,-53.0
scale object texture 30,1,-1
position object 30,-100.0,-15.0,-110.0

   `south
make object plain 26,100,7.5
texture object 26,1
scale object texture 26,-0.5,-1
position object 26,0,7.5/2,-100.0

make object plain 31,50,7.5
texture object 31,1
position object 31,50.0,-20.0+7.5/2.0,-382.5

   `east
make object plain 27,100,7.5
yrotate object 27,90
texture object 27,1
scale object texture 27,0.5,1
position object 27,-50.0,7.5/-2,-50.0

make object plain 32,25.0,7.5
yrotate object 32,90
texture object 32,1
position object 32,75.0,-20.0+7.5/2.0,-370.0

   `west
make object plain 28,100,7.5
yrotate object 28,90
texture object 28,1
scale object texture 28,0.5,-1
position object 28,-150.0,7.5/-2,-50.0


for x=25 to 30
set object specular x,rgb(230,210,200)
set object specular power x,50
set object emissive x,rgb(0,0,10)
set object filter x,0
enable object zwrite x
enable object zread x
next x



`jump-pads
make object sphere 11,5,12,12
scale object 11,150,10,150
position object 11,0,7.52,8.0

make object sphere 12,5,12,12
scale object 12,150,10,150
position object 12,-8.0,0.02,-8.0

make object sphere 13,5,12,12
scale object 13,150,10,150
position object 13,8.0,0.02,-8.0

make object sphere 14,5,12,12
scale object 14,150,10,150
position object 14,-58.0,-7.48,-50.0

make object sphere 15,5,12,12
scale object 15,150,10,150
position object 15,-95.0,-7.48,-95.0

make object sphere 16,5,12,12
scale object 16,150,10,150
`position object 16,-100.0,-17.48,-110.0
position object 16,50.0,-17.5,-282.0

make object sphere 17,5,12,12
scale object 17,150,10,150
position object 17,47.5,-17.5,-207.0

make object sphere 18,5,12,12
scale object 18,150,10,150
position object 18,55.0,-17.5,-282.0

make object sphere 19,5,12,12
scale object 19,150,10,150
position object 19,45.0,-17.5,-282.0

`comic-outline
make object sphere 4,5.2,32,32
scale object 4,-100,-100,-100
color object 4,rgb(0,0,0)
set object ambient 4,0
set object collision off 4

`light
make light 1
color light 1,rgb(255,255,255)
position light 1,5,100,5
set light range 1,200

c_f=10
`background
cls : backdrop off
for x=0 to 32
ink rgb(111-x*c_f,222-x*c_f,255-x*c_f),0
line x,0,x,64
next x
for x=32 to 0 step -1
ink rgb(111-x*c_f,222-x*c_f,255-x*c_f),0
line abs(32-x)+32,0,abs(32-x)+32,64
next x
get image 5,0,0,64,64,4
backdrop on
make object sphere 5,10,32,32
scale object 5,8000,8000,8000 : texture object 5,5
scale object texture 5,4,4 : position object 5,-25,-5,-55
`set object 5,1,0,0,0,1,0,1
set object cull 5,0
set object filter 5,0
set object specular 5,rgb(155,205,255)
set object specular power 5,100
set object emissive 5,rgb(10,30,50)
set object collision off 5

`collision ball
make object sphere 7,5.1,32,32
hide object 7
scale object 7,50,100,50



state_50=1
start_50=object position z(50)

v#=0.01
vr#=0.1
xm#=0.0
zm#=0.0

camd#=30.0
camh#=20.0
cama#=180.0
cama_offset#=10.0

one=1
res_x#=0.0
res_y#=20.0
res_z#=50.0

r=1 : b=1 : g=1

dim texts$(13)
texts$(1)=" "
texts$(2)="Move Ball with Arrowkeys."
texts$(3)=" "
texts$(4)="Rotate Cam with left-/rightclick"
texts$(5)=" "
texts$(6)="Zoom with mousewheel"
texts$(7)=" "
texts$(8)="Change Zoom with Button 3 (mousewheel)"
texts$(9)=" "
texts$(10)=" "
texts$(11)=" "
texts$(12)="Thanks to Lower Logic (global ball rotation) and Ric (setting up rotation functions)"

textx=25
set text font "Lucida console"
set text size 14
set text to bold

up as boolean
down as boolean
left as boolean
right as boolean

sync rate 60

do

gosub move_platforms

remstart
ink rgb(200,210,220),0
set cursor 0,0
print "xm#=";xm#
print "zm#=";zm#
remend
oldx#=x#
oldy#=y#
oldz#=z#

if cama#=0.0
   up=downkey() or joystick down()
   down=upkey() or joystick up()
   left=rightkey() or joystick right()
   right=leftkey() or joystick left()
endif
if cama#=270.0
   up=leftkey() or joystick left()
   down=rightkey() or joystick right()
   left=downkey() or joystick down()
   right=upkey() or joystick up()
endif
if cama#=180.0
   up=upkey() or joystick up()
   down=downkey() or joystick down()
   left=leftkey() or joystick left()
   right=rightkey() or joystick right()
endif
if cama#=90.0
   up=rightkey() or joystick right()
   down=leftkey() or joystick left()
   left=upkey() or joystick up()
   right=downkey() or joystick down()
endif

ang#=360*(vr#^2)/2.5

`rotate for e/w-wall collision
zrotate object 7,object angle z(7)-90

`inc/dec speed depending on keys (e.g. v#*0=0 / v#*1=v# ) and collision
`east wall collision
if object collision(7,0)<>27 and object collision(7,0)<>32 then inc xm#,v#*right
if object collision(7,0)<>28 then dec xm#,v#*left

`wall collision east
if object collision(7,0)=27 or object collision(7,0)=32
   if abs(xm#)<0.045
      dec x#,abs(xm#)/10.0
   else
      xm#=xm#*-0.75
   endif
   if xm#>0.002 then dec xm#,xm#/10.0
endif

`wall collision west
if object collision(7,0)=28
   if abs(xm#)<0.045
      dec x#,abs(xm#)/10.0
   else
      xm#=xm#*-0.75
   endif
   if xm#<-0.002 then inc xm#,xm#/10.0
endif

`stop if low speed
if abs(xm#)<0.002 then xm#=0.0

`rotate back
zrotate object 7,object angle z(7)+90

`rotate for n/s-wall collision
xrotate object 7,object angle x(7)+90
`north wall collision
if object collision(7,0)<>8 and object collision(7,0)<>25 and object collision(7,0)<>29 then inc zm#,v#*up
`south wall collision
if object collision(7,0)<>26 and object collision(7,0)<>31 then dec zm#,v#*down

`wall collision north
if object collision(7,0)=8 or object collision(7,0)=25 or object collision(7,0)=29
   if abs(zm#)<0.05
      dec z#,abs(zm#)/10.0
   else
      zm#=zm#*-0.75
   endif
   if zm#>0.002 then dec zm#,zm#/10.0
endif

`wall collision south
if object collision(7,0)=26 or object collision(7,0)=31
   if abs(zm#)<0.05
      inc z#,abs(zm#)/10.0
   else
      zm#=zm#*-0.75
   endif
   if zm#<-0.002 then inc zm#,zm#/10.0
endif

`stop if low speed
if abs(zm#)<0.002 then zm#=0.0

`rotate back
xrotate object 7,object angle x(7)-90

`if moving then rotate ball depending on speed
if xm#>0.0 then rotate_gz(99,-ang#*(xm#*10.0))
if xm#<0.0 then rotate_gz(99,ang#*abs(xm#*10.0))
if zm#>0.0 then rotate_gx(99,ang#*(zm#*10.0))
if zm#<0.0 then rotate_gx(99,-ang#*abs(zm#*10.0))


`reset
if y#<-25.0 and time=0 then one=1: time=20
if one then x#=res_x# : y#=res_y# :  z#=res_z# : text 50,50,str$( mouseclick()) : one=0 : rotate object 99,rnd(360),rnd(360),rnd(360) : xm#=0.0 : zm#=0.0
if x#>-50.0 and z#<-145.0 and res_x#=0.0 and res_y#=20.0 and res_z#=50.0 then checktime=500 : res_x#=-50.0 : res_y#=10.0 : res_z#=-150.0

if checktime>0 then shadow_text(screen width()/2,screen height()/2+500-checktime,"Checkpoint",rgb(150,255,180),1) : dec checktime

`check different grounds and set resistance factor
`               object   3  =  icy/metal ground
if object collision(7,0)=3
   d#=6.0
else
   d#=2.0
   if object collision(7,0)=47 or object collision(7,0)=48 or object collision(7,0)=50 then d#=7.0
endif

`set ground resistance depending on speed
f#=((xm#*xm#)*100.0+(zm#*zm#)*100.0)/5.0
if f#<d# then f#=d#
f#=10.0-f#
`print f#
`f#=5.0

`decrease speed depending on speed
if xm#<0.0 then inc xm#,v#/f#
if xm#>0.0 then dec xm#,v#/f#
if zm#<0.0 then inc zm#,v#/f#
if zm#>0.0 then dec zm#,v#/f#

`gravity and ground collision
if object collision(7,0)=0
   if jump=0
      y#=y#-0.5
   endif
else
   if object collision(7,0)<>8
      if object collision(7,0)<25 or object collision(7,0)>46
         y#=object size z(object collision(7,0))/2.0+object position y(object collision(7,0))+2.5
      endif
   endif
endif

`add movements to position
x#=x#+xm#
z#=z#+zm#

`re-position objects
position object 99,x#,y#,z#
position object 4,x#,y#,z#
`position shadow correct
if object collision(7,0)>0 and object collision(7,0)<>8
   if object collision(7,0)>25 or object collision(7,0)<11
      sy#=object size z(object collision(7,0))/2.0+object position y(object collision(7,0)+0.005)
   else
      if sy#=0 or sy#=0.0
         for for#=1.0 to 100.0
            position object 2,x#,object position y(2)-for#/10.0,z#
            if object collision(2,0)>0 then sy#=for#/10.0 : exit
         next for#
      endif
   endif
endif
`fix if falling
if sy#>y#-2.5 then sy#=y#-2.49
position object 2,x#,sy#+0.01,z#
position object 7,x#,y#,z#
scale object 2,100.0+(sy#-y#)*5.0+32.5,0.03,100.0+(sy#-y#)*5.0+32.5
if object collision(7,0)>0
   rotate object 2,object angle x(object collision(7,0)),0,object angle z(object collision(7,0))
else
   rotate object 2,0,0,0
endif

`fix jumpers
set object collision off 45
set object collision off 46

`roll up ramp
if object collision(7,0)=30 then y#=y#+.5 : zm#=zm#-.02

`jump-pads jumping
if object collision(7,0)>10 and object collision(7,0)<25
jump=30
y#=y#+0.05
endif
text 100,500,str$(object collision(7,0))+" "+str$(object visible(99))+" "+str$(object position z(30))

if jump>0 then y#=y#+jump/15 : jump=jump-1


`color jumpers
if object collision(7,0)>10 and object collision(7,0)<20 then ru=1 : gu=1 : bu=1 : r=0 : g=0 : b=255
for x=1 to 2
if ru=1 then inc r : if gu=1 then inc g : if bu<1 then inc b
`if ru=0 then dec r : if gu=0 then dec g : if bu<0 then dec b
if r=255 then ru=0 : if g=255 then gu=0 : if b=255 then bu=0
if r=0 then ru=1   : if g=0 then gu=1   : if b=0 then bu=1
next x

for x=11 to 19
if object collision(7,0)=x
   change=x
endif
if change=x
   color object x,rgb(r,g,b)
else
   color object x,rgb(255,255,255)
endif
next x


`fix jumpers
set object collision on 45
set object collision on 46

`if mousebutton 2 pressed -> rotate cam
if mouseclick()=2 and time2<=0 then cama#=wrapvalue(cama#-90) : time2=60
if mouseclick()=1 and time2<=0 then cama#=wrapvalue(cama#+90) : time2=60

camd#=abs(camd#-mousemovez()/100.0)
if mouseclick()=4 and time<=0
if camd#<>15.0
camd#=15.0
time=50
else
 camd#=30.0 : time=50
 endif
endif

`set cam
chase_cam(0,99,camd#,camh#+y#,cama#+cama_offset#)

`rotate bg-sphere
rotate object 5,object angle x(5)+0.1,object angle y(5)+0.1,object angle z(5)+0.1

gosub interface

if time>0 then dec time
if time2>0 then dec time2

sync
loop



remstart Rotate_GX
   This function rotates the given object around the global (world) x axis by
   the given amount.
   Param    obj      The object to rotate
   Param    amount#  The angle to rotate the object by
remend

function rotate_GX(obj as integer,amount# as float)
   rem get normal vectors for X, Y, and Z axes of the object
   x#=object position x(obj):y#=object position y(obj):z#=object position z(obj)
   move object right obj,1
   xx#=object position x(obj)-x#:xy#=object position y(obj)-y#:xz#=object position z(obj)-z#
   move object left obj,1:move object up obj,1
   yx#=object position x(obj)-x#:yy#=object position y(obj)-y#:yz#=object position z(obj)-z#
   move object down obj,1:move object obj,1
   zx#=object position x(obj)-x#:zy#=object position y(obj)-y#:zz#=object position z(obj)-z#
   move object obj,-1
   rem rotate the vectors
   xx1#=xx#
   xy1#=xy#*cos(amount#)-xz#*sin(amount#)
   xz1#=xz#*cos(amount#)+xy#*sin(amount#)
   zx1#=zx#
   zy1#=zy#*cos(amount#)-zz#*sin(amount#)
   zz1#=zz#*cos(amount#)+zy#*sin(amount#)
   rem calculate angle z
   zr#=atanfull(xy1#,xx1#)
   rem calculate angle y
   xx2#=xx1#*cos(zr#)+xy1#*sin(zr#)
   xy2#=xy1#*cos(zr#)-xx1#*sin(zr#)
   xz2#=xz1#
   zx2#=zx1#*cos(zr#)+zy1#*sin(zr#)
   zy2#=zy1#*cos(zr#)-zx1#*sin(zr#)
   zz2#=zz1#
   yr#=atanfull(xx2#,xz2#)-90
   rem calculate angle x
   zx3#=zx2#*cos(yr#+90)-zz2#*sin(yr#+90)
   zy3#=zy2#
   xr#=atanfull(zy3#,zx3#)+180
   if xr#+1>xr# and yr#+1>yr# and zr#+1>zr#
      rotate object obj,xr#,yr#,zr#
   endif
endfunction


remstart Rotate_GZ
   This function rotates the given object around the global (world) z axis by
   the given amount.
   Param    obj      The object to rotate
   Param    amount#  The angle to rotate the object by
remend
function rotate_GZ(obj,amount#)
   rem Rotating around the global Z axis is trivial
   rem as it is the first rotation anyway in the default ZYX rotation order
   rotate object obj,object angle x(obj),object angle y(obj),object angle z(obj)+amount#
endfunction


function chase_cam(CamNum#,id,camDist,Height#,yAng#)

   `grab the cameras current position
   xPos#=object position x(id)
   yPos#=object position y(id)
   zPos#=object position z(id)

   `work out new position
   xCamPos#=newxvalue(xPos#,yAng#,camDist)
   zCamPos#=newzvalue(zPos#,yAng#,camDist)

   `work out camera height
   yCamPos#=Height#
   if Height#<yPos# then yCamPos#=yPos#

   s=20
   xCamPos#=curvevalue(xCamPos#,camera position x(CamNum#),s)
   yCamPos#=curvevalue(yCamPos#,camera position y(CamNum#),s)
   zCamPos#=curvevalue(zCamPos#,camera position z(CamNum#),s)

   `update camera position
   position camera CamNum#,xCamPos#,yCamPos#,zCamPos#
   point camera CamNum#,xPos#,yPos#,zPos#

endfunction


interface:

   shadow_text(screen width()-text width("FPS: "+str$(screen fps())),0,"FPS: "+str$(screen fps()),rgb(200,210,220),0)
   for x=1 to array count(texts$(0))
      shadow_text(textx,x*10,texts$(x),rgb(200,210,220),0)
   next x

return

function shadow_text(x#,y#,text$,color,center)
ink rgb(10,20,30),0
if center=0 then text x#+1,y#+2,text$
if center=1 then center text x#+1,y#+2,text$
ink color,0
if center=0 then text x#,y#,text$
if center=1 then center text x#,y#,text$
endfunction

move_platforms:

if state_50=1
   position object 50,object position x(50),object position y(50),object position z(50)-0.1
else
   position object 50,object position x(50),object position y(50),object position z(50)+0.1
endif

if state_50=1
   if object position z(50)<start_50-25.0 then state_50=0
else
   if object position z(50)>start_50+5.0 then state_50=1
endif

if object collision(7,0)=50
   if state_50=1 then zm#=zm#+.005
   if state_50=0 then zm#=zm#-.005
endif

return

`Global rotation functions by Lower Logic

gosub display

`udt's
type balltype
  x as float
  y as float
  z as float
  vx as float
  vy as float
  vz as float
  omega as float `angular velocity
endtype
myball as balltype

type boardtype
  omega as float `angular velocity
endtype
board as boardtype


gosub make_ball
gosub make_background
gosub make_textures
gosub make_board
gosub set_ball_properties
gosub set_ground_properties
gosub make_vectors
gosub make_spirit_levels




do

gosub control_board
gosub collision
gosub move_ball
gosub move_camera
gosub apply_friction
gosub update_spirit_levels
gosub nudge
gosub replace

sync
loop

nudge:

if spacekey()=1 then position object ball,object position x(ball)+5,object position y(ball),object position z(ball)

return

replace:

if object position y(ball)<-100
  position object ball,0,20,0.1
  myball.vx=0
  myball.vy=0
  myball.vz=0
endif

return

make_spirit_levels:

pitchback=free_image()
create bitmap 1,100,100
word$="PITCH"
ink rgb(180,180,255),0
text 50-text width(word$)/2.0,0,word$
box 0,50,100,100
get image pitchback,0,0,100,100,1
delete bitmap 1
sprite pitchback,100,668,pitchback
set sprite alpha pitchback,130

pitch=free_image()
create bitmap 1,100,100
ink -1,0
box 0,49,100,51
get image pitch,0,0,100,100,1
delete bitmap 1
sprite pitch,150,718,pitch
offset sprite pitch,50,50

rollback=free_image()
create bitmap 1,100,100
word$="ROLL"
ink rgb(180,180,255),0
text 50-text width(word$)/2.0,0,word$
box 0,50,100,100
get image rollback,0,0,100,100,1
delete bitmap 1
sprite rollback,824,668,rollback
set sprite alpha rollback,130

roll=free_image()
create bitmap 1,100,100
ink -1,0
box 0,49,100,51
get image roll,0,0,100,100,1
delete bitmap 1
sprite roll,874,718,roll
offset sprite roll,50,50






return

update_spirit_levels:

rotate sprite pitch,-anglex#
rotate sprite roll,anglez#

return

apply_friction:

dec myball.vx,myball.vx*friction#
dec myball.vz,myball.vz*friction#

return

move_camera:

position object cameradummy,object position x(ball),object position y(ball),object position z(ball)
rotate object cameradummy,0,0,0
rotate_gx(cameradummy,anglex#)
move object cameradummy,-100
move object up cameradummy,100
point object cameradummy,object position x(ball),object position y(ball),object position z(ball)
roll object left cameradummy,anglez#
position camera object position x(cameradummy),object position y(cameradummy),object position z(cameradummy)
set camera to object orientation cameradummy
set object to camera orientation cube
pitch object up cube,45

return

make_background:

background=free_image()
create bitmap 1,500,500
ink rgb(0,255,0),0
for n=0 to 499 step 10
line n,0,n,500
line 0,n,500,n
next n
get image background,0,0,500,500,1
delete bitmap 1
cube=free_object()
make object cube cube,-500
texture object cube,background


return

make_vectors:

vleft=1
vright=2
vahead=3
vbehind=4
vabove=5
vbelow=6

null=make vector3(vleft)
null=make vector3(vright)
null=make vector3(vahead)
null=make vector3(vbehind)
null=make vector3(vabove)
null=make vector3(vbelow)

set vector3 vleft,-10,0,0
set vector3 vright,10,0,0
set vector3 vahead,0,0,10
set vector3 vbehind,0,0,-10
set vector3 vabove,0,10,0
set vector3 vbelow,0,-10,0

return

collision:


`repeat for each vector 1 to 6
for n=1 to 6
  `store xyz coordinates around ball
  x#=object position x(ball)+x vector3(n)
  y#=object position y(ball)+y vector3(n)
  z#=object position z(ball)+z vector3(n)

  dist#=intersect object(ground,object position x(ball),object position y(ball),object position z(ball),x#,y#,z#)
  if dist#=0 then dist#=1000
  if dist#<=2.5
    `if collision in a certain direction is detected, then reverse the velocity in that direction, and multiply by dampening amount
    overlap#=2.5-dist#
    if n=1
      myball.vx=-myball.vx*damp#
      position object ball,object position x(ball)+overlap#,object position y(ball),object position z(ball)
    endif
    if n=2
      myball.vx=-myball.vx*damp#
      position object ball,object position x(ball)-overlap#,object position y(ball),object position z(ball)
    endif
    if n=3
      myball.vz=-myball.vz*damp#
      position object ball,object position x(ball),object position y(ball),object position z(ball)-overlap#
    endif
    if n=4
      myball.vz=-myball.vz*damp#
      position object ball,object position x(ball),object position y(ball),object position z(ball)+overlap#
    endif
    if n=5
      myball.vy=-myball.vy*damp#
      position object ball,object position x(ball),object position y(ball)-overlap#,object position z(ball)
    endif
    if n=6
      myball.vy=-myball.vy*damp#
      position object ball,object position x(ball),object position y(ball)+overlap#,object position z(ball)
    endif

  endif
next n

return


move_ball:

dec myball.vy,gravity#
inc myball.vx,sin(anglez#)/mass#
inc myball.vz,sin(-anglex#)/mass#

if myball.vx>2.5 then myball.vx=2.5
if myball.vx<-2.5 then myball.vx=-2.5
if myball.vz>2.5 then myball.vz=2.5
if myball.vz<-2.5 then myball.vz=-2.5

if abs(myball.vx)<0.005 then myball.vx=0
if abs(myball.vz)<0.005 then myball.vz=0

position object ball,object position x(ball)+myball.vx,object position y(ball)+myball.vy,object position z(ball)+myball.vz
rotate_gz(ball,(-17*myball.vx))
rotate_gx(ball,(17*myball.vz))

`set light to follow ball
position light 1,object position x(ball),object position y(ball)+40,object position z(ball)

`update ball reflection
position object ball2,object position x(ball),-object position y(ball)+1,object position z(ball)
rotate_gz(ball2,(17*myball.vx))
rotate_gx(ball2,(-17*myball.vz))

return


control_board:


if leftkey()=1 and anglez#>-25 then dec anglez#,board.omega
if rightkey()=1 and anglez#<25 then inc anglez#,board.omega
if upkey()=1 and anglex#>-25 then dec anglex#,board.omega
if downkey()=1 and anglex#<25 then inc anglex#,board.omega



return


set_ball_properties:


  gravity#=0.05
  damp#=0.4
  mass#=6.0
  friction#=0.004

return


set_ground_properties:

board.omega=0.4

return

make_textures:

blue=free_image()
create bitmap 1,10,10
ink rgb(180,180,255),0
box 0,0,10,10
get image blue,0,0,10,10
delete bitmap 1

red=free_image()
create bitmap 1,10,10
ink rgb(255,0,0),0
box 0,0,10,10
get image red,0,0,10,10
delete bitmap 1

green=free_image()
create bitmap 1,10,10
ink rgb(0,255,0),0
box 0,0,10,10
get image green,0,0,10,10
delete bitmap 1

magenta=free_image()
create bitmap 1,10,10
ink rgb(255,0,255),0
box 0,0,10,10
get image magenta,0,0,10,10
delete bitmap 1



return

make_board:

`dummy
cameradummy=free_object()
make object cube cameradummy,1
hide object cameradummy

`ground

ground=free_object()
make object box ground,200,2,200
texture object ground,blue
set object transparency ground,5
set alpha mapping on ground,50


`all other board objects attached as limbs for simplicity with collision

`back
temp=free_object()
make object box temp,200,10,5
make mesh from object 1,temp
delete object temp
add limb ground,1,1
delete mesh 1
offset limb ground,1,0,0,100
texture limb ground,1,red

`front
temp=free_object()
make object box temp,200,10,5
make mesh from object 1,temp
delete object temp
add limb ground,2,1
delete mesh 1
offset limb ground,2,0,0,-100
texture limb ground,2,red

`left
temp=free_object()
make object box temp,5,10,200
make mesh from object 1,temp
delete object temp
add limb ground,3,1
delete mesh 1
offset limb ground,3,-100,0,0
texture limb ground,3,red

`right
temp=free_object()
make object box temp,5,10,200
make mesh from object 1,temp
delete object temp
add limb ground,4,1
delete mesh 1
offset limb ground,4,100,0,0
texture limb ground,4,red

limb=4
for z=1 to 20
  for x=1 to 20
    read data$
    if data$<>"000"
      inc limb
      temp=free_object()
      if data$="0xr"
        make object box temp,10,4,10
        data$="02r"
      else
        make object box temp,10,2,10
      endif
      make mesh from object 1,temp
      delete object temp
      add limb ground,limb,1
      delete mesh 1
      offset limb ground,limb,-105+x*10,val(left$(data$,2))*2-1,105-z*10
      if mid$(data$,3)="r" then texture limb ground,limb,red
      if mid$(data$,3)="g" then texture limb ground,limb,green
      if mid$(data$,3)="b" then texture limb ground,limb,blue
      if mid$(data$,3)="m" then texture limb ground,limb,magenta

      `reflection
      temp=free_object()
      make object box temp,10,2,10
      position object temp,-105+x*10,-val(left$(data$,2))*2-1,105-z*10
      if mid$(data$,3)="r" then texture object temp,red
      if mid$(data$,3)="g" then texture object temp,green
      if mid$(data$,3)="b" then texture object temp,blue
      if mid$(data$,3)="m" then texture object temp,magenta
      set object transparency temp,1
      set alpha mapping on temp,20
    endif
  next x
next z

return

make_ball:

`make ball
create bitmap 1,256,256
ink -1,0
box 0,0,128,128
box 128,128,256,256
ballimage=free_image()
get image ballimage,0,0,256,256,1
delete bitmap 1
ball=free_object()
make object sphere ball,5,20,20
texture object ball,ballimage
scale object texture ball,2,2
position object ball,0,20,0.1

`ball reflection
ball2=free_object()
make object sphere ball2,5,20,20
texture object ball2,ballimage
scale object texture ball2,2,2
set object transparency ball2,5
set alpha mapping on ball2,20


return

display:

set display mode 1024,768,32
hide mouse
sync on
sync rate 60
autocam off
color backdrop 0
position camera 0,20,-100

make light 1
set light range 1,200

hide light 0
set ambient light 50

return

function free_object()

repeat
inc n
until object exist(n)=0

endfunction n

function free_image()

repeat
inc n
until image exist(n)=0

endfunction n


remstart Rotate_GX
   This function rotates the given object around the global (world) x axis by
   the given amount.
   Param    obj      The object to rotate
   Param    amount#  The angle to rotate the object by
remend

function rotate_GX(obj as integer,amount# as float)
   rem get normal vectors for X, Y, and Z axes of the object
   x#=object position x(obj):y#=object position y(obj):z#=object position z(obj)
   move object right obj,1
   xx#=object position x(obj)-x#:xy#=object position y(obj)-y#:xz#=object position z(obj)-z#
   move object left obj,1:move object up obj,1
   yx#=object position x(obj)-x#:yy#=object position y(obj)-y#:yz#=object position z(obj)-z#
   move object down obj,1:move object obj,1
   zx#=object position x(obj)-x#:zy#=object position y(obj)-y#:zz#=object position z(obj)-z#
   move object obj,-1
   rem rotate the vectors
   xx1#=xx#
   xy1#=xy#*cos(amount#)-xz#*sin(amount#)
   xz1#=xz#*cos(amount#)+xy#*sin(amount#)
   zx1#=zx#
   zy1#=zy#*cos(amount#)-zz#*sin(amount#)
   zz1#=zz#*cos(amount#)+zy#*sin(amount#)
   rem calculate angle z
   zr#=atanfull(xy1#,xx1#)
   rem calculate angle y
   xx2#=xx1#*cos(zr#)+xy1#*sin(zr#)
   xy2#=xy1#*cos(zr#)-xx1#*sin(zr#)
   xz2#=xz1#
   zx2#=zx1#*cos(zr#)+zy1#*sin(zr#)
   zy2#=zy1#*cos(zr#)-zx1#*sin(zr#)
   zz2#=zz1#
   yr#=atanfull(xx2#,xz2#)-90
   rem calculate angle x
   zx3#=zx2#*cos(yr#+90)-zz2#*sin(yr#+90)
   zy3#=zy2#
   xr#=atanfull(zy3#,zx3#)+180
   if xr#+1>xr# and yr#+1>yr# and zr#+1>zr#
      rotate object obj,xr#,yr#,zr#
   endif
endfunction

remstart Rotate_GY
   This function rotates the given object around the global (world) y axis by
   the given amount.
   Param    obj      The object to rotate
   Param    amount#  The angle to rotate the object by
remend


function rotate_GY(obj,amount#)
   rem get normal vectors for X, Y, and Z axes of the object
   x#=object position x(obj):y#=object position y(obj):z#=object position z(obj)
   move object right obj,1
   xx#=object position x(obj)-x#:xy#=object position y(obj)-y#:xz#=object position z(obj)-z#
   move object left obj,1:move object up obj,1
   yx#=object position x(obj)-x#:yy#=object position y(obj)-y#:yz#=object position z(obj)-z#
   move object down obj,1:move object obj,1
   zx#=object position x(obj)-x#:zy#=object position y(obj)-y#:zz#=object position z(obj)-z#
   move object obj,-1

   rem rotate the vectors
   xx1#=xx#*cos(amount#)+xz#*sin(amount#)
   xy1#=xy#
   xz1#=xz#*cos(amount#)-xx#*sin(amount#)
   zx1#=zx#*cos(amount#)+zz#*sin(amount#)
   zy1#=zy#
   zz1#=zz#*cos(amount#)-zx#*sin(amount#)

   rem calculate angle z
   zr#=atanfull(xy1#,xx1#)
   rem calculate angle y
   xx2#=xx1#*cos(zr#)+xy1#*sin(zr#)
   xy2#=xy1#*cos(zr#)-xx1#*sin(zr#)
   xz2#=xz1#
   zx2#=zx1#*cos(zr#)+zy1#*sin(zr#)
   zy2#=zy1#*cos(zr#)-zx1#*sin(zr#)
   zz2#=zz1#
   yr#=atanfull(xx2#,xz2#)-90
   rem calculate angle x
   zx3#=zx2#*cos(yr#+90)-zz2#*sin(yr#+90)
   zy3#=zy2#
   xr#=atanfull(zy3#,zx3#)+180
   if xr#+1>xr# and yr#+1>yr# and zr#+1>zr#
      rotate object obj,xr#,yr#,zr#
   endif

endfunction




remstart Rotate_GZ
   This function rotates the given object around the global (world) z axis by
   the given amount.
   Param    obj      The object to rotate
   Param    amount#  The angle to rotate the object by
remend
function rotate_GZ(obj,amount#)
   rem Rotating around the global Z axis is trivial
   rem as it is the first rotation anyway in the default ZYX rotation order
   rotate object obj,object angle x(obj),object angle y(obj),object angle z(obj)+amount#
endfunction

data "000","11g","12g","13g","14g","15g","16g","17g","18g","19g","000","11g","12g","13g","14g","15g","16g","17g","000","000"
data "000","11g","000","000","000","000","000","000","000","20g","000","10g","000","000","000","000","000","18g","19g","20g"
data "000","11g","000","02g","02g","02g","02g","000","000","21g","000","09g","000","000","000","000","000","000","000","21g"
data "000","11g","000","02g","02g","02g","02g","000","000","22g","000","08g","000","000","000","000","000","000","000","22g"
data "000","11g","000","02g","02g","02g","02g","000","000","23g","000","07g","06g","05g","04g","000","000","000","000","23g"
data "000","11g","000","03g","000","02g","02g","000","000","24g","000","000","000","000","03g","000","000","000","000","24g"
data "000","11g","000","04g","000","02g","02g","000","000","25g","000","000","000","000","02g","000","000","000","000","25g"
data "000","11g","000","05g","000","02g","02g","000","000","000","000","000","000","02r","01g","02r","000","000","000","26g"
data "000","11g","000","06g","000","02r","01g","02r","000","20r","20r","02r","02r","02r","000","02r","000","000","000","27g"
data "000","11g","000","07g","000","02r","000","02r","20r","18g","08g","08g","02g","000","000","02r","000","000","000","28g"
data "000","11g","000","08g","000","02r","000","02r","20r","18g","08g","08g","02g","000","000","02r","000","000","000","29g"
data "000","11g","000","09g","000","02r","000","02r","000","20r","20r","02r","02r","02r","02r","02r","000","000","000","30g"
data "000","11g","000","10g","000","02r","000","02r","000","000","000","000","000","000","000","000","000","000","000","31g"
data "13r","11g","11g","11g","13r","02r","000","02r","000","06r","06r","000","000","000","000","000","000","000","000","000"
data "13r","13r","000","13r","13r","04r","02g","02g","03g","04g","04g","000","000","000","000","000","000","000","000","000"
data "000","000","000","000","000","04r","03r","000","000","04g","04g","000","04b","04b","04b","000","000","000","000","10g"
data "02r","02r","02r","02r","02r","0xr","04r","05r","06r","04g","04g","000","04b","02m","04b","000","10g","10g","10g","10g"
data "000","000","000","000","000","01g","02g","03g","04g","04g","04g","000","04b","04b","04b","000","000","000","000","10g"
data "000","000","02r","02r","02r","02r","000","000","000","000","000","000","000","000","000","000","000","000","000","10g"
data "000","000","000","000","000","000","000","000","000","000","000","000","000","000","000","000","000","000","000","10g"

`Global rotation functions by Lower Logic

set display mode 1024,768,32
sync on
sync rate 60
autocam off
hide mouse
fog off
position camera 0,25.0,20.0

`make textures
create bitmap 99,256,256
ink rgb(140,100,0),0
box 0,0,128,128
box 128,128,256,256
ink rgb(220,210,200),0
box 0,128,128,256
box 128,0,256,128
ink rgb(0,0,0),0
for x=126 to 130
line x,0,x,256
line 0,x,256,x
next x
for x=0 to 2
line x,0,x,256
line 0,x,256,x
next x
for x=254 to 256
line x,0,x,256
line 0,x,256,x
next x
get image 99,0,0,256,256,1
delete bitmap 99
create bitmap 1,256,256
ink rgb(20,80,140),0
box 0,0,128,128
box 128,128,256,256
ink rgb(200,210,220),0
box 0,128,128,256
box 128,0,256,128
ink rgb(0,0,0),0
x=128
line x,0,x,256
line 0,x,256,x
x=0
line x,0,x,256
line 0,x,256,x
x=256
line x,0,x,256
line 0,x,256,x
get image 1,0,0,256,256,1
delete bitmap 1

`make ball
make object sphere 99,5,64,64
texture object 99,99
set object specular 99,rgb(250,240,200)
set object specular power 99,25
set object emissive 99,rgb(30,20,0)
set object ambient 99,1
set object collision off 99
set object filter 99,0

`shadow
make object sphere 2,5,32,32
scale object 2,130,0.01,130
yrotate object 2,90
fix object pivot 2
color object 2,0
ghost object on 2,1
set object ambient 2,1
set object emissive 2,rgb(0,0,0)
set object specular 2,rgb(0,0,0)
set object specular power 2,100
set object collision off 2

`ground
   `ice
make object plain 3,100,100
pitch object down 3,-90
color object 3,rgb(0,0,0)
set reflection shading on 3
position object 3,0,7.5,50.0
set object transparency 3,5

 `normal
make object plain 6,100,100
pitch object down 6,-90
texture object 6,1
scale object texture 6,0.999,0.999
position object 6,0,0,-50.0
set object specular 6,rgb(230,210,200)
set object specular power 6,50
set object emissive 6,rgb(0,0,10)
set object filter 6,0

make object plain 45,100,100
position object 45,-100.0,-7.5,-50.0

make object plain 46,100,100
position object 46,-100.0,-17.5,-150.0

make object plain 47,100,5
position object 47,0.0,-17.5,-150.0

make object plain 48,5,50
position object 48,47.5,-17.5,-150.0-27.5

make object plain 49,25,50
position object 49,50.0,-10.0,-175.0-50.0/2.0-50.0

make object plain 50,25,50
position object 50,50.0,-10.0,-175.0-50.0/2.0-120.0

make object plain 51,50,25
position object 51,50.0,-20.0,-370.0

make object plain 53,50,25
position object 53,0.0,-27.0,-370.0

for x=45 to 53
if x<>52
pitch object down x,-90
texture object x,1
set object specular x,rgb(230,210,200)
set object specular power x,50
set object emissive x,rgb(0,0,10)
set object filter x,0
endif
next x

`walls
   `north
make object plain 8,100,7.5/2
texture object 8,1
scale object texture 8,1,0.5
position object 8,0,7.5/4,0
set object specular 8,rgb(230,210,200)
set object specular power 8,50
set object emissive 8,rgb(0,0,10)
set object filter 8,0

make object plain 9,100,7.5/2
texture object 9,1
scale object texture 9,-1,0.5
position object 9,0,(7.5/4)*3,0
set object specular 9,rgb(230,210,200)
set object specular power 9,50
set object emissive 9,rgb(0,0,10)
set object filter 9,0
set object collision off 9

make object plain 25,100,7.5
texture object 25,1
scale object texture 25,0.5,1
position object 25,0,7.5*1.5,100.0

make object plain 29,100,7.5
texture object 29,1
scale object texture 29,-0.5,1
position object 29,-100.0,7.5/-2,0

   `test
make object plain 30,100,25
texture object 30,1
xrotate object 30,-53.0
scale object texture 30,1,-1
position object 30,-100.0,-15.0,-110.0

make object plain 52,25,25
texture object 52,1
xrotate object 52,-73.0
yrotate object 52,-90.0
position object 52,13.1,-23.6,-370.0

   `south
make object plain 26,100,7.5
texture object 26,1
scale object texture 26,-0.5,-1
position object 26,0,7.5/2,-100.0

make object plain 31,50,7.5
texture object 31,1
position object 31,50.0,-20.0+7.5/2.0,-382.5

   `east
make object plain 27,100,7.5
yrotate object 27,90
texture object 27,1
scale object texture 27,0.5,1
position object 27,-50.0,7.5/-2,-50.0

make object plain 32,25.0,7.5
yrotate object 32,90
texture object 32,1
position object 32,75.0,-20.0+7.5/2.0,-370.0

   `west
make object plain 28,100,7.5
yrotate object 28,90
texture object 28,1
scale object texture 28,0.5,-1
position object 28,-150.0,7.5/-2,-50.0


for x=25 to 30
set object specular x,rgb(230,210,200)
set object specular power x,50
set object emissive x,rgb(0,0,10)
set object filter x,0
enable object zwrite x
enable object zread x
next x



`jump-pads
make object sphere 11,5,12,12
scale object 11,150,10,150
position object 11,0,7.52,8.0

make object sphere 12,5,12,12
scale object 12,150,10,150
position object 12,-8.0,0.02,-8.0

make object sphere 13,5,12,12
scale object 13,150,10,150
position object 13,8.0,0.02,-8.0

make object sphere 14,5,12,12
scale object 14,150,10,150
position object 14,-58.0,-7.48,-50.0

make object sphere 15,5,12,12
scale object 15,150,10,150
position object 15,-95.0,-7.48,-95.0

make object sphere 16,5,12,12
scale object 16,150,10,150
`position object 16,-100.0,-17.48,-110.0
position object 16,50.0,-17.5,-282.0

make object sphere 17,5,12,12
scale object 17,150,10,150
position object 17,47.5,-17.5,-207.0

make object sphere 18,5,12,12
scale object 18,150,10,150
position object 18,55.0,-17.5,-282.0

make object sphere 19,5,12,12
scale object 19,150,10,150
position object 19,45.0,-17.5,-282.0

`comic-outline
make object sphere 4,5.2,32,32
scale object 4,-100,-100,-100
color object 4,rgb(0,0,0)
set object ambient 4,0
set object collision off 4

`light
make light 1
color light 1,rgb(255,255,255)
position light 1,5,100,5
set light range 1,200

c_f=10
`background
cls : backdrop off
for x=0 to 32
ink rgb(111-x*c_f,222-x*c_f,255-x*c_f),0
line x,0,x,64
next x
for x=32 to 0 step -1
ink rgb(111-x*c_f,222-x*c_f,255-x*c_f),0
line abs(32-x)+32,0,abs(32-x)+32,64
next x
get image 5,0,0,64,64,4
backdrop on
make object sphere 5,10,32,32
scale object 5,8000,8000,8000 : texture object 5,5
scale object texture 5,4,4 : position object 5,-25,-5,-55
`set object 5,1,0,0,0,1,0,1
set object cull 5,0
set object filter 5,0
set object specular 5,rgb(155,205,255)
set object specular power 5,100
set object emissive 5,rgb(10,30,50)
set object collision off 5

`collision ball
make object sphere 7,5.1,32,32
hide object 7
scale object 7,50,100,50



state_50=1
start_50=object position z(50)

v#=0.01
vr#=0.1
xm#=0.0
zm#=0.0

camd#=30.0
camh#=20.0
cama#=90.0
cama_offset#=10.0

one=1
res_x#=0.0
res_y#=20.0
res_z#=50.0
fall#=-25.0

r=1 : b=1 : g=1

dim texts$(13)
texts$(1)=" "
texts$(2)="Move Ball with Arrowkeys."
texts$(3)=" "
texts$(4)="Rotate Cam with left-/rightclick"
texts$(5)=" "
texts$(6)="Zoom with mousewheel"
texts$(7)=" "
texts$(8)="Change Zoom with Button 3 (mousewheel)"
texts$(9)=" "
texts$(10)=" "
texts$(11)=" "
texts$(12)="Thanks to Lower Logic (global ball rotation) and Ric (setting up rotation functions)"

textx=25
set text font "Lucida console"
set text size 14
set text to bold

up as boolean
down as boolean
left as boolean
right as boolean

start_time=timer()

do

gosub move_platforms

remstart
ink rgb(200,210,220),0
set cursor 0,0
print "xm#=";xm#
print "zm#=";zm#
remend
oldx#=x#
oldy#=y#
oldz#=z#

if cama#=0.0
   up=downkey() or joystick down()
   down=upkey() or joystick up()
   left=rightkey() or joystick right()
   right=leftkey() or joystick left()
endif
if cama#=270.0
   up=leftkey() or joystick left()
   down=rightkey() or joystick right()
   left=downkey() or joystick down()
   right=upkey() or joystick up()
endif
if cama#=180.0
   up=upkey() or joystick up()
   down=downkey() or joystick down()
   left=leftkey() or joystick left()
   right=rightkey() or joystick right()
endif
if cama#=90.0
   up=rightkey() or joystick right()
   down=leftkey() or joystick left()
   left=upkey() or joystick up()
   right=downkey() or joystick down()
endif

ang#=360*(vr#^2)/2.5

`rotate for e/w-wall collision
zrotate object 7,object angle z(7)-90

`inc/dec speed depending on keys (e.g. v#*0=0 / v#*1=v# ) and collision
`east wall collision
if object collision(7,0)<>27 and object collision(7,0)<>32 then inc xm#,v#*right
if object collision(7,0)<>28 then dec xm#,v#*left

`wall collision east
if object collision(7,0)=27 or object collision(7,0)=32
   if abs(xm#)<0.045
      dec x#,abs(xm#)/10.0
   else
      xm#=xm#*-0.75
   endif
   if xm#>0.002 then dec xm#,xm#/10.0
endif

`wall collision west
if object collision(7,0)=28
   if abs(xm#)<0.045
      dec x#,abs(xm#)/10.0
   else
      xm#=xm#*-0.75
   endif
   if xm#<-0.002 then inc xm#,xm#/10.0
endif

`stop if low speed
if abs(xm#)<0.002 then xm#=0.0

`rotate back
zrotate object 7,object angle z(7)+90

`rotate for n/s-wall collision
xrotate object 7,object angle x(7)+90
`north wall collision
if object collision(7,0)<>8 and object collision(7,0)<>25 and object collision(7,0)<>29 then inc zm#,v#*up
`south wall collision
if object collision(7,0)<>26 and object collision(7,0)<>31 then dec zm#,v#*down

`wall collision north
if object collision(7,0)=8 or object collision(7,0)=25 or object collision(7,0)=29
   if abs(zm#)<0.05
      dec z#,abs(zm#)/10.0
   else
      zm#=zm#*-0.75
   endif
   if zm#>0.002 then dec zm#,zm#/10.0
endif

`wall collision south
if object collision(7,0)=26 or object collision(7,0)=31
   if abs(zm#)<0.05
      inc z#,abs(zm#)/10.0
   else
      zm#=zm#*-0.75
   endif
   if zm#<-0.002 then inc zm#,zm#/10.0
endif

`stop if low speed
if abs(zm#)<0.002 then zm#=0.0

`rotate back
xrotate object 7,object angle x(7)-90

`if moving then rotate ball depending on speed
if xm#>0.0 then rotate_gz(99,-ang#*(xm#*10.0))
if xm#<0.0 then rotate_gz(99,ang#*abs(xm#*10.0))
if zm#>0.0 then rotate_gx(99,ang#*(zm#*10.0))
if zm#<0.0 then rotate_gx(99,-ang#*abs(zm#*10.0))


`reset
if y#<fall# and time=0 then one=1: time=20
if one then x#=res_x# : y#=res_y# :  z#=res_z# : text 50,50,str$( mouseclick()) : one=0 : rotate object 99,rnd(360),rnd(360),rnd(360) : xm#=0.0 : zm#=0.0
if x#>-50.0 and z#<-145.0 and res_x#<>-50.0 and res_y#<>10.0 and res_z#<>-150.0 then checktime=500 : res_x#=-50.0 : res_y#=10.0 : res_z#=-150.0: fall#=-40.0

if checktime>0 then shadow_text(screen width()/2,screen height()/2+500-checktime,"Checkpoint",rgb(150+checktime/10,255,180+checktime/10),1) : dec checktime

`check different grounds and set resistance factor
`               object   3  =  icy/metal ground
if object collision(7,0)=3
   d#=6.0
else
   d#=2.0
   if object collision(7,0)=47 or object collision(7,0)=48 or object collision(7,0)=50 then d#=7.0
endif

`set ground resistance depending on speed
f#=((xm#*xm#)*100.0+(zm#*zm#)*100.0)/5.0
if f#<d# then f#=d#
f#=10.0-f#
`print f#
`f#=5.0

`decrease speed depending on speed
if xm#<0.0 then inc xm#,v#/f#
if xm#>0.0 then dec xm#,v#/f#
if zm#<0.0 then inc zm#,v#/f#
if zm#>0.0 then dec zm#,v#/f#

`gravity and ground collision
if object collision(7,0)=0
   if jump=0
      y#=y#-0.5
   endif
else
   if object collision(7,0)<>8
      if object collision(7,0)<25 or object collision(7,0)>46
         if object collision(7,0)<>52 and object collision(7,0)<>30 then y#=object size z(object collision(7,0))/2.0+object position y(object collision(7,0))+2.5
      endif
   endif
endif

`roll up ramp 2
if object collision(7,52)=1 then y#=y#+.15 : xm#=xm#-.006

`add movements to position
x#=x#+xm#
z#=z#+zm#

`re-position objects
position object 99,x#,y#,z#
position object 4,x#,y#,z#
`position shadow correct
if object collision(7,0)>0 and object collision(7,0)<>8
   if object collision(7,0)>25 or object collision(7,0)<11
      sy#=object size z(object collision(7,0))/2.0+object position y(object collision(7,0)+0.005)
   else
      if sy#=0 or sy#=0.0
         for for#=1.0 to 100.0
            position object 2,x#,object position y(2)-for#/10.0,z#
            if object collision(2,0)>0 then sy#=for#/10.0 : exit
         next for#
      endif
   endif
endif
`fix if falling
if sy#>y#-2.5 then sy#=y#-2.49
position object 2,x#,sy#+0.01,z#
position object 7,x#,y#,z#
scale object 2,100.0+(sy#-y#)*5.0+32.5,0.03,100.0+(sy#-y#)*5.0+32.5
if object collision(7,0)>0
   rotate object 2,object angle x(object collision(7,0)),0,object angle z(object collision(7,0))
else
   rotate object 2,0,0,0
endif

`fix jumpers
set object collision off 45
set object collision off 46

`roll up ramp 1
if object collision(7,0)=30 then y#=y#+.45 : zm#=zm#-.006


`jump-pads jumping
if object collision(7,0)>10 and object collision(7,0)<25
jump=30
y#=y#+0.05
endif

if jump>0 then y#=y#+jump/15 : jump=jump-1


`color jumpers
if object collision(7,0)>10 and object collision(7,0)<20 then ru=1 : gu=1 : bu=1 : r=0 : g=0 : b=255
for x=1 to 2
if ru=1 then inc r : if gu=1 then inc g : if bu<1 then inc b
`if ru=0 then dec r : if gu=0 then dec g : if bu<0 then dec b
if r=255 then ru=0 : if g=255 then gu=0 : if b=255 then bu=0
if r=0 then ru=1   : if g=0 then gu=1   : if b=0 then bu=1
next x

for x=11 to 19
if object collision(7,0)=x
   change=x
endif
if change=x
   color object x,rgb(r,g,b)
else
   color object x,rgb(255,255,255)
endif
next x


`fix jumpers
set object collision on 45
set object collision on 46

if object collision(7,0)=53 and wintime$="" then won=1

`if mousebutton 2 pressed -> rotate cam
if mouseclick()=2 and time2<=0 then cama#=wrapvalue(cama#-90) : time2=60
if mouseclick()=1 and time2<=0 then cama#=wrapvalue(cama#+90) : time2=60

camd#=abs(camd#-mousemovez()/100.0)
if mouseclick()=4 and time<=0
if camd#<>15.0
camd#=15.0
time=50
else
 camd#=30.0 : time=50
 endif
endif

`set cam
chase_cam(0,99,camd#,camh#+y#,cama#+cama_offset#)

`rotate bg-sphere
rotate object 5,object angle x(5)+0.1,object angle y(5)+0.1,object angle z(5)+0.1

gosub interface
gosub update_time

if time>0 then dec time
if time2>0 then dec time2

sync
loop



remstart Rotate_GX
   This function rotates the given object around the global (world) x axis by
   the given amount.
   Param    obj      The object to rotate
   Param    amount#  The angle to rotate the object by
remend

function rotate_GX(obj as integer,amount# as float)
   rem get normal vectors for X, Y, and Z axes of the object
   x#=object position x(obj):y#=object position y(obj):z#=object position z(obj)
   move object right obj,1
   xx#=object position x(obj)-x#:xy#=object position y(obj)-y#:xz#=object position z(obj)-z#
   move object left obj,1:move object up obj,1
   yx#=object position x(obj)-x#:yy#=object position y(obj)-y#:yz#=object position z(obj)-z#
   move object down obj,1:move object obj,1
   zx#=object position x(obj)-x#:zy#=object position y(obj)-y#:zz#=object position z(obj)-z#
   move object obj,-1
   rem rotate the vectors
   xx1#=xx#
   xy1#=xy#*cos(amount#)-xz#*sin(amount#)
   xz1#=xz#*cos(amount#)+xy#*sin(amount#)
   zx1#=zx#
   zy1#=zy#*cos(amount#)-zz#*sin(amount#)
   zz1#=zz#*cos(amount#)+zy#*sin(amount#)
   rem calculate angle z
   zr#=atanfull(xy1#,xx1#)
   rem calculate angle y
   xx2#=xx1#*cos(zr#)+xy1#*sin(zr#)
   xy2#=xy1#*cos(zr#)-xx1#*sin(zr#)
   xz2#=xz1#
   zx2#=zx1#*cos(zr#)+zy1#*sin(zr#)
   zy2#=zy1#*cos(zr#)-zx1#*sin(zr#)
   zz2#=zz1#
   yr#=atanfull(xx2#,xz2#)-90
   rem calculate angle x
   zx3#=zx2#*cos(yr#+90)-zz2#*sin(yr#+90)
   zy3#=zy2#
   xr#=atanfull(zy3#,zx3#)+180
   if xr#+1>xr# and yr#+1>yr# and zr#+1>zr#
      rotate object obj,xr#,yr#,zr#
   endif
endfunction


remstart Rotate_GZ
   This function rotates the given object around the global (world) z axis by
   the given amount.
   Param    obj      The object to rotate
   Param    amount#  The angle to rotate the object by
remend
function rotate_GZ(obj,amount#)
   rem Rotating around the global Z axis is trivial
   rem as it is the first rotation anyway in the default ZYX rotation order
   rotate object obj,object angle x(obj),object angle y(obj),object angle z(obj)+amount#
endfunction


function chase_cam(CamNum#,id,camDist,Height#,yAng#)

   `grab the cameras current position
   xPos#=object position x(id)
   yPos#=object position y(id)
   zPos#=object position z(id)

   `work out new position
   xCamPos#=newxvalue(xPos#,yAng#,camDist)
   zCamPos#=newzvalue(zPos#,yAng#,camDist)

   `work out camera height
   yCamPos#=Height#
   if Height#<yPos# then yCamPos#=yPos#

   s=20
   xCamPos#=curvevalue(xCamPos#,camera position x(CamNum#),s)
   yCamPos#=curvevalue(yCamPos#,camera position y(CamNum#),s)
   zCamPos#=curvevalue(zCamPos#,camera position z(CamNum#),s)

   `update camera position
   position camera CamNum#,xCamPos#,yCamPos#,zCamPos#
   point camera CamNum#,xPos#,yPos#,zPos#

endfunction


interface:

   shadow_text(screen width()-text width("FPS: "+str$(screen fps())),0,"FPS: "+str$(screen fps()),rgb(200,210,220),0)
   for x=1 to array count(texts$(0))
      shadow_text(textx,x*10,texts$(x),rgb(200,210,220),0)
   next x

return

function shadow_text(x#,y#,text$,color,center)
ink rgb(10,20,30),0
if center=0 then text x#+1,y#+2,text$
if center=1 then center text x#+1,y#+2,text$
ink color,0
if center=0 then text x#,y#,text$
if center=1 then center text x#,y#,text$
endfunction

move_platforms:

if state_50=1
   position object 50,object position x(50),object position y(50),object position z(50)-0.1
else
   position object 50,object position x(50),object position y(50),object position z(50)+0.1
endif

if state_50=1
   if object position z(50)<start_50-25.0 then state_50=0
else
   if object position z(50)>start_50+5.0 then state_50=1
endif

if object collision(7,0)=50
   if state_50=1 then zm#=zm#+.005
   if state_50=0 then zm#=zm#-.005
endif

return

update_time:

runtime=timer()-start_time
sec=runtime/1000
if sec>=60 then start_time=timer() : inc min
if sec<10 then sec$="0"+str$(sec) else sec$=str$(sec)
shadow_text(screen width()/2,0,str$(min)+":"+sec$,rgb(200,210,220),1)

if won=1 then wintime$="You won in "+str$(min)+":"+sec$+" Minutes!" :won=2
if won=0 then wintime$=""
shadow_text(screen width()/2,screen height()/2,wintime$,rgb(100,210,160),1)

return

remstart
Line-Roller by Master Xilo (Hurricane-Eye Entertainment)
http://www.freewebs.com/hurricane-eyeentertainment/index.htm

CONTROLS:
- press space-button to start
- press return to "pay" 1 point (score) to reload the level (if not yet started)
- click and hold the mouse button to draw lines

Try to get the amount of yellow boxes needed as "target" by drawing lines on wich the ball rolls. 
The end point of a line must be more down and right than the startpoint.
You loose if the ball falls / rolls out of the screen.


remend

``Setup
set display mode 640,480,32

Sync on:sync rate 60 
set window off
autocam off
position camera 0,0,0
point camera 0,0,1
set camera fov 45
randomize timer()
ink 0,0


``Make textures
make memblock 1,12+256*256*4
write memblock dword 1,0,256
write memblock dword 1,4,256
write memblock dword 1,8,32
for y=0 to 255
    for x=0 to 255
        write memblock dword 1,12+(x+y*256)*4,rgb(x,y,255-y)
    next x
next y
make image from memblock 5,1:delete memblock 1
make memblock 1,12+256*256*4
write memblock dword 1,0,256
write memblock dword 1,4,256
write memblock dword 1,8,32
for y=0 to 255
    for x=0 to 255
        write memblock dword 1,12+(x+y*256)*4,rgb(255-y,x,y)
    next x
next y
make image from memblock 6,1:delete memblock 1
make memblock 1,12+256*256*4
write memblock dword 1,0,256
write memblock dword 1,4,256
write memblock dword 1,8,32
for y=0 to 255
    for x=0 to 255
        write memblock dword 1,12+(x+y*256)*4,rgb(x,255-y,y)
    next x
next y
make image from memblock 7,1:delete memblock 1

make memblock 1,12+6*1*4
write memblock dword 1,0,6
write memblock dword 1,4,1
write memblock dword 1,8,32
write memblock dword 1,12+4*0,rgb(255, 0, 0)
write memblock dword 1,12+4*1,rgb(255, 128, 0)
write memblock dword 1,12+4*2,rgb(255, 255, 0)
write memblock dword 1,12+4*3,rgb(0, 255, 0)
write memblock dword 1,12+4*4,rgb(0, 0, 255)
write memblock dword 1,12+4*5,rgb(128, 0, 128)
make image from memblock 4,1:delete memblock 1

make memblock 1,12+1*1*4
write memblock dword 1,0,1
write memblock dword 1,4,1
write memblock dword 1,8,32
write memblock dword 1,12,rgb(255, 255, 0)
make image from memblock 3,1:delete memblock 1

make memblock 1,12+1*1*4
write memblock dword 1,0,1
write memblock dword 1,4,1
write memblock dword 1,8,32
write memblock dword 1,12,rgb(1, 1, 1)
make image from memblock 2,1:delete memblock 1


``Main Player Sphere
make object sphere 1,15
position object 1,-320,240,580
texture object 1,4

make object sphere 3,15
scale object 3,-110,-110,-110
glue object to limb 3,1,0
set object light 3,0
texture object 3,2

``Background
backdrop off
Make object plain 2,680,500
position object 2,0,0,600
texture object 2,5
set object light 2,0
set object transparency 2,4:set alpha mapping on 2,40



dim lines(1000,3) as integer
currentline=0
score=0
target=1
current=0
speed#=0

gosub SETUPLevel

do
    
    
    if started
    
    
    if mouseclick()
        if click=0
            lines(currentline,0)=mousex()
            lines(currentline,1)=mousey()
        endif
        click=1
        lines(currentline,2)=mousex()
        lines(currentline,3)=mousey()
    else
        if click=1 then click=0:if ((lines(i,0)>lines(i,2) or lines(i,1)>lines(i,3))=0) then inc currentline
    endif
    
    for i=0 to currentline-1*(click=0)
        ink 0,0
        if (lines(i,0)>lines(i,2) or lines(i,1)>lines(i,3)) then ink rgb(255,0,0),0
        line lines(i,0),lines(i,1),lines(i,2),lines(i,3)
    next i
    
    for i=100 to 100+target*2
        if object exist (i) then yrotate object i,object angle y(i)+5
    next i
    
    col=OBJECT COLLISION(1,0)
    if col>=100
        delete object col:inc current
    endif


    position object 1,object position x(1)+1,object position y(1)-speed#,object position z(1)
    zrotate object 1,object angle z(1)-8
    speed#=speed#+0.1
    
    pointcol1=POINT(object position x(1)+321,480-(object position y(1)+240)+5)
    pointcol2=POINT(object position x(1)+321,480-(object position y(1)+240)+6)
    pointcol3=POINT(object position x(1)+321,480-(object position y(1)+240)+7)
    pointcol4=POINT(object position x(1)+321,480-(object position y(1)+240)+8)
    pointcol=(pointcol1=0 or pointcol2=0 or pointcol3=0 or pointcol4=0)
    
    if pointcol
        x=object position x(1)+321
        y=480-(object position y(1)+240)+8
        repeat 
            x=x+1
        until POINT(x,y)>=0 and POINT(x,y-1)>=0 and POINT(x,y-2)>=0 and POINT(x,y-3)>=0
        diff=x-(object position x(1)+321)
        position object 1,object position x(1)+diff,object position y(1),object position z(1)
        
        speed#=-(0.5-diff/20.0)
        if speed<=0 then speed#=0.1
    endif
    
    
    
    if current>=target
        score=score+current
        inc target
        current=0
        started=0
        currentline=0
        click=0
        position object 1,-320,240,580
        gosub SETUPLevel
        speed#=0
    endif
    
    if object position y(1)<-240 or object position x(1)>320
        target=1
        lastscore=score
        score=0
        current=0
        started=0
        gameover=1:
        currentline=0
        click=0
        position object 1,-320,240,580
        gosub SETUPLevel
        speed#=0
    endif
    
    endif
    
    if returnkey() and started=0
        if key=0
        score=score-1
        current=0
        started=0
        currentline=0
        click=0
        position object 1,-320,240,580
        gosub SETUPLevel
        speed#=0
        endif
        key=1
    else 
        key=0
    endif
    
    ink 0,0
    set cursor 32,32:Print "FPS: ";screen fps();" Score: ";score;" Target: ";current;" / ";target
    if spacekey() then started=1:gameover=0
    if started=0 then text 260,220,"Press space to start"
    if gameover then text 280,240,"GAME OVER! Last Score: "+str$(lastscore)
    
    sync
loop

SETUPLevel:
    posx=32
    posy=32
    
    delete objects 100,10000

    
    for i=100 to 100+target*2
        if object exist (i) then delete object i
        make object cube i,20
        
        position object i,-320+rnd(620),240-rnd(480),580
        posx=posx+rnd(620)/target
        posy=posy+rnd(460)/target
        texture object i,3
    next i
    texture object 2,5+rnd(2)
return

Redflames. Visuals were good, and the moving camera helped. Really
well done for your first entry.

Ric. I really liked this. The physics, particularly the bouncing,
were well done, and the lighting and reflections looked good. I also
spent at least an full hour addicted to it, trying to get the ball
in the purple box, but never managed it. Something else I did notice
was that the ball seemed to display some sort of hysteresis, but I
still can't decide whether it helps or not. Good work.

for x=100 to 10000
if object exist(x) then delete object x
next x

set display mode 800,600,32
sync on
sync rate 60

Start:



Scroll as float = 0

rem *** Airplane ***
type AirplaneType
   X as float
   Y as float
   Speed as float
   MinSpeed as float
   MaxSpeed as float
   SpeedX as float
   SpeedY as float
   Angle as float
endtype
global Airplane as AirplaneType
CreateAirplane()

rem Level/Score
global Level as integer = 1
global Score as integer = 0

ResetAirplane()
BuildLevel()


do
   cls

   ink 0xFFFFFFFF, 0
   print "FPS: ", screen fps()
   print "Scroll: ", str$(Scroll,0)
   print "Level: ", Level
   print "Rings: ", RingsPassed
   print
   print "SCORE: ", Score

   ControlAirplane()
   UpdateAirplane()
   DrawAirplane(Scroll)

   Scroll = Airplane.X-300

   ShowMatrix(Scroll)
   ShowRings(Scroll)

   sync
loop












function CreateRings(Rings,MaxY)
   rem Variables
   global RingCount as integer : RingCount = Rings
   global RingHeight as integer = 50
   global RingsPassed as integer = 0
   rem Array
   dim Ring(Rings) as RingType
   for r = 1 to Rings
      Ring(r).X = 500 + rnd(MaxPosX-500)
      Ring(r).Y = 100 + rnd(MaxY-100)
      Ring(r).C = rnd(0xFFFFFF)
      Ring(r).Passed = 0
      Ring(r).Size = RingHeight
   next r
endfunction

   type RingType
      X as integer
      Y as integer
      C as dword `Color
      Passed as boolean `if the airplane already scrolled out of the screen
      Size as integer `Size increases when a ring is hit
   endtype

function CreateMatrix(Segments,Min,Max,SegSizeX)
   rem Variables
   global SegmentSizeX as integer : SegmentSizeX = SegSizeX
   global SegmentCount as integer : SegmentCount = Segments
   global MaxPosX as integer : MaxPosX = Segments*SegSizeX
   rem Create Terrain
   dim Matrix(Segments) as integer
   Matrix(0) = Max
   Height = (Min + Max)/2
   MaxDif = (Max - Min)/10
   for s = 1 to Segments
      Height = Height + MaxDif - rnd(MaxDif*2)
      if Height < Min then Height = Min
      if Height > Max then Height = Max
      Matrix(s) = Height
   next s
   Matrix(Segments)=Max
endfunction

function ShowRings(Scroll)
   sw = screen width()
   for r = 1 to RingCount
      xp = Ring(r).X - Scroll
      if xp>-20 or sp<sw+20
         ink Ring(r).C, 0
         ellipse xp, Ring(r).Y, Ring(r).Size*0.4, Ring(r).Size
      endif
   next r
endfunction

function ShowMatrix(Scroll)
   pos2 = -Scroll
   sw = screen width()
   for s = 1 to SegmentCount
      pos1 = pos2
      pos2 = s*SegmentSizeX - Scroll
      if pos2 > 0 and pos1 < sw
         line pos1,Matrix(s-1),pos2,Matrix(s)
      endif
   next s
endfunction

function UpdateAirplaneSpeed()
   Airplane.SpeedX = sin(Airplane.Angle)*Airplane.Speed
   Airplane.SpeedY = cos(Airplane.Angle)*Airplane.Speed
endfunction

function ControlAirplane()
   rl = rightkey()-leftkey()
   ud = upkey()-downkey()
   if rl<>0
      Airplane.Angle = wrapvalue(Airplane.Angle-rl*2.3)
   endif
   if ud<>0
      Airplane.Speed = Airplane.Speed + ud*0.1
      if Airplane.Speed < Airplane.MinSpeed then Airplane.Speed = Airplane.MinSpeed
      if Airplane.Speed > Airplane.MaxSpeed then Airplane.Speed = Airplane.MaxSpeed
   endif
   if ud or rl then UpdateAirplaneSpeed()
endfunction

function UpdateAirplane()
   rem Gravity
   AirPlane.Angle = wrapvalue(AirPlane.Angle - (180-AirPlane.Angle)/360.0)
   UpdateAirplaneSpeed()
   rem Position
   inc Airplane.X, Airplane.SpeedX
   inc Airplane.Y, Airplane.SpeedY
   rem Rings
   for r = 1 to RingCount
      if Ring(r).Passed=0
         xdis = Airplane.X - Ring(r).X
         ydis = Airplane.Y - Ring(r).Y
         if abs(xdis)<20
            Ring(r).Passed=1
            if abs(ydis)<RingHeight
               inc RingsPassed
               inc Score, Airplane.Speed*10
               inc Ring(r).Size
            endif
         endif
      else
         if Ring(r).Size>RingHeight and Ring(r).Size<RingHeight*3
            inc Ring(r).Size
         endif
      endif
   next r
   rem Win
   if Airplane.X > MaxPosX+100
      Nextlevel()
   endif
   rem Crash
   ycol = GetMatrixHeight(Airplane.X)-20
   if Airplane.Y > ycol then PlayerLost(1)
endfunction

function GetMatrixHeight(X)
   for s = 1 to SegmentCount
      if s*SegmentSizeX > X then h = Matrix(s) : exitfunction h
   next s
   sh = screen height()
endfunction sh

function DrawAirplane(Scroll)
   xp = Airplane.X - Scroll
   yp = Airplane.Y
   rotate sprite 1, 90-Airplane.Angle
   paste sprite 1, xp, yp
endfunction

function NextLevel()
   rem Defeat
   if RingsPassed < RingCount/2
      PlayerLost(0)
   endif
   rem Victory
   cls rgb(0,0,90)
   ink 0xFFFFFF00,0
   x = screen width()/2
   center text x, 100, "You successfuly finished Level "+str$(Level)+"!"
   center text x, 140, "Rings hit: "+str$(RingsPassed)+"/"+str$(RingCount)
   center text x, 180, "Your score: "+str$(Score)
   center text x, 300, "- Press spacekey to continue -"
   sync
   wait 1000
   repeat : until spacekey()=1
   rem New level
   inc Level
   ResetAirplane()
   BuildLevel()
   inc Airplane.MinSpeed, 0.5
   inc Airplane.MaxSpeed, 0.5
endfunction

function PlayerLost(Crash as boolean)
   cls rgb(90,0,0)
   ink 0xFF00FFFF,0
   x = screen width()/2
   if Crash
      center text x, 100, "You crashed into the terrain!"
   else
      center text x, 100, "You didn't hit enough rings!"
   endif
   center text x, 140, "Rings hit: "+str$(RingsPassed)+"/"+str$(RingCount)
   center text x, 180, "Your score: "+str$(Score)
   center text x, 300, "- Press spacekey to end, return to restart -"
   sync
   wait 1000
   do
      if spacekey()=1 then end
      if returnkey()=1 then goto Start
   loop
endfunction


function ResetAirplane()
   AirPlane.X = 0
   Airplane.Y = 200
   Airplane.Angle = 90 `Angle clockwise from top -> 90 = to the right side
   Airplane.MaxSpeed = 6.5
   Airplane.MinSpeed = 2.8
   Airplane.Speed = (Airplane.MaxSpeed+Airplane.MinSpeed)/2
   UpdateAirplaneSpeed()
   rotate sprite 1, 0
endfunction

function BuildLevel()
   CreateMatrix(50+10*Level,300+100/Level,600,60)
   CreateRings(10+3*Level,320)
endfunction


function CreateAirplane()
   cls 0
   ink rgb(255,255,255),0
   line 10,10,70,10
   line 10,10, 8, 8
   line  8, 8, 6, 2
   line  6, 2, 4, 1
   line  4, 1, 2, 1
   line  2, 1, 1, 4
   line  1, 4, 1,15
   line  1,15, 3,17
   line  3,17, 7,18
   line  7,18,10,19
   line  7,18,5,20
   circle 3,22,3
   line 10,19,30,23
   line 30,23,40,25
   line 40,25,65,20
   line 65,20,69,15
   line 69,15,71,12
   line 71,12,70,10
   rem Seat-Thing
   line 30,10,36, 7
   line 36, 7,38,10
   rem Wings
   line 34, 4,54, 4
   line 34,28,54,28
   line 39, 4,39,28
   line 50, 4,50,28
   rem Wheel
   line 55,23,60,28
   circle 60,28,3
   rem Rotor
   line 71,12,73,12
   line 73, 3,73,21
   rem Get image
   get image 1, 0,0,75,35, 1
   sprite 1, 0,0, 1
   hide sprite 1
   offset sprite 1, sprite width(1)/2, sprite height(1)/2
   set sprite 1, 0,1
endfunction

sync on : set global collision on : disable escapekey : set camera range 5,10000

type xyz
    x as float
    y as float
    z as float
endtype

ol as xyz
nw as xyz
tmpxyz as xyz

#constant PLAYER_SPEED 3.0
#constant ENEMY_SPEED 3.5
#constant PLAYER_TURN 1.0
#constant ENEMY_TURN 0.8
#constant CAM_SMOOTH 7

global CurObj as integer
global CurImg as integer
global ECenterX as float
global ECenterY as float
global ECenterZ as float
CurObj = 0
CurImg = 0

inc CurObj
make object plain CurObj,10000,10000
Xrotate object CurObj,90
Ground = CurObj

inc CurObj
make object box CurObj,2,2,10000
ColorLimb(CurObj, 0, rgb(0,0,0))
EnemyBullet = CurObj
inc CurObj
make object box CurObj,2,2,10000
ColorLimb(CurObj, 0, rgb(0,0,0))
PlayerBullet = CurObj
position object PlayerBullet,0,5050,0
position object EnemyBullet,0,5050,0
Xrotate object PlayerBullet,90
Xrotate object EnemyBullet,90
fix object pivot PlayerBullet
fix object pivot EnemyBullet
hide object PlayerBullet
hide object EnemyBullet
set object collision on PlayerBullet
set object collision on EnemyBullet
set object collision to boxes PlayerBullet
set object collision to boxes EnemyBullet

Player = MakePlane()
Enemy = MakePlane()
glue object to limb PlayerBullet,Player,0
glue object to limb EnemyBullet,Enemy,0
position object Player,500,5000,0
position object Enemy,-500,5000,0

null = make matrix4(1)
null = make vector3(2)

MakeExplosion()

color backdrop rgb(50,50,100)

PlayerHealth = 100
EnemyHealth = 100

do

    if Stop = 0
        camx# = camera position x()
        camy# = camera position y()
        camz# = camera position z()
        position camera object position x(Player),object position y(Player),object position z(Player)
        set camera to object orientation Player
        pitch camera down 20
        move camera -1000
        pitch camera up 20
        newcamx# = camera position x()
        newcamy# = camera position y()
        newcamz# = camera position z()
        position camera curvevalue(newcamx#,camx#,CAM_SMOOTH),curvevalue(newcamy#,camy#,CAM_SMOOTH),curvevalue(newcamz#,camz#,CAM_SMOOTH)

        move object Player,PLAYER_SPEED
        position object Enemy,object position x(Enemy)-object position x(Player),object position y(Enemy),object position z(Enemy)-object position z(Player)
        position object Player,0,object position y(Player),0
        pitch object down Player,(upkey()-downkey())*PLAYER_TURN
        roll object right Player,(rightkey()-leftkey())*PLAYER_TURN
        if reloading
            dec reloading
            if reloading = 10
                hide object PlayerBullet
            endif
        endif
        if spacekey()
            if reloading = 0
                show object PlayerBullet
                reloading = 20
                ol.x = object position x(Player)
                ol.y = object position y(Player)
                ol.z = object position z(Player)
                move object Player,10000
                nw.x = object position x(Player)
                nw.y = object position y(Player)
                nw.z = object position z(Player)
                position object Player,ol.x,ol.y,ol.z
                tmpxyz.x = object position x(Enemy)
                tmpxyz.y = object position y(Enemy)
                tmpxyz.z = object position z(Enemy)
                if CheckLineIntersectSphere(ol, nw, tmpxyz, 100)
                    dec EnemyHealth
                endif
            endif
        endif

        move object Enemy,ENEMY_SPEED

        currentx# = object angle x(Enemy)
        currenty# = object angle y(Enemy)
        currentz# = object angle z(Enemy)
        AimMode = 1
        if object position y(Enemy) < 200
            rotate object Enemy,-90,0,0
            AimMode = 0
        else
            point object Enemy,object position x(Player),object position y(Player),object position z(Player)
            distx# = object position x(Enemy)
            disty# = object position y(Enemy)-object position y(Player)
            distz# = object position z(Enemy)
            if (distx#*distx#+disty#*disty#+distz#*distz#) < 500*500
                steerclear = 1
            else
                if steerclear
                    if (distx#*distx#+disty#*disty#+distz#*distz#) > 900*900
                        steerclear = 0
                    endif
                endif
            endif
            if steerclear
                Xrotate object Enemy,object angle x(Enemy)+180.0
                AimMode = 0
            endif
        endif
        wantedx# = wrapvalue(object angle x(Enemy)+180.0-currentx#)-180.0
        wantedy# = wrapvalue(object angle y(Enemy)+180.0-currenty#)-180.0
        wantedz# = wrapvalue(object angle z(Enemy)+180.0-currentz#)-180.0
        OnTarget = 1
        if wantedx# >= ENEMY_TURN
            inc currentx#,ENEMY_TURN
            OnTarget = 0
        else
            if wantedx# <= -ENEMY_TURN
                dec currentx#,ENEMY_TURN
                OnTarget = 0
            endif
        endif
        if wantedy# >= ENEMY_TURN
            inc currenty#,ENEMY_TURN
            OnTarget = 0
        else
            if wantedy# <= -ENEMY_TURN
                dec currenty#,ENEMY_TURN
                OnTarget = 0
            endif
        endif
        if wantedz# >= ENEMY_TURN
            inc currentz#,ENEMY_TURN
            OnTarget = 0
        else
            if wantedz# <= -ENEMY_TURN
                dec currentz#,ENEMY_TURN
                OnTarget = 0
            endif
        endif
        rotate object Enemy,currentx#,currenty#,currentz#
        if reloaded > 0
            dec reloaded
            if reloaded = 15
                hide object EnemyBullet
            endif
        endif
        if OnTarget and AimMode
            if reloaded = 0
                show object EnemyBullet
                reloaded = 20
                ol.x = object position x(Enemy)
                ol.y = object position y(Enemy)
                ol.z = object position z(Enemy)
                move object Enemy,10000
                nw.x = object position x(Enemy)+rnd(3000)-1500
                nw.y = object position y(Enemy)+rnd(3000)-1500
                nw.z = object position z(Enemy)+rnd(3000)-1500
                position object Enemy,ol.x,ol.y,ol.z
                tmpxyz.x = object position x(Player)
                tmpxyz.y = object position y(Player)
                tmpxyz.z = object position z(Player)
                if CheckLineIntersectSphere(ol, nw, tmpxyz, 100)
                    dec PlayerHealth
                endif
            endif
        endif

        if camera position y() <= 0
            if hidden = 0
                hidden = 1
                hide object Ground
            endif
        else
            if hidden = 1
                hidden = 0
                show object Ground
            endif
        endif

        if object collision(Player, Enemy)
            Stop = 1
            explosionx# = object position x(Player)+object position x(Enemy)
            explosiony# = object position y(Player)+object position y(Enemy)
            explosionz# = object position z(Player)+object position z(Enemy)
            ShowExplosion(explosionx#*0.5,explosiony#*0.5,explosionz#*0.5)
            hide object Player
            hide object Enemy
            Msg$ = "...IT'S A DRAW..."
        else
            if object position y(Enemy) < 50
                Stop = 1
                explosionx# = object position x(Enemy)
                explosiony# = object position y(Enemy)
                explosionz# = object position z(Enemy)
                ShowExplosion(explosionx#,explosiony#,explosionz#)
                hide object Enemy
                Msg$ = "YOU WIN!"
            else
                if object position y(Player) < 50
                    Stop = 1
                    explosionx# = object position x(Player)
                    explosiony# = object position y(Player)
                    explosionz# = object position z(Player)
                    ShowExplosion(explosionx#,explosiony#,explosionz#)
                    hide object Player
                    Msg$ = "YOU LOSE!"
                else
                    if EnemyHealth <= 0
                        Stop = 1
                        explosionx# = object position x(Enemy)
                        explosiony# = object position y(Enemy)
                        explosionz# = object position z(Enemy)
                        ShowExplosion(explosionx#,explosiony#,explosionz#)
                        hide object Enemy
                        Msg$ = "YOU WIN!"
                    else
                        if PlayerHealth <= 0
                            Stop = 1
                            explosionx# = object position x(Player)
                            explosiony# = object position y(Player)
                            explosionz# = object position z(Player)
                            ShowExplosion(explosionx#,explosiony#,explosionz#)
                            hide object Player
                            Msg$ = "YOU LOSE!"
                        endif
                    endif
                endif
            endif
        endif
    else
        MoveExplosion()
        inc dead
        if dead = 20
            show object 1000
        endif
        if dead > 150
            set text font "Impact"
            set text size 100
            set text to bold
            center text screen width()/2,100,Msg$
            set text font "System"
            set text to normal
            set text size 12
        endif
    endif
    if escapekey()
        delete objects 1,800
        end
    endif
    
    text 0,0,"Altitude: "+str$(object position y(Player)*0.1,1)+ " metres"
    text 0,20,"Player Health: "+str$(PlayerHealth)
    text 0,40,"Enemy Health: "+str$(EnemyHealth)

    sync
loop

function MoveExplosion()
    camx# = camera position x()
    camy# = camera position y()
    camz# = camera position z()
    for i = 101 to 800
        distx# = object position x(i)-ECenterX
        disty# = object position y(i)-ECenterY
        distz# = object position z(i)-ECenterZ
        distx# = distx#*1.1
        disty# = disty#*1.1
        distz# = distz#*1.1
        position object i,distx#+ECenterX,disty#+ECenterY,distz#+ECenterZ
        point object i,camx#,camy#,camz#
    next i
endfunction

function ShowExplosion(x#,y#,z#)
    backdrop off
    cls 0
    make object plain 1000,1000,1000
    lock object on 1000
    position object 1000,0,0,10
    ColorLimb(1000,0,rgb(0,0,0))
    set alpha mapping on 1000,2
    hide object 1000
    ECenterX = x#
    ECenterY = y#
    ECenterZ = z#
    dec x#,100.0
    dec y#,100.0
    dec z#,100.0
    for i = 101 to 800
        position object i, x#+rnd(200), y#+rnd(200), z#+rnd(200)
        point object i, camera position x(), camera position y(), camera position z()
        show object i
    next i
endfunction

function MakeExplosion()
    Col1 = MakeColor(rgb(255,100,100))
    Col2 = MakeColor(rgb(255,255,100))
    Col3 = MakeColor(rgb(255,200,50))
    Col4 = MakeColor(rgb(255,200,100))
    Col5 = MakeColor(rgb(255,220,100))
    Col6 = MakeColor(rgb(255,230,100))
    Col7 = MakeColor(rgb(255,240,150))
    nextobjnum = 100
    for t = 1 to 7
        select t
            case 1 : col = Col1 : endcase
            case 2 : col = Col2 : endcase
            case 3 : col = Col3 : endcase
            case 4 : col = Col4 : endcase
            case 5 : col = Col5 : endcase
            case 6 : col = Col6 : endcase
            case 7 : col = Col7 : endcase
        endselect
        for d = 1 to 100
            inc nextobjnum
            make object plain nextobjnum,50,50
            ghost object on nextobjnum
            texture object nextobjnum,col
            hide object nextobjnum
        next d
    next t
endfunction

function MakePlane()
    inc CurObj
    make object cylinder CurObj,100
    make mesh from object 10,CurObj

    autocam off

    lock vertexdata for limb CurObj,0
    for i = 0 to get vertexdata vertex count()
        if get vertexdata position y(i) < 0
            set vertexdata position i,get vertexdata position x(i)*0.1,get vertexdata position y(i),get vertexdata position z(i)*0.1
        else
            set vertexdata position i,get vertexdata position x(i)*0.3,get vertexdata position y(i),get vertexdata position z(i)*0.3
        endif
    next i
    unlock vertexdata
    lock vertexdata for mesh 10
    for i = 0 to get vertexdata vertex count()
        if get vertexdata position y(i) < 0
            set vertexdata position i,get vertexdata position x(i)*0.1,get vertexdata position y(i),get vertexdata position z(i)*0.1
        else
            set vertexdata position i,get vertexdata position x(i)*0.3,get vertexdata position y(i),get vertexdata position z(i)*0.3
        endif
    next i
    unlock vertexdata
    make object box CurObj+1,100,1,20
    make object box CurObj+2,100,1,20
    make object sphere CurObj+3,10
    make object sphere CurObj+4,10
    make object sphere CurObj+5,50,20,20
    make object cylinder CurObj+6,40
    make object cylinder CurObj+7,40
    Xrotate object CurObj,90
    fix object pivot CurObj
    make mesh from object 1,CurObj+1
    make mesh from object 2,CurObj+2
    make mesh from object 3,CurObj+3
    lock vertexdata for mesh 3
    for i = 0 to get vertexdata vertex count()
        if get vertexdata position z(i) > 0
            set vertexdata position i,get vertexdata position x(i),get vertexdata position y(i),0
        endif
    next i
    unlock vertexdata
    make mesh from object 4,CurObj+4
    make mesh from object 5,CurObj+5
    make mesh from object 6,CurObj+6
    make mesh from object 7,CurObj+7
    add limb CurObj,1,1
    add limb CurObj,2,2
    add limb CurObj,3,3
    add limb CurObj,4,4
    add limb CurObj,5,5
    add limb CurObj,6,6
    add limb CurObj,7,7
    add limb CurObj,8,5
    offset limb CurObj,1,0,30,15
    offset limb CurObj,2,0,30,-25
    offset limb CurObj,3,0,-50,0
    offset limb CurObj,4,0,-50,0
    offset limb CurObj,5,0,50,0
    offset limb CurObj,6,30,30,-5
    offset limb CurObj,7,-30,30,-5
    offset limb CurObj,8,0,55,0
    rotate limb CurObj,1,90,0,0
    rotate limb CurObj,2,90,0,0
    rotate limb CurObj,6,90,0,0
    rotate limb CurObj,7,90,0,0
    scale limb CurObj,3,100,200,500
    scale limb CurObj,4,500,200,100
    scale limb CurObj,5,61,5,61
    scale limb CurObj,6,10,100,10
    scale limb CurObj,7,10,100,10
    scale limb CurObj,8,100,5,100
    delete object CurObj+1
    delete object CurObj+2
    delete object CurObj+3
    delete object CurObj+4
    delete object CurObj+5
    delete object CurObj+6
    delete object CurObj+7
    set object normals CurObj
    set object smoothing CurObj,100
    set object ambient CurObj,0
    set object light CurObj,0
    ColorLimb(CurObj,0,rgb(255,0,0))
    ColorLimb(CurObj,1,rgb(0,0,255))
    ColorLimb(CurObj,2,rgb(0,0,255))
    ColorLimb(CurObj,3,rgb(255,0,0))
    ColorLimb(CurObj,4,rgb(255,0,0))
    ColorLimb(CurObj,5,rgb(255,0,0))
    ColorLimb(CurObj,6,rgb(255,0,0))
    ColorLimb(CurObj,7,rgb(255,0,0))
    ColorLimb(CurObj,8,rgb(100,100,255))
    MakeCartoon(CurObj,0,10)
    MakeCartoon(CurObj,1,1)
    MakeCartoon(CurObj,2,2)
    MakeCartoon(CurObj,3,3)
    MakeCartoon(CurObj,4,4)
    MakeCartoon(CurObj,5,5)
    MakeCartoon(CurObj,6,6)
    MakeCartoon(CurObj,7,7)
    MakeCartoon(CurObj,8,5)
    delete mesh 1
    delete mesh 2
    delete mesh 3
    delete mesh 4
    delete mesh 5
    delete mesh 6
    delete mesh 7
    delete mesh 10
    set object collision on CurObj
    set object collision to boxes CurObj
endfunction CurObj

function MakeCartoon(ObjNum as integer, LimbNum as integer, MeshNum as integer)
    lmb = NextLimb(ObjNum)
    add limb ObjNum,lmb,MeshNum
    offset limb ObjNum,lmb,limb offset x(ObjNum,LimbNum),limb offset y(ObjNum,LimbNum),limb offset z(ObjNum,LimbNum)
    rotate limb ObjNum,lmb,limb angle x(ObjNum,LimbNum),limb angle y(ObjNum,LimbNum),limb angle z(ObjNum,LimbNum)
    scale limb ObjNum,lmb,limb scale x(ObjNum,LimbNum)*-1.0-5,limb scale y(ObjNum,LimbNum)*1.0+5,limb scale z(ObjNum,LimbNum)*1.0+5
    ColorLimb(ObjNum,lmb,rgb(0,0,0))
endfunction

function NextLimb(ObjNum as integer)
    i = 0
    repeat
        inc i
    until limb exist(ObjNum, i) = 0
endfunction i

function ColorLimb(ObjNum as integer, LimbNum as integer, Col as dword)
    texture limb ObjNum,LimbNum,MakeColor(Col)
endfunction

function MakeColor(Col as dword)
    inc CurImg
    make memblock 1,16
    write memblock dword 1,0,1
    write memblock dword 1,4,1
    write memblock dword 1,8,32
    write memblock dword 1,12,Col
    make image from memblock CurImg,1
    delete memblock 1
endfunction CurImg

function CheckLineIntersectSphere(p1 as xyz, p2 as xyz, pSphere as xyz, R as float)
    a as float
    b as float
    c as float

    D as float
    Sq as float
    A2 as float
    mu as float

    L as xyz
    vRel as xyz

    `calculate vectors
    L.x = p2.x-p1.x
    L.y = p2.y-p1.y
    L.z = p2.z-p1.z
    vRel.x = p1.x-pSphere.x
    vRel.y = p1.y-pSphere.y
    vRel.z = p1.z-pSphere.z

    `set up quadratic equation
    a = (L.X * L.X) + (L.Y * L.Y) + (L.z * L.z)
    b = 2.0 * ((L.X * vRel.X) + (L.Y * vRel.Y) + (L.z * vRel.z))
    c = (pSphere.X * pSphere.X) + (pSphere.Y * pSphere.Y) + (pSphere.z * pSphere.z) + (p1.X * p1.X) + (p1.Y * p1.Y) + (p1.z * p1.z) - (2 * ((pSphere.X * p1.X) + (pSphere.Y * p1.Y) + (pSphere.z * p1.z))) - (R * R)

    `calculate discriminant
    D = (b * b) - (4 * a * c)
    if D < 0 or a = 0
        exitfunction 0
    endif
endfunction 1

function createsound(name$,soundnumber,frequency#,length#,loudness#,bend#,decay#,vibratospeed#,vibratodepth#,tremelospeed#,tremelodepth#,attack#)

outWord as word
dword1 as dword: dword2 as dword: dword3 as dword: dword4 as dword
dword5 as dword: dword6 as dword: dword7 as dword

samples=int((length#/1000)*44100)

if memblock exist(1) then delete memblock 1
make memblock 1,samples*2+28

` write 28 memblock header bytes
dword1=1      ` gg query: is this the number of channels?
dword2=2      ` gg query: is this the number of bytes per sample?
dword3=22050  ` gg query: seems to be half the number of samples per second - why?
dword4=88200  ` gg query: is this the number of bytes per second?
dword5=4      ` gg query: what does this represent?
dword6=16     ` gg query:     (ditto)            ?
dword7=0      ` gg query:     (ditto)            ?

position=0
write memblock dword 1, position, dword1 : inc position,4
write memblock dword 1, position, dword2 : inc position,4
write memblock dword 1, position, dword3 : inc position,4
write memblock dword 1, position, dword4 : inc position,4
write memblock dword 1, position, dword5 : inc position,4
write memblock dword 1, position, dword6 : inc position,4
write memblock dword 1, position, dword7 : inc position,4

rem generate and write wave
riseinloudness#=loudness#
for x=1 to samples
  outInteger=int(sin((x/122.5)*(frequency#+vibratodepth#*sin(theta#)))*(loudness#-fallinloudness#-riseinloudness#+tremelodepth#*sin(phi#)))*3.0
  if outInteger <-32767 then outInteger=-32767  ` gg query: is this the valid range?
  if outInteger>32767 then outInteger=32767     ` gg query:       (ditto)          ?
  outWord=outInteger
  inc theta#,vibratospeed#
  inc phi#,tremelospeed#
  dec frequency#,bend#

  if fallinloudness#<loudness#
    inc fallinloudness#,decay#
  endif

  if riseinloudness#>0
    dec riseinloudness#,attack#
  endif

  write memblock word 1, position, outWord : inc position,2
next x

if sound exist(soundnumber)=1 then delete sound soundnumber

make sound from memblock 999, 1 ` assumes you won't need sound number 999!
clone sound soundnumber, 999
delete sound 999

` memblock no longer required
delete memblock 1

endfunction

createsound("foot steps",1,200,20,500,.1,4.0,2.1,10,9.2,9.2,10)

REM Project: birdofprey1
REM Created: 9/7/2007 4:30:10 PM
REM By: Virtual Nomad
REM ***** Main Source File *****
REM

set display mode 800,600,32 : sync on : sync rate 60
autocam off : set camera range 0.1,5000 : color backdrop rgb(255,255,192)
fog on : fog distance 4000 : fog color rgb(168,148,109) : randomize timer()
ink rgb(0,0,0),rgb(255,255,255)

make matrix 1,5000.0,5000.0,50,50
position matrix 1,-2500.0,0.0,-2500.0
randomize matrix 1,20.0
set matrix wireframe off 1
update matrix 1

rem body
make object box 1,10.0,10.0,30.0

rem rightwing
make object triangle 2,0.0,0.0,20.0,70.0,00.0,20.0,0.0,0.0,0.0
make mesh from object 1,2
add limb 1,1,1

delete mesh 1
delete object 2

rem leftwing
make object triangle 2,0.0,0.0,20.0,-70.0,0.0,20.0,0.0,0.0,0.0
make mesh from object 1,2
add limb 1,2,1

delete mesh 1
delete object 2

rem attach wings
offset limb 1,1,5.0,5.0,-5.0
offset limb 1,2,-5.0,5.0,-5.0

rem head
make object cube 2,10.0
make mesh from object 1,2
add limb 1,3,1
offset limb 1,3,0.0,0.0,20.0
set limb smoothing 1,3,100 `eh?

delete mesh 1
delete object 2

color object 1,rgb(143,105,45)


remstart
camy# = 0.0
camx# = 0.0
camz# = -200.0


position camera 0,0,0
point camera 0,0,100.0
remend

position object 1,0.0,1000.0,-200.0
set object cull 1,0

toggle = 1
stage = 1
wingza# = 0.0
accel# = 1.0

rem critter
make object sphere 10,100.0
color object 10,rgb(128,128,0)


do

gosub _critter

gosub _move:
gosub _flap:
gosub _look:
gosub _gravity:

gosub _kill:

set cursor 0,0
print screen fps()
print "speed: ",speed#
print "altitude: ", object position y(1)
print "xa#: ",object angle x(1)
sync
loop

_flap:

if mouseclick() = 1 `flap
   if lastflap + 5 < timer()
     rotate limb 1,1,0.0,0.0,(wingza#)
     rotate limb 1,2,0.0,0.0,(wingza#*-1.0)
     lastflap = timer()
     wingza# = wingza# + (toggle*5.0)
     if abs(wingza#) => 45.0
         toggle = toggle * -1
     endif

   endif
else `glide
   if wingza# <> 0.0
      if wingza# < 0.0
         toggle = 1
      else
         toggle = -1
      endif

      if lastflap + 10 < timer()
         wingza# = wingza# + (toggle * 5.0)
         rotate limb 1,1,0.0,0.0,wingza#
         rotate limb 1,2,0.0,0.0,(wingza#*-1.0)
         lastflap = timer()
      endif
   endif
endif


return

_look:

headya# = headya# + (mousemovex()/4.0)
headxa# = headxa# + (mousemovey()/4.0)
if headya# < -45.0 then headya# = -45.0
if headya# > 45.0 then headya# = 45.0
if headxa# < -45.0 then headxa# = -45.0
if headxa# > 45.0 then headxa# = 45.0

rotate limb 1,3,headxa#,headya#,0.0


px# = object position x(1) : py# = object position y(1) : pz# = object position z(1)
pya# = object angle y(1) : pxa# = object angle z(1) : pza# = object angle z(1)

if controlkey() = 1 `lock camera for swoop
   camya# = pya#
   camxa# = pxa#+40.0
   camza# = pza#
else
camya# = wrapvalue(pya# + headya#) : camxa# = wrapvalue(pxa# + headxa#)
camza# = pza#
endif

position camera px#,py#,pz#

rotate camera camxa#,camya#,camza# : move camera -200.0
return

_move:

if mouseclick() = 1 then accel# = 2.0 else accel# = 1.0

if upkey() = 1 and lastkey + 10 < timer()
   xrotate object 1,(object angle x(1) + (1.0*accel#))
   if object angle x(1) > 80.0 then xrotate object 1,80.0
   lastkey = timer()
endif

if downkey() = 1 and lastkey + 10 < timer()
   xrotate object 1,(object angle x(1) - (1.0*accel#))
   if object angle x(1) < -80.0 then xrotate object 1,-80.0
   lastkey = timer()
endif

if leftkey() and lastkey + 10 < timer()
   yrotate object 1,wrapvalue(object angle y(1) - (1.0))
   lastkey = timer()
endif

if rightkey() and lastkey + 10 < timer()
   yrotate object 1,wrapvalue(object angle y(1) + (1.0))
   lastkey = timer()
endif



speed# = abs(object angle x(1)/10.0)*accel#
if speed# < 1.0 then speed# = 1.0*accel#

move object 1,speed#


return

_gravity:
vel# = abs(object angle x(1))*0.1
position object 1,object position x(1),object position y(1)-vel#,object position z(1)
return

_critter:
critspeed# = 10.0
tcrit = rnd(500) + 500
if lastcritmove + tcrit < timer()
   yrotate object 10,wrapvalue(rnd(90)-45.0)
   scurry = rnd(4)
   if scurry < 4
      move object 10,critspeed#
      color object 10,rgb(255,255,0)
   else
      color object 10,rgb(255,255,255)
   endif
   lastcritmove = timer()
endif

vy# = get ground height (1,object position x(10),object position z(10))
position object 10,object position x(10),vy#+50.0,object position z(10)

return

_kill:

kpx# = object position x(1) : kpy# = object position y(1) : kpz# = object position z(1)
cpx# = object position x(10) : cpy# = object position y(10) : cpz# = object position z(10)

if abs(kpx#-cpx#) < 51.0 and abs(kpy#-cpy#) < 51.0 and abs(kpz#-cpz#) < 51.0
   color object 10,rgb(255,0,0)
endif
return

sync on : set global collision on : disable escapekey : set camera range 5,10000

autocam off

type xyz
    x as float
    y as float
    z as float
endtype

ol as xyz
nw as xyz
tmpxyz as xyz

#constant PLAYER_SPEED 3.0
#constant ENEMY_SPEED 3.5
#constant PLAYER_TURN 1.0
#constant ENEMY_TURN 0.8
#constant CAM_SMOOTH 7

global CurObj as integer
global CurImg as integer
global ECenterX as float
global ECenterY as float
global ECenterZ as float
CurObj = 0
CurImg = 0

inc CurObj
make object plain CurObj,10000,10000
Xrotate object CurObj,90
Ground = CurObj

inc CurObj
make object box CurObj,2,2,10000
ColorLimb(CurObj, 0, rgb(0,0,0))
EnemyBullet = CurObj
inc CurObj
make object box CurObj,2,2,10000
ColorLimb(CurObj, 0, rgb(0,0,0))
PlayerBullet = CurObj
position object PlayerBullet,0,5050,0
position object EnemyBullet,0,5050,0
Xrotate object PlayerBullet,90
Xrotate object EnemyBullet,90
fix object pivot PlayerBullet
fix object pivot EnemyBullet
hide object PlayerBullet
hide object EnemyBullet
set object collision on PlayerBullet
set object collision on EnemyBullet
set object collision to boxes PlayerBullet
set object collision to boxes EnemyBullet

Player = MakePlane()
Enemy = MakePlane()
glue object to limb PlayerBullet,Player,0
glue object to limb EnemyBullet,Enemy,0
position object Player,500,5000,0
position object Enemy,-500,5000,0

null = make matrix4(1)
null = make vector3(2)

MakeExplosion()

color backdrop rgb(50,50,100)

PlayerHealth = 100
EnemyHealth = 100

createsound("LowerEngine",0,1,1,261,8000,0.00,1.00,0.15,5,0.00,0,0.00)
createsound("Explosion",0,2,1,1000,8000,-0.02,0.50,0.50,10,0.00,0,0.00)
createsound("Shoot",0,3,100,200,8000,-0.01,1.00,1.00,5,0.00,0,10.00)
clone sound 4,3
set sound speed 1,100000
loop sound 1
set sound speed 2,20000
set sound speed 3,30000
set sound speed 4,30000

do

    if Stop = 0
        camx# = camera position x()
        camy# = camera position y()
        camz# = camera position z()
        position camera object position x(Player),object position y(Player),object position z(Player)
        set camera to object orientation Player
        pitch camera down 20
        move camera -1000
        pitch camera up 20
        newcamx# = camera position x()
        newcamy# = camera position y()
        newcamz# = camera position z()
        position camera curvevalue(newcamx#,camx#,CAM_SMOOTH),curvevalue(newcamy#,camy#,CAM_SMOOTH),curvevalue(newcamz#,camz#,CAM_SMOOTH)

        move object Player,PLAYER_SPEED
        position object Enemy,object position x(Enemy)-object position x(Player),object position y(Enemy),object position z(Enemy)-object position z(Player)
        position object Player,0,object position y(Player),0
        pitch object down Player,(upkey()-downkey())*PLAYER_TURN
        roll object right Player,(rightkey()-leftkey())*PLAYER_TURN
        if reloading
            dec reloading
            if reloading = 5
                hide object PlayerBullet
                if hit1
                    hide object hitobj1
                endif
            endif
        endif
        if spacekey()
            if reloading = 0
                show object PlayerBullet
                play sound 3
                reloading = 10
                ol.x = object position x(Player)
                ol.y = object position y(Player)
                ol.z = object position z(Player)
                move object Player,10000
                nw.x = object position x(Player)
                nw.y = object position y(Player)
                nw.z = object position z(Player)
                position object Player,ol.x,ol.y,ol.z
                tmpxyz.x = object position x(Enemy)
                tmpxyz.y = object position y(Enemy)
                tmpxyz.z = object position z(Enemy)
                if CheckLineIntersectSphere(ol, nw, tmpxyz, 100)
                    dec EnemyHealth
                    fx# = object position x(Enemy)+rnd(100)-50
                    fy# = object position y(Enemy)+rnd(100)-50
                    fz# = object position z(Enemy)+rnd(100)-50
                    hitobj1 = rnd(699)+101
                    hit1 = 1
                    position object hitobj1,fx#,fy#,fz#
                    show object hitobj1
                    point object hitobj1,camera position x(),camera position y(),camera position z()
                endif
            endif
        endif

        move object Enemy,ENEMY_SPEED

        currentx# = object angle x(Enemy)
        currenty# = object angle y(Enemy)
        currentz# = object angle z(Enemy)
        AimMode = 1
        if object position y(Enemy) < 200
            rotate object Enemy,-90,0,0
            AimMode = 0
        else
            point object Enemy,object position x(Player),object position y(Player),object position z(Player)
            distx# = object position x(Enemy)
            disty# = object position y(Enemy)-object position y(Player)
            distz# = object position z(Enemy)
            if (distx#*distx#+disty#*disty#+distz#*distz#) < 500*500
                steerclear = 1
            else
                if steerclear
                    if (distx#*distx#+disty#*disty#+distz#*distz#) > 900*900
                        steerclear = 0
                    endif
                endif
            endif
            if steerclear
                Xrotate object Enemy,object angle x(Enemy)+180.0
                AimMode = 0
            endif
        endif
        wantedx# = wrapvalue(object angle x(Enemy)+180.0-currentx#)-180.0
        wantedy# = wrapvalue(object angle y(Enemy)+180.0-currenty#)-180.0
        wantedz# = wrapvalue(object angle z(Enemy)+180.0-currentz#)-180.0
        OnTarget = 1
        if wantedx# >= ENEMY_TURN
            inc currentx#,ENEMY_TURN
            OnTarget = 0
        else
            if wantedx# <= -ENEMY_TURN
                dec currentx#,ENEMY_TURN
                OnTarget = 0
            endif
        endif
        if wantedy# >= ENEMY_TURN
            inc currenty#,ENEMY_TURN
            OnTarget = 0
        else
            if wantedy# <= -ENEMY_TURN
                dec currenty#,ENEMY_TURN
                OnTarget = 0
            endif
        endif
        if wantedz# >= ENEMY_TURN
            inc currentz#,ENEMY_TURN
            OnTarget = 0
        else
            if wantedz# <= -ENEMY_TURN
                dec currentz#,ENEMY_TURN
                OnTarget = 0
            endif
        endif
        rotate object Enemy,currentx#,currenty#,currentz#
        if reloaded > 0
            dec reloaded
            if reloaded = 5
                hide object EnemyBullet
                if hit2
                    hide object hitobj2
                endif
            endif
        endif
        if OnTarget and AimMode
            if reloaded = 0
                show object EnemyBullet
                play sound 4
                reloaded = 10
                ol.x = object position x(Enemy)
                ol.y = object position y(Enemy)
                ol.z = object position z(Enemy)
                move object Enemy,10000
                nw.x = object position x(Enemy)+rnd(3000)-1500
                nw.y = object position y(Enemy)+rnd(3000)-1500
                nw.z = object position z(Enemy)+rnd(3000)-1500
                position object Enemy,ol.x,ol.y,ol.z
                tmpxyz.x = object position x(Player)
                tmpxyz.y = object position y(Player)
                tmpxyz.z = object position z(Player)
                if CheckLineIntersectSphere(ol, nw, tmpxyz, 100)
                    dec PlayerHealth
                    fx# = object position x(Player)+rnd(100)-50
                    fy# = object position y(Player)+rnd(100)-50
                    fz# = object position z(Player)+rnd(100)-50
                    hitobj2 = rnd(699)+101
                    hit2 = 1
                    position object hitobj2,fx#,fy#,fz#
                    show object hitobj2
                    point object hitobj2,camera position x(),camera position y(),camera position z()
                endif
            endif
        endif

        if camera position y() <= 0
            if hidden = 0
                hidden = 1
                hide object Ground
            endif
        else
            if hidden = 1
                hidden = 0
                show object Ground
            endif
        endif

        if object collision(Player, Enemy)
            Stop = 1
            explosionx# = object position x(Player)+object position x(Enemy)
            explosiony# = object position y(Player)+object position y(Enemy)
            explosionz# = object position z(Player)+object position z(Enemy)
            ShowExplosion(explosionx#*0.5,explosiony#*0.5,explosionz#*0.5)
            hide object Player
            hide object Enemy
            Msg$ = "...IT'S A DRAW..."
        else
            if object position y(Enemy) < 50
                Stop = 1
                explosionx# = object position x(Enemy)
                explosiony# = object position y(Enemy)
                explosionz# = object position z(Enemy)
                ShowExplosion(explosionx#,explosiony#,explosionz#)
                hide object Enemy
                Msg$ = "YOU WIN!"
            else
                if object position y(Player) < 50
                    Stop = 1
                    explosionx# = object position x(Player)
                    explosiony# = object position y(Player)
                    explosionz# = object position z(Player)
                    ShowExplosion(explosionx#,explosiony#,explosionz#)
                    hide object Player
                    Msg$ = "YOU LOSE!"
                else
                    if EnemyHealth <= 0
                        Stop = 1
                        explosionx# = object position x(Enemy)
                        explosiony# = object position y(Enemy)
                        explosionz# = object position z(Enemy)
                        ShowExplosion(explosionx#,explosiony#,explosionz#)
                        hide object Enemy
                        Msg$ = "YOU WIN!"
                    else
                        if PlayerHealth <= 0
                            Stop = 1
                            explosionx# = object position x(Player)
                            explosiony# = object position y(Player)
                            explosionz# = object position z(Player)
                            ShowExplosion(explosionx#,explosiony#,explosionz#)
                            hide object Player
                            Msg$ = "YOU LOSE!"
                        endif
                    endif
                endif
            endif
        endif

        rem 3D SOUNDS!!! :D
        set identity matrix4 1
        set vector3 2,object position x(Enemy),object position y(Enemy)-object position y(Player),object position z(Enemy)
        set sound volume 1,FixTo(100.0,(3000.0/sqrt(length vector3(2))))
        text 0,60,str$(length vector3(2))
        rotate z matrix4 1,object angle z(Player)
        rotate y matrix4 1,object angle y(Player)
        rotate x matrix4 1,object angle x(Player)
        null# = inverse matrix4(1,1)
        transform coords vector3 2,2,1
        pan# = x vector3(2)*10.0
        if pan# > 10000.0 then pan# = 10000.0
        if pan# < -10000.0 then pan# = -10000.0
        set sound pan 1,pan#
    else
        MoveExplosion()
        inc dead
        if dead = 20
            show object 1000
        endif
        if dead > 150
            set text font "Impact"
            set text size 100
            set text to bold
            center text screen width()/2,100,Msg$
            set text font "System"
            set text to normal
            set text size 12
        endif
    endif
    if escapekey()
        delete objects 1,800
        end
    endif
    
    text 0,0,"Altitude: "+str$(object position y(Player)*0.1,1)+ " metres"
    text 0,20,"Player Health: "+str$(PlayerHealth)
    text 0,40,"Enemy Health: "+str$(EnemyHealth)

    sync
loop

function FixTo(a#, b#)
    if b# < a#
        exitfunction b#
    endif
endfunction a#

function MoveExplosion()
    camx# = camera position x()
    camy# = camera position y()
    camz# = camera position z()
    for i = 101 to 800
        distx# = object position x(i)-ECenterX
        disty# = object position y(i)-ECenterY
        distz# = object position z(i)-ECenterZ
        distx# = distx#*1.1
        disty# = disty#*1.1
        distz# = distz#*1.1
        position object i,distx#+ECenterX,disty#+ECenterY,distz#+ECenterZ
        point object i,camx#,camy#,camz#
    next i
endfunction

function ShowExplosion(x#,y#,z#)
    stop sound 1
    play sound 2
    backdrop off
    cls 0
    make object plain 1000,1000,1000
    lock object on 1000
    position object 1000,0,0,10
    ColorLimb(1000,0,rgb(0,0,0))
    set alpha mapping on 1000,2
    hide object 1000
    ECenterX = x#
    ECenterY = y#
    ECenterZ = z#
    dec x#,100.0
    dec y#,100.0
    dec z#,100.0
    for i = 101 to 800
        position object i, x#+rnd(200), y#+rnd(200), z#+rnd(200)
        point object i, camera position x(), camera position y(), camera position z()
        show object i
    next i
endfunction

function MakeExplosion()
    Col1 = MakeColor(rgb(255,100,100))
    Col2 = MakeColor(rgb(255,255,100))
    Col3 = MakeColor(rgb(255,200,50))
    Col4 = MakeColor(rgb(255,200,100))
    Col5 = MakeColor(rgb(255,220,100))
    Col6 = MakeColor(rgb(255,230,100))
    Col7 = MakeColor(rgb(255,240,150))
    nextobjnum = 100
    for t = 1 to 7
        select t
            case 1 : col = Col1 : endcase
            case 2 : col = Col2 : endcase
            case 3 : col = Col3 : endcase
            case 4 : col = Col4 : endcase
            case 5 : col = Col5 : endcase
            case 6 : col = Col6 : endcase
            case 7 : col = Col7 : endcase
        endselect
        for d = 1 to 100
            inc nextobjnum
            make object plain nextobjnum,50,50
            ghost object on nextobjnum
            texture object nextobjnum,col
            hide object nextobjnum
        next d
    next t
endfunction

function MakePlane()
    inc CurObj
    make object cylinder CurObj,100
    make mesh from object 10,CurObj

    lock vertexdata for limb CurObj,0
    for i = 0 to get vertexdata vertex count()
        if get vertexdata position y(i) < 0
            set vertexdata position i,get vertexdata position x(i)*0.1,get vertexdata position y(i),get vertexdata position z(i)*0.1
        else
            set vertexdata position i,get vertexdata position x(i)*0.3,get vertexdata position y(i),get vertexdata position z(i)*0.3
        endif
    next i
    unlock vertexdata
    lock vertexdata for mesh 10
    for i = 0 to get vertexdata vertex count()
        if get vertexdata position y(i) < 0
            set vertexdata position i,get vertexdata position x(i)*0.1,get vertexdata position y(i),get vertexdata position z(i)*0.1
        else
            set vertexdata position i,get vertexdata position x(i)*0.3,get vertexdata position y(i),get vertexdata position z(i)*0.3
        endif
    next i
    unlock vertexdata
    make object box CurObj+1,100,1,20
    make object box CurObj+2,100,1,20
    make object sphere CurObj+3,10
    make object sphere CurObj+4,10
    make object sphere CurObj+5,50,20,20
    make object cylinder CurObj+6,40
    make object cylinder CurObj+7,40
    Xrotate object CurObj,90
    fix object pivot CurObj
    make mesh from object 1,CurObj+1
    make mesh from object 2,CurObj+2
    make mesh from object 3,CurObj+3
    lock vertexdata for mesh 3
    for i = 0 to get vertexdata vertex count()
        if get vertexdata position z(i) > 0
            set vertexdata position i,get vertexdata position x(i),get vertexdata position y(i),0
        endif
    next i
    unlock vertexdata
    make mesh from object 4,CurObj+4
    make mesh from object 5,CurObj+5
    make mesh from object 6,CurObj+6
    make mesh from object 7,CurObj+7
    add limb CurObj,1,1
    add limb CurObj,2,2
    add limb CurObj,3,3
    add limb CurObj,4,4
    add limb CurObj,5,5
    add limb CurObj,6,6
    add limb CurObj,7,7
    add limb CurObj,8,5
    offset limb CurObj,1,0,30,15
    offset limb CurObj,2,0,30,-25
    offset limb CurObj,3,0,-50,0
    offset limb CurObj,4,0,-50,0
    offset limb CurObj,5,0,50,0
    offset limb CurObj,6,30,30,-5
    offset limb CurObj,7,-30,30,-5
    offset limb CurObj,8,0,55,0
    rotate limb CurObj,1,90,0,0
    rotate limb CurObj,2,90,0,0
    rotate limb CurObj,6,90,0,0
    rotate limb CurObj,7,90,0,0
    scale limb CurObj,3,100,200,500
    scale limb CurObj,4,500,200,100
    scale limb CurObj,5,61,5,61
    scale limb CurObj,6,10,100,10
    scale limb CurObj,7,10,100,10
    scale limb CurObj,8,100,5,100
    delete object CurObj+1
    delete object CurObj+2
    delete object CurObj+3
    delete object CurObj+4
    delete object CurObj+5
    delete object CurObj+6
    delete object CurObj+7
    set object normals CurObj
    set object smoothing CurObj,100
    set object ambient CurObj,0
    set object light CurObj,0
    ColorLimb(CurObj,0,rgb(255,0,0))
    ColorLimb(CurObj,1,rgb(0,0,255))
    ColorLimb(CurObj,2,rgb(0,0,255))
    ColorLimb(CurObj,3,rgb(255,0,0))
    ColorLimb(CurObj,4,rgb(255,0,0))
    ColorLimb(CurObj,5,rgb(255,0,0))
    ColorLimb(CurObj,6,rgb(255,0,0))
    ColorLimb(CurObj,7,rgb(255,0,0))
    ColorLimb(CurObj,8,rgb(100,100,255))
    MakeCartoon(CurObj,0,10)
    MakeCartoon(CurObj,1,1)
    MakeCartoon(CurObj,2,2)
    MakeCartoon(CurObj,3,3)
    MakeCartoon(CurObj,4,4)
    MakeCartoon(CurObj,5,5)
    MakeCartoon(CurObj,6,6)
    MakeCartoon(CurObj,7,7)
    MakeCartoon(CurObj,8,5)
    delete mesh 1
    delete mesh 2
    delete mesh 3
    delete mesh 4
    delete mesh 5
    delete mesh 6
    delete mesh 7
    delete mesh 10
    set object collision on CurObj
    set object collision to boxes CurObj
endfunction CurObj

function MakeCartoon(ObjNum as integer, LimbNum as integer, MeshNum as integer)
    lmb = NextLimb(ObjNum)
    add limb ObjNum,lmb,MeshNum
    offset limb ObjNum,lmb,limb offset x(ObjNum,LimbNum),limb offset y(ObjNum,LimbNum),limb offset z(ObjNum,LimbNum)
    rotate limb ObjNum,lmb,limb angle x(ObjNum,LimbNum),limb angle y(ObjNum,LimbNum),limb angle z(ObjNum,LimbNum)
    scale limb ObjNum,lmb,limb scale x(ObjNum,LimbNum)*-1.0-5,limb scale y(ObjNum,LimbNum)*1.0+5,limb scale z(ObjNum,LimbNum)*1.0+5
    ColorLimb(ObjNum,lmb,rgb(0,0,0))
endfunction

function NextLimb(ObjNum as integer)
    i = 0
    repeat
        inc i
    until limb exist(ObjNum, i) = 0
endfunction i

function ColorLimb(ObjNum as integer, LimbNum as integer, Col as dword)
    texture limb ObjNum,LimbNum,MakeColor(Col)
endfunction

function MakeColor(Col as dword)
    inc CurImg
    make memblock 1,16
    write memblock dword 1,0,1
    write memblock dword 1,4,1
    write memblock dword 1,8,32
    write memblock dword 1,12,Col
    make image from memblock CurImg,1
    delete memblock 1
endfunction CurImg

function CheckLineIntersectSphere(p1 as xyz, p2 as xyz, pSphere as xyz, R as float)
    a as float
    b as float
    c as float

    D as float
    Sq as float
    A2 as float
    mu as float

    L as xyz
    vRel as xyz

    `calculate vectors
    L.x = p2.x-p1.x
    L.y = p2.y-p1.y
    L.z = p2.z-p1.z
    vRel.x = p1.x-pSphere.x
    vRel.y = p1.y-pSphere.y
    vRel.z = p1.z-pSphere.z

    `set up quadratic equation
    a = (L.X * L.X) + (L.Y * L.Y) + (L.z * L.z)
    b = 2.0 * ((L.X * vRel.X) + (L.Y * vRel.Y) + (L.z * vRel.z))
    c = (pSphere.X * pSphere.X) + (pSphere.Y * pSphere.Y) + (pSphere.z * pSphere.z) + (p1.X * p1.X) + (p1.Y * p1.Y) + (p1.z * p1.z) - (2 * ((pSphere.X * p1.X) + (pSphere.Y * p1.Y) + (pSphere.z * p1.z))) - (R * R)

    `calculate discriminant
    D = (b * b) - (4 * a * c)
    if D < 0 or a = 0
        exitfunction 0
    endif
endfunction 1

function createsound(name$,soundtype,soundnumber,frequency#,length#,loudness#,bend#,decay#,vibratospeed#,vibratodepth#,tremelospeed#,tremelodepth#,attack#)

outWord as word
dword1 as dword: dword2 as dword: dword3 as dword: dword4 as dword
dword5 as dword: dword6 as dword: dword7 as dword

samples=int((length#/1000)*44100)

if memblock exist(1) then delete memblock 1
make memblock 1,samples*2+44

` write 28 memblock header bytes
dword1=1      ` gg query: is this the number of channels?
dword2=2
dword3=22050  ` gg query: seems to be half the number of samples per second - why?
dword4=88200  ` gg query: is this the number of bytes per second?
dword5=4      ` gg query: what does this represent?
dword6=16     ` gg query:     (ditto)            ?
dword7=0      ` gg query:     (ditto)            ?

position=0
write memblock byte 1, position, asc("R") : inc position
write memblock byte 1, position, asc("I") : inc position
write memblock byte 1, position, asc("F") : inc position
write memblock byte 1, position, asc("F") : inc position

write memblock dword 1, position, samples*2+36 : inc position,4

write memblock byte 1, position, asc("W") : inc position
write memblock byte 1, position, asc("A") : inc position
write memblock byte 1, position, asc("V") : inc position
write memblock byte 1, position, asc("E") : inc position

write memblock byte 1, position, asc("f") : inc position
write memblock byte 1, position, asc("m") : inc position
write memblock byte 1, position, asc("t") : inc position
write memblock byte 1, position, asc(" ") : inc position
write memblock dword 1, position, 16 : inc position,4

write memblock word 1, position, dword1 : inc position,2
write memblock word 1, position, dword2 : inc position,2
write memblock dword 1, position, dword3 : inc position,4
write memblock dword 1, position, dword4 : inc position,4
write memblock word 1, position, dword5 : inc position,2
write memblock word 1, position, dword6 : inc position,2
`write memblock word 1, position, dword7 : inc position,2 `MAYBE UNCOMMENT?

write memblock byte 1, position, asc("d") : inc position
write memblock byte 1, position, asc("a") : inc position
write memblock byte 1, position, asc("t") : inc position
write memblock byte 1, position, asc("a") : inc position
write memblock dword 1, position, samples*2 : inc position,4

rem generate and write wave
`inc param_attackamount#,0.0001
riseinloudness#=loudness#
for x=1 to samples
  outInteger=int(sin((x/122.5)*(frequency#+vibratodepth#*sin(theta#)))*(loudness#-fallinloudness#-riseinloudness#+tremelodepth#*sin(phi#)))*3.0
  if outInteger <-32767 then outInteger=-32767  ` gg query: is this the valid range?
  if outInteger>32767 then outInteger=32767     ` gg query:       (ditto)          ?
  outWord=outInteger
  inc theta#,vibratospeed#
  inc phi#,tremelospeed#
  dec frequency#,bend#
  if fallinloudness#<loudness#
		inc fallinloudness#,decay#
  endif
  if riseinloudness#>0
    dec riseinloudness#,attack#
  endif
  write memblock word 1,position,outWord : inc position,2
next x

if file exist(name$+".wav") then delete file name$+".wav"
open to write 1,name$+".wav"
make file from memblock 1,1
close file 1

if sound exist(soundnumber)=1 then delete sound soundnumber

if soundtype
    load 3dsound name$+".wav", soundnumber
else
    load sound name$+".wav", soundnumber
endif

` memblock no longer required
delete memblock 1

endfunction

Sync On: Sync Rate 60:AutoCam Off
Color Backdrop RGB(50,50,180)
Set Camera Range .1,15000
Fog Distance 4000,8000
Fog Color Rgb(50,50,180)
Fog On

Create_Heightmap(20,20)
Grass()
Make_Terrain()
Place_Houses()
Sync
Position Camera 100,100,100
Turn Camera Right 45
Do
   Control_Plane()
   Set Cursor 0,0
   Print Screen FPS()
   Print "Speed: ";Speed(0)*15.0
   Print "Altitude: ";Height(0)
   Fog Distance 4000,8000
   Fog Color Rgb(50,50,180)
   Sync
Loop

Function Control_Plane()
   Dim Speed(0) as Float
   Dim Height(0) as Float
   Speed(0)=Speed(0)+(UpKey()-DownKey())*.001
   If Speed(0)>5 Then Speed(0)=5
   If Speed(0)<0 Then Speed(0)=0
   Pitch Camera Up .1*(KeyState(31)-KeyState(17))
   Roll Camera Left .1*(KeyState(30)-KeyState(32))
   Turn Camera Left .05*(LeftKey()-RightKey())
   Move Camera Speed(0)
   x#=Camera Position X()
   z#=Camera Position Z()
   ground#=Get Terrain Ground Height(1,x#,z#)+.5
   Height(0)=Camera Position Y()-.01
   If Height(0)<ground# Then Height(0)=ground#
   Position Camera x#,Height(0),z#
EndFunction

Function Make_Terrain()
   `If Not File Exist("Temp_Terrain.dbo")
      File$="Heightmap.bmp"
      Load Image File$,101,1
      Make Object Terrain 1
      Set Terrain Heightmap 1,File$
      Set Terrain Texture 1,4,4
      Set Terrain Tiling 1,4
      Set Terrain Scale 1,1000,100,1000
      Set Terrain Split 1,16
      Build Terrain 1
      Set Object Fog 1,1
      Set OBject Light 1,0
      `Save Terrain "Temp_Terrain.dbo",1
   `EndIf
Endfunction

Function Place_Houses()
   tx=Object Size X(1)
   tz=Object Size Z(1)
   Make Object Box 1000,2,4,2
   For i = 1 to 3000
      Instance Object 1000+i,1000
      x#=Rnd(tx):z#=Rnd(tz)
      y#=Get Terrain Ground Height(1,x#,z#)+1.0
      Position Object 1000+i,x#,y#,z#
   Next i
Endfunction


Function Splotch(ImageID,h,s)
   Set Cursor 500,0
   Print s
   `Lock Pixels
   Ink 0,0
   Box 200,200,230+s,230+s
   c=rnd(7)+h-3
   Ink Rgb(c,c,c),0
   r=rnd(s/2)+s/4
   For i# = 0.0 to 360.0 step 2
      x=sin(i#)*r+215+s/2
      y=cos(i#)*r+215+s/2
      line 207+s/2,207+s/2,x,y
      r=r+(rnd(2)-1)
      if r>s+15 then r=s+15
      m=s-15:If m<2 then m=2
      if r<m then r=m
   Next i#
   `Unlock Pixels
   Get Image ImageID,200,200,230+s,230+s,1
Endfunction

Function Create_Heightmap(x,y)
   Ink rgb(128,128,128),0
   Box 0,0,199,199
   For ny=0 to 5
      For nx=0 to 5
         Randomize Timer()
         TileHeight=10+rnd(6)+rnd(6)+rnd(6)
         ox=32+(nx*32):oy=32+(ny*32)
         mx=32+((nx+1)*32):my=32+((ny+1)*32)
         Splotch(1,TileHeight,34)
         Sprite 1,200,200,1
         Size Sprite 1,84,84
         Set Sprite 1,0,1
         Set Sprite Alpha 1,100
         Paste Sprite 1,ox+rnd(32)-26,oy+rnd(32)-26
         Size Sprite 1,64,64
         Paste Sprite 1,ox+rnd(32)-16,oy+rnd(32)-16
         Box ox,oy,mx,my
      Next nx
   Next ny
   For ny=0 to 5
      For nx=0 to 5
         Randomize Timer()
         ox=32+(nx*32):oy=32+(ny*32)
         For i = 1 to rnd(3)+2
            sx=ox+rnd(32)-16:sy=oy+rnd(32)-16
            h=point(sx,sy)+Rnd(5)-Rnd(5)
            Splotch(1,h,15)
            Sprite 1,200,200,1
            Set Sprite 1,0,1
            Set Sprite Alpha 1,128
            Paste Sprite 1,sx,sy
         Next i
         Randomize Timer()
         ox=32+(nx*32):oy=32+(ny*32)
         for noise=1 to rnd(50)+rnd(50)+rnd(50)+50
            noisex=rnd(32)+ox
            noisey=rnd(32)+oy
            c=point(noisex,noisey)
            c=rgbr(c)+(rnd(5)-2)
            if c<0 then c=0
            if c>255 then c=255
            ink rgb(c,c,c),0
            dot noisex,noisey
         Next noise
      Next nx
   Next ny
   Blur Bitmap 0,2
   if file exist("Heightmap.bmp") Then Delete File "Heightmap.bmp"
   Get Image 2,32,32,32+x*5,32+y*5,0
   Save Image "Heightmap.bmp",2
   If Sprite Exist(1) Then Delete Sprite 1
   Ink Rgb(255,255,255),0
   Print "Heightmap Done"
   Sync
Endfunction

Function Grass()
   If Bitmap Exist(1) Then Delete Bitmap 1
   Create Bitmap 1,512,512
   Set Current Bitmap 1
   Ink Rgb(0,90,0),0
   Box 0,0,511,511
   g=0
   Do
      Splotch(1,180,15)
      Sprite 1,200,200,1
      Size Sprite 1,rnd(3)+1,Rnd(3)+1
      Set Sprite Alpha 1,128
      Set Sprite Diffuse 1,0,255,0
      Paste Sprite 1,rnd(67)-2,rnd(67)-2
      g=g+1
      If rnd(500)+500<g Then Exit
   Loop
   Get Image 3,1,1,64,64,0
   Ink Rgb(0,90,0),0
   Box 0,0,511,511
   g=0
   Do
      Splotch(1,rnd(80)+130,30)
      Sprite 1,200,200,1
      Size Sprite 1,rnd(10)+10,Rnd(10)+10
      Set Sprite Alpha 1,64
      Set Sprite Diffuse 1,0,255,0
      Paste Sprite 1,rnd(75)-10,rnd(75)-10
      g=g+1
      If rnd(1000)+200<g Then Exit
   Loop
   Sprite 2,-1000,0,2
   Set Sprite Alpha 2,50
   Size Sprite 2,512,512
   Paste Sprite 2,0,0
   Get Image 4,1,1,64,64,0
   Set Current Bitmap 0
   Delete Bitmap 1
   Delete Sprite 1
Endfunction

Sync On: Sync Rate 60:AutoCam Off
Color Backdrop RGB(50,50,180)
Set Camera Range .02,15000
Fog Distance 4000,8000
Fog Color Rgb(50,50,180)
Fog On

Null=Make Vector3(1)
Null=MAke Vector3(2)

#Constant _Gravity .02
#Constant _Lift .02
#Constant _Friction .98

Make_Angle_Indicator()
Cls
Make_Plane()
Create_Heightmap(20,20)
Grass()
Make_Terrain()
Place_Houses()
Sync
Position Camera 100,100,100
x#=Camera Position X()
z#=Camera Position Z()
y#=Get Terrain Ground Height(1,x#,z#)+.5
Position Camera x#,y#,z#
Turn Camera Right 45
Do
   Control_Plane()
   Draw_Altitude()
   Position_Instruments()
   Set Cursor 0,0
   Print Screen FPS()
   Print "Speed: ";Int(Speed(0)*15.0)
   Print "Altitude: ";Int(Height(0))
   Fog Distance 4000,8000
   Fog Color Rgb(50,50,180)
   Sync
Loop


Function Control_Plane()
   Dim Speed(0) as Float
   Dim Thrust(0) as Float
   Dim Height(0) as Float
   Dim Lift(0)
   Dim OnGroundFlag(0)
   Set Vector3 1,Camera Position X(),Camera Position Y(),Camera Position Z()
   Thrust(0)=Thrust(0)+(UpKey()-DownKey())*.0001
   If Thrust(0)>.1 Then Thrust(0)=.1
   If Thrust(0)<0 Then Thrust(0)=0
   Pitch Camera Up .1*(KeyState(31)-KeyState(17))
   Roll Camera Left .1*(KeyState(30)-KeyState(32))
   Turn Camera Left .05*(LeftKey()-RightKey())
   Move Camera Thrust(0)
   Lift(0)=Speed(0)*_Lift
   Pitch Camera Up 90
   Move Camera Lift(0)
   Pitch Camera Down 90
   x#=Camera Position X()
   z#=Camera Position Z()
   ground#=Get Terrain Ground Height(1,x#,z#)+.5
   Height(0)=Camera Position Y()-_Gravity
   x#=x#+X Vector3(2):Height(0)=Height(0)+Y Vector3(2):z#=z#+Z Vector3(2)
   If Height(0)<ground#
      Height(0)=ground#
      `If Y Vector3(2)<-.1 and OnGroundFlag(0)=0 Then Crash()
      OnGroundFlag(0)=1
   Else
      OnGroundFlag(0)=0
   Endif
   Position Camera x#,Height(0),z#
   Set Vector3 2,x#-X Vector3(1),Height(0)-Y Vector3(1),z#-Z Vector3(1)
   Multiply Vector3 2,_Friction
   Speed(0)=Length Vector3(2)
EndFunction

Function Crash()
   Get Image 555,0,0,Screen Width(),Screen Height()
   Sprite 555,-2000,0,555
   Set Sprite Diffuse 555,255,0,0
   Set Sprite Alpha 555,80
   Paste Sprite 555,0,0
   Size Sprite 555,Sprite Width(555)-4,Sprite Height(555)-4
   Paste Sprite 555,2,2
   Size Sprite 555,Sprite Width(555)-8,Sprite Height(555)-8
   Paste Sprite 555,6,6
   Size Sprite 555,Sprite Width(555)-16,Sprite Height(555)-16
   Paste Sprite 555,12,14

   Sync
   Do
   Loop
Endfunction

Function Draw_Altitude()
   y1#=Get Terrain Ground Height(1,Camera Position X(),Camera Position Z())
   y2#=Height(0)
   d#=y2#-y1#
   Ink RGB(255,0,0),0
   y=Screen Height()-5
   Line 0,y,20,y
   Ink RGB(255,0,0),0
   If d#>100
      Ink RGB(255,255,0),0
      d#=d#/10
   Endif
   If d#>100
      Ink RGB(255,255,255),0
      d#=d#/10
   Endif
   y=y-(d#/2)
   Line 0,y,20,y
   Ink RGB(255,255,255),0
Endfunction


Function Make_Terrain()
   `If Not File Exist("Temp_Terrain.dbo")
      File$="Heightmap.bmp"
      Load Image File$,101,1
      Make Object Terrain 1
      Set Terrain Heightmap 1,File$
      Set Terrain Texture 1,4,4
      Set Terrain Tiling 1,4
      Set Terrain Scale 1,1000,100,1000
      Set Terrain Split 1,16
      Build Terrain 1
      Set Object Fog 1,1
      Set OBject Light 1,0
      `Save Terrain "Temp_Terrain.dbo",1
   `EndIf
Endfunction

Function Place_Houses()
   tx=Object Size X(1)
   tz=Object Size Z(1)
   Make Object Box 1000,2,4,2
   For i = 1 to 3000
      Instance Object 1000+i,1000
      x#=Rnd(tx):z#=Rnd(tz)
      y#=Get Terrain Ground Height(1,x#,z#)+1.0
      Position Object 1000+i,x#,y#,z#
   Next i
Endfunction

Function Make_Angle_Indicator()
   Ink RGB(255,255,0),0
   Box 0,0,7,7
   Ink RGB(0,0,255),0
   Box 8,0,16,7
   Ink RGB(255,0,0),0
   Box 0,8,16,16
   Ink 0,0
   Line 0,0,0,16
   Line 4,0,4,16
   Line 8,0,8,16
   Line 12,0,12,16
   Get Image 99,0,0,16,16,1
   Make Object Sphere 99,.25,20,20
   Texture Object 99,99
   Set Object Light 99,0
   Disable Object ZDepth 99
   Ink RGB(255,255,255),0
EndFunction

Function Make_Plane()
   Ink RGB(64,64,64),0
   Box 0,0,64,64
   Get Image 98,0,0,64,64,1
   Ink RGB(255,255,255),0
   Make Object Cylinder 98,9
   Scale Object 98,100,30,100
   Set Object Cull 98,0
   `Set Object Light 98,0
   Texture Object 98,98
   Color Object 98,RGB(32,32,32)
   Disable Object ZDepth 98
   Make Object Cylinder 97,9
   Scale Object 97,100,30,100
   Set Object Cull 97,0
   `Set Object Light 97,0
   Texture Object 97,98
   Color Object 97,RGB(32,32,32)
   Disable Object ZDepth 97
Endfunction


Function Position_Instruments()
   Align_Object_With_Camera(99)
   Move Object 99,3
   Move Object Down 99,1.6
   Move Object Right 99,2
   Rotate Object 99,0,0,0
   Align_Object_With_Camera(98)
   Move Object Down 98,2.5
   Pitch Object Down 98,10
   Align_Object_With_Camera(97)
   Move Object Up 97,3
Endfunction

Function Align_Object_With_Camera(ObjID)
   Position Object ObjID,Camera Position X(),Camera Position Y(),Camera Position Z()
   Rotate Object ObjID,Camera Angle X(),Camera Angle Y(),Camera Angle Z()
EndFunction

Function Splotch(ImageID,h,s)
   Set Cursor 500,0
   Print s
   `Lock Pixels
   Ink 0,0
   Box 200,200,230+s,230+s
   c=rnd(7)+h-3
   Ink Rgb(c,c,c),0
   r=rnd(s/2)+s/4
   For i# = 0.0 to 360.0 step 2
      x=sin(i#)*r+215+s/2
      y=cos(i#)*r+215+s/2
      line 207+s/2,207+s/2,x,y
      r=r+(rnd(2)-1)
      if r>s+15 then r=s+15
      m=s-15:If m<2 then m=2
      if r<m then r=m
   Next i#
   `Unlock Pixels
   Get Image ImageID,200,200,230+s,230+s,1
Endfunction

Function Create_Heightmap(x,y)
   Ink rgb(128,128,128),0
   Box 0,0,199,199
   For ny=0 to 5
      For nx=0 to 5
         Randomize Timer()
         TileHeight=10+rnd(6)+rnd(6)+rnd(6)
         ox=32+(nx*32):oy=32+(ny*32)
         mx=32+((nx+1)*32):my=32+((ny+1)*32)
         Splotch(1,TileHeight,34)
         Sprite 1,200,200,1
         Size Sprite 1,84,84
         Set Sprite 1,0,1
         Set Sprite Alpha 1,100
         Paste Sprite 1,ox+rnd(32)-26,oy+rnd(32)-26
         Size Sprite 1,64,64
         Paste Sprite 1,ox+rnd(32)-16,oy+rnd(32)-16
         Box ox,oy,mx,my
      Next nx
   Next ny
   For ny=0 to 5
      For nx=0 to 5
         Randomize Timer()
         ox=32+(nx*32):oy=32+(ny*32)
         For i = 1 to rnd(3)+2
            sx=ox+rnd(32)-16:sy=oy+rnd(32)-16
            h=point(sx,sy)+Rnd(5)-Rnd(5)
            Splotch(1,h,15)
            Sprite 1,200,200,1
            Set Sprite 1,0,1
            Set Sprite Alpha 1,128
            Paste Sprite 1,sx,sy
         Next i
         Randomize Timer()
         ox=32+(nx*32):oy=32+(ny*32)
         for noise=1 to rnd(50)+rnd(50)+rnd(50)+50
            noisex=rnd(32)+ox
            noisey=rnd(32)+oy
            c=point(noisex,noisey)
            c=rgbr(c)+(rnd(5)-2)
            if c<0 then c=0
            if c>255 then c=255
            ink rgb(c,c,c),0
            dot noisex,noisey
         Next noise
      Next nx
   Next ny
   Blur Bitmap 0,2
   if file exist("Heightmap.bmp") Then Delete File "Heightmap.bmp"
   Get Image 2,32,32,32+x*5,32+y*5,0
   Save Image "Heightmap.bmp",2
   If Sprite Exist(1) Then Delete Sprite 1
   Ink Rgb(255,255,255),0
   Print "Heightmap Done"
   Sync
Endfunction

Function Grass()
   If Bitmap Exist(1) Then Delete Bitmap 1
   Create Bitmap 1,512,512
   Set Current Bitmap 1
   Ink Rgb(0,90,0),0
   Box 0,0,511,511
   g=0
   Do
      Splotch(1,180,15)
      Sprite 1,200,200,1
      Size Sprite 1,rnd(3)+1,Rnd(3)+1
      Set Sprite Alpha 1,128
      Set Sprite Diffuse 1,0,255,0
      Paste Sprite 1,rnd(67)-2,rnd(67)-2
      g=g+1
      If rnd(500)+500<g Then Exit
   Loop
   Get Image 3,1,1,64,64,0
   Ink Rgb(0,90,0),0
   Box 0,0,511,511
   g=0
   Do
      Splotch(1,rnd(80)+130,30)
      Sprite 1,200,200,1
      Size Sprite 1,rnd(10)+10,Rnd(10)+10
      Set Sprite Alpha 1,64
      Set Sprite Diffuse 1,0,255,0
      Paste Sprite 1,rnd(75)-10,rnd(75)-10
      g=g+1
      If rnd(1000)+200<g Then Exit
   Loop
   Sprite 2,-1000,0,2
   Set Sprite Alpha 2,50
   Size Sprite 2,512,512
   Paste Sprite 2,0,0
   Get Image 4,1,1,64,64,0
   Set Current Bitmap 0
   Delete Bitmap 1
   Delete Sprite 1
Endfunction

RiiDii

Diggsey - nice job!