Sorry your browser is not supported!

sync on
set display mode 1024,768,32

global centerx=512
global centery=384
global player_position=1
global can_move=timer()

type bullet
   xpos as float
   ypos as float
   xstepvalue as float
   ystepvalue as float
   x_des as float
   y_des as float
   spritenumber as integer
   endstep as integer
endtype

dim shot(-1) as bullet

create bitmap 1,10,10
ink rgb(255,0,0),0
line 1,1,9,9:line 9,0,0,9:line 0,5,9,5:line 5,0,5,9
get image 1,0,0,9,9,1
delete bitmap 1


dim shapepoint(33,2)
for a = 1 to 32
   for b = 1 to 2
      read shapepoint(a,b)
   next b
next a

do
   cls
   for a = 1 to 32


      nextpoint=a+1
      if nextpoint>32 then nextpoint=1
      ink rgb(255,255,0),0
      line centerx+shapepoint(a,1),centery+shapepoint(a,2),centerx+(shapepoint(a,1)/16),centery+(shapepoint(a,2)/16)
      ink rgb(0,0,255),0
      line centerx+shapepoint(a,1),centery+shapepoint(a,2),centerx+shapepoint(nextpoint,1),centery+shapepoint(nextpoint,2)
      line centerx+(shapepoint(a,1)/16),centery+(shapepoint(a,2)/16),centerx+(shapepoint(nextpoint,1)/16),centery+(shapepoint(nextpoint,2)/16)


   next a
   if can_move<=timer()
      if leftkey()=1
         dec player_position
         can_move=timer()+100

      endif
      if rightkey()=1
         inc player_position
         can_move=timer()+100

      endif
      if spacekey()=1
         add_bullet()
         can_move=timer()+100

      endif
   endif

   if player_position<1 then player_position=32
   if player_position>32 then player_position=1
   if array count(shot())>=0 then move_bullets()

   ink rgb(255,0,255),0
   endpoint=player_position+1
   if endpoint>32 then endpoint=1
   box (centerx+shapepoint(player_position,1)+centerx+shapepoint(endpoint,1))/2-5,(centery+shapepoint(player_position,2)+centery+shapepoint(endpoint,2))/2-5,(centerx+shapepoint(player_position,1)+centerx+shapepoint(endpoint,1))/2+5,(centery+shapepoint(player_position,2)+centery+shapepoint(endpoint,2))/2+5
   sync
loop


` Square level
data -200,-200,-150,-200,-100,-200,-50,-200,0,-200,50,-200,100,-200,150,-200
data 200,-200,200,-150,200,-100,200,-50,200,0,200,50,200,100,200,150
data 200,200,150,200,100,200,50,200,0,200,-50,200,-100,200,-150,200
data -200,200,-200,150,-200,100,-200,50,-200,0,-200,-50,-200,-100,-200,-150

function add_bullet()
   array insert at top shot()
   endpoint=player_position+1
   if endpoint>32 then endpoint=1
   shot(0).xpos=(centerx+shapepoint(player_position,1)+centerx+shapepoint(endpoint,1))/2
   shot(0).ypos=(centery+shapepoint(player_position,2)+centery+shapepoint(endpoint,2))/2
   shot(0).x_des=(centerx+(shapepoint(player_position,1)/16)+centerx+(shapepoint(endpoint,1)/16))/2
   shot(0).y_des=(centery+(shapepoint(player_position,2)/16)+centery+(shapepoint(endpoint,2)/16))/2
   shot(0).xstepvalue=(shot(0).x_des-shot(0).xpos)/20
   shot(0).ystepvalue=(shot(0).y_des-shot(0).ypos)/20
   shot(0).spritenumber=free_sprite()
   shot(0).endstep=20
   sprite shot(0).spritenumber,shot(0).xpos,shot(0).ypos,1
endfunction

function move_bullets()
   for a = array count(shot()) to 0 step -1
   shot(a).xpos=shot(a).xpos+shot(a).xstepvalue
   shot(a).ypos=shot(a).ypos+shot(a).ystepvalue
   dec shot(a).endstep
   scale sprite shot(a).spritenumber,40+shot(a).endstep*3
   sprite shot(a).spritenumber,shot(a).xpos,shot(a).ypos,1
   if shot(a).endstep<=0
      delete sprite shot(a).spritenumber
      array delete element shot(),a
   endif
   next a
endfunction


function free_sprite()
   x=0
   repeat
      inc x
   until sprite exist(x)=0
endfunction x

global screenx=1024
global screeny=768
set display mode screenx,screeny,32
hide mouse
backdrop on
color backdrop 0
sync on
global xoff
xoff=int(screenx/2)
global yoff
yoff=int(screeny/2)

rem Set up sounds
for nums=1 to 4
  make_sound(nums)
next nums
set sound volume 1,80
set sound volume 2,80
set sound volume 3,80
set sound volume 4,90

rem Setup forcefield
global dim forcefield(2,11)
global dim angle#(2)
global dim shell(2)
global dim shell_top(2)
global rad=50
shell_top(0)=0
shell_top(1)=20
shell_top(2)=40
shell(0)=shell_top(0)
shell(1)=shell_top(1)
shell(2)=shell_top(2)

rem Setup ship
global ship_x#
global ship_y#
global ship
ship_a#=0.0
ship_step#=1.0
global ship_xp#=0.0
global ship_yp#=0.0
ship_max#=2.0
global dim sx#(50)
global dim sy#(50)
global dim sxp#(50)
global dim syp#(50)
global s_c=0
drag#=0.997
global shipfield=0
global shipfieldp=255
global shipfieldr=50

rem Set up target
t_a#=0.0
global target=0
global dim tx#(50)
global dim ty#(50)
global dim txp#(50)
global dim typ#(50)
global t_c=0
global target_shoot=0
global tsx#
global tsy#
global tsxp#
global tsyp#

rem Setup ammo
global shots=3
global dim ship_shotx#(3)
global dim ship_shoty#(3)
global dim ship_shotxp#(3)
global dim ship_shotyp#(3)
global dim ship_shot(3)
global fire=50

rem Set up chasers
global chasers=2
global dim cx#(chasers)
global dim cy#(chasers)
global dim cxp#(chasers)
global dim cyp#(chasers)
global dim c_a(chasers)
global dim c_d(chasers)

rem Set up scores
global ships=3
global level=1

rem Initialize
gosub reset_ship
gosub reset_target

instructions()
quit=0
while quit=0
  checkpoint=timer()
  draw_forcefield()
  draw_ship(ship_x#,ship_y#,ship_a#)
  draw_target(t_a#)
  draw_shots()
  display_score()
  if ship=0 and target=0 then draw_chasers()
  if ship=0 and target=0 then check_collision()
  if ship=0 and target=0 then check_shot(t_a#)
  sync
  if leftkey()
    ship_a#=ship_a#-ship_step#
    if ship_a#<0.0 then ship_a#=ship_a#+360.0
  endif
  if rightkey()
    ship_a#=ship_a#+ship_step#
    if ship_a#>360.0 then ship_a#=ship_a#-360.0
  endif
  if upkey()
    new_ship_xp#=ship_xp#+cos(ship_a#)/50.0
    new_ship_yp#=ship_yp#+sin(ship_a#)/50.0
    if abs(new_ship_xp#)<ship_max# and abs(new_ship_yp#)<ship_max#
      ship_xp#=new_ship_xp#
      ship_yp#=new_ship_yp#
    endif
  endif
  if controlkey()
    shipfield=1
  else
    shipfield=0
  endif
  if shipfield=1
    if shipfieldr=0
      dec shipfieldp
      if shipfieldp<0 then shipfieldp=0
    endif
    dec shipfieldr
    if shipfieldr<0 then shipfieldr=10
  endif
  if spacekey() and fire=0 and shipfield=0
    fire=50
    for x=1 to shots
      if ship_shot(x)=0
        ship_shotx#(x)=cos(ship_a#)*10.0+ship_x#
        ship_shoty#(x)=sin(ship_a#)*10.0+ship_y#
        ship_shotxp#(x)=cos(ship_a#)*4.0
        ship_shotyp#(x)=sin(ship_a#)*4.0
        ship_shot(x)=160
        x=shots
      endif
    next x
    play sound 1
  endif
  if fire>0 then dec fire
  ship_x#=ship_x#+ship_xp#
  if ship_x#<-xoff then ship_x#=ship_x#+screenx
  if ship_x#>xoff then ship_x#=ship_x#-screenx
  ship_xp#=ship_xp#*drag#
  ship_y#=ship_y#+ship_yp#
  if ship_y#<-yoff then ship_y#=ship_y#+screeny
  if ship_y#>yoff then ship_y#=ship_y#-screeny
  ship_yp#=ship_yp#*drag#
  t_a#=atan(ship_y#/ship_x#)
  if ship_x#<0.0 then t_a#=t_a#+180.0
  if ships=0
    game_over()
    quit=1
  endif
  set cursor 0,100
rem  while timer()-checkpoint<5
rem  endwhile
endwhile

end
reset_ship:
  ship_x#=300.0
  ship_y#=-200.0
  ship=0
  ship_a#=0.0
  ship_xp#=0.0
  ship_yp#=0.0
  for x=1 to shots
    ship_shot(x)=0
  next x
  shipfieldp=255
  gosub reset_chasers
return
reset_target:
  target=0
  for x=0 to 2
    for y=0 to 11
      forcefield(x,y)=2
    next y
    angle#(x)=0
  next x
  gosub reset_chasers
return
reset_chasers:
  for x=1 to chasers
    if x<level
      c_a(x)=1
      c_d(x)=x*50
    endif
    cx#(x)=0.0
    cy#(x)=0.0
  next x
return
function display_score()
  for x=1 to ships
    line screenx-(x*10),0,screenx-(x*10)-5,10
    line screenx-(x*10),0,screenx-(x*10)+5,10
    line screenx-(x*10)-5,10,screenx-(x*10),5
    line screenx-(x*10)+5,10,screenx-(x*10),5
  next x
  set cursor 0,0
  print "Level ";level
endfunction
function check_collision()
  set cursor 0,0
  for x=1 to shots
    if ship_shot(x)>0
      radius#=sqrt(ship_shotx#(x)^2+ship_shoty#(x)^2)
      if radius#<40.0+rad
        if radius#>30.0+rad
          fieldposition(2,x,1,ship_shotx#(x),ship_shoty#(x))
        else
          if radius#>20.0+rad
            fieldposition(1,x,1,ship_shotx#(x),ship_shoty#(x))
          else
            if radius#>rad
              fieldposition(0,x,1,ship_shotx#(x),ship_shoty#(x))
            else
              if radius#<20.0 and target=0
                play sound 3
                explode_target(x)
              endif
            endif
          endif
        endif
      endif
    endif
    for i=1 to chasers
      radius#=sqrt((ship_shotx#(x)-cx#(i))^2+(ship_shoty#(x)-cy#(i))^2)
      if radius#<9.0
        explode_chaser(x,i)
      endif
    next i
  next x
  if target_shoot=1 and ship=0
    radius#=sqrt((ship_x#-tsx#)^2+(ship_y#-tsy#)^2)
    if radius#<16.0
      explode_ship()
    endif
  endif
  radius#=sqrt(ship_x#^2+ship_y#^2)
  if radius#<40.0+rad
    if radius#>30.0+rad
      if fieldposition(2,x,2,ship_x#,ship_y#)=1
        explode_ship()
      endif
    else
      if radius#>20.0+rad
        if fieldposition(1,x,2,ship_x#,ship_y#)=1
          explode_ship()
        endif
      else
        if radius#>rad
          if fieldposition(0,x,2,ship_x#,ship_y#)=1
            explode_ship()
          endif
        endif
      endif
    endif
  endif
endfunction
function check_shot(a#)
  shotx#=cos(a#)*rad
  shoty#=sin(a#)*rad
  path=fieldposition(0,0,0,shotx#,shoty#)
  shotx#=cos(a#)*(20.0+rad)
  shoty#=sin(a#)*(20.0+rad)
  path=path+fieldposition(1,0,0,shotx#,shoty#)
  shotx#=cos(a#)*(40.0+rad)
  shoty#=sin(a#)*(40.0+rad)
  path=path+fieldposition(2,0,0,shotx#,shoty#)
  if path=0 and target_shoot=0 and ship=0
    target_shot(a#)
  endif
endfunction
function explode_chaser(x,i)
  ship_shot(x)=0
  c_a(i)=0
endfunction
function explode_ship()
  target_shoot=0
  explode=1
  if shipfield=1
    ship_xp#=-ship_xp#
    ship_yp#=-ship_yp#
    shipfieldp=shipfieldp-50
    explode=0
    if shipfieldp<0
      shipfieldp=0
      explode=1
    endif
    shipfield=0
  endif
  if explode=1
    ship=1
    s_c=255
    for i=1 to 50
      sx#(i)=ship_x#
      sy#(i)=ship_y#
      sxp#(i)=(rnd(60)-30)/100.0
      syp#(i)=(rnd(60)-30)/100.0
    next i
    ship_xp#=0.0
    ship_yp#=0.0
    play sound 3
  endif
endfunction
function explode_target(x)
  ship_shot(x)=0
  target=1
  t_c=255
  for i=1 to 50
    tx#(i)=0.0
    ty#(i)=0.0
    txp#(i)=(rnd(60)-30)/100.0
    typ#(i)=(rnd(60)-30)/100.0
  next i
endfunction
function fieldposition(a,x,c,shotx#,shoty#)
  returnvalue=0
  shot_angle=atan(shoty#/shotx#)
  if shotx#<0.0 then shot_angle=shot_angle+180
  shot_angle=shot_angle-int(angle#(a))
  while shot_angle<0
    shot_angle=shot_angle+360
  endwhile
  if shot_angle>360 then shot_angle=shot_angle-360
  fieldshot=int(shot_angle/30)
  if c=2
    if forcefield(a,fieldshot)>0
      dec forcefield(a,fieldshot)
      play sound 2
      returnvalue=1
    endif
  endif
  if c=1
    if forcefield(a,fieldshot)>0
      dec forcefield(a,fieldshot)
      ship_shot(x)=0
      returnvalue=1
      found=0
      for x=1 to shots
        if ship_shot(x)>0 then found=1
      next x
      if found=0 then fire=0
      play sound 2
    endif
  endif
  if c=0
    returnvalue=forcefield(a,fieldshot)
  endif
endfunction returnvalue
function target_shot(a#)
  play sound 4
  target_shoot=1
  tsx#=cos(a#)*20.0
  tsy#=sin(a#)*20.0
  tsxp#=tsx#/5.0
  tsyp#=tsy#/5.0
endfunction
function draw_shots()
  ink rgb(255,0,0),0
  for x=1 to shots
    if ship_shot(x)>0
      circle ship_shotx#(x)+xoff,ship_shoty#(x)+yoff,2
      ship_shotx#(x)=ship_shotx#(x)+ship_shotxp#(x)
      if ship_shotx#(x)<-xoff then ship_shotx#(x)=ship_shotx#(x)+screenx
      if ship_shotx#(x)>xoff then ship_shotx#(x)=ship_shotx#(x)-screenx
      ship_shoty#(x)=ship_shoty#(x)+ship_shotyp#(x)
      if ship_shoty#(x)<-yoff then ship_shoty#(x)=ship_shoty#(x)+screeny
      if ship_shoty#(x)>yoff then ship_shoty#(x)=ship_shoty#(x)-screeny
      dec ship_shot(x)
    endif
  next x
  if target_shoot=1
    for a=5 to 355 step 20
      ray=rnd(15)+4
      x=cos(a)*ray
      y=sin(a)*ray
      line tsx#+xoff,tsy#+yoff,tsx#+x+xoff,tsy#+y+yoff
    next a
    tsx#=tsx#+tsxp#
    tsy#=tsy#+tsyp#
    if tsx#<-xoff or tsx#>xoff or tsy#<-yoff or tsy#>yoff
      target_shoot=0
      tsx#=0.0
      tsy#=0.0
    endif
  endif
endfunction
function draw_target(a#)
  if target=0
    ink rgb(255,255,255),0
    nosex#=cos(a#)*20.0
    nosey#=sin(a#)*20.0
    leftwingx#=cos(a#+225)*20.0
    leftwingy#=sin(a#+225)*20.0
    rightwingx#=cos(a#+135)*20.0
    rightwingy#=sin(a#+135)*20.0
    line nosex#+xoff,nosey#+yoff,leftwingx#+xoff,leftwingy#+yoff
    line nosex#+xoff,nosey#+yoff,rightwingx#+xoff,rightwingy#+yoff
    line leftwingx#+xoff,leftwingy#+yoff,x#+xoff,y#+yoff
    line rightwingx#+xoff,rightwingy#+yoff,x#+xoff,y#+yoff
  else
    ink rgb(t_c,t_c,t_c),0
    for i=1 to 50
      dot tx#(i)+xoff,ty#(i)+yoff
      tx#(i)=tx#(i)+txp#(i)
      ty#(i)=ty#(i)+typ#(i)
    next i
    circle xoff,yoff,int(256-t_c)/2
    ink rgb(t_c,0,0),0
    circle xoff,yoff,256-t_c
    dec t_c
    if t_c=0
      inc level
      gosub reset_target
    endif
  endif
endfunction
function draw_chasers()
  for x=1 to chasers
    if c_a(x)=1
      if c_d(x)=0
        line cx#(x)+xoff-5,cy#(x)+yoff,cx#(x)+xoff+5,cy#(x)+yoff
        line cx#(x)+xoff,cy#(x)+yoff-5,cx#(x)+xoff,cy#(x)+yoff+5
        a#=atan((ship_y#-cy#(x))/(ship_x#-cx#(x)))
        if (ship_x#-cx#(x))<0.0 then a#=a#+180.0
        cxp#(x)=cxp#(x)+cos(a#)*0.1
        cyp#(x)=cyp#(x)+sin(a#)*0.1
        if abs(cxp#(x))>(level/8.0) then cxp#(x)=cxp#(x)-cos(a#)*0.1
        if abs(cyp#(x))>(level/8.0) then cyp#(x)=cyp#(x)-sin(a#)*0.1
        cx#(x)=cx#(x)+cxp#(x)
        cy#(x)=cy#(x)+cyp#(x)
        radius#=sqrt((cx#(x)-ship_x#)^2+(cy#(x)-ship_y#)^2)
        if radius#<10.0
          c_a(x)=0
          explode_ship()
        endif
      else
        dec c_d(x)
        if c_d(x)<0 then c_d(x)=0
      endif
    else
      if x<level-1
        c_a(x)=1
        c_d(x)=x*200
        cx#(x)=0.0
        cy#(x)=0.0
      endif
    endif
  next x
endfunction
function draw_ship(x#,y#,a#)
  if ship=0
    ink rgb(255,255,255),0
    nosex#=cos(a#)*10.0+x#
    nosey#=sin(a#)*10.0+y#
    leftwingx#=cos(a#+225)*10.0+x#
    leftwingy#=sin(a#+225)*10.0+y#
    rightwingx#=cos(a#+135)*10.0+x#
    rightwingy#=sin(a#+135)*10.0+y#
    line nosex#+xoff,nosey#+yoff,leftwingx#+xoff,leftwingy#+yoff
    line nosex#+xoff,nosey#+yoff,rightwingx#+xoff,rightwingy#+yoff
    line leftwingx#+xoff,leftwingy#+yoff,x#+xoff,y#+yoff
    line rightwingx#+xoff,rightwingy#+yoff,x#+xoff,y#+yoff
    if shipfield=1
      ink rgb(shipfieldp,shipfieldp,shipfieldp),0
      circle x#+xoff,y#+yoff,12
    endif
  else
    ink rgb(0,0,s_c),0
    for i=1 to 50
      dot sx#(i)+xoff,sy#(i)+yoff
      sx#(i)=sx#(i)+sxp#(i)
      sy#(i)=sy#(i)+syp#(i)
    next i
    dec s_c
    if s_c=0
      dec ships
      gosub reset_ship
    endif
  endif
endfunction
function draw_forcefield()
  for x=0 to 2
    piece=0
    for y=0 to 11
      if forcefield(x,y)>0
        if forcefield(x,y)=2 then ink rgb(0,128,0),0
        if forcefield(x,y)=1 then ink rgb(128,255,128),0
        inc piece
        step_angle#=angle#(x)+y*30.0
        xpos=cos(step_angle#)*(shell(x)+rad)
        ypos=sin(step_angle#)*(shell(x)+rad)
        newxpos=cos(step_angle#+30)*(shell(x)+rad)
        newypos=sin(step_angle#+30)*(shell(x)+rad)
        line xpos+xoff,ypos+yoff,newxpos+xoff,newypos+yoff
      endif
    next y
    angle#(x)=angle#(x)+(3-x)/5.0
    if angle#(x)>360.0 then angle#(x)=angle#(x)-360.0
    if shell(x)<shell_top(x) then inc shell(x)
    if piece=0
      select x
        case 0
          for y=0 to 11
            forcefield(x,y)=1
          next y
        endcase
        case 1
          for y=0 to 11
            forcefield(x,y)=forcefield(0,y)
            forcefield(0,y)=1
          next y
          shell(x)=0
          shell(0)=-20
        endcase
        case 2
          for y=0 to 11
            forcefield(x,y)=forcefield(1,y)
            forcefield(1,y)=forcefield(0,y)
            forcefield(0,y)=2
          next y
          shell(x)=20
          shell(1)=0
          shell(0)=-20
        endcase
      endselect
    endif
  next x
endfunction
function game_over()
  ink rgb(255,0,0),0
  for char=1 to 8
    read num
    for x=1 to num
      read xpos,ypos,xpos2,ypos2
      line xpos+xoff,ypos+yoff,xpos2+xoff,ypos2+yoff
    next x
  next char
  data 5,-110,-30,-130,-30,-130,-30,-130,30,-130,30,-110,30,-110,30,-110,0,-110,0,-115,0
  data 4,-100,30,-100,-30,-100,-30,-80,-30,-80,-30,-80,30,-80,0,-100,0
  data 4,-70,30,-70,-30,-70,-30,-60,0,-60,0,-50,-30,-50,-30,-50,30
  data 4,-20,-30,-40,-30,-40,-30,-40,30,-40,30,-20,30,-40,0,-30,0
  data 4,10,-30,30,-30,30,-30,30,30,30,30,10,30,10,30,10,-30
  data 4,40,-30,40,0,40,0,50,30,50,30,60,0,60,0,60,-30
  data 4,90,-30,70,-30,70,-30,70,30,70,30,90,30,70,0,80,0
  data 5,100,30,100,-30,100,-30,120,-30,120,-30,120,0,120,0,100,0,100,0,120,30
  set cursor xoff-100,yoff+100
  print "  LEVEL ATTAINED : ";level
  sync
  wait key
endfunction
function make_sound(number)
  format as dword
  channels as dword
  sampleRate as dword
  adr as dword
  chunkSize as dword
  sampleSize as dword
  dword7 as dword
  format = 1
  channels = 1
  sampleRate = 22050
  sampleSize = 16
  chunkSize = (int(sampleSize / 8.0+0.5))*channels
  adr = sampleRate*chunkSize
  dword7 = 0
  select number
    case 1
      length = 75
      wave#=0.1
      increment#=2.0
      gain#=0.1
      amplitude=32000
      decay=120
      speed=sampleRate
    endcase
    case 2
      length=600
      wave#=0.5
      increment#=2.0
      gain#=-0.001
      amplitude=40000
      decay=5
      speed=sampleRate
    endcase
    case 3
      length=2000
      wave#=0.0
      increment#=10.0
      gain#=0.05
      amplitude=65535
      decay=0
      speed = sampleRate
    endcase
    case 4
      length=4000
      wave#=0.0
      increment#=-1.0
      gain#=0.0
      amplitude=65000
      decay=1
      speed = sampleRate
    endcase
  endselect
  rem number of samples
  samples = length*sampleRate/1000
  rem size of memblock
  size = samples*int(sampleSize/8.0+0.5) + 28
  make memblock 1, size
  write memblock dword 1, 0, format
  write memblock dword 1, 4, channels
  write memblock dword 1, 8, sampleRate
  write memblock dword 1, 12, adr
  write memblock dword 1, 16, chunkSize
  write memblock dword 1, 20, sampleSize
  write memblock dword 1, 24, dword7
  pos = 28
  out as word
  for i = 1 to samples
      out = sin(wave#)*amplitude
      write memblock word 1, pos, out
      inc pos, 2
      wave#=wave#+increment#
      if wave#>360.0
        wave#=wave#-360.0
        increment#=increment#-gain#
      endif
      amplitude=amplitude-decay
  next i
  make sound from memblock number,1
  delete memblock 1
  set sound speed number,speed
endfunction
function instructions()
  while not returnkey()
    ink rgb(255,0,0),0
    text 100,100,"INSTRUCTIONS"
    text 100,120,"Left/Right arrow keys - rotate ship"
    text 100,140,"Up arrow - thrust ship"
    text 100,160,"SPACE - fire"
    text 100,180,"Ctrl - shields"
    text 100,220,"OBJECT"
    text 100,240,"Knock out force shields and shoot central ship."
    text 100,260,"Central ship will fire at you when it has a clear shot through the shields"
    text 100,280,"Central ship will re-generate shields when all segments of a shield layer are knocked out"
    text 100,300,"Your shields will deplete with use, and when hit"
    text 100,320,"Watch out for chasers"
    text 100,350,"Press ENTER to start game"
    sync
  endwhile
endfunction

`*****Snipe Invaders*****
randomize timer()
hide mouse
autocam off
sync on
`Create the skysphere data


    create bitmap 1, screen width(), screen height()
    set current bitmap 1
    ink rgb(150,150,255),0
    box 0,0,100,100
    ink rgb(200,200,200),0
    for x = 1 to 500
        circle rnd(100),rnd(100),1
    next x
    get image 1,0,0,100,100
    set current bitmap 0
    
make object sphere 11,500
set object cull 11, 0
texture object 11, 1    
    
`Create the first invader
invaderdata:
data 4,1, 8,1
data 3,2, 4,2, 5,2, 6,2, 7,2, 8,2, 9,2
data 2,3, 3,3, 5,3, 6,3, 7,3, 9,3, 10,3
data 1,4, 2,4, 3,4, 4,4, 5,4, 6,4, 7,4, 8,4, 9,4, 10,4, 11,4
data 1,5, 3,5, 4,5, 5,5, 6,5, 7,5, 8,5, 9,5, 11,5
data 1,6, 3,6, 9,6, 11,6
data 4,7, 5,7, 7,7, 8,7 

make object cube 1, 1
make mesh from object 1, 1
delete object 1

make object triangle 1, 0,0,0,0,0,0,0,0,0
restore invaderdata
for x = 1 to 44
    add limb 1,x,1
    read xo
    read yo
    offset limb 1, x, xo - 6, -yo + 4, 0
next x


dim mode$(10)
dim desty#(10)
dim tx#(10)
dim ty#(10)
dim tz#(10)
dim mx#(10)
dim my#(10)
dim mz#(10)
dim ptx#(10,44)
dim pty#(10,44)
dim ptz#(10,44)
dim pmx#(10,44)
dim pmy#(10,44)
dim pmz#(10,44)
for x = 1 to 10
    if x <> 1 then clone object x, 1
    position object x,  rnd(200) - 100, rnd(300) + 100, 0
    mode$(x) = "descend"
next x


`Create Ground
    create bitmap 1, screen width(), screen height()
    set current bitmap 1
    ink rgb(0,150,0),0
    box 0,0,100,100
    ink rgb(0,200,0),0
    for x = 1 to 500
        circle rnd(100),rnd(100),1
    next x
    get image 2,0,0,100,100
    set current bitmap 0
make matrix 1,500,500,30,30
position matrix 1, -250, -100, -250
prepare matrix texture 1,2,1,1
fill matrix 1, 0, 1
randomize matrix 1, 20
update matrix 1

make object sphere 12,.3
scale object 12, 100,100,100000



position camera 0,0,-200
fog on: fog distance 600: fog color rgb(100,100,200)



if file exist("highscore.DATA") = 0
    make file "highscore.DATA"
    highscore# = 0
endif

if file exist("highscore.DATA") = 1
    open to read 1, "highscore.DATA"
    read float 1, highscore#
    close file 1
endif


newgame:
spd# = .7
score = 0
do
    tmr = timer()

    pick screen mousex(), mousey(), 20000000000
    mx# = get pick vector x()
    my# = get pick vector y()
    mz# = get pick vector z()

set cursor 0,0
        `Control Aliens
        spd# = spd# + .00025
        for x = 1 to 10
            if mode$(x) = "descend"
                position object x, object position x(x), object position y(x) - 3, object position z(x)
                if object position y(x) < 50
                    mode$(x) = "right"
                    desty#(x) = 50
                endif
            endif
            if mode$(x) = "right"
                position object x, object position x(x)+ spd#, curvevalue(desty#(x),object position y(x),10), object position z(x)
                rotate object x, 0,curveangle(0,object angle y(x), 10),0
                if object position x(x) > 100
                    mode$(x) = "left"
                    desty#(x) = desty#(x) - 10
                    rotate object x, 0,object angle y(x) - 10,0
                endif
                if object position y(x) < get ground height(1,object position x(x) + 250, object position z(x) + 250) - 100 then goto youlose
            endif
            if mode$(x) = "left"
                position object x, object position x(x)- spd#, curvevalue(desty#(x),object position y(x),10), object position z(x)
                rotate object x, 0,curveangle(180,object angle y(x), 10),0
                if object position x(x) < -100
                    mode$(x) = "right"
                    desty#(x) = desty#(x) - 10
                    rotate object x, 0,object angle y(x) + 10,0                  
                endif
                if object position y(x) < get ground height(1,object position x(x) + 250, object position z(x) + 250) - 100 then goto youlose
            endif
            if mode$(x) = "fall"
                position object x, object position x(x) + mx#(x), object position y(x) + my#(x), object position z(x) + mz#(x)
                rotate object x, object angle x(x) + tx#(x), object angle y(x) + ty#(x), object angle z(x) + tz#(x)
                my#(x) = my#(x) - .3
                if object position y(x) < get ground height(1,object position x(x) + 250, object position z(x) + 250) - 100
                    for p = 1 to 44
                        ptx#(x,p) = rnd(10) - 5
                        pty#(x,p) = rnd(10) - 5
                        ptz#(x,p) = rnd(10) - 5
                        pmy#(x,p) = rnd(10) +3:pmy#(x,p) = pmy#(x,p) * .5
                        pmx#(x,p) = rnd(10) - 5:pmx#(x,p) = pmx#(x,p) * .5
                        pmz#(x,p) = rnd(10):pmz#(x,p) = pmz#(x,p) * .5
                    next p
                    mode$(x) = "explode"
                    rotate object x, 0,0,0
                    score = score + 100
                endif
            endif
            if mode$(x) = "explode"
                for p = 1 to 44
                    offset limb x,p, limb offset x(x,p) + pmx#(x,p), limb offset y(x,p) + pmy#(x,p), limb offset z(x,p) + pmz#(x,p)
                    rotate limb x,p, limb angle x(x,p) + ptx#(x,p), limb angle y(x,p) + pty#(x,p), limb angle y(x,p) + pty#(x,p)
                    pmy#(x,p) = pmy#(x,p) - .3
                next p
                if rnd(100) = 1
                    gosub rebuildship
                    mode$(x) = "descend"
                    position object x,  rnd(200) - 100, rnd(300) + 100, 0
                endif
            endif
            if intersect object(x, object position x(12), object position y(12), object position z(12), ox#,oy#,oz#) > 0
                mode$(x) = "fall"
                tx#(x) = rnd(10) - 5
                ty#(x) = rnd(10) - 5
                tz#(x) = rnd(10) - 5
                my#(x) = rnd(10) +3:my#(x) = my#(x) * .1
                mx#(x) = rnd(10) - 5:mx#(x) = mx#(x) * .1
                mz#(x) = rnd(10):mz#(x) = mz#(x) * .1
            endif
            for a = 1 to 10
                if desty#(a) = desty#(x) and object collision(a,x) = 1
                    dst# = object position x(a) - object position x(x)
                    position object x, object position x(x) - (dst# / 10), object position y(x), object position z(x)
                    position object a, object position x(a) + (dst# / 10), object position y(a), object position z(a)             
                endif
            next a

            
        next x


        if mouseclick() = 0 then msrd = 1
        if msrd = 1 and mouseclick() = 1
            position object 12, camera position x(), camera position y()-3, camera position z()
            point object 12, mx#, my# + 3, mz#
            msrd = 0
        endif
        ox# = object position x(12):oy# = object position y(12):oz# = object position z(12)
        move object 12, 100


        turn object right 11, .2
        
        ink rgb(255,0,0),0
        circle mousex(), mousey(),2
        circle mousex(), mousey(),1
        circle mousex(), mousey(),0
        
        set cursor 0,0
        if score > highscore# then highscore# = score
        print "SCORE: " +  str$(score)
        print " HIGH: " + str$(highscore#)
        
    sync
    while timer() - tmr < 30
    endwhile
loop


rebuildship:
    restore invaderdata
    for p = 1 to 44
        read xo
        read yo
        offset limb x, p, xo - 6, -yo + 4, 0
        rotate limb x,p,0,0,0
    next p
return


youlose:
    do
        tmr = timer()
        sync
            for x = 1 to 10
                position object x, object position x(x), object position y(x), object position z(x) - 2
                roll object left x, 3
            next x
            center text screen width()/2, screen height()/2, "GAME OVER"
            if score >= highscore# then center text screen width()/2, screen height()/2 + 15, "NEW HIGH SCORE!"
            center text screen width()/2, screen height()/2 + 30, "CLICK TO CONTINUE"
            if mouseclick() = 1
                for x = 1 to 10
                    position object x,  rnd(200) - 100, rnd(300) + 100, 0
                    rotate object x,0,0,0
                    mode$(x) = "descend"
                    desty#(x) = 50
                    gosub rebuildship
                next x
                if score >= highscore#
                    delete file "highscore.DATA"
                    open to write 1, "highscore.DATA"
                    write float 1, highscore#
                    close file 1
                endif
                goto newgame
            endif
        while timer() - tmr < 30
        endwhile
    loop
    

`*****Snipe Invaders*****
randomize timer()
hide mouse
autocam off
sync on
`Create the skysphere data


    create bitmap 1, screen width(), screen height()
    set current bitmap 1
    ink rgb(150,150,255),0
    box 0,0,100,100
    ink rgb(200,200,200),0
    for x = 1 to 500
        circle rnd(100),rnd(100),1
    next x
    get image 1,0,0,100,100
    set current bitmap 0
    
make object sphere 51,500
set object cull 51, 0
texture object 51, 1    
    
`Create the first invader
invaderdata:
data 4,1, 8,1
data 3,2, 4,2, 5,2, 6,2, 7,2, 8,2, 9,2
data 2,3, 3,3, 5,3, 6,3, 7,3, 9,3, 10,3
data 1,4, 2,4, 3,4, 4,4, 5,4, 6,4, 7,4, 8,4, 9,4, 10,4, 11,4
data 1,5, 3,5, 4,5, 5,5, 6,5, 7,5, 8,5, 9,5, 11,5
data 1,6, 3,6, 9,6, 11,6
data 4,7, 5,7, 7,7, 8,7 

make object cube 1, 1
make mesh from object 1, 1
delete object 1

make object triangle 1, 0,0,0,0,0,0,0,0,0
restore invaderdata
for x = 1 to 44
    add limb 1,x,1
    read xo
    read yo
    offset limb 1, x, xo - 6, -yo + 4, 0
next x


dim mode$(30)
dim desty#(30)
dim tx#(30)
dim ty#(30)
dim tz#(30)
dim mx#(30)
dim my#(30)
dim mz#(30)
dim tmout#(30)
dim ptx#(30,44)
dim pty#(30,44)
dim ptz#(30,44)
dim pmx#(30,44)
dim pmy#(30,44)
dim pmz#(30,44)
for x = 1 to 20
    if x <> 1 then clone object x, 1
    position object x,  rnd(200) - 100, rnd(500) + 100, 0
    mode$(x) = "descend"
next x


`Create Ground
    create bitmap 1, screen width(), screen height()
    set current bitmap 1
    ink rgb(0,150,0),0
    box 0,0,100,100
    ink rgb(0,200,0),0
    for x = 1 to 500
        circle rnd(100),rnd(100),1
    next x
    get image 2,0,0,100,100
    set current bitmap 0
make matrix 1,500,500,30,30
position matrix 1, -250, -100, -250
prepare matrix texture 1,2,1,1
fill matrix 1, 0, 1
randomize matrix 1, 20
update matrix 1

make object sphere 52,.3
scale object 52, 100,100,100000



position camera 0,0,-200
fog on: fog distance 600: fog color rgb(100,100,200)



if file exist("highscore.DATA") = 0
    open to write 1, "highscore.DATA"
    highscore# = 0
    write float 1, highscore#
    close file 1
endif

if file exist("highscore.DATA") = 1
    open to read 1, "highscore.DATA"
    read float 1, highscore#
    close file 1
endif


newgame:
spd# = .7
score = 0
do
    tmr = timer()

    pick screen mousex(), mousey(), 20000000000
    mx# = get pick vector x()
    my# = get pick vector y()
    mz# = get pick vector z()

set cursor 0,0
        `Control Aliens
        spd# = spd# + .0005
        for x = 1 to 20
            if mode$(x) = "descend"
                position object x, object position x(x), object position y(x) - spd#, object position z(x)
                if object position y(x) < 50
                    mode$(x) = "right"
                    desty#(x) = 50
                endif
            endif
            if mode$(x) = "right"
                position object x, object position x(x)+ spd#, curvevalue(desty#(x),object position y(x),10), object position z(x)
                rotate object x, 0,curveangle(0,object angle y(x), 10),0
                if object position x(x) > 100
                    mode$(x) = "left"
                    desty#(x) = desty#(x) - 10
                    rotate object x, 0,object angle y(x) - 10,0
                endif
                if object position y(x) < get ground height(1,object position x(x) + 250, object position z(x) + 250) - 100 then goto youlose
            endif
            if mode$(x) = "left"
                position object x, object position x(x)- spd#, curvevalue(desty#(x),object position y(x),10), object position z(x)
                rotate object x, 0,curveangle(180,object angle y(x), 10),0
                if object position x(x) < -100
                    mode$(x) = "right"
                    desty#(x) = desty#(x) - 10
                    rotate object x, 0,object angle y(x) + 10,0                  
                endif
                if object position y(x) < get ground height(1,object position x(x) + 250, object position z(x) + 250) - 100 then goto youlose
            endif
            if mode$(x) = "fall"
                position object x, object position x(x) + mx#(x), object position y(x) + my#(x), object position z(x) + mz#(x)
                rotate object x, object angle x(x) + tx#(x), object angle y(x) + ty#(x), object angle z(x) + tz#(x)
                my#(x) = my#(x) - .3
                if object position y(x) < get ground height(1,object position x(x) + 250, object position z(x) + 250) - 100
                    for p = 1 to 44
                        ptx#(x,p) = rnd(10) - 5
                        pty#(x,p) = rnd(10) - 5
                        ptz#(x,p) = rnd(10) - 5
                        pmy#(x,p) = rnd(10) +3:pmy#(x,p) = pmy#(x,p) * .5
                        pmx#(x,p) = rnd(10) - 5:pmx#(x,p) = pmx#(x,p) * .5
                        pmz#(x,p) = rnd(10):pmz#(x,p) = pmz#(x,p) * .5
                    next p
                    mode$(x) = "explode"
                    tmout#(x) = 200
                    rotate object x, 0,0,0
                    score = score + 100
                endif
            endif
            if mode$(x) = "explode"
                for p = 1 to 44
                    offset limb x,p, limb offset x(x,p) + pmx#(x,p), limb offset y(x,p) + pmy#(x,p), limb offset z(x,p) + pmz#(x,p)
                    rotate limb x,p, limb angle x(x,p) + ptx#(x,p), limb angle y(x,p) + pty#(x,p), limb angle y(x,p) + pty#(x,p)
                    pmy#(x,p) = pmy#(x,p) - .3
                next p
                tmout#(x) = tmout#(x) - 1
                if tmout#(x) < 0
                    gosub rebuildship
                    mode$(x) = "descend"
                    position object x,  rnd(200) - 100, rnd(300) + 100, 0
                endif
            endif
            if intersect object(x, object position x(52), object position y(52), object position z(52), ox#,oy#,oz#) > 0
                mode$(x) = "fall"
                tx#(x) = rnd(10) - 5
                ty#(x) = rnd(10) - 5
                tz#(x) = rnd(10) - 5
                my#(x) = rnd(10) +3:my#(x) = my#(x) * .1
                mx#(x) = rnd(10) - 5:mx#(x) = mx#(x) * .1
                mz#(x) = rnd(10):mz#(x) = mz#(x) * .1
            endif
            for a = 1 to 20
                if desty#(a) = desty#(x) and object collision(a,x) = 1
                    dst# = object position x(a) - object position x(x)
                    position object x, object position x(x) - (dst# / 10), object position y(x), object position z(x)
                    position object a, object position x(a) + (dst# / 10), object position y(a), object position z(a)             
                endif
            next a

            
        next x


        if mouseclick() = 0 then msrd = 1
        if msrd = 1 and mouseclick() = 1
            position object 52, camera position x(), camera position y()-2, camera position z()
            point object 52, mx#, my# + 3, mz#
            msrd = 0
        endif
        ox# = object position x(52):oy# = object position y(52):oz# = object position z(52)
        move object 52, 100


        turn object right 51, .2
        
        ink rgb(255,0,0),0
        circle mousex(), mousey(),2
        circle mousex(), mousey(),1
        circle mousex(), mousey(),0
        
        set cursor 0,0
        if score > highscore# then highscore# = score
        print "SCORE: " +  str$(score)
        print " HIGH: " + str$(highscore#)
        
    sync
    while timer() - tmr < 30
    endwhile
loop


rebuildship:
    restore invaderdata
    for p = 1 to 44
        read xo
        read yo
        offset limb x, p, xo - 6, -yo + 4, 0
        rotate limb x,p,0,0,0
    next p
return


youlose:
    do
        tmr = timer()
        sync
            for x = 1 to 20
                position object x, object position x(x), object position y(x), object position z(x) - 2
                roll object left x, 3
            next x
            center text screen width()/2, screen height()/2, "GAME OVER"
            if score >= highscore# then center text screen width()/2, screen height()/2 + 15, "NEW HIGH SCORE!"
            center text screen width()/2, screen height()/2 + 30, "PRESS SPACE TO CONTINUE"
            if spacekey() = 1
                for x = 1 to 20
                    position object x,  rnd(200) - 100, rnd(500) + 100, 0
                    rotate object x,0,0,0
                    mode$(x) = "descend"
                    desty#(x) = 50
                    gosub rebuildship
                next x
                if score >= highscore#
                    delete file "highscore.DATA"
                    open to write 1, "highscore.DATA"
                    write float 1, highscore#
                    close file 1
                endif
                goto newgame
            endif
        while timer() - tmr < 30
        endwhile
    loop
    

global dim direction(1000,3)
global totaldrag
global totalthing
global lives
global level
level=1

lives=3

for i=1 to 1000
   direction(i,1)=1
next i

sync on:sync rate 60

color backdrop 0

sync

cls

restore main
image(1,3)

cls

restore dragon
image(20,3)

cls

restore wire
image(5,3)

cls

restore thing
image(21,2)

sync

suspend for key

cls

`circle 5,5,5
`get image 1,0,0,10,10


ink rgb(139,69,19),rgb(139,69,19)
box 0,0,40,40
get image 4,0,0,40,40

ink rgb(160,82,45),rgb(160,82,45)
box 0,0,40,40
get image 3,0,0,40,40

ink rgb(205,133,63),rgb(205,133,63)
box 0,0,40,40
get image 2,0,0,40,40


make_level(level)



do



   if rightkey() then di=1
   if leftkey() then di=2
   if upkey() then di=3
   if downkey() then di=4

   m=m+1

   if m=>20 and spacekey()=0 and pump=0
      move(1,di)
      m=0
      di=0
   endif

   if spacekey()=1 or pump>0
      pump=fire(1,pump)
   endif


   a=sprite collision(1,0)

   if a>999 then delete sprite a

   sync

   t=t+1

   if t=>10
      enemy_drag()
      enemy_thing()
      t=0
   endif

   win()


loop

function move(spr,di)

   if di=1
      rotate sprite spr,90
      move sprite spr,40
      if sprite mirrored(spr)=1 then mirror sprite spr
   endif

   if di=2
      rotate sprite spr,-90
      move sprite spr,40
      if sprite mirrored(spr)=0 then mirror sprite spr
   endif

   if di=3
      rotate sprite spr,0
      move sprite spr,40
      if sprite mirrored(spr)=1 then mirror sprite spr
   endif

   if di=4
      rotate sprite spr,180
      move sprite spr,40
      if sprite mirrored(spr)=1 then mirror sprite spr
   endif

endfunction

function fire(chr,pump)

   if sprite exist(5)=0 then pump=0

   if pump=0
      sprite 5,sprite x(chr),sprite y(chr),5
      rotate sprite 5,sprite angle(chr)
      move sprite 5,50
      pump=60
   endif


   a=sprite collision(5,0)

   if pump=1
      delete sprite 5
      direction(a,2)=1
   endif

   if a>99 and a<1000
      direction(a,2)=0
      scale sprite a,100+pump

      if shiftkey()=1
         pump=pump+1

         if pump>120
            delete sprite a
            delete sprite 5
            pump=0
         endif
      else
         pump=pump-1
      endif
   else
      pump=pump-1
   endif


endfunction pump

function image(num,size)

   dim colors(100,3)

   read a$
   a$=a$+"-"

   repeat
      i=i+1

      for j=1 to len(a$)

         c$=c$+b$
         b$=mid$(a$,j)

         if b$="-" or b$=" "
            k=k+1
            colors(i,k)=val(c$)
            c$=""
            b$=""
         endif

      next j

      k=0
      read a$
      a$=a$+"-"

   until a$="XXX-"


   x=0
   y=0

   repeat
      read a
      x=x+1

      if a>0 and a<100
         ink rgb(colors(a,1),colors(a,2),colors(a,3)),rgb(colors(a,1),colors(a,2),colors(a,3))
         box (x-1)*size,(y-1)*size,x*size,y*size
      endif

      if a=100
         y=y+1
         x=0
      endif

   until a=-999

   get image num,0,0,x*size,y*size
   cls
   sprite 999,0,0,num
   rotate sprite 999,-90
   paste sprite 999,0,x*size
   get image num,0,2,(y)*size,(x)*size



endfunction

function hole(x,y,across)

for i=0 to across-1
   delete sprite (y)*50+x+1000+i
next i

endfunction

function make_enemy_drag(x,y)

totaldrag=totaldrag+1
sprite 100+totaldrag,x*40+10,y*40+110,20
rotate sprite 100+totaldrag,90

direction(totaldrag+100,2)=1

endfunction

function enemy_drag()

for i=1 to totaldrag
   if direction(i+100,2)=1
      move sprite i+100,10*direction(i+100,1)
      a=sprite collision(i+100,0)
      if a>999
         flip sprite i+100
         direction(i+100,1)=-direction(i+100,1)
      endif

      if a=1
         delete sprite a
         lives=lives-1
         sprite 1,20,0,1
         offset sprite 1,sprite width(1)/2,sprite height(1)/2
         if sprite exist(5)=1 then delete sprite 5
      endif

   else
      if sprite exist(5)=0 and sprite exist(i+100)=1
         direction(i+100,2)=1
         scale sprite i+100,100
      endif
   endif
next i

endfunction

function make_enemy_thing(x,y)

totalthing=totalthing+1
sprite 200+totalthing,x*40+10,y*40+105,21
rotate sprite 200+totalthing,90
flip sprite 200+totalthing
scale sprite 200+totalthing,120

direction(totalthing+200,2)=1

endfunction

function enemy_thing()

for i=1 to totalthing
   if direction(i+200,2)=1

      ang=sprite angle(i+200)

      rotate sprite i+200,0
      move sprite i+200,10

      rotate sprite i+200,ang

      if sprite collision(i+200,0)<1000
         up=1
      endif

      rotate sprite i+200,0
      move sprite i+200,-20
      rotate sprite i+200,ang


      if sprite collision(i+200,0)<1000
         down=1
      endif

      rotate sprite i+200,0
      move sprite i+200,10
      rotate sprite i+200,ang

      move sprite i+200,10

      if sprite collision(i+200,0)<1000
         horizontal=1
      endif

      move sprite i+200,-20

      if sprite collision(i+200,0)<1000
         horizontal=1
      endif

      move sprite i+200,10

      repeat
         repeat
            h=h+1
            k=rnd(3)
         until h=3 or k=direction(i+200,3)

         h=0

         select k
            case 1
               if up=1
                  go=1
                  rotate sprite i+200,0
                  move sprite i+200,10
                  rotate sprite i+200,ang
               endif
            endcase

            case 2
               if down=1
                  go=2
                  rotate sprite i+200,0
                  move sprite i+200,-10
                  rotate sprite i+200,ang
               endif
            endcase

            case 3
               if horizontal=1
                  move sprite i+200,10*direction(i+200,1)
                  a=sprite collision(i+200,0)
                  if a>999
                     flip sprite i+200
                     direction(i+200,1)=-direction(i+200,1)
                  endif
                  go=3
               endif

            endcase
         endselect

      until go>0

      if go<3 then direction(i+200,3)=go


      if a=1
         delete sprite a
         lives=lives-1
         sprite 1,20,0,1
         offset sprite 1,sprite width(1)/2,sprite height(1)/2
         if sprite exist(5)=1 then delete sprite 5
      endif

   else
      if sprite exist(5)=0 and sprite exist(i+200)=1
         direction(i+200,2)=1
         scale sprite i+200,100
      endif
   endif

   stop=0
   up=0
   down=0
   go=0
   horizontal=0

next i

endfunction

function win()

wi=1

for i=100 to 100+totaldrag
   if sprite exist(i)=1 then wi=0
next i

for i=200 to 200+totalthing
   if sprite exist(i)=1 then wi=0
next i

if wi=1
   level=level+1
   make_level(level)
endif

endfunction

function make_level(num)

totaldrag=0
totalthing=0

for x=0 to 21
   for y=1 to 14

      if y<4
         if x<>10 then sprite (y)*50+x+1000,(x-1)*40,y*40+100,2

      else
         if y<8
            sprite (y)*50+x+1000,(x-1)*40,y*40+100,3
         else
            sprite (y)*50+x+1000,(x-1)*40,y*40+100,4
         endif
      endif


   next y
next x



sprite 1,20,0,1
offset sprite 1,sprite width(1)/2,sprite height(1)/2

select num
   case 1
      hole(5,7,10)

      hole(3,4,5)
      hole(14,4,5)

      make_enemy_drag(5,7)
      make_enemy_drag(3,4)
      make_enemy_drag(14,4)

      make_enemy_thing(10,7)
   endcase
   case 2

      hole(2,3,7)
      hole(11,5,7)

      hole(8,11,6)

      hole(7,8,9)

      make_enemy_drag(2,3)
      make_enemy_drag(8,11)
      make_enemy_drag(11,5)

      make_enemy_thing(7,3)
      make_enemy_thing(7,8)

   endcase
endselect

endfunction

main:

data "247 247 247","30-144-255","255-0-0","0 0 0","XXX"

data 0,0,0,0,1,1,0,0,0,0,0,0,100
data 0,0,1,1,1,1,1,1,0,0,0,0,100
data 0,1,1,1,1,1,1,1,1,0,0,0,100
data 1,1,1,1,2,4,2,4,2,0,0,0,100
data 1,1,1,1,1,2,2,2,2,0,3,0,100
data 3,3,2,1,1,1,3,3,3,3,3,3,100
data 1,1,2,2,2,2,1,0,0,0,3,0,100
data 1,1,1,1,1,1,0,0,0,0,0,0,100
data 0,1,1,1,0,0,0,0,0,0,0,0,100
data 0,1,1,1,1,1,1,0,0,0,0,0,-999

dragon:

data "50-205-50","255 255 255","0 0 0","255-0-0"
data "XXX"

data 0,2,1,1,1,1,1,1,0,100
data 2,2,2,1,1,1,1,1,1,100
data 2,3,3,2,0,0,0,0,0,100
data 2,2,2,1,0,0,0,0,0,100
data 0,0,1,1,1,1,1,1,1,100
data 0,0,4,4,1,1,1,1,1,100
data 4,4,4,4,1,1,4,1,0,100
data 4,4,1,1,1,4,1,1,4,100
data 1,1,1,1,4,1,1,4,4,-999

thing:
data "178-34-34","255-255-0","255 255 255","0 0 0"
data "XXX"

data 0,0,1,1,1,1,1,1,1,0,0,0,100
data 0,2,2,2,2,2,2,2,1,1,0,0,100
data 2,2,3,3,3,3,3,2,2,1,1,0,100
data 2,3,4,3,3,4,3,3,2,2,2,0,100
data 2,3,4,3,3,4,3,3,2,2,2,0,100
data 2,2,3,3,3,3,3,2,2,1,1,0,100
data 2,2,2,2,2,2,2,2,1,1,1,3,100
data 1,2,2,1,1,2,2,1,1,1,0,3,100
data 0,1,1,1,1,1,1,1,1,3,3,3,100
data 0,0,1,2,1,1,1,2,1,0,0,0,100
data 0,0,0,2,0,0,0,2,0,0,0,0,100
data 0,2,2,2,2,0,2,2,2,0,0,0,-999


wire:

data "255 255 255"
data "XXX"

data 0,0,0,0,0,0,0,0,0,0,100
data 0,0,0,0,1,1,0,0,0,0,100
data 1,0,0,1,0,0,1,0,0,1,100
data 0,1,1,0,0,0,0,1,1,0,-999

sync on
sync rate 0

rem "speed" and "acc" attributes are only used
rem for the falling coins demonstration and can
rem be removed from the UDT
type Coin
   x as integer
   y as float
   timestamp as integer
   width as integer
   radius as integer
   side as integer
   color as dword
   speed as float
   acc as float
endtype

dim coins(10) as Coin

for c = 1 to array count(coins())
   coins(c).x = rnd(640)
   coins(c).y = 0-rnd(100)
   coins(c).radius = 10
   coins(c).width = rnd(8)+2
   coins(c).side = rnd(1)
   coins(c).color = rgb(150,150,30)
   coins(c).timestamp = timer()
   coins(c).acc = 0.5
next c

do
   cls

   rem drop those coins!
   for c = 1 to array count(coins())
      coins(c).speed = coins(c).speed + coins(c).acc
      coins(c).y = coins(c).y + coins(c).speed
      if coins(c).y >= screen height()-coins(c).radius
         coins(c).y = screen height()-coins(c).radius
         coins(c).speed = coins(c).speed*-0.8
      endif
   next c

   animateCoins()
   text 2,2, str$(screen fps())

sync
loop



function animateCoins()
   lock pixels
   time = timer()
   for c = 1 to array count(coins())
      if time > coins(c).timestamp+20
         if coins(c).side = 0
            coins(c).width = coins(c).width - 1
         else
            coins(c).width = coins(c).width + 1
         endif
         if coins(c).width >= coins(c).radius
            coins(c).side = 0
            coins(c).width = coins(c).radius
         endif
         if coins(c).width <= 2
            coins(c).side = 1
            coins(c).width = 2
            if coins(c).color = rgb(150,150,30)
               coins(c).color = rgb(240,200,0)
            else
               coins(c).color = rgb(150,150,30)
            endif
         endif
         coins(c).timestamp = timer()
      endif
      ink coins(c).color, 0
      for xrad = 1 to coins(c).width
         ellipse coins(c).x, coins(c).y, xrad, coins(c).radius
      next xrad
   next c
   unlock pixels
endfunction

set display mode 1280, 1024, 32
sync on
sync rate 0
rem D3D_INIT

null = make vector3(1) :`Velocity
null = make vector3(2) :`Paddle Normal
null = make vector3(3) :`Used for collision
null = make vector3(4) :`Used for collision


#constant CURVE_RADIUS 8.0



Type Coord3D
   x as float
   y as float
   z as float
EndType

Type PlayerData
   pos as Coord3D
   angle as float
EndType

Dim P(1) as PlayerData

P(1).pos.x = -10
P(1).pos.y = 5
P(1).pos.z = 0

make object sphere 1, 0.5
position object 1, P(1).pos.x, P(1).pos.y, P(1).pos.z
set vector3 1, 0.1, 0, 0 :`velocity of ball




P(1).angle = -45


make object box 2, 0.5, 6.0, 0.5
make object box 3, 0.5, 6.0, 0.5







position mouse screen width() * 0.5, 0
hide mouse


autocam off
position camera 0, 5, -30
point camera 0, 5, 0

global frameTime as float
frameTime = 1.0
startTime as integer
startTime = timer()
do
   frameTime = (frameTime * 0.8) + ((timer() - startTime) * 0.2)
   startTime = timer()

   if spacekey()
      P(1).pos.x = -5
      P(1).pos.y = 5
      P(1).pos.z = 0
      set vector3 1, 0.1, 0, 0 :`velocity of ball
   endif



   `P(1).angle =  45.0 + ((mousex() - (screen width() * 0.5)) * 0.5)
   inc P(1).angle, mousemovex() * 0.5
   if P(1).angle < -97
      P(1).angle = -97
   else
      if P(1).angle > 0 then P(1).angle = 0
   endif

   position object 2, -4 - (cos(P(1).angle) * CURVE_RADIUS), sin(P(1).angle) * CURVE_RADIUS, 0
   zrotate object  2, -P(1).angle

   position object 3,  4 + (cos(P(1).angle) * CURVE_RADIUS), sin(P(1).angle) * CURVE_RADIUS, 0
   zrotate object  3, P(1).angle + 180

   text 0,  0, "  a: " + str$(P(1).angle)
   text 0, 10, "ob2: " + str$(object angle x(2)) + ", " + str$(object angle y(2)) + ", " + str$(object angle z(2))
   text 0, 20, "ob3: " + str$(object angle x(3)) + ", " + str$(object angle y(3)) + ", " + str$(object angle z(3))



   `handle gravity
   set vector3 1, x vector3(1), y vector3(1) - (frameTime * 0.0098), z vector3(1)
   inc P(1).pos.x, x vector3(1) * frametime * 0.001
   inc P(1).pos.y, y vector3(1) * frametime * 0.001
   inc P(1).pos.z, z vector3(1) * frametime * 0.001
   position object 1, P(1).pos.x, P(1).pos.y, P(1).pos.z






   handleCollision(2, object hit (2, 1))
   handleCollision(3, object hit (3, 1))



   sync
loop


function handleCollision(paddle as integer, hit as boolean)
   text 200, (paddle-2) * 10, str$(paddle) + " = " + str$(hit)
   `Normal of paddle
   set vector3 2, cos(object angle z(paddle)), sin(object angle z(paddle)), 0
   normalize vector3 2, 2
   scale vector3 2, 2, 2.0

   `Get unit/normalized version of ball speed
   normalize vector3 3, 1
   `Temporarily invert
   multiply vector3 3, -1
   `Get scalar impulse
   I# = dot product vector3(2, 3) * 2.0
   `Multiply normal vector by it (and store in vector3(4))
   copy vector3 4, 2
   multiply vector3 4, I#
   `Un-invert
   multiply vector3 3, -1
   `Add to vector 4...
   add vector3 4, 3, 4
   `Normlize
   normalize vector3 4, 4
   `Scale by speed magnitude...
   multiply vector3 4, length vector3(1)


   if hit then copy vector3 1, 4
endfunction

`*****Snipe Invaders*****
randomize timer()
hide mouse
autocam off
sync on
`Create the skysphere data


    create bitmap 1, screen width(), screen height()
    set current bitmap 1
    ink rgb(150,150,255),0
    box 0,0,100,100
    ink rgb(200,200,200),0
    for x = 1 to 500
        circle rnd(100),rnd(100),1
    next x
    get image 1,0,0,100,100
    set current bitmap 0
    
make object sphere 51,500
set object cull 51, 0
texture object 51, 1    
    
`Create the first invader
invaderdata:
data 4,1, 8,1
data 3,2, 4,2, 5,2, 6,2, 7,2, 8,2, 9,2
data 2,3, 3,3, 5,3, 6,3, 7,3, 9,3, 10,3
data 1,4, 2,4, 3,4, 4,4, 5,4, 6,4, 7,4, 8,4, 9,4, 10,4, 11,4
data 1,5, 3,5, 4,5, 5,5, 6,5, 7,5, 8,5, 9,5, 11,5
data 1,6, 3,6, 9,6, 11,6
data 4,7, 5,7, 7,7, 8,7 

make object cube 1, 1
make mesh from object 1, 1
delete object 1

make object triangle 1, 0,0,0,0,0,0,0,0,0
restore invaderdata
for x = 1 to 44
    add limb 1,x,1
    read xo
    read yo
    offset limb 1, x, xo - 6, -yo + 4, 0
next x


dim mode$(30)
dim desty#(30)
dim tx#(30)
dim ty#(30)
dim tz#(30)
dim mx#(30)
dim my#(30)
dim mz#(30)
dim tmout#(30)
dim ptx#(30,44)
dim pty#(30,44)
dim ptz#(30,44)
dim pmx#(30,44)
dim pmy#(30,44)
dim pmz#(30,44)
for x = 1 to 20
    if x <> 1 then clone object x, 1
    position object x,  rnd(200) - 100, rnd(500) + 100, 0
    mode$(x) = "descend"
next x


`Create Ground
    create bitmap 1, screen width(), screen height()
    set current bitmap 1
    ink rgb(0,150,0),0
    box 0,0,100,100
    ink rgb(0,200,0),0
    for x = 1 to 500
        circle rnd(100),rnd(100),1
    next x
    get image 2,0,0,100,100
    set current bitmap 0
make matrix 1,500,500,30,30
position matrix 1, -250, -100, -250
prepare matrix texture 1,2,1,1
fill matrix 1, 0, 1
randomize matrix 1, 20
update matrix 1

make object sphere 52,.3
scale object 52, 100,100,100000



position camera 0,0,-200
fog on: fog distance 600: fog color rgb(100,100,200)



if file exist("highscore.DATA") = 0
    open to write 1, "highscore.DATA"
    highscore# = 0
    write float 1, highscore#
    close file 1
endif

if file exist("highscore.DATA") = 1
    open to read 1, "highscore.DATA"
    read float 1, highscore#
    close file 1
endif


newgame:
spd# = .7
score = 0
do

    tmr = timer()

    pick screen mousex(), mousey(), 20000000000
    mx# = get pick vector x()
    my# = get pick vector y()
    mz# = get pick vector z()

set cursor 0,0
        `Control Aliens
        spd# = spd# + .00025
        for x = 1 to 20
            if mode$(x) = "descend"
                position object x, object position x(x), object position y(x) - spd#, object position z(x)
                if object position y(x) < 50
                    mode$(x) = "right"
                    desty#(x) = 50
                endif
            endif
            if mode$(x) = "right"
                position object x, object position x(x)+ spd#, curvevalue(desty#(x),object position y(x),10), object position z(x)
                rotate object x, 0,curveangle(0,object angle y(x), 10),0
                if object position x(x) > 100
                    mode$(x) = "left"
                    desty#(x) = desty#(x) - 10
                    rotate object x, 0,object angle y(x) - 10,0
                endif
                if object position y(x) < get ground height(1,object position x(x) + 250, object position z(x) + 250) - 100 then goto youlose
            endif
            if mode$(x) = "left"
                position object x, object position x(x)- spd#, curvevalue(desty#(x),object position y(x),10), object position z(x)
                rotate object x, 0,curveangle(180,object angle y(x), 10),0
                if object position x(x) < -100
                    mode$(x) = "right"
                    desty#(x) = desty#(x) - 10
                    rotate object x, 0,object angle y(x) + 10,0                  
                endif
                if object position y(x) < get ground height(1,object position x(x) + 250, object position z(x) + 250) - 100 then goto youlose
            endif
            if mode$(x) = "fall"
                position object x, object position x(x) + mx#(x), object position y(x) + my#(x), object position z(x) + mz#(x)
                rotate object x, object angle x(x) + tx#(x), object angle y(x) + ty#(x), object angle z(x) + tz#(x)
                my#(x) = my#(x) - .3
                if object position y(x) < get ground height(1,object position x(x) + 250, object position z(x) + 250) - 100
                    for p = 1 to 44
                        ptx#(x,p) = rnd(10) - 5
                        pty#(x,p) = rnd(10) - 5
                        ptz#(x,p) = rnd(10) - 5
                        pmy#(x,p) = rnd(10) +3:pmy#(x,p) = pmy#(x,p) * .5
                        pmx#(x,p) = rnd(10) - 5:pmx#(x,p) = pmx#(x,p) * .5
                        pmz#(x,p) = rnd(10):pmz#(x,p) = pmz#(x,p) * .5
                    next p
                    mode$(x) = "explode"
                    tmout#(x) = 200
                    rotate object x, 0,0,0
                    score = score + 100
                endif
            endif
            if mode$(x) = "explode"
                for p = 1 to 44
                    offset limb x,p, limb offset x(x,p) + pmx#(x,p), limb offset y(x,p) + pmy#(x,p), limb offset z(x,p) + pmz#(x,p)
                    rotate limb x,p, limb angle x(x,p) + ptx#(x,p), limb angle y(x,p) + pty#(x,p), limb angle y(x,p) + pty#(x,p)
                    pmy#(x,p) = pmy#(x,p) - .3
                next p
                tmout#(x) = tmout#(x) - 1
                if tmout#(x) < 0
                    gosub rebuildship
                    mode$(x) = "descend"
                    position object x,  rnd(200) - 100, rnd(300) + 100, 0
                endif
            endif
            if intersect object(x, object position x(52), object position y(52), object position z(52), ox#,oy#,oz#) > 0
                mode$(x) = "fall"
                tx#(x) = rnd(10) - 5
                ty#(x) = rnd(10) - 5
                tz#(x) = rnd(10) - 5
                my#(x) = rnd(10) +3:my#(x) = my#(x) * .1
                mx#(x) = rnd(10) - 5:mx#(x) = mx#(x) * .1
                mz#(x) = rnd(10):mz#(x) = mz#(x) * .1
            endif
            for a = 1 to 20
                if desty#(a) = desty#(x) and object collision(a,x) = 1
                    dst# = object position x(a) - object position x(x)
                    position object x, object position x(x) - (dst# / 10), object position y(x), object position z(x)
                    position object a, object position x(a) + (dst# / 10), object position y(a), object position z(a)             
                endif
            next a

            
        next x

        if mouseclick() = 0 and object position z(52) > 0 then msrd = 1
        if msrd = 1 and mouseclick() = 1
            position object 52, camera position x(), camera position y()-2, camera position z()
            point object 52, mx#, my# + 3, mz#
            msrd = 0
        endif
        ox# = object position x(52):oy# = object position y(52):oz# = object position z(52)
        move object 52, 50


        turn object right 51, .2
        
        ink rgb(255,0,0),0
        circle mousex(), mousey(),2
        circle mousex(), mousey(),1
        circle mousex(), mousey(),0
        
        set cursor 0,0
        if score > highscore# then highscore# = score
        print "SCORE: " +  str$(score)
        print " HIGH: " + str$(highscore#)
        
    sync
    while timer() - tmr < 30
    endwhile
loop


rebuildship:
    restore invaderdata
    for p = 1 to 44
        read xo
        read yo
        offset limb x, p, xo - 6, -yo + 4, 0
        rotate limb x,p,0,0,0
    next p
return


youlose:
    do
        tmr = timer()
        sync
            for x = 1 to 20
                position object x, object position x(x), object position y(x), object position z(x) - 2
                roll object left x, 3
            next x
            center text screen width()/2, screen height()/2, "GAME OVER"
            if score >= highscore# then center text screen width()/2, screen height()/2 + 15, "NEW HIGH SCORE!"
            center text screen width()/2, screen height()/2 + 30, "PRESS SPACE TO CONTINUE"
            if spacekey() = 1
                for x = 1 to 20
                    position object x,  rnd(200) - 100, rnd(500) + 100, 0
                    rotate object x,0,0,0
                    mode$(x) = "descend"
                    desty#(x) = 50
                    gosub rebuildship
                next x
                if score >= highscore#
                    delete file "highscore.DATA"
                    open to write 1, "highscore.DATA"
                    write float 1, highscore#
                    close file 1
                endif
                goto newgame
            endif
        while timer() - tmr < 30
        endwhile
    loop
    

`*****Snipe Invaders*****
randomize timer()
hide mouse
autocam off
sync on
`Create the skysphere data


    create bitmap 1, screen width(), screen height()
    set current bitmap 1
    ink rgb(150,150,255),0
    box 0,0,100,100
    ink rgb(200,200,200),0
    for x = 1 to 500
        circle rnd(100),rnd(100),1
    next x
    get image 1,0,0,100,100
    set current bitmap 0
    
make object sphere 51,500
set object cull 51, 0
texture object 51, 1    
    
`Create the first invader
invaderdata:
data 4,1, 8,1
data 3,2, 4,2, 5,2, 6,2, 7,2, 8,2, 9,2
data 2,3, 3,3, 5,3, 6,3, 7,3, 9,3, 10,3
data 1,4, 2,4, 3,4, 4,4, 5,4, 6,4, 7,4, 8,4, 9,4, 10,4, 11,4
data 1,5, 3,5, 4,5, 5,5, 6,5, 7,5, 8,5, 9,5, 11,5
data 1,6, 3,6, 9,6, 11,6
data 4,7, 5,7, 7,7, 8,7

data 4,3,  8,3,  6,6 

make object cube 1, 1
make mesh from object 1, 1
delete object 1

make object triangle 1, 0,0,0,0,0,0,0,0,0
restore invaderdata
for x = 1 to 47
    add limb 1,x,1
    read xo
    read yo
    offset limb 1, x, xo - 6, -yo + 4, 0
    if x = 47 then scale limb 1, x, 500,100,100
next x
hide limb 1, 45
hide limb 1, 46
hide limb 1, 47

dim mode$(30)
dim desty#(30)
dim tx#(30)
dim ty#(30)
dim tz#(30)
dim mx#(30)
dim my#(30)
dim mz#(30)
dim tmout#(30)
dim ptx#(30,44)
dim pty#(30,44)
dim ptz#(30,44)
dim pmx#(30,44)
dim pmy#(30,44)
dim pmz#(30,44)
for x = 1 to 20
    if x <> 1 then clone object x, 1
    position object x,  rnd(200) - 100, rnd(500) + 100, 0
    mode$(x) = "descend"
next x


`Create Ground
    create bitmap 1, screen width(), screen height()
    set current bitmap 1
    ink rgb(0,150,0),0
    box 0,0,100,100
    ink rgb(0,200,0),0
    for x = 1 to 500
        circle rnd(100),rnd(100),1
    next x
    get image 2,0,0,100,100
    set current bitmap 0
make matrix 1,500,500,30,30
position matrix 1, -250, -100, -250
prepare matrix texture 1,2,1,1
fill matrix 1, 0, 1
randomize matrix 1, 20
update matrix 1

make object sphere 52,.3
scale object 52, 100,100,100000



position camera 0,0,-200
fog on: fog distance 600: fog color rgb(100,100,200)



if file exist("highscore.DATA") = 0
    open to write 1, "highscore.DATA"
    highscore# = 0
    write float 1, highscore#
    close file 1
endif

if file exist("highscore.DATA") = 1
    open to read 1, "highscore.DATA"
    read float 1, highscore#
    close file 1
endif

make object box 53, 2,2,7
hide object 53

newgame:
spd# = .7
score = 0
do

    tmr = timer()

    pick screen mousex(), mousey(), 20000000000
    mx# = get pick vector x()
    my# = get pick vector y()
    mz# = get pick vector z()

set cursor 0,0
        `Control Aliens
        spd# = spd# + .00025
        for x = 1 to 20
            if mode$(x) = "descend"
                position object x, object position x(x), object position y(x) - spd#, object position z(x)
                if object position y(x) < 50
                    mode$(x) = "right"
                    desty#(x) = 50
                endif
            endif
            if mode$(x) = "right"
                position object x, object position x(x)+ spd#, curvevalue(desty#(x),object position y(x),10), object position z(x)
                rotate object x, 0,curveangle(0,object angle y(x), 10),0
                if object position x(x) > 100
                    mode$(x) = "left"
                    desty#(x) = desty#(x) - 10
                    rotate object x, 0,object angle y(x) - 10,0
                endif
                if object position y(x) < get ground height(1,object position x(x) + 250, object position z(x) + 250) - 100 then goto youlose
                if rnd(2000) = 1 and object visible(53) = 0
                    position object 53, object position x(x), object position y(x) - 3, object position z(x)
                    point object 53, camera position x(), camera position y() - 5, camera position z()
                    show object 53
                endif            
            endif
            if mode$(x) = "left"
                position object x, object position x(x)- spd#, curvevalue(desty#(x),object position y(x),10), object position z(x)
                rotate object x, 0,curveangle(180,object angle y(x), 10),0
                if object position x(x) < -100
                    mode$(x) = "right"
                    desty#(x) = desty#(x) - 10
                    rotate object x, 0,object angle y(x) + 10,0                  
                endif
                if object position y(x) < get ground height(1,object position x(x) + 250, object position z(x) + 250) - 100 then goto youlose
            
                if rnd(2000) = 1 and object visible(53) = 0
                    position object 53, object position x(x), object position y(x) - 3, object position z(x)
                    point object 53, camera position x(), camera position y() - 5, camera position z()
                    show object 53
                endif
            endif
            if mode$(x) = "fall"
                position object x, object position x(x) + mx#(x), object position y(x) + my#(x), object position z(x) + mz#(x)
                rotate object x, object angle x(x) + tx#(x), object angle y(x) + ty#(x), object angle z(x) + tz#(x)
                my#(x) = my#(x) - .3
                if object position y(x) < get ground height(1,object position x(x) + 250, object position z(x) + 250) - 100
                    for p = 1 to 44
                        ptx#(x,p) = rnd(10) - 5
                        pty#(x,p) = rnd(10) - 5
                        ptz#(x,p) = rnd(10) - 5
                        pmy#(x,p) = rnd(10) +3:pmy#(x,p) = pmy#(x,p) * .5
                        pmx#(x,p) = rnd(10) - 5:pmx#(x,p) = pmx#(x,p) * .5
                        pmz#(x,p) = rnd(10):pmz#(x,p) = pmz#(x,p) * .5
                    next p
                    mode$(x) = "explode"
                    tmout#(x) = 200
                    rotate object x, 0,0,0
                    score = score + 100
                endif
            endif
            if mode$(x) = "explode"
                for p = 1 to 44
                    offset limb x,p, limb offset x(x,p) + pmx#(x,p), limb offset y(x,p) + pmy#(x,p), limb offset z(x,p) + pmz#(x,p)
                    rotate limb x,p, limb angle x(x,p) + ptx#(x,p), limb angle y(x,p) + pty#(x,p), limb angle y(x,p) + pty#(x,p)
                    pmy#(x,p) = pmy#(x,p) - .3
                next p
                tmout#(x) = tmout#(x) - 1
                if tmout#(x) < 0
                    gosub rebuildship
                    mode$(x) = "descend"
                    position object x,  rnd(200) - 100, rnd(300) + 100, 0
                endif
            endif
            if intersect object(x, object position x(52), object position y(52), object position z(52), ox#,oy#,oz#) > 0
                mode$(x) = "fall"
                tx#(x) = rnd(10) - 5
                ty#(x) = rnd(10) - 5
                tz#(x) = rnd(10) - 5
                my#(x) = rnd(10) +3:my#(x) = my#(x) * .1
                mx#(x) = rnd(10) - 5:mx#(x) = mx#(x) * .1
                mz#(x) = rnd(10):mz#(x) = mz#(x) * .1
            endif
            for a = 1 to 20
                if desty#(a) = desty#(x) and object collision(a,x) = 1
                    dst# = object position x(a) - object position x(x)
                    position object x, object position x(x) - (dst# / 10), object position y(x), object position z(x)
                    position object a, object position x(a) + (dst# / 10), object position y(a), object position z(a)             
                endif
            next a

            
        next x

        if mouseclick() = 0 and object position z(52) > 0 then msrd = 1
        if msrd = 1 and mouseclick() = 1
            position object 52, camera position x(), camera position y()-2, camera position z()
            point object 52, mx#, my# + 3, mz#
            msrd = 0
        endif
        ox# = object position x(52):oy# = object position y(52):oz# = object position z(52)
        move object 52, 50

        move object 53, 3
        roll object left 53, 20
        if object position z(53) < -200 and object visible(53) = 1
            hide object 53
            cls rgb(255,255,255)
            for x = 1 to 20
                desty#(x) = desty#(x) - 20
            next x
        endif
        if intersect object(53, object position x(52), object position y(52), object position z(52),ox#,oy#,oz#) > 0
            hide object 53
            turn object left 52, rnd(10) - 5
            pitch object up 52, rnd(10) - 5
            move object 52, 300
        endif

        turn object right 51, .2
        
        ink rgb(255,0,0),0
        circle mousex(), mousey(),2
        circle mousex(), mousey(),1
        circle mousex(), mousey(),0
        
        set cursor 0,0
        if score > highscore# then highscore# = score
        print "SCORE: " +  str$(score)
        print " HIGH: " + str$(highscore#)
        
    sync
    while timer() - tmr < 30
    endwhile
loop


rebuildship:
    restore invaderdata
    for p = 1 to 44
        read xo
        read yo
        offset limb x, p, xo - 6, -yo + 4, 0
        rotate limb x,p,0,0,0
    next p
return


youlose:
    do
        hide object 53
        tmr = timer()
        sync
            for x = 1 to 20
                position object x, object position x(x), object position y(x), object position z(x) - 2
                roll object left x, 3
            next x
            center text screen width()/2, screen height()/2, "GAME OVER"
            if score >= highscore# then center text screen width()/2, screen height()/2 + 15, "NEW HIGH SCORE!"
            center text screen width()/2, screen height()/2 + 30, "PRESS SPACE TO CONTINUE"
            if spacekey() = 1
                for x = 1 to 20
                    position object x,  rnd(200) - 100, rnd(500) + 100, 0
                    rotate object x,0,0,0
                    mode$(x) = "descend"
                    desty#(x) = 50
                    gosub rebuildship
                next x
                if score >= highscore#
                    delete file "highscore.DATA"
                    open to write 1, "highscore.DATA"
                    write float 1, highscore#
                    close file 1
                endif
                goto newgame
            endif
        while timer() - tmr < 30
        endwhile
    loop
    

set display mode 800, 600, 16
sync on
sync rate 0
set point light 0, 000, 200, -200
set light range 0, 1000
set ambient light 20
color backdrop 0


rem D3D_INIT

null = make vector3(1) :`Velocity
null = make vector3(2) :`Paddle Normal
null = make vector3(3) :`Used for collision
null = make vector3(4) :`Used for collision


#constant CURVE_RADIUS 12.0
#constant PADDLE_SPEED 0.135



Type Coord3D
   x as float
   y as float
   z as float
EndType

Type PlayerData
   angle as float
   targetAngle as float
   score as byte
EndType

Dim P(2) as PlayerData

P(1).angle = 225
P(2).angle = -45
P(1).targetAngle = 225
P(2).targetAngle = -45
P(1).score = 0
P(2).score = 0

`Make Paddles
make object box 2, 0.5, 6.0, 0.5
make object box 3, 0.5, 6.0, 0.5




Type BallData
   p as Coord3D
EndType
Global Ball as BallData
resetPlay()
`Make Ball
make object sphere 1, 0.5
position object 1, Ball.p.x, Ball.p.y, Ball.p.z





`Make floor
make object box 4, CURVE_RADIUS * 3.0, 4.0, 1.0
position object 4, 0, -CURVE_RADIUS * 1.2, 0
point object    4, 0, 0, 0





position mouse screen width() * 0.5, 0
hide mouse


autocam off
position camera 0, 3, -30
point camera 0, 2, 0

global frameTime as float
frameTime = 1.0
startTime as integer
startTime = timer()
do
   frameTime = (frameTime * 0.8) + ((timer() - startTime) * 0.2)
   startTime = timer()

   if spacekey() then resetPlay()




   `Handle Player 1
   if keystate(29)
      `Left Shift
      inc P(1).targetAngle, frameTime * PADDLE_SPEED
      if P(1).targetAngle > 280.0 then P(1).targetAngle = 280.0
   else
      if keystate(42)
         `Left Ctrl
         dec P(1).targetAngle, frameTime * PADDLE_SPEED
         if P(1).targetAngle < 90 then P(1).targetAngle = 90
      endif
   endif
   P(1).angle = curvevalue(P(1).targetAngle, P(1).angle, 200.0 / frameTime)

   `Handle Player 2
   if keystate(54)
      `right Shift
      inc P(2).targetAngle, frameTime * PADDLE_SPEED
      if P(2).targetAngle > 90.0 then P(2).targetAngle = 90.0
   else
      if keystate(157)
         `Right Ctrl
         dec P(2).targetAngle, frameTime * PADDLE_SPEED
         if P(2).targetAngle < -100 then P(2).targetAngle = -100
      endif
   endif
   P(2).angle = curvevalue(P(2).targetAngle, P(2).angle, 200.0 / frameTime)


   `text 0,  0, "P1: " + str$(P(1).angle)
   `text 0, 10, "P2: " + str$(P(2).angle)
   text 0, 0, "Player 1 Score: " + str$(P(1).score)
   p2score$ = "Player 2 Score: " + str$(P(2).score)
   text screen width() - text width(p2score$), 0, p2score$



   position object 2, -(CURVE_RADIUS*0.5) + (cos(P(1).angle) * CURVE_RADIUS), sin(P(1).angle) * CURVE_RADIUS, 0
   zrotate object  2, P(1).angle

   position object 3,  (CURVE_RADIUS*0.5) + (cos(P(2).angle) * CURVE_RADIUS), sin(P(2).angle) * CURVE_RADIUS, 0
   zrotate object  3, P(2).angle


   `handle gravity
   set vector3 1, x vector3(1), y vector3(1) - (frameTime * 0.0098), z vector3(1)
   inc Ball.p.x, x vector3(1) * frametime * 0.001
   inc Ball.p.y, y vector3(1) * frametime * 0.001
   inc Ball.p.z, z vector3(1) * frametime * 0.001
   position object 1, Ball.p.x, Ball.p.y, Ball.p.z






   handleCollision(2, object hit (2, 1))
   handleCollision(3, object hit (3, 1))

   if object hit (4, 1)
      `hit floor
      set vector3 1, x vector3(1), -y vector3(1), z vector3(1)
   endif


   objSx# = object screen x(1)
   objSy# = object screen y(1)
   if objSx# > screen width()
      resetPlay()
      inc P(1).score
   else
      if objSx# < 0
         resetPlay()
         inc P(2).score
      endif
   endif
   if objSy# > screen height() then resetPlay()

   sync
loop
end




function resetPlay()
   Ball.p.x = -5.0
   Ball.p.y = 5.0
   Ball.p.z = 0.0
   set vector3 1, 0, 0, 0 :`velocity of ball
   if object exist(1) then position object 1, Ball.p.x, Ball.p.y, Ball.p.z
endfunction



function handleCollision(paddle as integer, hit as boolean)
   `Normal of paddle
   set vector3 2, cos(object angle z(paddle)), sin(object angle z(paddle)), 0
   normalize vector3 2, 2
   scale vector3 2, 2, 2.0

   `Get unit/normalized version of ball speed
   normalize vector3 3, 1
   `Temporarily invert
   multiply vector3 3, -1
   `Get scalar impulse
   I# = dot product vector3(2, 3) * 2.0
   `Multiply normal vector by it (and store in vector3(4))
   copy vector3 4, 2
   multiply vector3 4, I#
   `Un-invert
   multiply vector3 3, -1
   `Add to vector 4...
   add vector3 4, 3, 4
   `Normlize
   normalize vector3 4, 4
   `Scale by speed magnitude...
   multiply vector3 4, length vector3(1) * 1.05


   if hit then copy vector3 1, 4
endfunction

sync on:sync rate 120

randomize timer()

draw sprites first
draw to front


global dim level(10100)
global dim enemies(10000,2)
global dim blocks(10000,2)
global dim tanks(10000,2)


global lives
global death
global score
global invinsable
global totalblock
global gas
global totaltank
global screeny
global speed
global basespeed


set image colorkey 255,0,255

ink rgb(0,100,0),rgb(0,100,0)
box 0,0,100,600
get image 10,0,0,100,600
cls



restore plane
image(1,4)

restore bullet
image(2,4)

restore heli
image(3,5)

restore block
image(4,15)

restore outline
image(5,2)

ink rgb(100,0,0),rgb(100,0,0)

box 0,0,100,12
get image 6,0,0,100,12
cls

box 0,0,50,50
get image 7,0,0,50,50
cls


do

   undim level()
   undim enemies()
   undim blocks()
   undim tanks()
   global dim level(10100)
   global dim enemies(10000,2)
   global dim blocks(10000,2)
   global dim tanks(10000,2)

   death=0
   score=0
   invinsable=255
   screeny=0
   speed=0
   basespeed=1
   totalblock=0
   totaltank=0
   gas=2000
   x=0
   y=0

   lives=3

   for i=1 to 10000
      a=rnd(30)

      if x=10

         if y mod 4=0
            level(i-rnd(9)-1)=4
         endif

         y=y+1
         x=0
         fue=0

         if rnd(10)=1 and y>6
            for j=0 to 2
               for k=0 to j
                  level(i-47+j*10-k)=3
                  level(i-46+j*10+k)=3
               next k
            next j

            for j=0 to 1
               for k=0 to j
                  level(i-7-j*10-k)=3
                  level(i-6-j*10+k)=3
               next k
            next j

         endif

      endif

      x=x+1

      select a
         case 1
            level(i)=1
            w=1
         endcase

      endselect

      if w=0 then level(i)=0
      w=0

   next i

   level(i+1)=-999





   sprite 1,400,450,1
   set sprite priority 1,1



   sprite 1000,0,0,10
   sprite 1001,700,0,10

   make_level()

   repeat

      flash=flash+1

      ink rgb(255,255,255),rgb(255,255,255)

      if flash<100
         center text screen width()/2,screen height()/2-100,"Press Space to Start"
      endif

      if flash>200 then flash=0

      sync

   until spacekey()=1


   repeat
      if invinsable>0
         set sprite alpha 1,255-invinsable
         invinsable=invinsable-1
      endif

      text 0,0,str$(screen fps())



      a=a-1
      a=fire(a)

      move_tank()





      control_enemy()
      screeny=screeny-speed

      move_blocks()

      fuel()
      display()
      move()


      sync

   until death=2



   for i=10 to enemies(0,0)+9
      if sprite exist(i)=1 then delete sprite i
   next i
   for i=1002 to totalblock+1001
      if sprite exist(i)=1 then delete sprite i
   next i
   for i=500 to totaltank+499
      if sprite exist(i)=1 then delete sprite i
    next i

loop

function fuel()

   if gas=0
      die()
   endif

   col=sprite collision(1,0)

   if col>500 and col<1000
      gas=2000
   endif

   center text screen width()/2,500,"Fuel"

   sprite 7,screen width()/2-51,550,5
   sprite 8,screen width()/2-49,550+2,6
   set sprite priority 7,1
   set sprite priority 8,1

   stretch sprite 8,gas/20,100

   gas=gas-1

endfunction

function display()

   ink rgb(255,255,255),rgb(255,255,255)

   text 150,10,"Lives: "+str$(lives)
   text 500,10,"Score: "+str$(score)

endfunction

function move()

   if upkey()=1
      speed=basespeed+1
   else
      speed=basespeed
   endif

   if rightkey()=1
      rotate sprite 1,90
      move sprite 1,2
      rotate sprite 1,0
   endif

   if leftkey()=1
      rotate sprite 1,-90
      move sprite 1,2
      rotate sprite 1,0
   endif

   col=sprite collision(1,0)

   if col>=1000 and invinsable=0
      die()
   endif

   basespeed=int(screeny/-10000)+1
   if basespeed>3 then basespeed=3



endfunction

function fire(a)

   if spacekey()=1 and a=<0
      for i=2 to 6
         if sprite exist(i)=0 then spr=i
         a=50
      next i
      if spr>0 then sprite spr,sprite x(1)+sprite width(1)/2-2,450,2
   endif

   for i=2 to 6
      if sprite exist(i)
         move sprite i,2
         if sprite y(i)<0 then delete sprite i
      endif
   next i


endfunction a


function control_enemy()

   for i=10 to enemies(0,0)+9


      if sprite exist(i)
         move sprite i,-speed


         if sprite y(i)>300 and sprite y(i)<500
            rotate sprite i,90
            if sprite exist(1)
              if sprite x(1)>sprite x(i)
                 move sprite i,1

                 if sprite collision(i,0)>1000
                    move sprite i,-1
                 endif
              else
                 move sprite i,-1
                 if sprite collision(i,0)>1000
                    move sprite i,1
                 endif
              endif
            endif
            rotate sprite i,0
         endif

         col=sprite collision(i,0)

         if col=1 and invinsable=0
            delete sprite i
            enemies(i-9,1)=-5
            die()
         endif


         for j=2 to 6
            if sprite exist(j)=1 and sprite exist(i)=1
               if sprite collision(i,j)=1
                  delete sprite i
                  delete sprite j
                  enemies(i-9,1)=-5
                  score=score+100
               endif
            endif
         next j

         if enemies(i-9,2)>screeny+600 and sprite exist(i)=1
            delete sprite i
            enemies(i-9,1)=-5
         endif

      else
         if enemies(i-9,1)>0 and enemies(i-9,2)>screeny and enemies(i-9,2)<screeny+600
            sprite i,enemies(i-9,1),enemies(i-9,2)-screeny,3
         endif
      endif

   next i

endfunction

function die()

   gas=2000
   lives=lives-1
   invinsable=255
   sprite 1,400,450,1

   if lives=0
      selection=1
      repeat
         set text size 20
         center text screen width()/2,screen height()/2,"GAME OVER"
         set text size 10
         center text screen width()/2,screen height()/2+50,"Score: "+str$(score)
         center text screen width()/2,screen height()/2+75,"Play again?"

         if rightkey()=1 then selection=2
         if leftkey()=1 then selection=1

         if selection=1
            ink rgb(100,100,0),rgb(100,100,0)
            center text screen width()/2-50,screen height()/2+100,"Yes"
            ink rgb(255,255,255),rgb(255,255,255)
            center text screen width()/2+50,screen height()/2+100,"No"
         endif

         if selection=2
            ink rgb(255,255,255),rgb(255,255,255)
            center text screen width()/2-50,screen height()/2+100,"Yes"
            ink rgb(100,100,0),rgb(100,100,0)
            center text screen width()/2+50,screen height()/2+100,"No"
         endif

         sync

         ink rgb(255,255,255),rgb(255,255,255)

      until returnkey()=1



      if selection=2
         end
      else
         death=2
      endif


   endif

endfunction

function make_enemy(x,y)

   enemies(0,0)=enemies(0,0)+1
   enemies(enemies(0,0),1)=x
   enemies(enemies(0,0),2)=y

endfunction

function make_level()


   x=100

   repeat

      i=i+1
      a=level(i)

      x=x+60
      if x=>700
         x=100
         y=y-60
      endif

      if a=1
         make_enemy(x,y)
      endif

      if a=3
         make_block(x,y)
      endif

      if a=4
         make_fuel_tank(x,y)
      endif


   until a=-999

endfunction

function make_block(x,y)

   totalblock=totalblock+1
   blocks(totalblock,1)=x
   blocks(totalblock,2)=y

endfunction

function move_blocks()
   for i=1002 to 1002+totalblock-1
      if sprite exist(i)
         move sprite i,-speed
         if blocks(i-1001,2)>screeny+600
            delete sprite i
            blocks(i-1001,1)=-5
         endif
      else
         if blocks(i-1001,1)>0 and blocks(i-1001,2)>screeny and blocks(i-1001,2)<screeny+600
            sprite i,blocks(i-1001,1),blocks(i-1001,2)-screeny,4
         endif
      endif

   next i
endfunction

function make_fuel_tank(x,y)

   totaltank=totaltank+1
   tanks(totaltank,1)=x
   tanks(totaltank,2)=y

endfunction

function move_tank()
   for i=500 to 500+totaltank-1
      if sprite exist(i)
         move sprite i,-speed
         if tanks(i-499,2)>screeny+600
            delete sprite i
            tanks(i-499,1)=-5
         endif
      else
         if tanks(i-499,1)>0 and tanks(i-499,2)>screeny and tanks(i-499,2)<screeny+600
            sprite i,tanks(i-499,1),tanks(i-499,2)-screeny,7
         endif
      endif
   next i
endfunction

function image(num,size)

   dim colors(100,3)

   read a$
   a$=a$+"-"

   repeat
      i=i+1

      for j=1 to len(a$)

         c$=c$+b$
         b$=mid$(a$,j)

         if b$="-" or b$=" "
            k=k+1
            colors(i,k)=val(c$)
            c$=""
            b$=""
         endif

      next j

      k=0
      read a$
      a$=a$+"-"

   until a$="XXX-"


   x=0
   y=0

   repeat
      read a
      x=x+1

      if a>0 and a<100
         ink rgb(colors(a,1),colors(a,2),colors(a,3)),rgb(colors(a,1),colors(a,2),colors(a,3))
         box (x-1)*size,(y-1)*size,x*size,y*size
      endif

      if a=0
         ink rgb(255,0,255),rgb(255,0,255)
         box (x-1)*size,(y-1)*size,x*size,y*size
      endif

      if a=100
         y=y+1
         x=0
      endif

   until a=-999

   get image num,0,0,(x-1)*size,y*size

   cls

endfunction

plane:
data "255-255-0"
data "XXX"

data 0,0,0,0,1,0,0,0,0,100
data 0,0,0,0,1,0,0,0,0,100
data 0,0,0,1,1,1,0,0,0,100
data 0,0,1,1,1,1,1,0,0,100
data 0,1,1,0,1,0,1,1,0,100
data 1,1,0,0,1,0,0,1,1,100
data 0,0,0,0,1,0,0,0,0,100
data 0,0,0,1,1,1,0,0,0,100
data 0,0,1,1,0,1,1,0,0,-999

bullet:
data "255-255-0"
data "XXX"

data 1,100
data 1,100
data 1,100
data 1,100
data 1,100
data 1,100
data 1,100
data 1,100
data 1,-999

heli:
data "238 154 0","34-139-34"
data "XXX"

data 0,0,0,0,0,0,0,0,0,100
data 0,0,0,0,0,1,1,0,0,100
data 0,0,0,0,0,0,0,1,1,100
data 2,0,0,0,0,2,2,2,0,100
data 2,2,2,2,2,2,2,2,2,100
data 2,0,0,0,0,2,2,2,2,100
data 0,0,0,0,0,0,2,2,0,100
data 0,0,0,0,0,1,1,1,1,-999

block:
data "0 100 0"
data "XXX"

data 1,1,1,1,100
data 1,1,1,1,100
data 1,1,1,1,100
data 1,1,1,1,100
data 1,1,1,1,-999

outline:
data "0 0 0"
data "XXX"

data 100
data 1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,100
data 1,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,1,100
data 1,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,1,100
data 1,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,1,100
data 1,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,1,100
data 1,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,1,100
data 1,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,1,100
data 1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,-999

sync on
sync rate 30
autocam off
color backdrop rgb(0,0,0)

wire=0 ` 0=ghosting, 1=wireframe

dim shapes(9,2,2)
for shp=0 to 7
  for cy=0 to 2
      for cx = 0 to 2
        read shapes(shp,cx,cy)
      next cx
  next cy
next shp

for c=1 to 17
  make object plain c,0.1,0.1
  hide object c
next c

position object 1,14.9,14.5,15.4
position object 2,14.1,14.5,15.4
position object 3,14.1,14.5,14.6
position object 4,14.9,14.5,14.6

position object 5,14.9,14.5,14.4
position object 6,14.1,14.5,14.4
position object 7,14.1,14.5,13.6
position object 8,14.9,14.5,13.6

position object 9,13.9,14.5,14.4
position object 10,13.1,14.5,14.4
position object 11,13.1,14.5,13.6
position object 12,13.9,14.5,13.6

position object 13,15.9,14.5,14.4
position object 14,15.1,14.5,14.4
position object 15,15.1,14.5,13.6
position object 16,15.9,14.5,13.6

position object 17,14.5,14.5,15.5
areasize=29
ghost=1

dim tempshape(2,2,2)
dim currshape(2,2,2)
dim tempblocks(areasize,areasize,areasize)
dim blockobj(areasize,areasize,areasize)
dim blockghost(areasize,areasize,areasize)

dim colour(10)
colour(1)=rgb(100,100,100)
colour(2)=rgb(255,0,0)
colour(3)=rgb(0,0,255)
colour(4)=rgb(0,255,0)
colour(5)=rgb(255,255,0)
colour(6)=rgb(0,255,255)
colour(7)=rgb(255,0,255)

start:

randomize val(right$(get time$(),2))*val(left$(right$(get time$(),5),2))
nextshape=rnd(6)
objs=0

dim blocks(areasize,areasize,areasize)
for cx=0 to areasize
  for cy=0 to areasize
    for cz=0 to areasize
    blocks(cx,cy,cz)=0
    blockghost(cx,cy,cz)=0
    next cz
  next cy
next cx

blocks(14,14,14)=1
blocks(14,14,15)=1
blocks(14,15,14)=1
blocks(14,15,15)=1
blocks(15,14,14)=1
blocks(15,14,15)=1
blocks(15,15,14)=1
blocks(15,15,15)=1
currframe=0
falling=1
newblock=1
fallfraction=0
camrot#=0
camxrot#=20
score=0
brlimit=0
lives=3
pause=0
fallspeed#=29
gameover=0
ghosty=-1

sw=screen width()
sh=screen height()

position camera 14.5,20,14.5
yrotate camera camrot#
xrotate camera camxrot#
move camera -15


do

  mx=mousemovex()
  my=mousemovey()
  if mx<>0
    camrot#=camrot#+(mx/4)
    camxrot#=camxrot#+(my/4)
    position camera 14.5,14.5,14.5
    yrotate camera camrot#
    xrotate camera camxrot#
    move camera -15
    position camera camera position x(), camera position y()+5, camera position z()
  endif

  ox=(sw-(sw/10))-object screen x(17)
  oy=(sh-(sh/10))-object screen y(17)
  for c=0 to 3
  mc=c*4
  line object screen x(mc+1)+ox,object screen y(mc+1)+oy,object screen x(mc+2)+ox,object screen y(mc+2)+oy
  line object screen x(mc+2)+ox,object screen y(mc+2)+oy,object screen x(mc+3)+ox,object screen y(mc+3)+oy
  line object screen x(mc+3)+ox,object screen y(mc+3)+oy,object screen x(mc+4)+ox,object screen y(mc+4)+oy
  line object screen x(mc+4)+ox,object screen y(mc+4)+oy,object screen x(mc+1)+ox,object screen y(mc+1)+oy
  next c

  keyspace=0
  keyreturn=0
  keybackspace=0
  if spacekey()=0
  space=0
  endif
  if (spacekey()=1) AND (space=0)
  space=1
  keyspace=1
  endif
  if returnkey()=0
  returnk=0
  endif
  if (returnkey()=1) AND (returnk=0)
  returnk=1
  keyreturn=1
  endif
  if keystate(14)=0
  backspace=0
  endif
  if (keystate(14)=1) AND (backspace=0)
  backspace=1
  keybackspace=1
  endif


if pause=0
  fallfraction=fallfraction+1;

  if ghosty>-1
    for cx=0 to 2
      for cy=0 to 2
        for cz=0 to 2
          if (cy-(shapey-ghosty)>-1) AND (cy-(shapey-ghosty)<3)
            if currshape(cx,cy-(shapey-ghosty),cz)=0
              if currshape(cx,cy,cz)<>0
                blocks(shapex+cx,ghosty+cy,shapez+cz)=0
                `blockghost(shapex+cx,ghosty+cy,shapez+cz)=0
              endif
            endif
          else
            if currshape(cx,cy,cz)<>0
              blocks(shapex+cx,ghosty+cy,shapez+cz)=0
              `blockghost(shapex+cx,ghosty+cy,shapez+cz)=0
            endif
          endif
        next cz
      next cy
    next cx
  endif

  if upkey()=0
  up=0
  endif
  if downkey()=0
  down=0
  endif
  if rightkey()=0
  right=0
  endif
  if leftkey()=0
  left=0
  endif

  moveshape=0
  rotateshape=0
  rotateblocks=0
  xrotate=0
  yrotate=0
  zrotate=0
  rmod=0
  oshapex=shapex
  oshapez=shapez
  mouseval=mouseclick()
  lmb=0
  mmb=0
  rmb=0
  if int(mouseval/8)=1
  mouseval=mouseval-8
  endif
  if int(mouseval/4)=1
  mouseval=mouseval-4
  mmb=1
  endif
  if int(mouseval/2)=1
  mouseval=mouseval-2
  rmb=1
  endif
  if mouseval=1
  lmb=1
  endif

  if (lmb=1) OR (shiftkey())
    if (rmb=1) OR (controlkey())
      if (rightkey()=1) AND (right=0)
        right=1
        rotateshape=1
        yrotate=1
        rmod=1
      endif
      if (leftkey()=1) AND (left=0)
        left=1
        rotateshape=1
        yrotate=1
        rmod=0
      endif
    else
      if (upkey()=1) AND (up=0)
        up=1
        rotateshape=1
        xrotate=1
        rmod=0
      endif
      if (downkey()=1) AND (down=0)
        down=1
        rotateshape=1
        xrotate=1
        rmod=1
      endif
      if (rightkey()=1) AND (right=0)
        right=1
        rotateshape=1
        zrotate=1
        rmod=1
      endif
      if (leftkey()=1) AND (left=0)
        left=1
        rotateshape=1
        zrotate=1
        rmod=0
      endif
    endif
  else
    if (rmb=1) OR (controlkey())
      if (upkey()=1) AND (up=0)
        up=1
        rotateblocks=1
        xrotate=1
        rmod=1
      endif
      if (downkey()=1) AND (down=0)
        down=1
        rotateblocks=1
        xrotate=1
        rmod=0
      endif
      if (rightkey()=1) AND (right=0)
        right=1
        rotateblocks=1
        zrotate=1
        rmod=0
      endif
      if (leftkey()=1) AND (left=0)
        left=1
        rotateblocks=1
        zrotate=1
        rmod=1
      endif
    endif
    if (upkey()=1) AND (up=0)
      up=1
      moveshape=1
      shapez=shapez+1
    endif
    if (downkey()=1) AND (down=0)
      down=1
      moveshape=1
      shapez=shapez-1
    endif
    if (rightkey()=1) AND (right=0)
      right=1
      moveshape=1
      shapex=shapex+1
    endif
    if (leftkey()=1) AND (left=0)
      left=1
      moveshape=1
      shapex=shapex-1
    endif
  endif

  if rotateblocks=1
      for cx = 0 to 2
        for cy = 0 to 2
          for cz = 0 to 2
            if (currshape(cx,cy,cz)<>0) then blocks(oshapex+cx,shapey+cy,oshapez+cz)=0
          next cz
        next cy
      next cx

    for cx= 0 to areasize
      for cy= 0 to areasize
        for cz= 0 to areasize
          if zrotate=1
            if rmod=0
              tempblocks(cx,cy,cz)= blocks(areasize-cy,cx,cz)
            else
              tempblocks(cx,cy,cz)= blocks(cy,areasize-cx,cz)
            endif
          endif
          if xrotate=1
            if rmod=0
              tempblocks(cx,cy,cz)= blocks(cx,areasize-cz,cy)
            else
              tempblocks(cx,cy,cz)= blocks(cx,cz,areasize-cy)
            endif
          endif
          if yrotate=1
            if rmod=0
              tempblocks(cx,cy,cz)= blocks(areasize-cz,cy,cx)
            else
              tempblocks(cx,cy,cz)= blocks(cz,cy,areasize-cx)
            endif
          endif
        next cz
      next cy
    next cx
    clear=1
      for cx = 0 to 2
        for cy = 0 to 2
          for cz = 0 to 2
            if (tempblocks(oshapex+cx,shapey+cy,oshapez+cz)<>0) AND (currshape(cx,cy,cz)<>0) then clear=0
          next cz
        next cy
      next cx

    if clear=1
      for cx= 0 to areasize
        for cy= 0 to areasize
          for cz= 0 to areasize
            blocks(cx,cy,cz)=tempblocks(cx,cy,cz)
          next cz
        next cy
      next cx
    endif

    for cx = 0 to 2
      for cy = 0 to 2
        for cz = 0 to 2
          blocks(shapex+cx,shapey+cy,shapez+cz)=currshape(cx,cy,cz)
        next cz
      next cy
    next cx

  endif

  if rotateshape=1
    clear=1

    if zrotate=1
      for cx = 0 to 2
        for cy = 0 to 2
          for cz = 0 to 2
            if rmod=0
              tempshape(2-cy,cx,cz)=currshape(cx,cy,cz)
            else
              tempshape(cy,2-cx,cz)=currshape(cx,cy,cz)
            endif
            if currshape(cx,cy,cz)<>0
              blocks(cx+oshapex,cy+shapey,cz+oshapez)=0
            endif
          next cz
        next cy
      next cx
    endif

    if xrotate=1
      for cx = 0 to 2
        for cy = 0 to 2
          for cz = 0 to 2
            if rmod=0
              tempshape(cx,2-cz,cy)=currshape(cx,cy,cz)
            else
              tempshape(cx,cz,2-cy)=currshape(cx,cy,cz)
            endif
            if currshape(cx,cy,cz)<>0
              blocks(cx+oshapex,cy+shapey,cz+oshapez)=0
            endif
          next cz
        next cy
      next cx
    endif

    if yrotate=1
      for cx = 0 to 2
        for cy = 0 to 2
          for cz = 0 to 2
            if rmod=0
              tempshape(2-cz,cy,cx)=currshape(cx,cy,cz)
            else
              tempshape(cz,cy,2-cx)=currshape(cx,cy,cz)
            endif
            if currshape(cx,cy,cz)<>0
              blocks(cx+oshapex,cy+shapey,cz+oshapez)=0
            endif
          next cz
        next cy
      next cx
    endif

    for cx = 0 to 2
      for cy = 0 to 2
        for cz = 0 to 2
          if (blocks(cx+shapex,cy+shapey,cz+shapez)<>0) AND (tempshape(cx,cy,cz)<>0)
            clear=0
          endif
        next cz
      next cy
    next cx

    for cx = 0 to 2
      for cy = 0 to 2
        for cz = 0 to 2
          if clear=0
            if currshape(cx,cy,cz)<>0
              blocks(cx+shapex,cy+shapey,cz+shapez)=currshape(cx,cy,cz)
            endif
          else
            currshape(cx,cy,cz)=tempshape(cx,cy,cz)
            if tempshape(cx,cy,cz)<>0
              blocks(cx+shapex,cy+shapey,cz+shapez)=tempshape(cx,cy,cz)
            endif
          endif
        next cz
      next cy
    next cx
  endif

  if moveshape=1

    clear=1
    for cx = 0 to 2
      for cy = 0 to 2
        for cz = 0 to 2
          if currshape(cx,cy,cz)<>0
            blocks(cx+oshapex,cy+shapey,cz+oshapez)=0
          endif
        next cz
      next cy
    next cx

    for cx = 0 to 2
      for cy = 0 to 2
        for cz = 0 to 2
          if (blocks(cx+shapex,cy+shapey,cz+shapez)<>0) AND (currshape(cx,cy,cz)<>0)
            clear=0
          endif
        next cz
      next cy
    next cx
    if clear=0
    shapex=oshapex
    shapez=oshapez
    endif
    for cx = 0 to 2
      for cy = 0 to 2
        for cz = 0 to 2
          if currshape(cx,cy,cz)<>0

            blocks(cx+shapex,cy+shapey,cz+shapez)=currshape(cx,cy,cz)
          endif

        next cz
      next cy
    next cx
  endif

  tmpfallspeed=int(fallspeed#)
  if (returnkey()) OR (mmb=1)
  tmpfallspeed=1
  endif

  if fallfraction>tmpfallspeed
    clear=1
    for cx = 0 to 2
      for cy = 0 to 2
        for cz = 0 to 2
          if currshape(cx,cy,cz)<>0
            blocks(cx+shapex,cy+shapey,cz+shapez)=0
          endif
        next cz
      next cy
    next cx
    shapey=shapey-1;
    for cx = 0 to 2
      for cy = 0 to 2
        for cz = 0 to 2
          if (blocks(cx+shapex,cy+shapey,cz+shapez)<>0) AND (currshape(cx,cy,cz)<>0)
            clear=0
          endif
        next cz
      next cy
    next cx
    if clear=0
    shapey=shapey+1;
    newblock=1
    endif
    for cx = 0 to 2
      for cy = 0 to 2
        for cz = 0 to 2
          if currshape(cx,cy,cz)<>0
            blocks(cx+shapex,cy+shapey,cz+shapez)=currshape(cx,cy,cz)
          endif
        next cz
      next cy
    next cx
    fallfraction=0;
    if shapey<4
    newblock=1
    lives=lives-1
    for cx = 0 to 2
      for cy = 0 to 2
        for cz = 0 to 2
          if currshape(cx,cy,cz)<>0
            blocks(cx+shapex,cy+shapey,cz+shapez)=0
          endif
        next cz
      next cy
    next cx
    endif
  endif

  if newblock=1
     fallspeed#=fallspeed#-0.3
     if fallspeed#<6 then fallspeed#=6
    rectfound=1
    while rectfound=1

      rectfound=0
      for axis=1 to 3
      plane=0
     while (plane < (areasize+1))
          blocksinplane=0
          limita=-1
          limitb=areasize+1
          limitc=-1
          limitd=areasize+1

            for counta=0 to areasize
              for countb=0 to areasize
                occupied=0
                select axis
                  case 1
                    if (blocks(counta,plane,countb)<>0) then occupied=1
                  endcase
                  case 2
                    if (blocks(plane,counta,countb)<>0) then occupied=1
                  endcase
                  case 3
                    if (blocks(counta,countb,plane)<>0) then occupied=1
                  endcase
                endselect

                if occupied=1
                  blocksinplane=blocksinplane+1
                  if countb>limita then limita=countb
                  if countb<limitb then limitb=countb
                  if counta>limitc then limitc=counta
                  if counta<limitd then limitd=counta
                endif
              next countb
            next counta

          rx=(limitc-limitd+1)
          ry=(limita-limitb+1)
          rectarea=rx*ry
                if plane>14.5
                  pmod=1
                  ptarget= areasize-1
                  ppatch=areasize
                else
                  pmod=-1
                  ptarget=1
                  ppatch=0
                endif
          if ((rectarea>5) AND (rectarea=blocksinplane)) AND ((plane<14) OR (plane>15))
            score=score+(rectarea*1000)
            if rx=ry then score=(score+((rectarea*rectarea)*1000))-(rectarea*1000)
            for cplane=plane to ptarget step pmod
              for ca=0 to areasize
                for cb=0 to areasize

                select axis
                  case 1: blocks(ca,cplane,cb)=blocks(ca,cplane+pmod,cb) : endcase
                  case 2: blocks(cplane,ca,cb)=blocks(cplane+pmod,ca,cb) : endcase
                  case 3: blocks(ca,cb,cplane)=blocks(ca,cb,cplane+pmod) : endcase
                endselect

                next cb
              next ca
            next cplane
              for ca=0 to areasize
                for cb=0 to areasize
                select axis
                  case 1: blocks(ca,ppatch,cb)=0 : endcase
                  case 2: blocks(ppatch,ca,cb)=0 : endcase
                  case 3: blocks(ca,cb,ppatch)=0 : endcase
                endselect

                next cb
              next ca
              plane=areasize
              rectfound=1
          endif
          plane=plane+1

        endwhile

      next axis
    endwhile

    rand=nextshape
    nextshape=rnd(6)
    clear=1
    shapex=13
    shapey=areasize-4
    shapez=13
    for cx=0 to 2
      for cy=0 to 2
        if (shapes(rand,cx,cy)<>0) AND (blocks(shapex+cx,shapey+cy,shapez+1)<>0) then clear=0
      next cy
    next cx
    if clear=1
      for cx=0 to 2
        for cy=0 to 2
          currshape(cx,cy,0)=0
          currshape(cx,cy,2)=0
          currshape(cx,cy,1)=shapes(rand,cx,cy)
        next cy
      next cx
    else
      brlimit=1
    endif
    currframe=0
    newblock=0
    fallfraction=0
  endif
if ghost=1
  clear=1
  csy=shapey
  while (csy>-1) AND (clear=1)
    for cx=0 to 2
      for cy=0 to 2
        for cz=0 to 2
          if (cy-(shapey-csy)>-1) AND (cy-(shapey-csy)<3)
            if currshape(cx,cy-(shapey-csy),cz)=0
              if (blocks(shapex+cx,csy+cy,shapez+cz)<>0) AND (currshape(cx,cy,cz)<>0) then clear=0
            endif
          else
            if (blocks(shapex+cx,csy+cy,shapez+cz)<>0) AND (currshape(cx,cy,cz)<>0) then clear=0
          endif
        next cz
      next cx
    next cy
    if clear=1 then csy=csy-1
  endwhile
  csy=csy+1
  if csy>0
    for cx=0 to 2
      for cy=0 to 2
        for cz=0 to 2
          if (currshape(cx,cy,cz)<>0) AND (blocks(shapex+cx,csy+cy,shapez+cz)=0)
            blocks(shapex+cx,csy+cy,shapez+cz)=currshape(cx,cy,cz)+10
            blockghost(shapex+cx,ghosty+cy,shapez+cz)=0
          endif
        next cz
      next cy
    next cx
    ghosty=csy
  else
    ghosty=-1
  endif
endif

  for cx=0 to areasize
    for cy=0 to areasize
      for cz=0 to areasize
        if blocks(cx,cy,cz)<>0
          if blockobj(cx,cy,cz)=0
            obj=nextobj()
            make object cube obj,0.8
            position object obj,cx,cy,cz
            if blocks(cx,cy,cz)>9
              color object obj,colour(blocks(cx,cy,cz)-10)
              if wire=1
                set object wireframe obj,1
              else
                ghost object on obj
              endif
              blockghost(cx,cy,cz)=1
            else
              color object obj,colour(blocks(cx,cy,cz))
            endif
            blockobj(cx,cy,cz)=obj
          endif
          if (blocks(cx,cy,cz)>9) AND (blockghost(cx,cy,cz)=0)
            color object blockobj(cx,cy,cz),colour(blocks(cx,cy,cz)-10)
            if wire=1
              set object wireframe blockobj(cx,cy,cz),1
            else
              ghost object on blockobj(cx,cy,cz)
            endif
            blockghost(cx,cy,cz)=1
          endif
          if (blocks(cx,cy,cz)<10) AND (blockghost(cx,cy,cz)=1)
            if wire=1
              set object wireframe blockobj(cx,cy,cz),0
            else
              ghost object off blockobj(cx,cy,cz)
            endif
            blockghost(cx,cy,cz)=0
          endif
        else
          if blockobj(cx,cy,cz)<>0
            delete object blockobj(cx,cy,cz)
            blockobj(cx,cy,cz)=0
          endif
        endif
      next cz
    next cy
  next cx
endif

blocksize=sh/20
gap=blocksize/10
ox=sw-(blocksize*4)
oy=sh/2

text ox,(oy-text height("Next:"))-(blocksize/2),"Next:"

for cx=0 to 2
  for mcy=0 to 2
    if shapes(nextshape,cx,mcy)<>0
      cy=2-mcy
      ink colour(shapes(nextshape,cx,mcy)),rgb(0,0,0)
      line ox+(cx*blocksize)+gap,oy+(cy*blocksize)+gap,ox+(cx*blocksize)+gap,(oy+((cy+1)*blocksize))-gap
      line ox+(cx*blocksize)+gap,oy+(cy*blocksize)+gap,(ox+((cx+1)*blocksize))-gap,oy+(cy*blocksize)+gap
      line (ox+((cx+1)*blocksize))-gap,oy+(cy*blocksize)+gap,(ox+((cx+1)*blocksize))-gap,(oy+((cy+1)*blocksize))-gap
      line ox+(cx*blocksize)+gap,(oy+((cy+1)*blocksize))-gap,(ox+((cx+1)*blocksize))-gap,(oy+((cy+1)*blocksize))-gap
    endif
  next cy
next cx
ink rgb(255,255,255),rgb(0,0,0)



if (gameover=0) AND (keyspace=1)
if pause=0
pause=1
else
pause=0
endif
endif
if ((lives<0) AND (brlimit=1)) OR ((lives<0) OR (brlimit=1))
  gameover=1
  pause=1
  text (screen width()/2)-(text width("Game Over")/2),screen height()/2,"Game Over"
  if spacekey() then goto start
endif
if (pause=1) AND (gameover=0)
  if ghost=1
    text (screen width()/2)-(text width("Preview block: On  (Enter to change)")/2),10,"Preview block: On  (Enter to change)"
  else
    text (screen width()/2)-(text width("Preview block: Off  (Enter to change)")/2),10,"Preview block: Off  (Enter to change)"
  endif
  if wire=1
    text (screen width()/2)-(text width("Wireframe  (Backspace to change)")/2),25,"Wireframe  (Backspace to change)"
  else
    text (screen width()/2)-(text width("Ghosting  (Backspace to change)")/2),25,"Ghosting  (Backspace to change)"
  endif
  text (screen width()/2)-(text width("Paused")/2),screen height()/2,"Paused"
  if keyreturn=1
    if ghost=1
      ghost=0
    else
      ghost=1
    endif
  endif
  if keybackspace=1
    if wire=1
      wire=0
    else
      wire=1
    endif
  endif
endif
text (screen width()-blocksize)-text width("lives: "+str$(lives)),10,"lives: "+str$(lives)
text blocksize,10,"score: "+str$(score)
sync

loop


function ismiddle(x,y,z)
imc=0
res=0
if (x=14) OR (x=15) then imc=1
if (y=14) OR (y=15) then imc=imc+1
if (z=14) OR (z=15) then imc=imc+1
if imc=3 then res=1
endfunction res

function nextobj()
fcount=1
while object exist(fcount)=1
fcount=fcount+1
endwhile
res=fcount
endfunction res

data 0,2,0
data 0,2,0
data 2,2,0

data 0,2,0
data 0,2,0
data 0,2,2

data 0,3,0
data 3,3,3
data 0,0,0

data 0,4,4
data 4,4,0
data 0,0,0

data 4,4,0
data 0,4,4
data 0,0,0

data 5,5,0
data 5,5,0
data 0,0,0

data 0,6,0
data 0,6,0
data 0,6,0