Sorry your browser is not supported!

autocam off:sync on:hide mouse
rem xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx
rem                       SOME TEXTURES
rem xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx
color backdrop 0
ink rgb(250,255,0),0:set ambient light 100
set cursor 0,0
print " This code was tested in Windows Vista and works"
print " fine, but perhaps some of you, notice that goes "
print " to fast, or to slow, that means that not all PCs"
print " runs at the same speed."
print " Maybe you will have  to change the sync rate. "
print " Cheers. "

get image 10,0,0,390,130
set ambient light 30

gosub hand
rem wood texture
create bitmap 1,100,100
ink rgb(160,70,40),1
box 0,0,100,100:
ink rgb(140,50,20),1
for a= 1 to 2
for i= 1 to 100 step 5
line 0,i-13+rnd(16),100,i-13+rnd(16)
ink rgb(60+rnd(100),20,20),1
next i
next a
ink rgb(0,0,0),1
box 0,24,100,26
box 0,49,100,51
box 0,74,100,76
blur bitmap 1,4
get image 1,0,0,100,100
get image 2,0,0,50,50
delete bitmap 1
rem sky texture =========================================
create bitmap 1,100,100
set current bitmap 1
ink rgb(0,200,255),1
box 0,0,100,100
for i= 1 to 100
col=100+rnd(155)
ink rgb(col,col,col),1
b=5+rnd(80)
ba=5+rnd(80)
t=rnd(10)
box b,ba,b+t,ba+t
next i
blur bitmap 1,6
get image 3,0,0,100,100,1
delete bitmap 1

rem sponge texture ======================================
ink rgb(236,230,130),1
box 0,0,30,30
for i= 1 to 100
dot rnd(30),rnd(30),rgb(200,200,100)
next i
get image 4,0,0,30,30
rem bricks texture =====================================
create bitmap 1,50,50
ink rgb(136,110,90),0
box 0,0,50,50
for i= 1 to 100
dot rnd(50),rnd(50),rgb(80,20,0)
next i
blur bitmap 1,4
ink rgb(0,0,0),0
line 0,0,50,0
line 0,50,50,50
line 0,25,50,25
line 25,0,25,25
line 0,25,0,50
get image 5,0,0,50,50
delete bitmap 1
rem xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx
rem                   SOUNDS
rem xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx
load sound "sound2.wav",2:rem set sound speed 2,4000
load sound "sound3.wav",3
load sound "sound1.wav",4
load sound "sound5.wav",5
rem xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx
rem                        SKY
rem xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx
bola(5000,2000,0,0,0,3)
set object cull 5000,0
ghost object on 5000
zrotate object 5000,180
scale object texture 5000,2,2
bola(5001,2100,0,0,0,3)
set object cull 5001,0
scale object texture 5001,2,2
set object collision off 5000
set object collision off 5001

rem xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx
rem                       LIGHTS
rem xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx
make light 1
position light 1,155,110,106
hide light 1
rem ======================================================
Dim rota(11)as float
Dim rota2(21)as float
Dim rota3(21)as float
#constant ball=11
#constant floo_r=12

rem xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx
rem                     SCENERY
rem xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx
cube(101,50,1,10,0,100,0,1)  //tabla primera
zrotate object 101,-15

cube(102,50,1,10,40,80,0,1)  //tabla segunda

`hinge=====================================================
cube(104,0.5,30,5,10,130,0,0)
offset limb 104,0,0,-15,0
make mesh from object 1,104
add limb 104,1,1        //limb que actua de chivato
color object 104,rgb(255,255,0)
delete mesh 1
`==========================================================
`ball
bola(103,5,0,105,0,0)
yrotate object 103,90
color object 103,rgb(100,50,0)
make mesh from object 1,103
`making a Dumy ball ========================================
make object 130,1,0
scale object 130,100.2,100.2,100.2
set object collision off 130
color object 130,rgb(100,50,0)
`ramp 1 ====================================================
cube(106,50,1,10,22,130,0,1)
set object collision off 106

`upper box =================================================
cube(107,20,10,10,37,135,0,1)

`object floor ==============================================
cube(floo_r,450,0,450,40,0,70,0)
color object floo_r,rgb(0,100,0)

`creating the small figures=================================
rem ºººººººººººººººººººººººººººººººººººººººººººººººººººººººº
for i= 1 to 10
cube(i,7,10,2,0,0,0,0)
  offset limb i,0,0,5,-1
  position object i,27,0,50+i*8
next i
rem ºººººººººººººººººººººººººººººººººººººººººººººººººººººººº
`sponge ball=================================================
make object sphere ball,15,20,20
position object ball,27,5,9
texture object ball,4
scale object texture ball,10,10
scale object ball,75,100,100
zrotate object ball ,90

rem planck ==================================================
cube(50,50,0.2,4,50,4,0,2)
zrotate object 50,10
rem spindle
cube(52,2,4,4,50,1.8,0,2)
rem big post
cube(53,7,270,2,19,-5,-6,1)


`much more figures ºººººººººººººººººººººººººººººººººººººººººººººººººººººº
for i= 201 to 220
  make object box i,1.3,10,7        //making the 20 figures
  offset limb i,0,-0.6,5,0          //offeting up a bit
  make mesh from object i,i         //make a mesh in its real position
  delete object i                   //deleting the 20 firures
  make object i,i,0                 //making them again
  delete mesh i                     //deleting the meshes
  yrotate object i,-170+i*4         //rotating figures 4º*i
  position object i,117,0,130
  move object i,85                  //moving figures to_ last position
next

rem ----------
for i= 221 to 240
  make object box i,1.3,10,7
  offset limb i,0,0.6,5,0
  make mesh from object i,i
  delete object i
  make object i,i,0
  delete mesh i
  yrotate object i,250-i*4
  position object i,-62,0,130
  move object i,85
next
rem ºººººººººººººººººººººººººººººººººººººººººººººººººººººººººººººººººººº

rem          LAST BALL    ---------------------------------------
make object sphere 55,5
color object 55,rgb(100,50,0)
position object 55,113,3,214
yrotate object 55,90

rem  hand`s mast      -----------------------------------------
cube(56,1.5,1.5,100,155,2,125,0)
offset limb 56,0,0,0,50
color object 56,rgb(50,50,50)
make object plain 2000,15,15
make mesh from object 30,2000
add limb 56,1,30
offset limb 56,1,-1,4,90
rotate limb 56,1,90,0,90
texture limb 56,1,30
delete object 2000
delete mesh 30
set object 56,1,1,1
set object cull 56,0
xrotate object 56,-2
rem mast base
cube(63,4,10,10,152,2,125,1)
cube(64,4,10,10,158,2,125,1)

rem  brick`s wall ============================================
cube(57,20,100,10,155,50,106,5)
scale object texture 57,2,15

rem  switch  ==================================================
cube(58,10,10,5,155,92,110,0)
cube(59,8,8,6,155,92,110,0)
xrotate object 59,15

rem light bulb  ================================================
bola(60,20,155,113,106,0)
ghost object on 60
fade object 60,50
make object cylinder 61,10
position object 61,155,100,106
color object 61,rgb(10,10,10)

rem we need this ball for shining effect
bola(62,20,30,0,0,0)
set object cull 62,0
ghost object on 62
fade object 62, 75


rem credits end =============================================
make object plain 10000,40,30
xrotate object 10000,-80
texture object 10000,10
lock object on 10000
position object 10000,0,-9,20
hide object 10000

rem camera position at start
position camera -20,100,-70
point camera 0,120,0

rem *********************************************************
rem                  MAIN BUCLE
rem *********************************************************
do

sponge#=0.009   `scrolling speed for sponge texture
rem color backdrop rgb(0,160,100)
go#=0.03        `variable for moving the main ball

rem  positioning  Dumy ball on coordinates of main ball (103)
position object 130,bx#,by#,bz#
rem xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx
rem                  crono to chaing differents camera views
rem xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx
run=run+1
bx#=object position x(103)
by#=object position y(103)
bz#=object position z(103)
sx#=object position x(ball)
sy#=object position y(ball)
sz#=object position z(ball)

  if run>1500 then position camera -30,105,50:point camera bx#,by#,bz#
  if run >3000 then position camera 105,15,47:point camera sx#,sy#,sz#
  if run >7700 then run=7700:position camera 100,100,70:point camera sx#-40,sy#,sz#+30
  if run >4100 then position camera 97,70,48:point camera 27,0,190
  if run >5000 then position camera 70,45,300:point camera 120,0,190
rem **********************************************************************************

`if ball while falling down touch the planck down, it will zrotate -10º
if object collision(103,50) then zrotate object 50,-10::going=1


`Main ball moving
if object collision(103,12) then go#=0
move object 103,go#

rueda#=rueda#+1     rem variable for rotating the Dumy ball as the main one move
for i= 101 to 102
 if object collision(103,i)
    zrotate object 103,object angle z(i)
    zrotate object 130,-rueda#
 endif
next i

`if the ball isn`t on top of plancks,it falls down
if object collision(103,0)=0 then move object down 103,0.5:zrotate object 103,0

if object collision(103,104)
    zrotate object 104,object angle z(104)+0.1      //se rota la lengüeta
else
    if object angle z(104)>0
      zrotate object 104,object angle z(104)-0.1   //vuelve a su sitio la lengüeta
    endif
endif

 if object position y(103)<100 then cae#=0

rem ============================================
if going=1
`if ball position is < 56 then start moving and force texture scrolling of sponge ball
if object position z(ball)<56 then move object ball,0.03:scroll object texture ball,-sponge#,0
if object position z(ball)>50 then inc rota(1),0.5
endif

`bucle for increasing array rota()that will make the little figures push each other
for i=1 to 10
  if rota(i)>45 then inc rota(i+1),0.9
  xrotate object i,rota(i)
  if rota(i)>75 then rota(i)=75

next i

rem =============================================================================
if rota(10)>35 then inc rota2(1),0.7
for i= 1 to 20
  if rota2(i)>35 then inc rota2(i+1),0.7
  rotate limb 200+i,0,0,0,0-rota2(i)
  if rota2(i)>75 then rota2(i)=75     //avoiding angles increase more than 75º
next i
rem ================================

if rota(10)>35 then inc rota3(1),0.7
for i= 1 to 20
  if rota3(i)>35 then inc rota3(i+1),0.7
  rotate limb 220+i,0,0,0,rota3(i)
  if rota3(i)>75 then rota3(i)=75
next i
rem xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx
rem                            ADJUSTING SOUNDS
rem xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx
`figures falling sound
if rota(1)>45
  snd=snd+1
  if snd>60 then snd=0
  if snd=2 then play sound 2
  set sound speed 2,8000+rnd(2000)
endif
if run>5320 then stop sound 2
rem  ball fall down -----------
if object position y(103)<80
  snd2=snd2+1
  if snd2>1000 then snd2=1000
  if snd2<100 then play sound 3
  set sound speed 3,9000
endif
rem -----------
if run=1000
  set sound speed 4,6500
  play sound 4
endif

if object collision(56,59)
  snd5=snd5+1
  if snd5>100 then snd5=100
  if snd5=2 then play sound 5
endif


if run>6500
  snd6=snd6+1
  if snd6>100 then snd6=100
  if snd6=2 then play sound 3
endif

rem credits ================================================================
if run=7700
set ambient light 100
for i= 1 to 1000
if object exist(i)
hide object i
endif
next i
show object 10000
hide object 5000
hide object 5001
show object 10000
position camera 1000,0,-50
point camera 1000,0,0
m#=m#+0.005
position object 10000,0,-10,5+m#
endif

rem ===============================================================================
`last ball movements
if run>5320 and run<6500
position object 130,object position x(55),object position y(55),object position z(55)
move object 55,0.03
zrotate object 130,-rueda#
rem hide object 55
point camera object position x(130),object position y(130),object position z(130)
endif

if run>6500
pertiga#=pertiga#+0.1
if pertiga#>90 then pertiga#=90
xrotate object 56,-pertiga#
endif
if run>6800
position camera 40,100,130
point camera limb position x(56,1),limb position y(56,1),limb position z(56,1)
endif
rem   switching the light on
if object collision(56,59) then xrotate object 59,-15:show light 1:hide light 0:set object light 60,2


cx#=camera position x()
cy#=camera position y()
cz#=camera position z()
position object 62,cx#,cy#,cz#

sync
loop

function cube(obj,sx,sy,sz,x,y,z,img)
make object box obj,sx,sy,sz
position object obj,x,y,z
if img>0 then texture object obj,img
endfunction

function bola(obj,vol,x,y,z,img)
make object sphere obj,vol
position object obj,x,y,z
if img>0 then texture object obj,img
endfunction

hand:
ink rgb(0,0,0),1                 rem black mask
box 0,0,640,480
ink rgb(190,120,100),1
box 0,56,103,155                rem palm

ink rgb(255,180,150),1
for i= 1 to 50
 circle 60+i,48,15
 circle 110+i,48+i/10,15-i/10   rem indice
next i
ink rgb(255,180,150),1
for i= 1 to 50
 circle 60+i,48,13
 circle 110+i,48+i/10,13-i/10
next i

ink rgb(214,144,120),1
for i= 1 to 50
circle 50+i,80,15              rem anular
circle 50+i,113,15             rem medio
circle 50+i,113+33,15          rem meñique
circle 50-i,45+i/3,15
circle 50-i,45+i,15+i/6
circle 50+i/1.3,45+i/10,15-i/10
next

ink rgb(255,180,150),1
for i= 1 to 50
circle 50+i,80,13
circle 50+i,113,13
circle 50+i,113+33,13
circle 50-i,45+i/3,13
circle 50-i,45+i,13+i/6
circle 50+i/1.3,45+i/10,13-i/10
next

ink rgb(0,0,0),0
for i= 1 to 20
line 0,150+i,35,154+i          rem mask
next i
get image 1,0,0,172,162,1
create bitmap 1,172,162
paste image 1,0,0
blur bitmap 1,3
get image 30,0,0,172,162,1
delete bitmap 1
return

rem head
ink rgb(200,170,100),1
for i= 1 to 250
circle 300,i,122
circle 160+i/20,100+i/3,17   //brown edge
circle 440-i/20,100+i/3,17
circle 300,60+i,82
next i

ink rgb(240,220,0),1
for i= 1 to 250
circle 300,i,120
circle 160+i/20,100+i/3,15 //face´s contour
circle 440-i/20,100+i/3,15
circle 300,60+i,80
next i

ink rgb(255,255,255),1
for i= 1 to 30
circle 300,230+i,60      //mouth
next

ink rgb(240,220,0),1:box 240,168,370,268   //mask

ink rgb(200,170,100),1
for i= 1 to 3
circle 300,200+i,15    //nose
circle 278,200+i,7
circle 322,200+i,7
next i

ink rgb(240,220,0),1:box 268,170,331,205   //mask
ink rgb(0,0,0),1

for i= 1 to 30
ellipse 245,150,i,i
ellipse 355,150,i,i   // eyes
next i

ink rgb(200,170,100),1  //eyebrows
for i= 1 to 70
circle 210+i,100+i/5,4
circle 390-i,100+i/5,4
next i

get image 1,0,0,640,480,1
paste image 1,0,70

rem hair
ink rgb(0,0,0),1
for a= 1 to 6
for i= 1 to 90
line 150+a*50,30,102+i+a*50,-2
next i
next a
get image 3,138,0,460,480,1

rem ------------------------------------------------------
rem   eyes
ink rgb(255,255,255),1
box 394,138,587,247
ink rgb(5,5,5),1
for i= 1 to 10
ellipse 440,196,i,i
ellipse 539,195,i,i
next i
get image 1,394,138,587,247,1
rem ---------------------------------------------------
rem floor
cls
ink rgb(70,70,70),1
box 0,300,640,480
get image 2,0,0,640,480,1
rem ----------------------------------------------------
cls        `starting with the robot picture
rem leg
ink rgb(50,50,50),1
for i= 1 to 100
circle 100-i/2,20+i/2,16
circle 50+i/2,70+i,16-i/10
next i
ink rgb(200,200,0),1
for i= 1 to 100
circle 100-i/2,20+i/2,15
circle 50+i/2,70+i,15-i/10
next i
box 78,167,118,177
ink rgb(100,0,0),1
for i= 1 to 15
ellipse 50,70,i,i
next
ink rgb(150,120,40),1
for i= 1 to 15
ellipse 98,21,i,i
next i
ink rgb(50,50,50),1
for i=1 to 5
ellipse 99,21,i,i
next i
rem body ---------------------------------
ink rgb(0,100,0),1
for i= 1 to 15
ellipse 266,25,i,i
next i
ink rgb(150,120,40),1
for i= 1 to 50
ellipse 267,50,i,i/2
next
ink rgb(50,50,50),1
box 178,50,352,83
ink rgb(100,0,0),1
box 228,81,306,120
ink rgb(150,120,40),1
for i=165 to 362
circle i,63,5
next i
for i= 1 to 20
ink rgb(100,100,100),1
line 220,70+i,377,70+i
next
ink rgb(200,200,0),1
set cursor 235,73:print "U K H A   1 2 0 "
rem -------------------------------------
rem rocket
ink rgb(255,255,0),1
for i= 1 to 90
ellipse 20+i,250,i/15,i/15
next
ink rgb(50,50,50),1
box 118,244,161,258
ink rgb(255,0,0),1
for i= 1 to 20
line 177,250,160,262-i
next
rem geting images -----------------------------------
get image 10,33,0,124,178,1         rem left leg
get image 9,30,237,180,263          rem rocket
get image 11,152,0,380,130,1        rem body
get image 12,33,0,124,178,1         rem right leg
rem --------------------------------------------------
sprite 4,195,267,9                  rem rocket
sprite 1,215,295,10                 rem left leg
  offset sprite 1,68,18
sprite 2,100,200,11                 rem body
sprite 3,215,300,12                 rem right leg
  offset sprite 3,68,18
sprite 5,345,0,3:scale sprite 5,90  rem head
sprite 6,390,140,1                  rem eyes
sprite 7,0,0,2
do
rem robot animation -----------------------------------
a=a+1
if a<300 then g#=g#+0.2
if a>300 then g#=g#-0.2
if a>600 then a=0
if g#<0 then g#=0   rem stop

v=30
 rotate sprite 1,-v+g#
 rotate sprite 3,v-g#

rem rocket firing -------------------------------------
if rnd(200)=1 and sprite x(4)=195 then rk=1
if rk=1
rock=rock+15
offset sprite 4,-rock,0
endif
if rock >500 then rock=0:rk=0
if rk=0 then offset sprite 4,rock,0
rem -----------------------------------------------------
rem   eyes  animation
la=la+1
if la<100 then lg#=lg#+0.15
if la>100 then lg#=lg#-0.15
if la>200 then la=0
if lg#<0 then lg#=0   rem stop
offset sprite 6,-lg#,-lg#

rem ---------------------------------------------
sync
loop

Rem Project: War Machine
Rem Created: 08/02/2010 08:42:39
Rem by baxslash

Rem ***** Main Source File *****

autocam off
sync on
sync rate 60
global sw
global sh
sw=screen width()
sh=screen height()
hide mouse

`color backdrop RGB(159,243,255) `DAY
color backdrop RGB(10,0,100) `EVENING/NIGHT

set camera fov 70

global rate
rate = 60

`Make a simple world
make object box 10000, 1000, 2, 1000
color object 10000, RGB(50, 150,0)
position object 10000, 0,-1,0
for c=10001 to 10020
    if RND(1)=1
        X=RND(100)
        if RND(1)=1
            Z=RND(100)
        else
            Z=-RND(100)
        endif
    else
        X=-RND(100)
        if RND(1)=1
            Z=RND(100)
        else
            Z=-RND(100)
        endif
    endif
    make object cube c, 4
    position object c, X,2,Z
    set shadow shading on c,-1,50,shader
next c

`Make Body
`Hips
make object sphere 1, 4, 40,40
position object 1, 0,8, 0
color object 1, RGB(50,50,50)
`Feet
`Left
make object sphere 2, 2
position object 2, 3,1, 0
color object 2, RGB(50,50,50)
`Right
make object sphere 3, 2
position object 3, -3,1, 0
color object 3, RGB(50,50,50)
`Knees
`Left
LKnee=4
make object sphere LKnee, 2
position object LKnee, 3,5, 0
color object LKnee, RGB(100,100,100)
`Right
RKnee=5
make object sphere RKnee, 2
position object RKnee, -3,5, 0
color object RKnee, RGB(100,100,100)
`length of leg limbs
length=6
`Thighs
`Left
LThigh=6
make object box LThigh, 1,1,length
color object LThigh, RGB(100,100,100)
`Right
RThigh=7
make object box RThigh, 1,1,length
color object RThigh, RGB(100,100,100)
`Calves
`Left
LCalf=8
make object box LCalf, .5,.5,length
color object LCalf, RGB(100,100,100)
`Right
RCalf=9
make object box RCalf, .5,.5,length
color object RCalf, RGB(100,100,100)
`Toes
make object box 10, 1,.5,1
color object 10, RGB(50,50,50)
make object box 11, 1,.5,1
color object 11, RGB(50,50,50)
make object box 12, 1,.5,1
color object 12, RGB(50,50,50)
make object box 13, 1,.5,1
color object 13, RGB(50,50,50)
make object box 14, 1,.5,1
color object 14, RGB(50,50,50)
make object box 15, 1,.5,1
color object 15, RGB(50,50,50)
make object box 16, 1,.5,1
color object 16, RGB(50,50,50)
make object box 17, 1,.5,1
color object 17, RGB(50,50,50)
`Body
make object box 18, 6,3,6
color object 18, RGB(100,100,100)
`missile launcher
make object box 19, 1,1,2
color object 19, RGB(50,50,50)
make object box 20, 1,.5,.5
color object 19, RGB(5,5,5)

REM Shadows and light
set ambient light 0
hide light 0
`general light
make light 1
set point light 1, 50,100,-50
set light range 1, 3000
color light 1, RGB(255,255,255)
shader=1
SET GLOBAL SHADOW COLOR 0,0,0, 200
for x=1 to 20
    set shadow shading on x,-1,50,shader
    set shadow position -1,50,100,-50
next x

`Make dummy object
dummy=999
make object sphere dummy, 1
hide object dummy

`set up missile array
type type1
    Target as integer
    Life as integer
    Hit as integer
    TX as float
    TY as float
    TZ as float
endtype
Dim Missile(100) as type1
`set up explosion array
type type2
    Life as integer
endtype
Dim Boom(100) as type2
`set up parts array
type type3
    FX as float
    FY as float
    FZ as float
    RX as float
    RY as float
    RZ as float
endtype
Dim Part(300) as type3

global speed as float
global foot
global camang#
global Obj
camang# = 180
mdx#=100

`############################################################### MAIN LOOP START
do
    camera()
    gosub move
    update_explosions()
    update_parts()
    gosub firepower
    gosub _update_missiles
    target(p)
    sync
loop

`############################################################### MAIN LOOP END

function target(p)
    if p<>0
        ink RGB(255,0,0),0
    else
        ink RGB(0,255,0),0
    endif
    line mousex()-5,mousey(),mousex()+5,mousey()
    line mousex(),mousey()-5,mousex(),mousey()+5
endfunction

move:
    if moving=0 then move$=""
    if keystate(17)=1
        if moving=0
            move$="Backward"
            turn$=""
        endif
        moving=1
    endif
    if keystate(31)=1
        if moving=0
            move$="Forward"
            turn$=""
        endif
        moving=1
    endif
    if keystate(30)=1
        if move$="" then move$="Left"
        if moving=1
            if move$="Forward" then turn$="Left"
            if move$="Backward" then turn$="Right"
        endif
    endif
    if keystate(32)=1
        if move$="" then move$="Right"
        if moving=1
            if move$="Forward" then turn$="Right"
            if move$="Backward" then turn$="Left"
        endif
    endif
    if foot=0 `2 is left 3 is right
        foot=RND(1)+2
    endif
    set cursor 0,0
    if moving=1
        if move$="Forward"
            if prevmove$="Forward"
                if foot=2
                    foot=3
                else
                    foot=2
                endif
            endif
            if foot=2 then pos=1
            if foot=3 then pos=-1
            move object 1, 6
            move object right 1, pos*3
            FX#=object position x(1)
            FY#=object position y(foot)
            FZ#=object position z(1)
            prevmove$=move$
            move$="Committed"
        endif
        if move$="Backward"
            if prevmove$="Backward"
                if foot=2
                    foot=3
                else
                    foot=2
                endif
            endif
            if foot=2 then pos=1
            if foot=3 then pos=-1
            move object 1, -8
            move object right 1, pos*3
            FX#=object position x(1)
            FY#=object position y(foot)
            FZ#=object position z(1)
            prevmove$=move$
            move$="Committed"
        endif
        if move$="Settle"
            if foot=2
                foot=3
            else
                foot=2
            endif
            if foot=2 then pos=1
            if foot=3 then pos=-1
            if prevmove$="Forward" then move object 1, 3
            if prevmove$="Backward" then move object 1, -3
            move object right 1, pos*3
            FX#=object position x(1)
            FY#=object position y(foot)
            FZ#=object position z(1)
            prevmove$=move$
            move$="Committed"
        endif
        if move$="Committed"
            inc movecount
            `turn foot towards new position
            roty#=object angle y(foot)
            point object foot, FX#,FY#,FZ#
            newy#=object angle y(foot)
            if turnfoot#=0
                turnfoot#=(newy#-roty#)/rate
            endif
            rotate object foot, object angle x(foot), object angle y(foot)+turnfoot, object angle z(foot)
            `move foot towards new position
            if movefoot#=0
                dx#=FX#-object position x(foot)
                dy#=FY#-object position y(foot)
                dz#=FZ#-object position z(foot)
                d#=sqrt(dx#^2+dy#^2+dz#^2)
                movefoot#=d#/rate
            endif
            if movecount<=rate
                if turn$="Left" then turn object right 1, .3
                if turn$="Right" then turn object left 1, .3
                move object foot, movefoot#
                if movecount<=40
                    position object foot, object position x(foot), object position y(foot)+movefoot#*1.1, object position z(foot)
                else
                    position object foot, object position x(foot), object position y(foot)-movefoot#*1.1, object position z(foot)
                endif
                if movecount<=30
                    move object up 1, movefoot#/2
                else
                    move object down 1, movefoot#/2
                endif
                if object position y(foot)<1 then position object foot, object position x(foot), 1, object position z(foot)
                if object position y(1)<8 then position object 1, object position x(1), 8, object position z(1)
            else
                move$=""
                moving=0
                if prevmove$="Forward" or prevmove$="Backward"
                    if keystate(17)=0 and keystate(30)=0 and keystate(31)=0 and keystate(32)=0
                        move$="Settle":moving=1
                    endif
                endif
                movecount=0
                turnfoot#=0
                movefoot#=0
            endif
        endif
    endif
    `reposition hip
    PX#=object position x(2)-((object position x(2)-object position x(3))/2)
    PY#=object position y(1)
    PZ#=object position z(2)-((object position z(2)-object position z(3))/2)
    position object 1, PX#,PY#,PZ#
    `position Left knee
    dx#=object position x(1)-object position x(2)
    dy#=object position y(1)-object position y(2)
    dz#=object position z(1)-object position z(2)
    d#=sqrt(dx#^2+dy#^2+dz#^2)
    ang#=asin((d#/2)/length)
    hyp#=length * cos(ang#)
    mX#=(sqrt(dx#^2+dz#^2))/1.5
    mY#=dy#/2
    mZ#=sqrt(hyp#^2-mX#^2)
    position object LKnee, object position x(1),object position y(1)-mY#,object position z(1)
    set object to object orientation LKnee, 1
    move object right LKnee, mX#
    move object LKnee, mZ#
        
    `position Right knee
    dx#=object position x(1)-object position x(3)
    dy#=object position y(1)-object position y(3)
    dz#=object position z(1)-object position z(3)
    d#=sqrt(dx#^2+dy#^2+dz#^2)
    ang#=asin((d#/2)/length)
    hyp#=length * cos(ang#)
    mX#=(sqrt(dx#^2+dz#^2))/1.5
    mY#=dy#/2
    mZ#=sqrt(hyp#^2-mX#^2)
    position object RKnee, object position x(1),object position y(1)-mY#,object position z(1)
    set object to object orientation RKnee, 1
    move object left RKnee, mX#
    move object RKnee, mZ#
    
    `check knee pos
        dx#=object position x(LKnee)-object position x(2)
        dy#=object position y(LKnee)-object position y(2)
        dz#=object position z(LKnee)-object position z(2)
        d#=sqrt(dx#^2+dy#^2+dz#^2)
        if d#<>length
            point object LKnee, object position x(2),object position y(2),object position z(2)
            move object LKnee, d#-length
        endif
        dx#=object position x(LKnee)-object position x(1)
        dy#=object position y(LKnee)-object position y(1)
        dz#=object position z(LKnee)-object position z(1)
        d#=sqrt(dx#^2+dy#^2+dz#^2)
        if d#<>length
            point object LKnee, object position x(1),object position y(1),object position z(1)
            move object LKnee, d#-length
        endif
        
        dx#=object position x(RKnee)-object position x(3)
        dy#=object position y(RKnee)-object position y(3)
        dz#=object position z(RKnee)-object position z(3)
        d#=sqrt(dx#^2+dy#^2+dz#^2)
        if d#<>length
            point object RKnee, object position x(3),object position y(3),object position z(3)
            move object RKnee, d#-length
        endif
        dx#=object position x(RKnee)-object position x(1)
        dy#=object position y(RKnee)-object position y(1)
        dz#=object position z(RKnee)-object position z(1)
        d#=sqrt(dx#^2+dy#^2+dz#^2)
        if d#<>length
            point object RKnee, object position x(1),object position y(1),object position z(1)
            move object RKnee, d#-length
        endif
    
    `position thighs
    position object LThigh, object position x(1),object position y(1),object position z(1)
    point object LThigh, object position x(LKnee),object position y(LKnee),object position z(LKnee)
    move object LThigh, length/2
    position object RThigh, object position x(1),object position y(1),object position z(1)
    point object RThigh, object position x(RKnee),object position y(RKnee),object position z(RKnee)
    move object RThigh, length/2
    `position calves
    position object LCalf, object position x(LKnee),object position y(LKnee),object position z(LKnee)
    point object LCalf, object position x(2),object position y(2),object position z(2)
    move object LCalf, length/2
    position object RCalf, object position x(RKnee),object position y(RKnee),object position z(RKnee)
    point object RCalf, object position x(3),object position y(3),object position z(3)
    move object RCalf, length/2
    `position toes
    for x=10 to 13
        position object x, object position x(2),object position y(2),object position z(2)
        set object to object orientation x, 2
    next x
    for x=14 to 17
        position object x, object position x(3),object position y(3),object position z(3)
        set object to object orientation x, 3
    next x
    turn object right 11, 90
    turn object right 15, 90
    turn object right 12, 180
    turn object right 16, 180
    turn object left 13, 90
    turn object left 17, 90
    if moving=1
        if foot=2
            for x=10 to 13
                if movecount<=30 then pitch object down x, movecount
                if movecount>30 then pitch object down x, 60-movecount
            next x
        endif
        if foot=3
            for x=14 to 17
                if movecount<=30 then pitch object down x, movecount
                if movecount>30 then pitch object down x, 60-movecount
            next x
        endif
    endif
    for x=10 to 17
        move object x, 1.2
        move object down x, .75
    next x
    `position body
    position object 18, object position x(1),object position y(1)+2,object position z(1)
    rotate object 18, 0,camera angle y(),0
    `position launcher
    position object 19, object position x(18),object position y(18),object position z(18)
    set object to object orientation 19, 18
    move object right 19, 4.5
    position object 20, object position x(18),object position y(18),object position z(18)
    set object to object orientation 20, 18
    move object right 20, 3.5
return

function camera()
    sw#=sw
    if mousex()<sw/3
        camang#=camang#-(((sw#/3)-mousex())/100)
    endif
    if mousex()>(sw*2)/3
        camang#=camang#-((((sw*2)/3)-mousex())/100)
    endif
    set camera to follow object position x(1),10,object position z(1), camang#, 20,10, 10,0
    point camera object position x(1),10,object position z(1)
endfunction

firepower:
    p=pick object(mousex(), mousey(), 10001,11000)
    pd#=get pick distance()
    px#=get pick vector x()
    py#=get pick vector y()
    pz#=get pick vector z()
    tx#=px#+camera position x()
    ty#=py#+camera position y()
    tz#=pz#+camera position z()
    if mouseclick()=1
        if p<>0
            if prevmouse=0
                mx#=object position x(19)
                my#=object position y(19)
                mz#=object position z(19)
                gosub _make_missile
            endif
        endif
        prevmouse=1
    else
        prevmouse=0
    endif
return

_make_missile:
    Missile=5051
    while object exist(Missile)=1 or particles exist(Missile)=1
        inc Missile
    endwhile
    make object sphere Missile, .5,6,6
    Missile(Missile-5050).Target=p
    Missile(Missile-5050).Life=300
    Missile(Missile-5050).TX=object position x(p)
    Missile(Missile-5050).TY=object position y(p)
    Missile(Missile-5050).TZ=object position z(p)
    position object Missile, mx#,my#,mz#
    set object to object orientation Missile, 19
    MAKE PARTICLES Missile, 1, 100, 2
    color particles Missile, 10,10,10
    set particle emissions Missile, 100
    set particle speed Missile, 0.03
    set particle gravity Missile, 1
    set particle chaos Missile,1.0
    set particle life Missile,50
return
        
_update_missiles:
    for m=5051 to 5100
        if object exist(m)=1
            Targ=Missile(m-5050).Target
            if object exist(Targ)=1 and Missile(m-5050).Life>0
                Missile(m-5050).Life=Missile(m-5050).Life-1
                `check distance from target
                DX#=object position x(m)-object position x(Targ)
                DY#=object position y(m)-object position y(Targ)
                DZ#=object position z(m)-object position z(Targ)
                DT#=SQRT(DX#^2+DY#^2+DZ#^2)
                `check diff in angle from pointing at target
                dirMX#=object angle x(m)
                dirMY#=object angle y(m)
                dirMZ#=object angle z(m)
                point object m, object position x(Targ),object position y(Targ),object position z(Targ)
                TMX#=object angle x(m)
                TMY#=object angle y(m)
                TMZ#=object angle z(m)
                rotate object m, dirMX#,dirMY#,dirMZ#
                TdffX#=TMX#-dirMX#
                TdffY#=TMY#-dirMY#
                TdffZ#=TMZ#-dirMZ#
                if TdffX#>180 then TdffX#=TdffX#-360
                if TdffY#>180 then TdffY#=TdffY#-360
                if TdffZ#>180 then TdffZ#=TdffZ#-360
                Tdff#=TdffX#+TdffY#+TdffZ#
                `set change in angle
                if DT#>300
                    turnratio#=0.1
                else
                    turnratio#=1-(DT#/300)
                endif
                if Missile(m-5050).Life<250
                    rotate object m, object angle x(m)+TdffX#*turnratio#,object angle y(m)+TdffY#*turnratio#,object angle z(m)+TdffZ#*turnratio#
                else
                    turn object left m, .2-(RND(40)*.01)
                endif
                `move missile
                move object m, 15
                `move particles
                POSITION PARTICLE EMISSIONS m, object position x(m),object position y(m),object position z(m)
                `explode?
                insx#=object position x(m)
                insy#=object position y(m)
                insz#=object position z(m)
                if DT#<8
                    GOSUB _missile_explosion
                else
                    `blow up if hit something else
                    if Missile(m-5050).Hit=1
                        GOSUB _missile_explosion
                    endif
                endif
            else
                `missile blows up if object otherwise destroyed
                GOSUB _missile_explosion
            endif
        endif
        `let trails live a little after missile has blown up
        if particles exist(m)=1 and object exist(m)=0
            if Missile(m-5050).Life>0
                dec Life
            else
                Missile(m-5050).Life=0
                delete particles m
            endif
        endif
    next m
return

function update_explosions()
    for b=0 to 50
        if particles exist(b+5000)=1
            if Boom(b).Life>0
                Life=Boom(b).Life
                set particle emissions b+5000, 0
                dec Life
                Boom(b).Life=Life
            else
                Boom(b).Life=0
                delete particles b+5000
            endif
        endif
    next b
endfunction

_missile_explosion:
    rem Make particles
    Boom=5000
    while particles exist(Boom)=1
        inc Boom
    endwhile
    MAKE PARTICLES Boom, 1, 100, 3
    t=Missile(m-5050).Target
    TX#=Missile(m-5050).TX
    TY#=Missile(m-5050).TY
    TZ#=Missile(m-5050).TZ
    position particles Boom, TX#,TY#,TZ#
    color particles Boom, 255, 128, 0
    set particle emissions Boom, 100
    set particle speed Boom, 0.03
    set particle gravity Boom, 1
    set particle chaos Boom,1.0
    set particle life Boom,100
    Boom(Boom-5000).Life=1000
    delete object m
    set particle emissions m, 0
    `GOSUB _createExplosion
    if object exist(t) then destroy_target(t)
    Missile(m-5050).Target=0
    Missile(m-5050).Life=100
return

function destroy_target(t)
    X#=object position x(t)
    Y#=object position y(t)
    Z#=object position z(t)
    delete object t
    `make replacement parts and add forces
    gosub _GET_OBJ
    make object box Obj, 4,.1,4
    position object Obj, X#,Y#-1.95,Z#
    set shadow shading on Obj,-1,50,shader
    Part(Obj-9000).FX=0
    Part(Obj-9000).FY=.5
    Part(Obj-9000).FZ=0
    Part(Obj-9000).RX=RND(100)/10:Part(Obj-9000).RY=RND(100)/10:Part(Obj-9000).RZ=RND(100)/10
    gosub _GET_OBJ
    make object box Obj, 4,.1,4
    position object Obj, X#,Y#+1.95,Z#
    set shadow shading on Obj,-1,50,shader
    Part(Obj-9000).FX=0
    Part(Obj-9000).FY=1
    Part(Obj-9000).FZ=0
    Part(Obj-9000).RX=RND(100)/10:Part(Obj-9000).RY=RND(100)/10:Part(Obj-9000).RZ=RND(100)/10
    gosub _GET_OBJ
    make object box Obj, .1,4,4
    position object Obj, X#-1.95,Y#,Z#
    set shadow shading on Obj,-1,50,shader
    Part(Obj-9000).FX=-1
    Part(Obj-9000).FY=1
    Part(Obj-9000).FZ=0
    Part(Obj-9000).RX=RND(100)/10:Part(Obj-9000).RY=RND(100)/10:Part(Obj-9000).RZ=RND(100)/10
    gosub _GET_OBJ
    make object box Obj, .1,4,4
    position object Obj, X#+1.95,Y#,Z#
    set shadow shading on Obj,-1,50,shader
    Part(Obj-9000).FX=1
    Part(Obj-9000).FY=1
    Part(Obj-9000).FZ=0
    Part(Obj-9000).RX=RND(100)/10:Part(Obj-9000).RY=RND(100)/10:Part(Obj-9000).RZ=RND(100)/10
    gosub _GET_OBJ
    make object box Obj, 4,4,.1
    position object Obj, X#,Y#,Z#-1.95
    set shadow shading on Obj,-1,50,shader
    Part(Obj-9000).FX=0
    Part(Obj-9000).FY=1
    Part(Obj-9000).FZ=-1
    Part(Obj-9000).RX=RND(100)/10:Part(Obj-9000).RY=RND(100)/10:Part(Obj-9000).RZ=RND(100)/10
    gosub _GET_OBJ
    make object box Obj, 4,4,.1
    position object Obj, X#,Y#,Z#+1.95
    set shadow shading on Obj,-1,50,shader
    Part(Obj-9000).FX=0
    Part(Obj-9000).FY=1
    Part(Obj-9000).FZ=1
    Part(Obj-9000).RX=RND(100)/10:Part(Obj-9000).RY=RND(100)/10:Part(Obj-9000).RZ=RND(100)/10
endfunction

function update_parts()
    for p=9000 to 9299
        if object exist(p)
            FX#=Part(p-9000).FX
            FY#=Part(p-9000).FY
            FZ#=Part(p-9000).FZ
            RX#=Part(p-9000).RX
            RY#=Part(p-9000).RY
            RZ#=Part(p-9000).RZ
            position object p, object position x(p)+FX#,object position y(p)+FY#,object position z(p)+FZ#
            rotate object p, object angle x(p)+RX#,object angle y(p)+RY#,object angle z(p)+RZ#
            FX#=FX#*.9999
            FZ#=FZ#*.9999
            if object position y(p)>-2
                if FY#>0.0
                    if FY#<.1
                        FY#=-FY#
                    else
                        FY#=FY#*.9
                    endif
                else
                    FY#=FY#*1.05
                endif
            else
                delete object p
            endif
            Part(p-9000).FX=FX#
            Part(p-9000).FY=FY#
            Part(p-9000).FZ=FZ#
        endif
    next p
endfunction

_GET_OBJ:
    Obj=9000
    while object exist(Obj)=1
        inc Obj
    endwhile
return

autocam off
sync on
hide mouse
rem robot texture
ink rgb(20,20,20),1
    box 0,0,50,50
ink rgb(60,60,60),1
    box 10,10,40,40
    get image 1,0,0,50,50
    ink rgb(90,90,90),1
    box 0,0,50,50
ink rgb(70,70,70),1
    box 5,5,45,45
get image 2,0,0,50,50
rem =================================================
rem      NUMBER TEXTURE
cls
ink rgb(2,2,2),1
for i= 1 to 120
  ellipse 10+i,30,2,12
next i

ink rgb(255,255,255),1
for i= 1 to 115
  ellipse 12+i,30,2,10
next i

ink rgb(5,5,5),0
set cursor 15,24
print " L Z H A  120 "
get image 10,8,19,132,45,1
rem suelo
make object box 500,2200,1,2200
position object 500,0,-100,0
texture object 500,2:scale object texture 500,30,30
rem -------------------------------------------------
rem      CREATING DIFFERENTS PARTS
make object box 2, 11,50,11
make object box 3, 15,35,15
position object 3,0,0,5
make object box 4,7,40,11
perform csg difference 2,3
perform csg difference 2,4
delete object 3
delete object 4
make object cylinder 3,8
scale object 3,100,550,100
scale limb texture 3,0,1,5
offset limb 3,0,0,-4,0
make mesh from object 10,3
add limb 2,1,10
delete object 3
delete mesh 10
offset limb 2,0,0,-25,5
offset limb 2,1,0,0,5
make mesh from object 1,2                      rem mesh for legs
delete object 2

make object box 2,15,5,25                      rem foot
make object box 3,25,8,55
position object 3,-18,0,15
yrotate object 3,8
perform csg difference 2,3
yrotate object 3,-8
position object 3,18,0,15
perform csg difference 2,3
delete object 3
offset limb 2,0,0,-5,-9
delete object 3
make mesh from object 2,2

make object sphere 3,10
scale object texture 3,20,20
make mesh from object 10,3                      rem mesh for leg`s balls
delete object 3
delete object 2
rem --------------------------------------------
make object 2,2,1  :scale object texture 2,2,2  rem right leg
make object 3,2,1  :scale object texture 3,2,2  rem left leg
make object sphere 4,15                         rem right leg ball
make object sphere 5,15                         rem left leg ball
color object 4,rgb(70,40,0)
color object 5,rgb(70,40,0)
rem -------------------------------------------------------------
rem   guns
for i= 1 to 12
   make object box 100+i,1,1,35
   zrotate object 100+i,i*30
   offset limb 100+i,0,2.3,0,0
   make mesh from object 100+i,100+i
   delete object 100+i
next i

make object 21,101,1
for i= 2 to 12
  add limb 21,i-1,100+i
  delete mesh 100+i
next i

scale object 21,200,200,200
scale object texture 21,2,1
make mesh from object 30,21
delete object 21

rem ------------------------------------------------------------
make object box 1,40,14,14
rem right leg
add limb 1,1,1 :link limb 1,0,1:offset limb 1,1,-14,0,-5
add limb 1,2,1:link limb 1,1,2:offset limb 1,2,0,-50,0
add limb 1,3,10:link limb 1,2,3:offset limb 1,3,0,-50,5

rem left leg
add limb 1,4,1:link limb 1,0,4:offset limb 1,4,14,0,-5
add limb 1,5,1:link limb 1,4,5:offset limb 1,5,0,-50,0
add limb 1,6,10:link limb 1,5,6:offset limb 1,6,0,-50,5


rem  body  --------------------------------------------
make object sphere 10,100
lock vertexdata for limb 10,0
    for i = 1 to 25
        x# = get vertexdata position x(i)
        y# = get vertexdata position y(i)
        z# = get vertexdata position z(i)
        set vertexdata position i,x#,y#+25,z#
    next i
unlock vertexdata
rem set object normals 10
scale object 10,100,50,100
scale limb texture 10,0,5,5
offset limb 10,0,0,0,-20
make mesh from object 10,10
delete object 10
rem   NUMBER --------------------------------------------
make object box 50,30,10,0
offset limb 50,0,0,0,-8
texture object 50,10
set object 50,1,1,1,1
position object 50,0,-10,-30
rem -----------------------------------------------------

add limb 1,7,10: link limb 1,0,7              rem body  (big sphere)
add limb 1,8,30:link limb 1,7,8:offset limb 1,8,-25,-25,-40 rem gun
add limb 1,9,30:link limb 1,7,9:offset limb 1,9,25,-25,-40 rem gun
texture object 1,1
scale object texture 1,2,1
rem -----------------------------------------------------------------
position camera -99,15,-147
point camera 0,0,0
cam#=45
rem  this part of code is not mine ...someone on TGC Forum
Make Memblock 1, 1000
` Make the header for the sound inside the memblock
write memblock dword 1, 0, 1      ` wFormatTag
write memblock dword 1, 4, 1      ` nChannels
write memblock dword 1, 8, 22050  ` nSamplesPerSec
write memblock dword 1, 12, 44100 ` nAvgBytesPerSec
write memblock dword 1, 16, 2     ` nBlockAlign
write memblock dword 1, 20, 16    ` wBitsPerSample
write memblock dword 1, 24, 0     ` cbSize

` write crazy random data to memblock
for i = 28 to 999
   Write Memblock Byte  1, i, rnd( 255 )
next

` Convert the memblock to a sound
Make Sound From Memblock 1, 1
make sound from memblock 2,1
rem --------------------------------------------------------------------------
do
position object 50,object position x(1),-10,object position z(1)
rotate object 50,limb angle x(1,0)*1.5,limb angle y(1,0)*1.5,limb angle z(1,0)*1.1
rem scroll floor texture
scll#=0.0031
scroll object texture 500,0,scll#

rem -----------------------------------------------------------------------------
rem positioning copper ball on knees and feet
position object 2,limb position x(1,3),limb position y(1,3),limb position z(1,3)
position object 3,limb position x(1,6),limb position y(1,6),limb position z(1,6)
position object 4,limb position x(1,2),limb position y(1,2),limb position z(1,2)+5
position object 5,limb position x(1,5),limb position y(1,5),limb position z(1,5)+5
`---------------------------------------------------------
`Animation
al#=al#+1  rem timer to make body go up and down (limb 7)
if al#>300 then al#=0
if al#<150 then ss#=ss#+0.6
if al#>150 then ss#=ss#-0.6
offset limb 1,7,0,20+ss#/30,0
`---------------------------------------------------------

m=m+1    rem timer for animation

if m<300 then g#=g#+0.6
if m>300 then g#=g#-0.6
if m>599 then m=0
if g#<0 then g#=0           rem stop
rem  sound effects ++++++++++++++++++++++++++++++++
set sound speed 1,1000
if m<5 then play sound 1
if m>300 and m<305 then play sound 1
loop sound 2
set sound speed 2,10000+ss#*20:set sound volume 2,90
rem ++++++++++++++++++++++++++++++++++++++++++++++++
if m>150 and m<300 then g2#=g2#+0.5
if m<150 then g2#=g2#-0.5
if m=0 then g2#=0:g3#=0

if m>450 then g3#=g3#+0.5
if m>300 and m<450 then g3#=g3#-0.5

rem ---------------------------------------------------------
vl#=-15+g#/6
vl2#=g2#/2
vl3#=g3#/2
rotate limb 1,1,-30+vl#*1.5,10,0+2-vl#/2.5-5-vl#/10   rem right leg
rotate limb 1,4,-30-vl#*1.5,-10,-2-vl#/2.5+5-vl#/10   rem left leg
rotate limb 1,2,50-vl2#*2,0,10                        rem right knee
rotate limb 1,5,50-vl3#*2,0,-10                       rem left knee

rotate limb 1,0,0,0,(g#-100)/10                       rem waist limb 0
rotate limb 1,7,ss#/10,-5+g#/10,0                     rem twist (limb 7)
rem ajusting feet rotation with feet height
u#=object position y(2)
u2#=object position y(3)
xrotate object 2,-u#*0.6-55                           rem right foot
xrotate object 3,-u2#*0.6-55                          rem left foot

rem camera controls
control camera using arrowkeys 0,0.4,0.4
a#=wrapvalue(a#+mousemovex()/2)
cam#=wrapvalue(cam#+mousemovey()/2)
rotate camera cam#,a#,0

sync
loop

sync on
sync rate 30

type spark
    x# as float
    y# as float
    speed# as float
    angle# as float
    life as integer
    fadeout as integer
    fadein as integer
    fadestart as integer
    spritenum as integer
    spin# as float
    alpha as integer
    delay as integer
endtype

type aidata
    destx# as float
    desty# as float
    threat as integer
    moving as integer
    firing as integer
    avoiding as integer
    entering as integer
    determination# as float
    range as integer
endtype


type mech
    x# as float
    y# as float
    rot# as float
    toprot# as float
    legmove# as float
    lastmove as integer
    speed# as float
    move as integer
    hpbar as integer
    body as integer
    lleg as integer
    rleg as integer
    lfoot as integer
    rfoot as integer
    rweapon as integer
    lweapon as integer
    lfiring as float
    rfiring as float
    lrecoil# as float
    rrecoil# as float
    lrecoilvel# as float
    rrecoilvel# as float
    bodysway as integer
    firing as integer
    hp as integer
    maxhp
    ai as aidata
    corpsetimer as integer
endtype

type bullet
    x# as float
    y# as float
    accel# as float
    vel# as float
    spritenum as integer
    rot# as float
    live as integer
    distance as integer
    damage as integer
    owner as integer
    smoke# as float
endtype


dim mechs(0) as mech

dim bullets(0) as bullet

dim sparks(0) as spark

//images
//1:blank
//2:body
//3:lfoot
//4:rfoot





ink rgb(255,255,255),0
box 0,0,10,10
get image 1,0,0,1,1,1
blurback=findsprite()
sprite blurback,0,0,1
set sprite alpha blurback,100
set sprite diffuse blurback,0,0,0
set sprite blurback,0,1
size sprite blurback,screen width(),screen height()


cls
//ink rgb(96,128,159),0
    //box 90,90,110,110
    //box 85,95,115,105
    
ink rgb(66,88,111),0
       vlsetorigin(0,100,100)
       
       vlstartpoly(-10,10)
       vlpolyline(10,10)
       vlpolyline(15,5)
       vlpolyline(15,-5)
       vlpolyline(10,-10)
       vlpolyline(-10,-10)
       vlpolyline(-15,-5)
       vlpolyline(-15,5)
       vlendpoly()
       floodfill(100,100,rgb(96,128,159))
       
get image 2,85,90,116,111,0
sbody=findsprite()
sprite sbody,0,0,2
offset sprite sbody,15,10
hide sprite sbody
  
cls  
ink rgb(255,0,0),0
box 0,0,200,200
ink rgb(66,88,111),0   
       vlstartpoly(14,10)
       vlpolyline(19,10)
       vlpolyline(19,-10)
       vlpolyline(14,-10)
       vlendpoly()
       floodfill(116,100,rgb(96,128,159))
       
get image 3,114,90,120,111,0
slfoot=findsprite()
sprite slfoot,0,0,3
offset sprite slfoot,-14,10
hide sprite slfoot
       
cls
ink rgb(255,0,0),0
box 0,0,200,200
ink rgb(66,88,111),0
       vlstartpoly(-14,10)
       vlpolyline(-19,10)
       vlpolyline(-19,-10)
       vlpolyline(-14,-10)
       vlendpoly()
       floodfill(84,100,rgb(96,128,159))
       
get image 4,81,90,87,111,0       
srfoot=findsprite()
sprite srfoot,0,0,4
offset sprite srfoot,19,10
hide sprite srfoot       

cls
ink rgb(255,0,0),0
box 0,0,200,200
ink rgb(66,88,111),0
       vlstartpoly(-11,12)
       vlpolyline(-8,12)
       vlpolyline(-8,0)
       vlpolyline(-11,0)
       vlendpoly()
       floodfill(90,105,rgb(96,128,159))
       
get image 5,89,100,93,113,0       
slweapon=findsprite()
sprite slweapon,0,0,5
offset sprite slweapon,11,0
hide sprite slweapon  

cls
ink rgb(255,0,0),0
box 0,0,200,200
ink rgb(66,88,111),0
       vlstartpoly(11,12)
       vlpolyline(8,12)
       vlpolyline(8,0)
       vlpolyline(11,0)
       vlendpoly()
       floodfill(110,105,rgb(96,128,159))
       
get image 6,108,100,112,113,0       
srweapon=findsprite()
sprite srweapon,0,0,6
offset sprite srweapon,-8,0
hide sprite srweapon  

cls
ink rgb(255,0,0),0
box 0,0,200,200
ink rgb(230,60,0),0
       line 1,1,1,15
       line 2,1,2,15
       
get image 15,1,1,2,15,0       
sbullet=findsprite()
sprite sbullet,0,0,15
offset sprite sbullet,0,0
hide sprite sbullet 

cls
ink rgb(255,0,0),0
box 0,0,200,200
ink rgb(130,130,130),0
       line 1,1,1,10
       line 2,1,2,11
       line 3,1,3,10
ink rgb(200,0,0),0
       line 1,2,3,2
       line 1,4,3,4
       
get image 16,1,1,3,11,0       
srocket=findsprite()
sprite srocket,0,0,16
offset sprite srocket,1,0
hide sprite srocket

cls
ink rgb(255,0,0),0
box 0,0,200,200
ink rgb(50,200,50),0
       box 1,1,5,5
       
get image 20,1,1,5,5,0       
shbar=findsprite()
sprite shbar,0,0,20
offset sprite shbar,0,0
hide sprite shbar

cls
ink rgb(255,0,0),0
box 0,0,200,200
ink rgb(255,128,0),0
       box 1,1,2,3
       
get image 21,1,1,2,3,0       
sspark=findsprite()
sprite sspark,0,0,21
offset sprite sspark,0,0
hide sprite sspark


cls
ink rgb(0,0,0),0
box 0,0,200,200
ink rgb(80,80,80),0
       fillcircle(10,10,9)
       
get image 22,1,1,20,20,0    
ssmallsmoke=findsprite()
sprite ssmallsmoke,0,0,22
offset sprite ssmallsmoke,9,9
hide sprite ssmallsmoke

cls
ink rgb(0,0,0),0
box 0,0,200,200
ink rgb(66,88,111),0
       vlsetorigin(0,0,0)
       vlstartpoly(1,4)
       vlpolyline(4,1)
       vlpolyline(6,5)
       vlpolyline(4,5)
       vlpolyline(3,6)
       vlendpoly()
       floodfill(3,4,rgb(96,128,159))
       
get image 23,1,1,7,7,0       
ssmalldebri=findsprite()
sprite ssmalldebri,0,0,23
offset sprite ssmalldebri,3,3
hide sprite ssmalldebri

cls
ink rgb(0,0,0),0
box 0,0,200,200
ink rgb(255,90,0),0
       fillcircle(10,10,9)
       
get image 24,1,1,20,20,0       
sfireball=findsprite()
sprite sfireball,0,0,24
offset sprite sfireball,9,9
hide sprite sfireball

cls
ink rgb(0,0,0),0
box 0,0,200,200
ink rgb(255,255,255),0
       fillcircle(10,10,9)
       
get image 25,1,1,20,20,0       
sbrightfireball=findsprite()
sprite sbrightfireball,0,0,25
offset sprite sbrightfireball,9,9
hide sprite sbrightfireball

cls
ink rgb(0,0,0),0
box 0,0,200,200
ink rgb(255,255,255),0
       //line 2,1,1,400
       line 2,1,2,400
       //line 2,1,3,400
       
get image 26,1,1,4,401,0       
slight=findsprite()
sprite slight,0,0,26
offset sprite slight,1,0
hide sprite slight












addmech(screen width()/2,screen height()/2,0,0,100)


lastmove=0
killed=0
nextmech=150
gameend=0


ink rgb(255,255,255),0
box 0,0,screen width(),screen height()

do

    nextmech=nextmech-1
    if nextmech<0
        nextmech=300-(killed*10)
        if nextmech<90 then nextmech=90
        rx=rnd(screen width()-60)+30
        ry=rnd(screen height()-60)+30
        select rnd(3)
            case 0: addmech(rx,-50,rx,10,50)
            endcase
            case 1: addmech(rx,screen height()+50,rx,screen height()-10,50)
            endcase
            case 2: addmech(-50,ry,10,ry,50)
            endcase
            case 3: addmech(screen width()+50,ry,screen width()-10,ry,50)
            endcase
        endselect
    endif

    
    
        mechs(0).move=0
     
    if gameend=0    
        if downkey()
            mechs(0).move=1 
            mechs(0).lastmove=1 
        endif
        if upkey()
            mechs(0).move=1 
            mechs(0).lastmove=2 
        endif
        if rightkey()
            mechs(0).move=1 
            mechs(0).lastmove=3 
        endif
        if leftkey()
            mechs(0).move=1 
            mechs(0).lastmove=4 
        endif
    
    
    

        
        lmb=0
        mmb=0
        rmb=0
      
        mv=mouseclick()
        if int(mv/8)=1
            mv=mv-8
        endif
        if int(mv/4)=1
            mv=mv-4
            mmb=1
        endif
        if int(mv/2)=1
            mv=mv-2
            rmb=1
        endif
        if mv=1
            lmb=1
        endif
        
        
        if lmb=1
            mechs(0).firing=1    
        else
            if rmb=1
                mechs(0).firing=2    
            else
                mechs(0).firing=0
            endif
        endif
    endif
    
    
    targetangle#=wrapvalue(atanfull(-(mousex()-mechs(0).x#),(mousey()-mechs(0).y#)))
    mechs(0).toprot#=wrapvalue(mechs(0).toprot#)
    if (wrap180#(mechs(0).rot#+mechs(0).toprot#-targetangle#)>-3)
        if (wrap180#(mechs(0).rot#+mechs(0).toprot#-targetangle#)<3) 
            //mechs(0).firing=1
        else
            mechs(0).toprot#=mechs(0).toprot#-3
            
        endif
    else
        mechs(0).toprot#=mechs(0).toprot#+3
        
    endif
    
    
    
    for c=1 to array count(mechs(0))-1
        
        mechs(c).move=0
        mechs(c).ai.range=400
        
        if mechs(mechs(c).ai.threat).firing
            angle#=wrapvalue(atanfull(-(mechs(mechs(c).ai.threat).x#-mechs(c).x#),(mechs(mechs(c).ai.threat).y#-mechs(c).y#)))
            if (wrap180#(angle#-180-mechs(mechs(c).ai.threat).rot#-mechs(mechs(c).ai.threat).toprot#)<7) AND (wrap180#(angle#-180-mechs(mechs(c).ai.threat).rot#-mechs(mechs(c).ai.threat).toprot#)>-7)
                if (wrap180#(angle#-180-mechs(mechs(c).ai.threat).rot#-mechs(mechs(c).ai.threat).toprot#))>0
                    angle#=angle#-90
                else
                    angle#=angle#+90
                endif 
                    proposedx#=mechs(c).x#-sin(angle#)*40.0
                    proposedy#=mechs(c).y#+cos(angle#)*40.0
                if (mechs(c).ai.determination#<=0) AND (mechs(c).ai.entering=0)
                    mechs(c).ai.destx#=proposedx#
                    mechs(c).ai.desty#=proposedy#
                    mechs(c).ai.moving=1
                    mechs(c).ai.avoiding=1
                    mechs(c).ai.determination#=170
                else
                    mechs(c).ai.determination#=mechs(c).ai.determination#-(0.05*sqrt(((mechs(c).ai.destx#-proposedx#)*(mechs(c).ai.destx#-proposedx#))+((mechs(c).ai.desty#-proposedy#)*(mechs(c).ai.desty#-proposedy#))))    
                endif
            endif
        endif
        if mechs(c).ai.moving=1
            if mechs(c).ai.destx#>screen width()-10 then mechs(c).ai.destx#=screen width()-10
            if mechs(c).ai.destx#<10 then mechs(c).ai.destx#=10
            if mechs(c).ai.desty#>screen height()-10 then mechs(c).ai.desty#=screen height()-10
            if mechs(c).ai.desty#<10 then mechs(c).ai.desty#=10
            
            
            if (((mechs(c).ai.destx#-mechs(c).x#)*(mechs(c).ai.destx#-mechs(c).x#))+((mechs(c).ai.desty#-mechs(c).y#)*(mechs(c).ai.desty#-mechs(c).y#)))>25
                targetangle#=wrapvalue(atanfull(-(mechs(c).ai.destx#-mechs(c).x#),(mechs(c).ai.desty#-mechs(c).y#)))   
                if (wrap180#(mechs(c).rot#-targetangle#)>-3)
                    if (wrap180#(mechs(c).rot#-targetangle#)<3) 
                        mechs(c).move=1
                        mechs(c).lastmove=2
                    else
                        mechs(c).move=1
                        mechs(c).lastmove=4
                    endif
                else
                    mechs(c).move=1
                    mechs(c).lastmove=3
                endif
            else
                mechs(c).ai.determination#=0
                mechs(c).ai.moving=0
            endif
        else
            mechs(c).ai.avoiding=0
            mechs(c).ai.entering=0
        endif
        mechs(c).ai.threat=0
        inrange=0
        threatdist#=dist#(mechs(c).x#-mechs(mechs(c).ai.threat).x#,mechs(c).y#-mechs(mechs(c).ai.threat).y#)
        if (threatdist#< mechs(c).ai.range)
            inrange=1
        else
            if (mechs(c).ai.avoiding=0) AND (mechs(c).ai.entering=0)
                mechs(c).ai.destx#=mechs(mechs(c).ai.threat).x#-(((mechs(mechs(c).ai.threat).x#-mechs(c).x#)*(mechs(c).ai.range*0.9))/threatdist#)
                mechs(c).ai.desty#=mechs(mechs(c).ai.threat).y#-(((mechs(mechs(c).ai.threat).y#-mechs(c).y#)*(mechs(c).ai.range*0.9))/threatdist#)
                mechs(c).ai.moving=1
                //mechs(c).ai.determination#=170
            endif
        endif
        
        
        targetangle#=wrapvalue(atanfull(-(mechs(mechs(c).ai.threat).x#-mechs(c).x#),(mechs(mechs(c).ai.threat).y#-mechs(c).y#)))
        if mechs(c).hp<=0 then targetangle#=0
        mechs(c).toprot#=wrapvalue(mechs(c).toprot#)
        mechs(c).firing=0
        if (wrap180#(mechs(c).rot#+mechs(c).toprot#-targetangle#)>-3)
            if (wrap180#(mechs(c).rot#+mechs(c).toprot#-targetangle#)<3) 
                if mechs(c).ai.entering=0 then mechs(c).firing=1
            else
                mechs(c).toprot#=mechs(c).toprot#-3
                
            endif
        else
            mechs(c).toprot#=mechs(c).toprot#+3 
        endif
        if (wrap180#(mechs(c).rot#+mechs(c).toprot#-targetangle#)>-3)
            if (wrap180#(mechs(c).rot#+mechs(c).toprot#-targetangle#)<3) 
                if mechs(c).ai.entering=0 then mechs(c).firing=1
            endif                
        endif
        if mechs(c).hp<=0 then mechs(c).firing=0
    next c
    
    
    
    for c=0 to array count(mechs(0))-1
        if (mechs(c).corpsetimer>0)
            if (mechs(c).corpsetimer>90)
                    
                    if c=0
                        gameend=1    
                    else
                        killed=killed+1
                    endif
                    
                    delete sprite mechs(c).body 
                    delete sprite mechs(c).lfoot
                    delete sprite mechs(c).rfoot
                    delete sprite mechs(c).lleg
                    delete sprite mechs(c).rleg
                    delete sprite mechs(c).lweapon
                    delete sprite mechs(c).rweapon
                    array delete element mechs(0),c
                    set sprite diffuse blurback,0,0,0
                    c=c-1
                    
            else
                if backset>-1
                    mechs(c).corpsetimer=mechs(c).corpsetimer+1
                    set sprite diffuse blurback,sprite alpha(backset)/3,sprite alpha(backset)/3,sprite alpha(backset)/3
                endif
            endif
        else
            if (mechs(c).move=1) OR ( NOT (((abs(mechs(c).legmove#)-4)<1.1) AND ((abs(mechs(c).legmove#)-5)>-1.1)))
                select mechs(c).lastmove
                    case 1 
                        mechs(c).legmove#=mechs(c).legmove#+mechs(c).speed#
                        mechs(c).x#=mechs(c).x#+(mechs(c).speed#*sin(mechs(c).rot#))
                        mechs(c).y#=mechs(c).y#-(mechs(c).speed#*cos(mechs(c).rot#))
                    endcase
                    case 2
                        mechs(c).legmove#=mechs(c).legmove#-mechs(c).speed#
                        mechs(c).x#=mechs(c).x#-(mechs(c).speed#*sin(mechs(c).rot#))
                        mechs(c).y#=mechs(c).y#+(mechs(c).speed#*cos(mechs(c).rot#))
                    endcase
                    case 3
                        mechs(c).legmove#=mechs(c).legmove#+mechs(c).speed#
                        mechs(c).rot#=mechs(c).rot#+3
                    endcase
                    case 4
                        mechs(c).legmove#=mechs(c).legmove#+mechs(c).speed#
                        mechs(c).rot#=mechs(c).rot#-3
                    endcase
                endselect
            else
                if mechs(c).legmove#>0 then mechs(c).legmove#=5 else mechs(c).legmove#=-5
            endif
            
            
            
            if (mechs(c).firing=1)
                if mechs(c).lfiring=0
                    mechs(c).lfiring=8
                    addbullet(c,mechs(c).x#+getx#(mechs(c).bodysway-10,10,mechs(c).rot#+mechs(c).toprot#),mechs(c).y#+gety#(mechs(c).bodysway-10,10,mechs(c).rot#+mechs(c).toprot#),mechs(c).rot#+mechs(c).toprot#+frnd#(5.0)-2.5-1,sbullet,1500,1,13,0,0)
                    mechs(c).lrecoilvel#=-3
                endif
                if (mechs(c).rfiring=0) AND (mechs(c).lfiring=4)
                    mechs(c).rfiring=8
                    addbullet(c,mechs(c).x#+getx#(mechs(c).bodysway+10,10,mechs(c).rot#+mechs(c).toprot#),mechs(c).y#+gety#(mechs(c).bodysway+10,10,mechs(c).rot#+mechs(c).toprot#),mechs(c).rot#+mechs(c).toprot#+frnd#(5.0)-2.5+1,sbullet,1500,1,13,0,0)
                    mechs(c).rrecoilvel#=-3
                endif
            endif
            
            if (mechs(c).firing=2)
                if mechs(c).lfiring=0
                    mechs(c).lfiring=30
                    addbullet(c,mechs(c).x#+getx#(mechs(c).bodysway-10,10,mechs(c).rot#+mechs(c).toprot#),mechs(c).y#+gety#(mechs(c).bodysway-10,10,mechs(c).rot#+mechs(c).toprot#),mechs(c).rot#+mechs(c).toprot#-1,srocket,1500,20,1,0.5,0.1)
                    mechs(c).lrecoilvel#=-3
                endif
                if (mechs(c).rfiring=0) AND (mechs(c).lfiring=15)
                    mechs(c).rfiring=30
                    addbullet(c,mechs(c).x#+getx#(mechs(c).bodysway+10,10,mechs(c).rot#+mechs(c).toprot#),mechs(c).y#+gety#(mechs(c).bodysway+10,10,mechs(c).rot#+mechs(c).toprot#),mechs(c).rot#+mechs(c).toprot#+1,srocket,1500,20,1,0.5,0.1)
                    mechs(c).rrecoilvel#=-3
                endif
            endif
            
            
            while (mechs(c).legmove#>10)
                mechs(c).legmove#=mechs(c).legmove#-20
            endwhile
            while (mechs(c).legmove#<-10)
                mechs(c).legmove#=mechs(c).legmove#+20
            endwhile
            
            mechs(c).lrecoil#=mechs(c).lrecoil#+mechs(c).lrecoilvel#
            if (mechs(c).lrecoil#<-5)
                mechs(c).lrecoil#=-5
                mechs(c).lrecoilvel#=0.5
            endif
            if (mechs(c).lrecoil#>0) then mechs(c).lrecoil#=0
            if mechs(c).lfiring>0 then mechs(c).lfiring=mechs(c).lfiring-1
            
            mechs(c).rrecoil#=mechs(c).rrecoil#+mechs(c).rrecoilvel#
            if (mechs(c).rrecoil#<-5)
                mechs(c).rrecoil#=-5
                mechs(c).rrecoilvel#=0.5
            endif
            if (mechs(c).rrecoil#>0) then mechs(c).rrecoil#=0
            if mechs(c).rfiring>0 then mechs(c).rfiring=mechs(c).rfiring-1
            
            if mechs(c).lastmove=2
                mechs(c).bodysway=(abs(mechs(c).legmove#)-5)*0.5
            else
                mechs(c).bodysway=(-abs(mechs(c).legmove#)+5)*0.5
            endif
            
            copysprite(sbody,mechs(c).body,mechs(c).x#,mechs(c).y#,mechs(c).rot#+mechs(c).toprot#,cos(mechs(c).toprot#)*mechs(c).bodysway,-sin(mechs(c).toprot#)*mechs(c).bodysway)
            
            copysprite(slweapon,mechs(c).lweapon,mechs(c).x#,mechs(c).y#,mechs(c).rot#+mechs(c).toprot#,cos(mechs(c).toprot#)*mechs(c).bodysway,-sin(mechs(c).toprot#)*mechs(c).bodysway-mechs(c).lrecoil#)
            copysprite(srweapon,mechs(c).rweapon,mechs(c).x#,mechs(c).y#,mechs(c).rot#+mechs(c).toprot#,cos(mechs(c).toprot#)*mechs(c).bodysway,-sin(mechs(c).toprot#)*mechs(c).bodysway-mechs(c).rrecoil#)
            copysprite(slfoot,mechs(c).lfoot,mechs(c).x#,mechs(c).y#,mechs(c).rot#,0,0-abs(mechs(c).legmove#)+5)
            copysprite(srfoot,mechs(c).rfoot,mechs(c).x#,mechs(c).y#,mechs(c).rot#,0,abs(mechs(c).legmove#)-5)
            if (mechs(c).hp<mechs(c).maxhp) 
                if (mechs(c).hp<0) then mechs(c).hp=0
                size sprite mechs(c).hpbar,mechs(c).hp,5
                offset sprite mechs(c).hpbar,mechs(c).hp/2,0
                sprite mechs(c).hpbar,mechs(c).x#,mechs(c).y#-25,20
                if (mechs(c).hp<=0) 
                    
                    
                    
                    
                    
                        delay=0
                    for e=1 to 5
                
                        x#=mechs(c).x#+rnd(30)-15
                        y#=mechs(c).y#+rnd(30)-15
                        
                        num=10+rnd(10)
                        for d=1 to num
                            addspark(x#,y#,0.5+frnd#(2),frnd#(360),10+rnd(10),delay,10,10,10,sspark,100,0,200)
                        next d   
                        num=5+rnd(5)
                        for d=1 to num
                            addspark(x#,y#,0.2+frnd#(1),frnd#(360),30+rnd(5),delay,35,35,35,ssmallsmoke,40+frnd#(50),frnd#(10)-5.0,130)
                        next d  
                        num=6+rnd(4)
                        for d=1 to num
                            addspark(x#,y#,0.2+frnd#(1),frnd#(360),25,delay,30,30,30,sfireball,50+frnd#(50),frnd#(10)-5.0,130)
                        next d  
                        num=3+rnd(3)
                        for d=1 to num
                            addspark(x#,y#,0.2+frnd#(0.5),frnd#(360),20,delay,20,20,20,sbrightfireball,80+frnd#(50),frnd#(10)-5.0,100)
                        next d 
                        delay=rnd(70)
                    next e
                    
                    
                    num=4+rnd(3)
                    for d=1 to num
                        start=rnd(50)
                        addspark(mechs(c).x#,mechs(c).y#,0,frnd#(360),95,0, 35+start,15+start,rnd(10),slight,400,frnd#(6)-3,100)
                    next d  
                    
                    num=15+rnd(5)
                    for d=1 to num
                        backset=addspark(mechs(c).x#+frnd#(30)-15,mechs(c).y#+frnd#(30)-15,frnd#(0.2),frnd#(360),100,0,80,30,5+rnd(5),sbrightfireball,100+frnd#(80),frnd#(2)-1,70)
                    next d  
                    
                    
                    num=20+rnd(10)
                    for d=1 to num
                        addspark(mechs(c).x#,mechs(c).y#,1+frnd#(3),frnd#(360),15+rnd(5),90,30,30,30,sspark,100,0,255)
                    next d  
                    num=13+rnd(4)
                    for d=1 to num
                        addspark(mechs(c).x#+frnd#(10)-5,mechs(c).y#+frnd#(10)-5,0.6+frnd#(1.2),frnd#(360),30+rnd(5),90,20,20,20,ssmalldebri,100+frnd#(100),frnd#(40)-20.0,255)
                    next d   
                    num=15+rnd(5)
                    for d=1 to num
                        addspark(mechs(c).x#+frnd#(10)-5,mechs(c).y#+frnd#(10)-5,0.7+frnd#(1),frnd#(360),45+rnd(5),90,80,80,80,ssmallsmoke,40+frnd#(100),frnd#(10)-5.0,255)
                    next d  
                    num=6+rnd(4)
                    for d=1 to num
                        addspark(mechs(c).x#,mechs(c).y#,1+frnd#(1),frnd#(360),25,90,30,30,30,sfireball,100+frnd#(100),frnd#(10)-5.0,150)
                    next d  
                    num=4+rnd(4)
                    for d=1 to num
                        addspark(mechs(c).x#,mechs(c).y#,1+frnd#(0.7),frnd#(360),15,90,15,15,15,sbrightfireball,100+frnd#(100),frnd#(10)-5.0,200)
                    next d  
                    
                    //num=15+rnd(5)
                    //for d=1 to num
                    //    addspark(mechs(c).x#+frnd#(10)-5,mechs(c).y#+frnd#(10)-5,1.5+frnd#(0.2),frnd#(360),45+rnd(10),90,80,80,80,ssmallsmoke,40+frnd#(70),frnd#(10)-5.0,255)
                    //next d 
                    
                    
                    mechs(c).corpsetimer=1
                    
                endif
            endif
        endif
    next c
    
    for c=0 to array count(bullets(0))-1
        
        bullets(c).x#=bullets(c).x#-(bullets(c).vel#*sin(bullets(c).rot#))
        bullets(c).y#=bullets(c).y#+(bullets(c).vel#*cos(bullets(c).rot#))
        bullets(c).distance=bullets(c).distance-bullets(c).vel#
        bullets(c).vel#=bullets(c).vel#+bullets(c).accel#
        sprite bullets(c).spritenum,bullets(c).x#,bullets(c).y#,sprite image(bullets(c).spritenum)
        if (bullets(c).smoke#>0)
            for b=0 to int(bullets(c).smoke#*bullets(c).vel#)+1
                distance#=frnd#(bullets(c).vel#)
                addspark(bullets(c).x#+(distance#*sin(bullets(c).rot#)),bullets(c).y#-(distance#*cos(bullets(c).rot#)),frnd#(0.4),frnd#(360),15+rnd(5),0,20,15,5,ssmallsmoke,40+frnd#(50),frnd#(10)-5.0,100)
                
            next b
        endif
        if (bullets(c).distance<=0)
            delete sprite bullets(c).spritenum
            array delete element bullets(0),c
            c=c-1 
        else
            if bullets(c).live>0
                bullets(c).live=bullets(c).live-1
            else
                for b=0 to array count(mechs(0))-1
                    if (sprite hit(bullets(c).spritenum,mechs(b).body)) AND (b<>bullets(c).owner)
                        mechs(b).hp=mechs(b).hp-bullets(c).damage
                        num=5+rnd(4)
                        for d=1 to num
                            addspark(bullets(c).x#,bullets(c).y#,1+frnd#(2),bullets(c).rot#+180+frnd#(140)-70,10,0,20,20,20,sspark,100,0,255)
                        next d
                        num=2+rnd(2)
                        for d=1 to num
                            addspark(bullets(c).x#,bullets(c).y#,0.2+frnd#(0.5),bullets(c).rot#+180+frnd#(280)-140,20,0,40,40,40,ssmallsmoke,15+frnd#(15),0,255)
                        next d
                        //num=rnd(1)
                        //for d=1 to num
                        //    addspark(bullets(c).x#,bullets(c).y#,1.5+frnd#(0.5),bullets(c).rot#+180+frnd#(60)-30,5,20,ssmalldebri,50+frnd#(100),frnd#(20)-10.0)
                        //next d
                        b=array count(mechs(0))
                        
                        delete sprite bullets(c).spritenum
                        array delete element bullets(0),c
                        c=c-1 
                    endif
                next b
            endif
        endif
        
    next c
    
    for c=0 to array count(sparks(0))-1
        if sparks(c).delay<=0
            show sprite sparks(c).spritenum
            if (sparks(c).life<=0)
                if backset=sparks(c).spritenum then backset=-1
                delete sprite sparks(c).spritenum
                array delete element sparks(0),c
                c=c-1
            else
                sparks(c).x#=sparks(c).x#-(sparks(c).speed#*sin(sparks(c).angle#))
                sparks(c).y#=sparks(c).y#+(sparks(c).speed#*cos(sparks(c).angle#))
                if (sparks(c).life<sparks(c).fadeout)
                    set sprite alpha sparks(c).spritenum,((sparks(c).life*sparks(c).alpha)/sparks(c).fadeout)
                else
                    if (sparks(c).life>sparks(c).fadein) AND (sparks(c).life<=sparks(c).fadestart)
                        set sprite alpha sparks(c).spritenum,sparks(c).alpha-(((sparks(c).life-sparks(c).fadein)*sparks(c).alpha)/(sparks(c).fadestart-sparks(c).fadein))
                    else
                        if (sparks(c).life>sparks(c).fadestart) then  set sprite alpha sparks(c).spritenum,0
                    endif
                endif
                rotate sprite sparks(c).spritenum,sprite angle(sparks(c).spritenum)+sparks(c).spin#
                sprite sparks(c).spritenum,sparks(c).x#,sparks(c).y#,sprite image(sparks(c).spritenum)
                sparks(c).life=sparks(c).life-1
            endif
        else
            sparks(c).delay=sparks(c).delay-1
        endif
        
        
    next c
    
    text 0,0,str$(screen fps())+" fps (should be 30)"
    text 200,0,"Move: arrow keys"
    text 200,20,"Guns: left click"
    text 200,40,"Rockets: right click"
    text 0,50,"Killed: "+str$(killed)
    text 0,70,"Next enemy: "+str$((nextmech/30)+1)
    if gameend=1
        text screen width()/2- (text width("You died, but took "+str$(killed)+" of them with you!")/2),screen height()/2,"You died, but took "+str$(killed)+" of them with you!"
    endif
    sync
loop

function vlsetorigin(rotation#,x#,y#)
    global vlrotation#=rotation#
    global vlx#=x#
    global vly#=y#
endfunction

function getx#(x#,y#,angle#)
    ret#=(cos(angle#)*x#)+(-sin(angle#)*y#)
endfunction ret#

function gety#(x#,y#,angle#)
    ret#=(sin(angle#)*x#)+(cos(angle#)*y#)
endfunction ret#

function vldrawline(x1#,y1#,x2#,y2#)
    line vlx#+((cos(vlrotation#)*x1#)+(-sin(vlrotation#)*y1#)),vly#+((sin(vlrotation#)*x1#)+(cos(vlrotation#)*y1#)),vlx#+((cos(vlrotation#)*x2#)+(-sin(vlrotation#)*y2#)),vly#+((sin(vlrotation#)*x2#)+(cos(vlrotation#)*y2#))
endfunction

function vlstartpoly(x#,y#)
    global vlpolyx#=x#
    global vlpolyy#=y#
    global vlpolystartx#=x#
    global vlpolystarty#=y#
endfunction

function vlpolyline(x#,y#)
    line vlx#+((cos(vlrotation#)*vlpolyx#)+(-sin(vlrotation#)*vlpolyy#)),vly#+((sin(vlrotation#)*vlpolyx#)+(cos(vlrotation#)*vlpolyy#)),vlx#+((cos(vlrotation#)*x#)+(-sin(vlrotation#)*y#)),vly#+((sin(vlrotation#)*x#)+(cos(vlrotation#)*y#))
    vlpolyx#=x#
    vlpolyy#=y#
endfunction

function vlendpoly()
    line vlx#+((cos(vlrotation#)*vlpolyx#)+(-sin(vlrotation#)*vlpolyy#)),vly#+((sin(vlrotation#)*vlpolyx#)+(cos(vlrotation#)*vlpolyy#)),vlx#+((cos(vlrotation#)*vlpolystartx#)+(-sin(vlrotation#)*vlpolystarty#)),vly#+((sin(vlrotation#)*vlpolystartx#)+(cos(vlrotation#)*vlpolystarty#))
endfunction

function findsprite()
res=1
while sprite exist(res)=1
res=res+1
endwhile
endfunction res

function addmech(x#,y#,tx#,ty#,health)
    array insert at bottom mechs(0)
    index=array count(mechs(0))-1
    mechs(index).x#=x#
    mechs(index).y#=y#
    mechs(index).rot#=0
    mechs(index).legmove#=0
    mechs(index).hp=health
    mechs(index).maxhp=health
    mechs(index).speed#=1.2
    mechs(index).ai.moving=1
    mechs(index).ai.entering=1
    mechs(index).ai.destx#=tx#
    mechs(index).ai.desty#=ty#
    
    mechs(index).rweapon=findsprite()
    sprite mechs(index).rweapon,0,0,1
    set sprite mechs(index).rweapon,0,1
    set sprite priority mechs(index).rweapon,3
    mechs(index).lweapon=findsprite()
    sprite mechs(index).lweapon,0,0,1
    set sprite mechs(index).lweapon,0,1
    set sprite priority mechs(index).lweapon,3
    
    mechs(index).body=findsprite()
    sprite mechs(index).body,0,0,1
    set sprite mechs(index).body,0,1
    set sprite priority mechs(index).body,2
    
    mechs(index).lfoot=findsprite()
    sprite mechs(index).lfoot,0,0,1
    set sprite mechs(index).lfoot,0,1
    set sprite priority mechs(index).lfoot,1
    mechs(index).rfoot=findsprite()
    sprite mechs(index).rfoot,0,0,1
    set sprite mechs(index).rfoot,0,1
    set sprite priority mechs(index).rfoot,1
    
    
    mechs(index).lleg=findsprite()
    sprite mechs(index).lleg,0,0,1
    set sprite mechs(index).lleg,0,1
    mechs(index).rleg=findsprite()
    sprite mechs(index).rleg,0,0,1
    set sprite mechs(index).rleg,0,1

    
    
    mechs(index).hpbar=findsprite()
    sprite mechs(index).hpbar,0,0,1
    set sprite mechs(index).hpbar,0,1
endfunction

function addbullet(owner,x#,y#,rot#,sourcesprite,distance,damage,vel#,accel#,smoke#)
    array insert at bottom bullets(0)
    index=array count(bullets(0))-1
    bullets(index).x#=x#
    bullets(index).y#=y#
    bullets(index).rot#=rot#
    bullets(index).live=2
    bullets(index).distance=distance
    bullets(index).damage=damage
    bullets(index).vel#=vel#
    bullets(index).accel#=accel#
    bullets(index).owner=owner
    bullets(index).smoke#=smoke#
    
    bullets(index).spritenum=findsprite()
    clone sprite sourcesprite,bullets(index).spritenum
    set sprite bullets(index).spritenum,0,1
    set sprite priority bullets(index).spritenum,10
    rotate sprite bullets(index).spritenum,bullets(index).rot#
    show sprite bullets(index).spritenum
endfunction


function addspark(x#,y#,speed#,angle#,life,delay,fadestart,fadein,fadeout,sourcesprite,scale,spin#,alpha)
    array insert at bottom sparks(0)
    index=array count(sparks(0))-1
    sparks(index).x#=x#
    sparks(index).y#=y#
    sparks(index).speed#=speed#
    sparks(index).angle#=angle#
    sparks(index).life=life
    sparks(index).fadein=fadein
    sparks(index).fadeout=fadeout
    sparks(index).fadestart=fadestart
    sparks(index).spin#=spin#
    sparks(index).alpha=alpha
    sparks(index).delay=delay
    
    sparks(index).spritenum=findsprite()
    clone sprite sourcesprite,sparks(index).spritenum
    set sprite sparks(index).spritenum,0,1
    set sprite priority sparks(index).spritenum,20
    rotate sprite sparks(index).spritenum,sparks(index).angle#
    scale sprite sparks(index).spritenum,scale
    hide sprite sparks(index).spritenum
    ret=sparks(index).spritenum
endfunction ret

function copysprite(source,target,x,y,rot#,ox#,oy#)
    offset sprite target,sprite offset x(source)+ox#,sprite offset y(source)+oy#
    rotate sprite target,rot#
    sprite target,x,y,sprite image(source)
endfunction

function floodfill(x,y,colour)
    lock pixels
    targetcolour=point(x,y)
    floodfillrec(x,y,targetcolour,colour)
    unlock pixels
endfunction

function floodfillrec(x,y,targetcolour,colour)
    if point(x,y)=targetcolour
        dot x,y,colour
        floodfillrec(x-1,y,targetcolour,colour)
        floodfillrec(x+1,y,targetcolour,colour)
        floodfillrec(x,y-1,targetcolour,colour)
        floodfillrec(x,y+1,targetcolour,colour)
    endif
endfunction

function frnd#(range#)
  ret#=rnd(range#*1000.0)/1000.0
endfunction ret#

function wrap180#(angle#)
    ret#=wrapvalue(angle#)
    if ret#>180 then ret#=ret#-360
    if ret#<-180 then ret#=ret#+360
endfunction ret#

function dist#(x#,y#)
ret#=sqrt((x#*x#)+(y#*y#))
endfunction ret#

function FillCircle( CX as integer, CY as integer, R as integer ) `Not mine!!! From somewhere on the DBPro forums
   local x as integer
   local y as integer
   local i as integer
   local s as integer

   s=R*0.70710678 : ` this number is sin(45) - precalculate!
   box CX-s, CY-s, CX+s+1, CY+s+1
   s=s+1 : ` Faster than 'inc s'?
   i=R*R
   for y=s to R
      x=sqrt( i-(y*y) )

      ` Draw top and bottom
      box CX-x, CY-y, CX+x+1, CY-y+1
      box CX-x, CY+y, CX+x+1, CY+y+1

      ` Draw left and right
      box CX-y, CY-x, CX-y+1, CY+x+1
      box CX+y, CY-x, CX+y+1, CY+x+1
   next y
endfunction

sync on
sync rate 30

type spark
    x# as float
    y# as float
    speed# as float
    angle# as float
    life as integer
    fadeout as integer
    fadein as integer
    fadestart as integer
    spritenum as integer
    spin# as float
    alpha as integer
    delay as integer
    mechtie as integer
endtype

type aidata
    ally as integer
    destx# as float
    desty# as float
    threat as integer
    moving as integer
    firing as integer
    avoiding as integer
    entering as integer
    determination# as float
    range as integer
endtype



type mech
    x# as float
    y# as float
    rot# as float
    toprot# as float
    legmove# as float
    lastmove as integer
    speed# as float
    move as integer
    hpbar as integer
    sbar as integer
    body as integer
    lleg as integer
    rleg as integer
    lfoot as integer
    rfoot as integer
    rweapon as integer
    lweapon as integer
    lfiring as float
    rfiring as float
    lrecoil# as float
    rrecoil# as float
    lrecoilvel# as float
    rrecoilvel# as float
    bodysway as integer
    firing as integer
    hp# as float 
    shield# as float
    shieldregen# as float
    maxshield# as float
    ai as aidata
    corpsetimer as integer
endtype

type bullet
    x# as float
    y# as float
    accel# as float
    vel# as float
    spritenum as integer
    rot# as float
    live as integer
    distance as integer
    damage# as integer
    owner as integer
    smoke# as float
    hittype as integer
endtype


dim mechs(0) as mech

dim bullets(0) as bullet

dim sparks(0) as spark

//images
//1:blank
//2:body
//3:lfoot
//4:rfoot





ink rgb(255,255,255),0
box 0,0,10,10
get image 1,0,0,1,1,1
blurback=findsprite()
sprite blurback,0,0,1
set sprite alpha blurback,100
set sprite diffuse blurback,0,0,0
set sprite blurback,0,1
size sprite blurback,screen width(),screen height()


cls
//ink rgb(96,128,159),0
    //box 90,90,110,110
    //box 85,95,115,105
    
ink rgb(66,88,111),0
       vlsetorigin(0,100,100)
       
       vlstartpoly(-10,10)
       vlpolyline(10,10)
       vlpolyline(15,5)
       vlpolyline(15,-5)
       vlpolyline(10,-10)
       vlpolyline(-10,-10)
       vlpolyline(-15,-5)
       vlpolyline(-15,5)
       vlendpoly()
       floodfill(100,100,rgb(96,128,159))
       
get image 2,85,90,116,111,0
sbody=findsprite()
sprite sbody,0,0,2
offset sprite sbody,15,10
hide sprite sbody
  
cls  
ink rgb(255,0,0),0
box 0,0,200,200
ink rgb(66,88,111),0   
       vlstartpoly(14,10)
       vlpolyline(19,10)
       vlpolyline(19,-10)
       vlpolyline(14,-10)
       vlendpoly()
       floodfill(116,100,rgb(96,128,159))
       
get image 3,114,90,120,111,0
slfoot=findsprite()
sprite slfoot,0,0,3
offset sprite slfoot,-14,10
hide sprite slfoot
       
cls
ink rgb(255,0,0),0
box 0,0,200,200
ink rgb(66,88,111),0
       vlstartpoly(-14,10)
       vlpolyline(-19,10)
       vlpolyline(-19,-10)
       vlpolyline(-14,-10)
       vlendpoly()
       floodfill(84,100,rgb(96,128,159))
       
get image 4,81,90,87,111,0       
srfoot=findsprite()
sprite srfoot,0,0,4
offset sprite srfoot,19,10
hide sprite srfoot       

cls
ink rgb(255,0,0),0
box 0,0,200,200
ink rgb(66,88,111),0
       vlstartpoly(-11,12)
       vlpolyline(-8,12)
       vlpolyline(-8,0)
       vlpolyline(-11,0)
       vlendpoly()
       floodfill(90,105,rgb(96,128,159))
       
get image 5,89,100,93,113,0       
slweapon=findsprite()
sprite slweapon,0,0,5
offset sprite slweapon,11,0
hide sprite slweapon  

cls
ink rgb(255,0,0),0
box 0,0,200,200
ink rgb(66,88,111),0
       vlstartpoly(11,12)
       vlpolyline(8,12)
       vlpolyline(8,0)
       vlpolyline(11,0)
       vlendpoly()
       floodfill(110,105,rgb(96,128,159))
       
get image 6,108,100,112,113,0       
srweapon=findsprite()
sprite srweapon,0,0,6
offset sprite srweapon,-8,0
hide sprite srweapon  

cls
ink rgb(255,0,0),0
box 0,0,200,200
ink rgb(230,60,0),0
       line 1,1,1,20
       line 2,1,2,20
       
get image 15,1,1,2,20,0       
sbullet=findsprite()
sprite sbullet,0,0,15
offset sprite sbullet,0,0
hide sprite sbullet 

cls
ink rgb(255,0,0),0
box 0,0,200,200
ink rgb(130,130,130),0
       line 1,1,1,10
       line 2,1,2,11
       line 3,1,3,10
ink rgb(200,0,0),0
       line 1,2,3,2
       line 1,4,3,4
       
get image 16,1,1,3,11,0       
srocket=findsprite()
sprite srocket,0,0,16
offset sprite srocket,1,0
hide sprite srocket

cls
ink rgb(255,0,0),0
box 0,0,200,200
ink rgb(50,200,50),0
       box 1,1,5,5
       
get image 20,1,1,5,5,0       
shbar=findsprite()
sprite shbar,0,0,20
offset sprite shbar,0,0
hide sprite shbar

cls
ink rgb(255,0,0),0
box 0,0,200,200
ink rgb(50,100,200),0
       box 1,1,5,5
       
get image 27,1,1,5,5,0       
ssbar=findsprite()
sprite ssbar,0,0,27
offset sprite ssbar,0,0
hide sprite ssbar

cls
ink rgb(255,0,0),0
box 0,0,200,200
ink rgb(255,128,0),0
       box 1,1,2,3
       
get image 21,1,1,2,3,0       
sspark=findsprite()
sprite sspark,0,0,21
offset sprite sspark,0,0
hide sprite sspark

cls
ink rgb(255,0,0),0
box 0,0,200,200
ink rgb(50,100,200),0
       box 1,1,2,3
       
get image 28,1,1,2,3,0       
sbspark=findsprite()
sprite sbspark,0,0,28
offset sprite sbspark,0,0
hide sprite sbspark

cls
ink rgb(0,0,0),0
box 0,0,200,200
ink rgb(50,100,200),0
       circle 20,20,19   
       circle 18,22,17
       circle 21,23,17        
get image 29,1,1,40,40,0       
sshield=findsprite()
sprite sshield,0,0,29
offset sprite sshield,20,20
hide sprite sshield


cls
ink rgb(0,0,0),0
box 0,0,200,200
ink rgb(80,80,80),0
       fillcircle(10,10,9)
       
get image 22,1,1,20,20,0    
ssmallsmoke=findsprite()
sprite ssmallsmoke,0,0,22
offset sprite ssmallsmoke,9,9
hide sprite ssmallsmoke

cls
ink rgb(0,0,0),0
box 0,0,200,200
ink rgb(66,88,111),0
       vlsetorigin(0,0,0)
       vlstartpoly(1,4)
       vlpolyline(4,1)
       vlpolyline(6,5)
       vlpolyline(4,5)
       vlpolyline(3,6)
       vlendpoly()
       floodfill(3,4,rgb(96,128,159))
       
get image 23,1,1,7,7,0       
ssmalldebri=findsprite()
sprite ssmalldebri,0,0,23
offset sprite ssmalldebri,3,3
hide sprite ssmalldebri

cls
ink rgb(0,0,0),0
box 0,0,200,200
ink rgb(255,90,0),0
       fillcircle(10,10,9)
       
get image 24,1,1,20,20,0       
sfireball=findsprite()
sprite sfireball,0,0,24
offset sprite sfireball,9,9
hide sprite sfireball

cls
ink rgb(0,0,0),0
box 0,0,200,200
ink rgb(255,255,255),0
       fillcircle(10,10,9)
       
get image 25,1,1,20,20,0       
sbrightfireball=findsprite()
sprite sbrightfireball,0,0,25
offset sprite sbrightfireball,9,9
hide sprite sbrightfireball

cls
ink rgb(0,0,0),0
box 0,0,200,200
ink rgb(255,255,255),0
       //line 2,1,1,400
       line 2,1,2,400
       //line 2,1,3,400
       
get image 26,1,1,4,401,0       
slight=findsprite()
sprite slight,0,0,26
offset sprite slight,1,0
hide sprite slight












addmech(screen width()/2,screen height()/2,0,0,80,30)


lastmove=0
killed=0
nextmech=150
gameend=0


ink rgb(255,255,255),0
box 0,0,screen width(),screen height()

do

    nextmech=nextmech-1
    if nextmech<0
        nextmech=300-(killed*5)
        if killed<3
            hp=20
            shield=0
        else
            if killed<5
                hp=40
                shield=0
            else
                if killed<7
                    hp=30
                    shield=10
                else
                    if killed<10
                        hp=70
                        shield=0
                    else
                        hp=30
                        shield=20
                    endif
                endif
            endif
        endif
        if nextmech<90 then nextmech=90
        rx=rnd(screen width()-60)+30
        ry=rnd(screen height()-60)+30
        select rnd(3)
            case 0: addmech(rx,-50,rx,10,hp,shield)
            endcase
            case 1: addmech(rx,screen height()+50,rx,screen height()-10,hp,shield)
            endcase
            case 2: addmech(-50,ry,10,ry,hp,shield)
            endcase
            case 3: addmech(screen width()+50,ry,screen width()-10,ry,hp,shield)
            endcase
        endselect
       
    endif

    
    
        mechs(0).move=0
     
    if gameend=0    
        if downkey()
            mechs(0).move=1 
            mechs(0).lastmove=1 
        endif
        if upkey()
            mechs(0).move=1 
            mechs(0).lastmove=2 
        endif
        if rightkey()
            mechs(0).move=1 
            mechs(0).lastmove=3 
        endif
        if leftkey()
            mechs(0).move=1 
            mechs(0).lastmove=4 
        endif
    
    
    

        
        lmb=0
        mmb=0
        rmb=0
      
        mv=mouseclick()
        if int(mv/8)=1
            mv=mv-8
        endif
        if int(mv/4)=1
            mv=mv-4
            mmb=1
        endif
        if int(mv/2)=1
            mv=mv-2
            rmb=1
        endif
        if mv=1
            lmb=1
        endif
        
        
        if lmb=1
            mechs(0).firing=1    
        else
            if rmb=1
                mechs(0).firing=2    
            else
                mechs(0).firing=0
            endif
        endif
    endif
    
    
    targetangle#=wrapvalue(atanfull(-(mousex()-mechs(0).x#),(mousey()-mechs(0).y#)))
    mechs(0).toprot#=wrapvalue(mechs(0).toprot#)
    if (wrap180#(mechs(0).rot#+mechs(0).toprot#-targetangle#)>-3)
        if (wrap180#(mechs(0).rot#+mechs(0).toprot#-targetangle#)<3) 
            //mechs(0).firing=1
        else
            mechs(0).toprot#=mechs(0).toprot#-3
            
        endif
    else
        mechs(0).toprot#=mechs(0).toprot#+3
        
    endif
    
    
    
    for c=1 to array count(mechs(0))-1
        
        mechs(c).move=0
        mechs(c).ai.range=400
        
        
        if mechs(mechs(c).ai.threat).firing
            angle#=wrapvalue(atanfull(-(mechs(mechs(c).ai.threat).x#-mechs(c).x#),(mechs(mechs(c).ai.threat).y#-mechs(c).y#)))
            if (wrap180#(angle#-180-mechs(mechs(c).ai.threat).rot#-mechs(mechs(c).ai.threat).toprot#)<7) AND (wrap180#(angle#-180-mechs(mechs(c).ai.threat).rot#-mechs(mechs(c).ai.threat).toprot#)>-7)
                if (wrap180#(angle#-180-mechs(mechs(c).ai.threat).rot#-mechs(mechs(c).ai.threat).toprot#))>0
                    angle#=angle#-90
                else
                    angle#=angle#+90
                endif 
                    proposedx#=mechs(c).x#-sin(angle#)*40.0
                    proposedy#=mechs(c).y#+cos(angle#)*40.0
                if (mechs(c).ai.determination#<=0) AND (mechs(c).ai.entering=0)
                    mechs(c).ai.destx#=proposedx#
                    mechs(c).ai.desty#=proposedy#
                    mechs(c).ai.moving=1
                    mechs(c).ai.avoiding=1
                    mechs(c).ai.determination#=170
                else
                    mechs(c).ai.determination#=mechs(c).ai.determination#-(0.05*sqrt(((mechs(c).ai.destx#-proposedx#)*(mechs(c).ai.destx#-proposedx#))+((mechs(c).ai.desty#-proposedy#)*(mechs(c).ai.desty#-proposedy#))))    
                endif
            endif
        endif
        if mechs(c).ai.moving=1
            if mechs(c).ai.destx#>screen width()-10 then mechs(c).ai.destx#=screen width()-10
            if mechs(c).ai.destx#<10 then mechs(c).ai.destx#=10
            if mechs(c).ai.desty#>screen height()-10 then mechs(c).ai.desty#=screen height()-10
            if mechs(c).ai.desty#<10 then mechs(c).ai.desty#=10
            
            
            if (((mechs(c).ai.destx#-mechs(c).x#)*(mechs(c).ai.destx#-mechs(c).x#))+((mechs(c).ai.desty#-mechs(c).y#)*(mechs(c).ai.desty#-mechs(c).y#)))>25
                targetangle#=wrapvalue(atanfull(-(mechs(c).ai.destx#-mechs(c).x#),(mechs(c).ai.desty#-mechs(c).y#)))   
                if (wrap180#(mechs(c).rot#-targetangle#)>-3)
                    if (wrap180#(mechs(c).rot#-targetangle#)<3) 
                        mechs(c).move=1
                        mechs(c).lastmove=2
                    else
                        mechs(c).move=1
                        mechs(c).lastmove=4
                    endif
                else
                    mechs(c).move=1
                    mechs(c).lastmove=3
                endif
            else
                mechs(c).ai.determination#=0
                mechs(c).ai.moving=0
            endif
        else
            mechs(c).ai.avoiding=0
            mechs(c).ai.entering=0
        endif
        mechs(c).ai.threat=0
        inrange=0
        threatdist#=dist#(mechs(c).x#-mechs(mechs(c).ai.threat).x#,mechs(c).y#-mechs(mechs(c).ai.threat).y#)
        if (threatdist#< mechs(c).ai.range)
            inrange=1
        else
            if (mechs(c).ai.avoiding=0) AND (mechs(c).ai.entering=0)
                mechs(c).ai.destx#=mechs(mechs(c).ai.threat).x#-(((mechs(mechs(c).ai.threat).x#-mechs(c).x#)*(mechs(c).ai.range*0.9))/threatdist#)
                mechs(c).ai.desty#=mechs(mechs(c).ai.threat).y#-(((mechs(mechs(c).ai.threat).y#-mechs(c).y#)*(mechs(c).ai.range*0.9))/threatdist#)
                mechs(c).ai.moving=1
                //mechs(c).ai.determination#=170
            endif
        endif
        
        holdfire=0
        
        if (mechs(c).shield#<mechs(c).maxshield#) AND (inrange=0)
            holdfire=1
        endif
        
        targetangle#=wrapvalue(atanfull(-(mechs(mechs(c).ai.threat).x#-mechs(c).x#),(mechs(mechs(c).ai.threat).y#-mechs(c).y#)))
        if mechs(c).hp#<=0 then targetangle#=0
        mechs(c).toprot#=wrapvalue(mechs(c).toprot#)
        mechs(c).firing=0
        if (wrap180#(mechs(c).rot#+mechs(c).toprot#-targetangle#)>-3)
            if (wrap180#(mechs(c).rot#+mechs(c).toprot#-targetangle#)<3) 
                if (mechs(c).ai.entering=0) AND (holdfire=0) then mechs(c).firing=1
            else
                mechs(c).toprot#=mechs(c).toprot#-3
                
            endif
        else
            mechs(c).toprot#=mechs(c).toprot#+3 
        endif
        if (wrap180#(mechs(c).rot#+mechs(c).toprot#-targetangle#)>-3)
            if (wrap180#(mechs(c).rot#+mechs(c).toprot#-targetangle#)<3) 
                if (mechs(c).ai.entering=0) AND (holdfire=0) then mechs(c).firing=1
            endif                
        endif
        if mechs(c).hp#<=0 then mechs(c).firing=0
    next c
    
    
    
    for c=0 to array count(mechs(0))-1
        if (mechs(c).corpsetimer>0)
            if (mechs(c).corpsetimer>90)
                    
                    
                    
                    delete sprite mechs(c).body 
                    delete sprite mechs(c).lfoot
                    delete sprite mechs(c).rfoot
                    delete sprite mechs(c).lleg
                    delete sprite mechs(c).rleg
                    delete sprite mechs(c).lweapon
                    delete sprite mechs(c).rweapon
                    array delete element mechs(0),c
                    set sprite diffuse blurback,0,0,0
                    c=c-1
                    
            else
                if backset>-1
                    mechs(c).corpsetimer=mechs(c).corpsetimer+1
                    set sprite diffuse blurback,sprite alpha(backset)/3,sprite alpha(backset)/3,sprite alpha(backset)/3
                endif
            endif
        else
            if (mechs(c).move=1) OR ( NOT (((abs(mechs(c).legmove#)-4)<1.1) AND ((abs(mechs(c).legmove#)-5)>-1.1)))
                select mechs(c).lastmove
                    case 1 
                        mechs(c).legmove#=mechs(c).legmove#+mechs(c).speed#
                        mechs(c).x#=mechs(c).x#+(mechs(c).speed#*sin(mechs(c).rot#))
                        mechs(c).y#=mechs(c).y#-(mechs(c).speed#*cos(mechs(c).rot#))
                    endcase
                    case 2
                        mechs(c).legmove#=mechs(c).legmove#-mechs(c).speed#
                        mechs(c).x#=mechs(c).x#-(mechs(c).speed#*sin(mechs(c).rot#))
                        mechs(c).y#=mechs(c).y#+(mechs(c).speed#*cos(mechs(c).rot#))
                    endcase
                    case 3
                        mechs(c).legmove#=mechs(c).legmove#+mechs(c).speed#
                        mechs(c).rot#=mechs(c).rot#+3
                    endcase
                    case 4
                        mechs(c).legmove#=mechs(c).legmove#+mechs(c).speed#
                        mechs(c).rot#=mechs(c).rot#-3
                    endcase
                endselect
            else
                if mechs(c).legmove#>0 then mechs(c).legmove#=5 else mechs(c).legmove#=-5
            endif
            
            
            
            if (mechs(c).firing=1)
                if mechs(c).lfiring=0
                    mechs(c).lfiring=8
                    addbullet(c,mechs(c).x#+getx#(mechs(c).bodysway-10,10,mechs(c).rot#+mechs(c).toprot#),mechs(c).y#+gety#(mechs(c).bodysway-10,10,mechs(c).rot#+mechs(c).toprot#),mechs(c).rot#+mechs(c).toprot#+frnd#(5.0)-2.5-1,sbullet,1500,2,15,0,0,1)
                    mechs(c).lrecoilvel#=-3
                endif
                if (mechs(c).rfiring=0) AND (mechs(c).lfiring=4)
                    mechs(c).rfiring=8
                    addbullet(c,mechs(c).x#+getx#(mechs(c).bodysway+10,10,mechs(c).rot#+mechs(c).toprot#),mechs(c).y#+gety#(mechs(c).bodysway+10,10,mechs(c).rot#+mechs(c).toprot#),mechs(c).rot#+mechs(c).toprot#+frnd#(5.0)-2.5+1,sbullet,1500,2,15,0,0,1)
                    mechs(c).rrecoilvel#=-3
                endif
            endif
            
            if (mechs(c).firing=2)
                if mechs(c).lfiring=0
                    mechs(c).lfiring=30
                    addbullet(c,mechs(c).x#+getx#(mechs(c).bodysway-10,10,mechs(c).rot#+mechs(c).toprot#),mechs(c).y#+gety#(mechs(c).bodysway-10,10,mechs(c).rot#+mechs(c).toprot#),mechs(c).rot#+mechs(c).toprot#-1,srocket,1500,20,1.7,0.5,0.1,2)
                    mechs(c).lrecoilvel#=-3
                endif
                if (mechs(c).rfiring=0) AND (mechs(c).lfiring=15)
                    mechs(c).rfiring=30
                    addbullet(c,mechs(c).x#+getx#(mechs(c).bodysway+10,10,mechs(c).rot#+mechs(c).toprot#),mechs(c).y#+gety#(mechs(c).bodysway+10,10,mechs(c).rot#+mechs(c).toprot#),mechs(c).rot#+mechs(c).toprot#+1,srocket,1500,20,1.7,0.5,0.1,2)
                    mechs(c).rrecoilvel#=-3
                endif
            endif
            
            if mechs(c).firing=0
                if mechs(c).shield#<mechs(c).maxshield# 
                    mechs(c).shield#=mechs(c).shield#+mechs(c).shieldregen#
                    if c=0
                        text screen width()/2- (text width("Shield Charging!")/2),100,"Shield Charging!"
                    endif
                endif
            endif
            
            
            while (mechs(c).legmove#>10)
                mechs(c).legmove#=mechs(c).legmove#-20
            endwhile
            while (mechs(c).legmove#<-10)
                mechs(c).legmove#=mechs(c).legmove#+20
            endwhile
            
            mechs(c).lrecoil#=mechs(c).lrecoil#+mechs(c).lrecoilvel#
            if (mechs(c).lrecoil#<-5)
                mechs(c).lrecoil#=-5
                mechs(c).lrecoilvel#=0.5
            endif
            if (mechs(c).lrecoil#>0) then mechs(c).lrecoil#=0
            if mechs(c).lfiring>0 then mechs(c).lfiring=mechs(c).lfiring-1
            
            mechs(c).rrecoil#=mechs(c).rrecoil#+mechs(c).rrecoilvel#
            if (mechs(c).rrecoil#<-5)
                mechs(c).rrecoil#=-5
                mechs(c).rrecoilvel#=0.5
            endif
            if (mechs(c).rrecoil#>0) then mechs(c).rrecoil#=0
            if mechs(c).rfiring>0 then mechs(c).rfiring=mechs(c).rfiring-1
            
            if mechs(c).lastmove=2
                mechs(c).bodysway=(abs(mechs(c).legmove#)-5)*0.6
            else
                mechs(c).bodysway=(-abs(mechs(c).legmove#)+5)*0.6
            endif
            
            copysprite(sbody,mechs(c).body,mechs(c).x#,mechs(c).y#,mechs(c).rot#+mechs(c).toprot#,cos(mechs(c).toprot#)*mechs(c).bodysway,-sin(mechs(c).toprot#)*mechs(c).bodysway)
            
            copysprite(slweapon,mechs(c).lweapon,mechs(c).x#,mechs(c).y#,mechs(c).rot#+mechs(c).toprot#,cos(mechs(c).toprot#)*mechs(c).bodysway,-sin(mechs(c).toprot#)*mechs(c).bodysway-mechs(c).lrecoil#)
            copysprite(srweapon,mechs(c).rweapon,mechs(c).x#,mechs(c).y#,mechs(c).rot#+mechs(c).toprot#,cos(mechs(c).toprot#)*mechs(c).bodysway,-sin(mechs(c).toprot#)*mechs(c).bodysway-mechs(c).rrecoil#)
            copysprite(slfoot,mechs(c).lfoot,mechs(c).x#,mechs(c).y#,mechs(c).rot#,0,0-abs(mechs(c).legmove#)+5)
            copysprite(srfoot,mechs(c).rfoot,mechs(c).x#,mechs(c).y#,mechs(c).rot#,0,abs(mechs(c).legmove#)-5)
            //if (mechs(c).hp<mechs(c).maxhp) 
                
                
                if mechs(c).shield#>mechs(c).maxshield# then mechs(c).shield#=mechs(c).maxshield#
                
                if (mechs(c).hp#<0) then mechs(c).hp#=0
                size sprite mechs(c).hpbar,mechs(c).hp#,5
                offset sprite mechs(c).hpbar,((mechs(c).hp#+mechs(c).shield#)/2.0)+1,0
                sprite mechs(c).hpbar,mechs(c).x#,mechs(c).y#-25,20
                size sprite mechs(c).sbar,mechs(c).shield#,5
                offset sprite mechs(c).sbar,((mechs(c).hp#+mechs(c).shield#)/2.0)-mechs(c).hp#-1,0
                sprite mechs(c).sbar,mechs(c).x#,mechs(c).y#-25,27
                if (mechs(c).hp#<=0) 
                    if c=0
                        gameend=1    
                    else
                        killed=killed+1
                    endif
                    
                    
                    
                    
                        delay=0
                    for e=1 to 5
                
                        x#=mechs(c).x#+rnd(30)-15
                        y#=mechs(c).y#+rnd(30)-15
                        
                        num=10+rnd(10)
                        for d=1 to num
                            addspark(x#,y#,0.5+frnd#(2),frnd#(360),10+rnd(10),delay,10,10,10,sspark,100,0,200,-1)
                        next d   
                        num=5+rnd(5)
                        for d=1 to num
                            addspark(x#,y#,0.2+frnd#(1),frnd#(360),30+rnd(5),delay,35,35,35,ssmallsmoke,40+frnd#(50),frnd#(10)-5.0,130,-1)
                        next d  
                        num=6+rnd(4)
                        for d=1 to num
                            addspark(x#,y#,0.2+frnd#(1),frnd#(360),25,delay,30,30,30,sfireball,50+frnd#(50),frnd#(10)-5.0,130,-1)
                        next d  
                        num=3+rnd(3)
                        for d=1 to num
                            addspark(x#,y#,0.2+frnd#(0.5),frnd#(360),20,delay,20,20,20,sbrightfireball,80+frnd#(50),frnd#(10)-5.0,100,-1)
                        next d 
                        delay=rnd(70)
                    next e
                    
                    
                    num=4+rnd(3)
                    for d=1 to num
                        start=rnd(50)
                        addspark(mechs(c).x#,mechs(c).y#,0,frnd#(360),95,0, 35+start,15+start,rnd(10),slight,400,frnd#(6)-3,100,-1)
                    next d  
                    
                    num=15+rnd(5)
                    for d=1 to num
                        backset=addspark(mechs(c).x#+frnd#(30)-15,mechs(c).y#+frnd#(30)-15,frnd#(0.2),frnd#(360),100,0,80,30,5+rnd(5),sbrightfireball,100+frnd#(80),frnd#(2)-1,70,-1)
                    next d  
                    
                    
                    num=20+rnd(10)
                    for d=1 to num
                        addspark(mechs(c).x#,mechs(c).y#,1+frnd#(3),frnd#(360),15+rnd(5),90,30,30,30,sspark,100,0,255,-1)
                    next d  
                    num=13+rnd(4)
                    for d=1 to num
                        addspark(mechs(c).x#+frnd#(10)-5,mechs(c).y#+frnd#(10)-5,0.6+frnd#(1.2),frnd#(360),30+rnd(5),90,20,20,20,ssmalldebri,100+frnd#(100),frnd#(40)-20.0,255,-1)
                    next d   
                    num=15+rnd(5)
                    for d=1 to num
                        addspark(mechs(c).x#+frnd#(10)-5,mechs(c).y#+frnd#(10)-5,0.7+frnd#(1),frnd#(360),45+rnd(5),90,80,80,80,ssmallsmoke,40+frnd#(100),frnd#(10)-5.0,255,-1)
                    next d  
                    num=6+rnd(4)
                    for d=1 to num
                        addspark(mechs(c).x#,mechs(c).y#,1+frnd#(1),frnd#(360),25,90,30,30,30,sfireball,100+frnd#(100),frnd#(10)-5.0,150,-1)
                    next d  
                    num=4+rnd(4)
                    for d=1 to num
                        addspark(mechs(c).x#,mechs(c).y#,1+frnd#(0.7),frnd#(360),15,90,15,15,15,sbrightfireball,100+frnd#(100),frnd#(10)-5.0,200,-1)
                    next d  
                    
                    //num=15+rnd(5)
                    //for d=1 to num
                    //    addspark(mechs(c).x#+frnd#(10)-5,mechs(c).y#+frnd#(10)-5,1.5+frnd#(0.2),frnd#(360),45+rnd(10),90,80,80,80,ssmallsmoke,40+frnd#(70),frnd#(10)-5.0,255)
                    //next d 
                    
                    
                    mechs(c).corpsetimer=1
                    
                endif
            endif
        //endif
    next c
    
    for c=0 to array count(bullets(0))-1
        
        bullets(c).x#=bullets(c).x#-(bullets(c).vel#*sin(bullets(c).rot#))
        bullets(c).y#=bullets(c).y#+(bullets(c).vel#*cos(bullets(c).rot#))
        bullets(c).distance=bullets(c).distance-bullets(c).vel#
        bullets(c).vel#=bullets(c).vel#+bullets(c).accel#
        sprite bullets(c).spritenum,bullets(c).x#,bullets(c).y#,sprite image(bullets(c).spritenum)
        if (bullets(c).smoke#>0)
            for b=0 to int(bullets(c).smoke#*bullets(c).vel#)+1
                distance#=frnd#(bullets(c).vel#)
                addspark(bullets(c).x#+(distance#*sin(bullets(c).rot#)),bullets(c).y#-(distance#*cos(bullets(c).rot#)),frnd#(0.4),frnd#(360),15+rnd(5),0,20,15,5,ssmallsmoke,40+frnd#(50),frnd#(10)-5.0,100,-1)
                
            next b
        endif
        if (bullets(c).distance<=0)
            delete sprite bullets(c).spritenum
            array delete element bullets(0),c
            c=c-1 
        else
            if bullets(c).live>0
                bullets(c).live=bullets(c).live-1
            else
                for b=0 to array count(mechs(0))-1
                    if (sprite hit(bullets(c).spritenum,mechs(b).body)) AND (b<>bullets(c).owner)
                        
                        if mechs(b).shield#<bullets(c).damage#
                            mechs(b).hp#=mechs(b).hp#-(bullets(c).damage#-mechs(b).shield#)
                            mechs(b).shield#=0
                        else
                            mechs(b).shield#=mechs(b).shield#-bullets(c).damage#
                            num=5+rnd(4)
                            for d=1 to num
                                addspark(bullets(c).x#,bullets(c).y#,1+frnd#(2),atanfull(bullets(c).y#-mechs(b).y#,bullets(c).x#-mechs(b).x#)+90+90+frnd#(40)-20,10,0,20,20,20,sbspark,150,0,255,-1)
                                addspark(bullets(c).x#,bullets(c).y#,1+frnd#(2),atanfull(bullets(c).y#-mechs(b).y#,bullets(c).x#-mechs(b).x#)+90-90+frnd#(40)-20,15,0,20,20,20,sbspark,150,0,255,-1)
                            next d
                            addspark(mechs(b).x#,mechs(b).y#,0,frnd#(360),15,0,20,20,20,sshield,120+rnd(40),frnd#(5)+1,30,b)
                        endif
                        
                        
                        
                        select bullets(c).hittype
                            case 1:
                                num=5+rnd(4)
                                for d=1 to num
                                    addspark(bullets(c).x#,bullets(c).y#,1+frnd#(2),bullets(c).rot#+180+frnd#(140)-70,10,0,20,20,20,sspark,100,0,255,-1)
                                next d
                                num=2+rnd(2)
                                for d=1 to num
                                    addspark(bullets(c).x#,bullets(c).y#,0.2+frnd#(0.5),bullets(c).rot#+180+frnd#(280)-140,20,0,40,40,40,ssmallsmoke,15+frnd#(15),0,255,-1)
                                next d
                            endcase
                            case 2:
                                x#=bullets(c).x#-(2.0*sin(bullets(c).rot#))+rnd(30)-15
                                y#=bullets(c).y#+(2.0*cos(bullets(c).rot#))+rnd(30)-15
                                
                                num=10+rnd(10)
                                delay=0
                                for d=1 to num
                                    addspark(x#,y#,0.5+frnd#(2),frnd#(360),10+rnd(10),delay,10,10,10,sspark,100,0,200,-1)
                                next d   
                                num=5+rnd(5)
                                for d=1 to num
                                    addspark(x#,y#,0.2+frnd#(1),frnd#(360),30+rnd(5),delay,35,35,35,ssmallsmoke,40+frnd#(50),frnd#(10)-5.0,130,-1)
                                next d  
                                num=6+rnd(4)
                                for d=1 to num
                                    addspark(x#,y#,0.2+frnd#(1),frnd#(360),25,delay,30,30,30,sfireball,50+frnd#(50),frnd#(10)-5.0,130,-1)
                                next d  
                                num=3+rnd(3)
                                for d=1 to num
                                    addspark(x#,y#,0.2+frnd#(0.5),frnd#(360),20,delay,20,20,20,sbrightfireball,80+frnd#(50),frnd#(10)-5.0,100,-1)
                                next d     
                            endcase
                        endselect
                        //num=rnd(1)
                        //for d=1 to num
                        //    addspark(bullets(c).x#,bullets(c).y#,1.5+frnd#(0.5),bullets(c).rot#+180+frnd#(60)-30,5,20,ssmalldebri,50+frnd#(100),frnd#(20)-10.0)
                        //next d
                        b=array count(mechs(0))
                        
                        delete sprite bullets(c).spritenum
                        array delete element bullets(0),c
                        c=c-1 
                    endif
                next b
            endif
        endif
        
    next c
    
    for c=0 to array count(sparks(0))-1
        if sparks(c).delay<=0
            show sprite sparks(c).spritenum
            if (sparks(c).life<=0)
                if backset=sparks(c).spritenum then backset=-1
                delete sprite sparks(c).spritenum
                array delete element sparks(0),c
                c=c-1
            else
                sparks(c).x#=sparks(c).x#-(sparks(c).speed#*sin(sparks(c).angle#))
                sparks(c).y#=sparks(c).y#+(sparks(c).speed#*cos(sparks(c).angle#))
                if sparks(c).mechtie>-1
                sparks(c).x#=mechs(sparks(c).mechtie).x#
                sparks(c).y#=mechs(sparks(c).mechtie).y#
                endif
                if (sparks(c).life<sparks(c).fadeout)
                    set sprite alpha sparks(c).spritenum,((sparks(c).life*sparks(c).alpha)/sparks(c).fadeout)
                else
                    if (sparks(c).life>sparks(c).fadein) AND (sparks(c).life<=sparks(c).fadestart)
                        set sprite alpha sparks(c).spritenum,sparks(c).alpha-(((sparks(c).life-sparks(c).fadein)*sparks(c).alpha)/(sparks(c).fadestart-sparks(c).fadein))
                    else
                        if (sparks(c).life>sparks(c).fadestart) then  set sprite alpha sparks(c).spritenum,0
                    endif
                endif
                rotate sprite sparks(c).spritenum,sprite angle(sparks(c).spritenum)+sparks(c).spin#
                sprite sparks(c).spritenum,sparks(c).x#,sparks(c).y#,sprite image(sparks(c).spritenum)
                sparks(c).life=sparks(c).life-1
            endif
        else
            sparks(c).delay=sparks(c).delay-1
        endif
        
        
    next c
    
    text 0,0,str$(screen fps())+" fps (should be 30)"
    text 200,0,"Move: arrow keys"
    text 200,20,"Guns: left click"
    text 200,40,"Rockets: right click"
    text 200,60,"Shield charges when not firing."
    text 0,50,"Killed: "+str$(killed)
    text 0,100,"Next enemy: "+str$((nextmech/30)+1)
    if gameend=1
        text screen width()/2- (text width("You died, but took "+str$(killed)+" of them with you!")/2),screen height()/2,"You died, but took "+str$(killed)+" of them with you!"
    endif
    sync
loop

function vlsetorigin(rotation#,x#,y#)
    global vlrotation#=rotation#
    global vlx#=x#
    global vly#=y#
endfunction

function getx#(x#,y#,angle#)
    ret#=(cos(angle#)*x#)+(-sin(angle#)*y#)
endfunction ret#

function gety#(x#,y#,angle#)
    ret#=(sin(angle#)*x#)+(cos(angle#)*y#)
endfunction ret#

function vldrawline(x1#,y1#,x2#,y2#)
    line vlx#+((cos(vlrotation#)*x1#)+(-sin(vlrotation#)*y1#)),vly#+((sin(vlrotation#)*x1#)+(cos(vlrotation#)*y1#)),vlx#+((cos(vlrotation#)*x2#)+(-sin(vlrotation#)*y2#)),vly#+((sin(vlrotation#)*x2#)+(cos(vlrotation#)*y2#))
endfunction

function vlstartpoly(x#,y#)
    global vlpolyx#=x#
    global vlpolyy#=y#
    global vlpolystartx#=x#
    global vlpolystarty#=y#
endfunction

function vlpolyline(x#,y#)
    line vlx#+((cos(vlrotation#)*vlpolyx#)+(-sin(vlrotation#)*vlpolyy#)),vly#+((sin(vlrotation#)*vlpolyx#)+(cos(vlrotation#)*vlpolyy#)),vlx#+((cos(vlrotation#)*x#)+(-sin(vlrotation#)*y#)),vly#+((sin(vlrotation#)*x#)+(cos(vlrotation#)*y#))
    vlpolyx#=x#
    vlpolyy#=y#
endfunction

function vlendpoly()
    line vlx#+((cos(vlrotation#)*vlpolyx#)+(-sin(vlrotation#)*vlpolyy#)),vly#+((sin(vlrotation#)*vlpolyx#)+(cos(vlrotation#)*vlpolyy#)),vlx#+((cos(vlrotation#)*vlpolystartx#)+(-sin(vlrotation#)*vlpolystarty#)),vly#+((sin(vlrotation#)*vlpolystartx#)+(cos(vlrotation#)*vlpolystarty#))
endfunction

function findsprite()
res=1
while sprite exist(res)=1
res=res+1
endwhile
endfunction res

function addmech(x#,y#,tx#,ty#,health#,shield#)
    array insert at bottom mechs(0)
    index=array count(mechs(0))-1
    mechs(index).x#=x#
    mechs(index).y#=y#
    mechs(index).rot#=0
    mechs(index).legmove#=0
    mechs(index).hp#=health#
    mechs(index).shield#=shield#
    mechs(index).maxshield#=shield#
    mechs(index).shieldregen#=0.2
    mechs(index).speed#=1.2
    mechs(index).ai.moving=1
    mechs(index).ai.entering=1
    mechs(index).ai.destx#=tx#
    mechs(index).ai.desty#=ty#
    
    mechs(index).rweapon=findsprite()
    sprite mechs(index).rweapon,0,0,1
    set sprite mechs(index).rweapon,0,1
    set sprite priority mechs(index).rweapon,3
    mechs(index).lweapon=findsprite()
    sprite mechs(index).lweapon,0,0,1
    set sprite mechs(index).lweapon,0,1
    set sprite priority mechs(index).lweapon,3
    
    mechs(index).body=findsprite()
    sprite mechs(index).body,0,0,1
    set sprite mechs(index).body,0,1
    set sprite priority mechs(index).body,2
    
    mechs(index).lfoot=findsprite()
    sprite mechs(index).lfoot,0,0,1
    set sprite mechs(index).lfoot,0,1
    set sprite priority mechs(index).lfoot,1
    mechs(index).rfoot=findsprite()
    sprite mechs(index).rfoot,0,0,1
    set sprite mechs(index).rfoot,0,1
    set sprite priority mechs(index).rfoot,1
    
    
    mechs(index).lleg=findsprite()
    sprite mechs(index).lleg,0,0,1
    set sprite mechs(index).lleg,0,1
    mechs(index).rleg=findsprite()
    sprite mechs(index).rleg,0,0,1
    set sprite mechs(index).rleg,0,1

    
    
    mechs(index).hpbar=findsprite()
    sprite mechs(index).hpbar,0,0,1
    set sprite mechs(index).hpbar,0,1
    
    mechs(index).sbar=findsprite()
    sprite mechs(index).sbar,0,0,1
    set sprite mechs(index).sbar,0,1
endfunction

function addbullet(owner,x#,y#,rot#,sourcesprite,distance,damage#,vel#,accel#,smoke#,hittype)
    array insert at bottom bullets(0)
    index=array count(bullets(0))-1
    bullets(index).x#=x#
    bullets(index).y#=y#
    bullets(index).rot#=rot#
    bullets(index).live=2
    bullets(index).distance=distance
    bullets(index).damage#=damage#
    bullets(index).vel#=vel#
    bullets(index).accel#=accel#
    bullets(index).owner=owner
    bullets(index).smoke#=smoke#
    bullets(index).hittype=hittype
    
    bullets(index).spritenum=findsprite()
    clone sprite sourcesprite,bullets(index).spritenum
    set sprite bullets(index).spritenum,0,1
    set sprite priority bullets(index).spritenum,10
    rotate sprite bullets(index).spritenum,bullets(index).rot#
    show sprite bullets(index).spritenum
endfunction


function addspark(x#,y#,speed#,angle#,life,delay,fadestart,fadein,fadeout,sourcesprite,scale,spin#,alpha,mechtie)
    array insert at bottom sparks(0)
    index=array count(sparks(0))-1
    sparks(index).x#=x#
    sparks(index).y#=y#
    sparks(index).speed#=speed#
    sparks(index).angle#=angle#
    sparks(index).life=life
    sparks(index).fadein=fadein
    sparks(index).fadeout=fadeout
    sparks(index).fadestart=fadestart
    sparks(index).spin#=spin#
    sparks(index).alpha=alpha
    sparks(index).delay=delay
    sparks(index).mechtie=mechtie
    
    sparks(index).spritenum=findsprite()
    clone sprite sourcesprite,sparks(index).spritenum
    set sprite sparks(index).spritenum,0,1
    set sprite priority sparks(index).spritenum,20
    rotate sprite sparks(index).spritenum,sparks(index).angle#
    scale sprite sparks(index).spritenum,scale
    hide sprite sparks(index).spritenum
    ret=sparks(index).spritenum
endfunction ret

function copysprite(source,target,x,y,rot#,ox#,oy#)
    offset sprite target,sprite offset x(source)+ox#,sprite offset y(source)+oy#
    rotate sprite target,rot#
    sprite target,x,y,sprite image(source)
endfunction

function floodfill(x,y,colour)
    lock pixels
    targetcolour=point(x,y)
    floodfillrec(x,y,targetcolour,colour)
    unlock pixels
endfunction

function floodfillrec(x,y,targetcolour,colour)
    if point(x,y)=targetcolour
        dot x,y,colour
        floodfillrec(x-1,y,targetcolour,colour)
        floodfillrec(x+1,y,targetcolour,colour)
        floodfillrec(x,y-1,targetcolour,colour)
        floodfillrec(x,y+1,targetcolour,colour)
    endif
endfunction

function frnd#(range#)
  ret#=rnd(range#*1000.0)/1000.0
endfunction ret#

function wrap180#(angle#)
    ret#=wrapvalue(angle#)
    if ret#>180 then ret#=ret#-360
    if ret#<-180 then ret#=ret#+360
endfunction ret#

function dist#(x#,y#)
ret#=sqrt((x#*x#)+(y#*y#))
endfunction ret#

function FillCircle( CX as integer, CY as integer, R as integer ) `Not mine!!! From somewhere on the DBPro forums
   local x as integer
   local y as integer
   local i as integer
   local s as integer

   s=R*0.70710678 : ` this number is sin(45) - precalculate!
   box CX-s, CY-s, CX+s+1, CY+s+1
   s=s+1 : ` Faster than 'inc s'?
   i=R*R
   for y=s to R
      x=sqrt( i-(y*y) )

      ` Draw top and bottom
      box CX-x, CY-y, CX+x+1, CY-y+1
      box CX-x, CY+y, CX+x+1, CY+y+1

      ` Draw left and right
      box CX-y, CY-x, CX-y+1, CY+x+1
      box CX+y, CY-x, CX+y+1, CY+x+1
   next y
endfunction