Sorry your browser is not supported!

[name]
name_of_level$

[player]
controller (1=arrowkeys 2=WASD), x, y, z
...

[ball]
x, y, z, xspeed, yspeed, zspeed
...

[generator]
x, y, z, shootdelay (60 = 1 second), shootspeedx, shootspeedy, shootspeedz
...

[goal]
goals_needed
x, y, z, size
...

[obstacle]
x, y, z, width, length, height
...

[camera]
zenith, azimuth, distance
x, y, z
spin_degrees
zoomedin_zenith, zoomedin_azimuth, zoomedin_distance

sync on
set display mode 1024, 768, 32

global keydown
keydown=1

randomize timer()
make_image(1,"Red",rgb(255,0,0))
make_image(2,"Green",rgb(0,255,0))
make_image(3,"Blue",rgb(0,0,255))
set text size 24

dim rps(3)
rps(1)=1
rps(2)=2
rps(3)=3


cls
center text 512, 300, "Instructions:  You have 15 seconds to match as many colors as possible."
center text 512, 350, "The top box shows the current color to match.  The bottom boxes remind you of your keys."
center text 512, 400, "Keys:  Red=Left Arrow, Green=Down Arrow, Blue=Right Arrow."
center text 512, 450, "Hitting the correct key adds a point.  Hitting an incorrect key subtacts a point."
center text 512, 500, "press any key to begin."
sync
sync
wait key

t=timer()
tt=t+15000

repeat

  cls
  sync
  wait 50
  t=timer()
  text 5,5, "score:  "+ str$(score)
  text 800,5, "time left: " + str$((tt-t)/1000)
  sync
`  wait 200
  a=rnd(2)+1
  paste image a, 362,20


  paste image 1, 30, 450
  paste image 2, 362, 450
  paste image 3, 694, 450


  sync
  k=get_input()
  if k=rps(a) then inc score else dec score
until t>tt

cls

center text 512, 324, "Time up!"
center text 512, 384, "Final Score:  " +str$(score)
center text 512, 444, "Press escape to exit"


sync
do
loop


Function make_image(num as integer, t$ as string, col as dword )
  ink col, 0
  box 0,0,300,300
  ink rgb(255,255,255), 0
  set text size 48
  set text font "arial"
  text 150- (text width(t$)/2), 150- (text height(t$)/2), t$
  get image num, 0,0,300,300,1
endfunction

function get_input()
  if keydown=1
  repeat
    s=scancode()
  until s=0
  endif

  repeat
    s=scancode()
  until s<>0
  keydown=1


  if s=203 then s=1 `left key.  Rock
  if s=208 then s=2 `up key.  Paper
  if s=205 then s=3 `right key. Scissors

endfunction s

Rem Project: User_Click
Rem Created: 4/30/2007 7:24:34 PM

Rem ***** Main Source File *****

`This is my entry to the DBP Apil-may 2007 challenge:
Start:
CLS
gosub setupWindow
gosub Instructions
`Start Loop
do
gosub Mouse
loop
`Endloop

`Subs
Mouse:
repeat
CLS
ink rgb(255,0,0),0 : box side,top,side2,bottum
set text transparent
ink rgb(255,255,255),0 : text 0,0,"Score: "+str$(score)
if mouseclick()=1 and mousex()=>side and mousex()=<side2 and mousey()=>top and mousey()=<bottum
CLS
score=score+10
   Side=rnd(10+550)
   top=rnd(10+350)
   side2=side+20
   bottum=top+20
      ink rgb(255,0,0),0
endif
  Elapsed=(Timer()-T)/1000
  TimeLeft=Seconds-Elapsed
  Text 0,20,Str$(TimeLeft)+" Seconds Left"
Until TimeLeft=0
if timeleft=0
   CLS
   center text screen width()/2,20,"Your Score Was: "+str$(score)
   center text screen width()/2,40,"Play again? y/n"
   set cursor screen width()/2-40,60 : input "> ";continue$
      if continue$="y" or continue$="Y" then goto Start
      if continue$="n" or continue$="N" then end
endif
return

Instructions:
randomize timer()
set text size 24 : set text font "arial"
center text screen width()/2,20,"Instructions"
set text size 18
line 100,57,540,57
center text screen width()/2,70,"Click the red squares to gain points"
center text screen width()/2,90,"The objective of the game is to get the highest score"
center text screen width()/2,110,"Press any key to begin"
line 100,140,540,140
wait key
CLS
   Side=rnd(10+550)
   top=rnd(10+350)
   side2=side+20
   bottum=top+20
      ink rgb(255,0,0),0
      box side,top,side2,bottum
return

setupWindow:
T=Timer()
Seconds=20: Rem change this value to alter the length of the timer
score=0
set window on
set window size 700,500
set window title "Apil - May 2007 DBP User reaction entry"
set window position screen width()/2+150,screen height()/2+100
return

REM ***************
REM Target Practice
REM Author: Phaelax
REM ***************

sync on
sync rate 40
hide mouse
randomize timer()

fastest = 99999
nuts = 0
headshots = 0

gx = rnd(610)+15
gy = rnd(400)+60

color as dword
color = rgb(rnd(128)+128,rnd(128)+128,rnd(128)+128)

bodies = 0

DO
   cls

   timerz = timer()

   if blowup = 0 then bonus = 4000-(timerz - timestamp)

   if timerz > timestamp+4000 or t# > 18
      inc bodies
      timestamp = timer()
      gx = rnd(610)+15
      gy = rnd(400)+60
      t# = 0
      blowup = 0
   color = rgb(rnd(128)+128,rnd(128)+128,rnd(128)+128)
   endif

   if mouseclick() = 1 and flag = 0
      flag = 1
      if mouseWithin(gx-15,gy-60,gx+15,gy+20)
         d = (mousex()-gx)^2 + (mousey()-(gy-50))^2
         if d <= 100
            inc headshots
            inc score, 1000
            headFlag = 1
            headTimer = timer()
         endif

         d = (mousex()-gx)^2 + (mousey()-gy)^2
         if d <= 70
            inc nuts
            dec score, 5000
            nutFlag = 1
            nutTimer = timer()
         endif
         blowup = 1
         inc score, bonus
         inc hits
         totalTime = totalTime + (timerz-timestamp)
         avgSpeed = totalTime/bodies
         if timerz-timestamp < fastest then fastest = timerz-timestamp
      else
         inc misses
         dec score, 500
      endif
   endif

   if mouseclick() = 0 then flag = 0

   if blowup = 1 then inc t#,0.3

   ink color,0
   draw_guy(gx,gy,t#)

   if nutFlag = 1
      center text 320,46,"Disrespectful nut shot!  -5000"
      if nutTimer+4000 < timer() then nutFlag = 0
   endif

   if headFlag = 1
      center text 320,62,"Head shot!  +1000"
      if headTimer+4000 < timer() then headFlag = 0
   endif


   rem draw mouse cursor
   mx = mousex()
   my = mousey()
   ink rgb(0,255,0),0
   line mx-5,my,mx+5,my
   line mx,my-5,mx,my+5

   rem calculate accuracy
   if hits+misses = 0
      acc = 0
   else
      acc = (hits/(hits+misses+0.0))*100.0
   endif

   center text 320,10,str$(bonus)
   center text 320,30,"Round "+str$(bodies)

   set cursor 0,0
   print "Score: ",score
   print "Hits: ",hits
   print "Misses: ",misses
   print "Accuracy: ",acc,"%"
   print "Fastest Time: ",fastest
   print "Average Speed: ", avgSpeed
   print "Head Shots: ", headshots
   print "Disrespectful Hits: ", nuts

   sync
LOOP



function draw_guy(x as integer, y as integer, t as float)
   g# = -4.0
   v = 20

   if t > 0
      x1 = x+v*cos(270)*t
      y1 = y+(v*sin(270)*t - 0.5*g#*t^2)
      x2 = x+v*cos(300)*t
      y2 = y+(v*sin(300)*t - 0.5*g#*t^2)
      x3 = x+v*cos(225)*t
      y3 = y+(v*sin(225)*t - 0.5*g#*t^2)
      x4 = x+v*cos(315)*t
      y4 = y+(v*sin(315)*t - 0.5*g#*t^2)
      x5 = x+v*cos(180)*t
      y5 = y+(v*sin(180)*t - 0.5*g#*t^2)
      x6 = x+v*cos(0)*t
      y6 = y+(v*sin(0)*t - 0.5*g#*t^2)
      draw_head(x1,y1)
      draw_body(x2,y2)
      draw_leftArm(x3,y3)
      draw_rightArm(x4,y4)
      draw_leftLeg(x5,y5)
      draw_rightLeg(x6,y6)
   else
      draw_head(x,y)
      draw_body(x,y)
      draw_leftArm(x,y)
      draw_rightArm(x,y)
      draw_leftLeg(x,y)
      draw_rightLeg(x,y)
   endif

endfunction




function draw_head(x,y)
   circle x,y-50,10
endfunction


function draw_leftArm(x,y)
   line x,y-34,x-10,y-20
endfunction


function draw_rightArm(x,y)
   line x,y-34,x+10,y-20
endfunction


function draw_leftLeg(x,y)
   line x,y,x-15,y+20
endfunction


function draw_rightLeg(x,y)
   line x,y,x+15,y+20
endfunction


function draw_body(x,y)
   line x,y,x,y-40
endfunction


function mouseWithin(x1,y1,x2,y2)
   if mousex() > x1 and mousex() < x2 and mousey() > y1 and mousey() < y2 then exitfunction 1
endfunction 0

REM Project: AGH
REM Created: 5/3/2007 2:54:16 PM
REM
REM ***** Main Source File *****
REM

SET DISPLAY MODE 1024, 768, 32

INK RGB(50, 50, 0), 0
BOX 1, 1, 65, 65
GET IMAGE 1, 1, 1, 65, 65, 1
CLS 0
INK RGB(255, 255, 0), 0
FOR i = 0 to 6
   LINE 1, 15+i, 9, 1+i
   LINE 9, 1+i, 17, 15+i
   INK RGB(255-(30*i), 255-(30*i), 0), 0
NEXT i
GET IMAGE 2, 1, 1, 17, 20, 1
CLS 0
INK RGB(255, 255, 255), 0
FOR i = 1 to 5
   ELLIPSE 5, 5, i, i
   INK RGB(255-(30*i), 255-(30*i), 255-(30*i)), 0
NEXT i
GET IMAGE 3, 1, 1, 11, 11, 1
CLS 0
INK RGB(255, 0, 0), 0
FOR i = 1 to 5
   ELLIPSE 5, 5, i, i
   INK RGB(255-(30*i), 0, 0), 0
NEXT i
GET IMAGE 4, 1, 1, 11, 11, 1
CLS 0
INK RGB(255, 255, 255), 0
LINE 8,1,8,17
LINE 9,1,9,17
LINE 1,8,17,8
LINE 1,9,17,9
GET IMAGE 5, 1, 1, 17, 17, 1
CLS 0
INK RGB(255, 0, 0), 0
LINE 8,1,8,17
LINE 9,1,9,17
LINE 1,8,17,8
LINE 1,9,17,9
GET IMAGE 6, 1, 1, 17, 17, 6
CLS 0
INK RGB(255, 255, 255), 0

SYNC ON : HIDE MOUSE : AUTOCAM OFF : SYNC RATE 60

REPEAT
   CENTER TEXT SCREEN WIDTH()/2, 150, "Holy BANANANAS. You are Ron Gollinplecker and you have been appointed"
   CENTER TEXT SCREEN WIDTH()/2, 165, "this team's Sphere Exterminator. Your Extermispheretron 6816 vaporiz-"
   CENTER TEXT SCREEN WIDTH()/2, 180, "zles spheres into next Christmas. It has a varying range based on the"
   CENTER TEXT SCREEN WIDTH()/2, 195, "intensity of the targeted sphere's longing and desire for an end to -"
   CENTER TEXT SCREEN WIDTH()/2, 210, "its misphery. Shoot quickly, dear Gollinplecker, for the window is a-"
   CENTER TEXT SCREEN WIDTH()/2, 225, "ll too short, and you wouldn't want to be gobbled and.. spheregested."
   CENTER TEXT SCREEN WIDTH()/2, 275, "PRESS ENTER TO CONTINUE. MOOSE."
   CENTER TEXT SCREEN WIDTH()/2, 325, "Oh yeah, and if you misfire, you lose your weapon for some seconds..."
   SYNC
UNTIL RETURNKEY() = 1

GLOBAL dTimer
GLOBAL loopTime
GLOBAL lastTime
GLOBAL grav#
GLOBAL mouseSens#
GLOBAL jumpVel#
GLOBAL jump
GLOBAL jumpFwd
GLOBAL jumpBack
GLOBAL jumpLeft
GLOBAL jumpRight
GLOBAL moving
GLOBAL hp

TYPE killBall
   dist AS FLOAT
   startDist AS FLOAT
   up AS INTEGER
   spr AS INTEGER
   redSpr AS INTEGER
   obj AS INTEGER
   speed AS FLOAT
   killMin AS FLOAT
   killMax AS FLOAT
   KILL as INTEGER
ENDTYPE

DIM killBalls(20) AS killball

FOR i = 1 TO 20
   killBalls(i).up = 0
   killBalls(i).spr = 0
   killBalls(i).redSpr = 0
   killBalls(i).obj = 0
   killBalls(i).KILL = 0
NEXT i

UpdateDelta()

COLOR BACKDROP RGB(150, 150, 255)
MAKE OBJECT SPHERE 1000, 1
HIDE OBJECT 1000

MAKE OBJECT BOX 999, 500, 1, 500
COLOR OBJECT 999, RGB(50, 50, 0)
MAKE OBJECT BOX 998, 500, 1, 500
POSITION OBJECT 998, 0, 300, 0
GHOST OBJECT ON 998

`MAKE-A DA GUN
MAKE OBJECT CYLINDER 1001, 5
MAKE OBJECT BOX 1002, 1, 0.1, 2
MAKE MESH FROM OBJECT 1, 1002
ADD LIMB 1001, 1, 1
OFFSET LIMB 1001, 1, 0, 2, -3
SCALE OBJECT 1001, 20, 100, 20
COLOR OBJECT 1001, 0
COLOR LIMB 1001, 1, RGB(50, 50, 50)
XROTATE OBJECT 1001, 90
LOCK OBJECT ON 1001
POSITION OBJECT 1001, 1, -2, 2
DELETE OBJECT 1002
SET AMBIENT LIGHT 20


FOR i = 1 TO 20
   MAKE OBJECT BOX i, 5, 500, 5
   COLOR OBJECT i, RGB(255, 0, 0)
   GHOST OBJECT ON i
NEXT i

FOR i = 1 TO 5
   POSITION OBJECT i, -250, 50, -250+(i-1)*100
NEXT i

FOR i = 6 TO 10
   POSITION OBJECT i, 250, 50, 250-(i-6)*100
NEXT i

FOR i = 11 TO 15
   POSITION OBJECT i, -250+(i-11)*100, 50, 250
NEXT i

FOR i = 16 TO 20
   POSITION OBJECT i, 250-(i-16)*100, 50, -250
NEXT i


POSITION CAMERA 0, 15, 0

grav# = 0.1
mouseSens# = 0.2
killInterval = 3000
gunInterval = 5000
gunTimer = 0
hp = 5
score = 0
SPRITE 1, SCREEN WIDTH()-100, SCREEN HEIGHT()-100, 1
SPRITE 2, SCREEN WIDTH()-100, SCREEN HEIGHT()-100, 2
SPRITE 3, -30, -30, 3
SPRITE 4, -40, -40, 4
SPRITE 5, SCREEN WIDTH()/2-8, SCREEN HEIGHT()/2-8, 5
SPRITE 6, SCREEN WIDTH()/2-8, SCREEN HEIGHT()/2-8, 6
HIDE SPRITE 6


killTime = TIMER()

REPEAT
   UpdateDelta()
   MouseMove()
   PlayerMove()
   TEXT 5, 5, "LIFE FORCE:"
   BOX 100, 5, 200, 20, RGB(110, 0, 0), RGB(110, 0, 0), RGB(110, 0, 0), RGB(110, 0, 0)
   BOX 100, 5, 100+(hp*20), 20, RGB(255, 0, 0), RGB(255, 0, 0), RGB(255, 0, 0), RGB(255, 0, 0)
   TEXT 5, 20, "SCORE: "+STR$(score)
   IF (TIMER() - killTime) > killInterval
      MakeKillBall(1.0, 200.0, 30.0)
      killTime = TIMER()
   ENDIF
   IF gunTimer = 1
      IF (TIMER() - gunTime) > gunInterval
         SHOW OBJECT 1001
         SHOW SPRITE 5
         gunTimer = 0
      ENDIF
   ELSE
      pick = PICK OBJECT(SCREEN WIDTH()/2, SCREEN HEIGHT()/2, 21, 40)
      kb = 0
      HIDE SPRITE 6
      SHOW SPRITE 5
      onTarget = 0
      IF pick <> 0
         kb = GetKillBallByObj(pick)
         IF killBalls(kb).KILL = 1
            HIDE SPRITE 5
            SHOW SPRITE 6
            onTarget = 1
         ENDIF
      ENDIF
      IF MOUSECLICK() = 1 AND clicked = 0
         IF onTarget = 1
            DestroyKillBall(kb)
            INC score
         ELSE
            HIDE OBJECT 1001
            HIDE SPRITE 5
            HIDE SPRITE 6
            gunTimer = 1
            gunTime = TIMER()
         ENDIF
      ENDIF
      clicked = MOUSECLICK()
   ENDIF
   IF moving = 1
      POSITION OBJECT 1001, 2, -2, 2+SIN(TIMER())*0.2
   ELSE
      POSITION OBJECT 1001, 2, -2, 2
   ENDIF
   `TEXT 5, 5, "FPS: "+STR$(SCREEN FPS())
   SYNC
UNTIL hp <= 0

COLOR BACKDROP 0
REPEAT
   CENTER TEXT SCREEN WIDTH()/2, 150, "BOOOOO!"
   CENTER TEXT SCREEN WIDTH()/2, 250, "SCORE: "+STR$(score)
   CENTER TEXT SCREEN WIDTH()/2, 350, "PRESS ENTER"
   SYNC
UNTIL RETURNKEY()=1

END

FUNCTION MakeKillBall(spd#, startD#, kdist#)
   nextBall = NextKillBall()
   IF nextBall <> -1
      killBalls(nextBall).up = 1
      killBalls(nextBall).dist = 1.0
      killBalls(nextBall).spr = NextSprite()
      CLONE SPRITE 3, killBalls(nextBall).spr
      killBalls(nextBall).redSpr = NextSprite()
      CLONE SPRITE 4, killBalls(nextBall).redSpr
      killBalls(nextBall).obj = NextObj()
      MAKE OBJECT SPHERE killBalls(nextBall).obj, 10
      SET OBJECT SPECULAR killBalls(nextBall).obj, RGB(200, 200, 200)
      killBalls(nextBall).speed = spd#
      kmax# = RND(30.0)+30.0
      killBalls(nextBall).killMin = kmax# - kdist#
      killBalls(nextBall).killMax = kmax#
      killBalls(nextBall).startDist = startD#
      ROTATE OBJECT killBalls(nextBall).obj, WRAPVALUE(RND(80)+270), WRAPVALUE(RND(360)), 0.0
      MOVE OBJECT killBalls(nextBall).obj, startD#
   ENDIF
ENDFUNCTION

FUNCTION DestroyKillBall(b)
   IF killBalls(b).up = 1
      killBalls(b).up = 0
      DELETE SPRITE killBalls(b).spr
      DELETE SPRITE killBalls(b).redSpr
      DELETE OBJECT killBalls(b).obj
      killBalls(b).spr = 0
      killBalls(b).redSpr = 0
      killBalls(b).obj = 0
      killBalls(b).KILL = 0
   ENDIF
ENDFUNCTION

FUNCTION MouseMove()
   XROTATE CAMERA CAMERA ANGLE X()+MOUSEMOVEY()*mouseSens#
   YROTATE CAMERA WRAPVALUE(CAMERA ANGLE Y()+MOUSEMOVEX()*mouseSens#)
   IF CAMERA ANGLE X() > 25.0 THEN XROTATE CAMERA 25.0
   IF CAMERA ANGLE X() < -90.0 THEN XROTATE CAMERA -90.0
ENDFUNCTION

FUNCTION PlayerMove()
   plSpeed# = 2.0
   xAng# = CAMERA ANGLE X()
   yAng# = CAMERA ANGLE Y()
   zAng# = 0.0
   tplPosX# = CAMERA POSITION X()
   tplPosY# = CAMERA POSITION Y()
   tplPosZ# = CAMERA POSITION Z()
   IF jump = 0
      ROTATE CAMERA 0, YAng#, 0
      IF KEYSTATE(17) = 1 THEN MOVE CAMERA Delta(plSpeed#)
      IF KEYSTATE(31) = 1 THEN MOVE CAMERA Delta((plSpeed#/2)*-1)
      IF KEYSTATE(30) = 1
         YROTATE CAMERA yAng#-90
         tSpd# = plSpeed#
         IF KEYSTATE(17) = 1 THEN tSpd# = tSpd#/2
         MOVE CAMERA Delta(tSpd#)
         YROTATE CAMERA yAng#+90
      ENDIF
      IF KEYSTATE(32) = 1
         YROTATE CAMERA yAng#-90
         tSpd# = plSpeed#
         IF KEYSTATE(17) = 1 THEN tSpd# = tSpd#/2
         MOVE CAMERA Delta(tSpd#*-1)
         YROTATE CAMERA yAng#+90
      ENDIF
      ROTATE CAMERA xAng#, yAng#, zAng#
   ELSE
      IF jumpFwd = 1 THEN MOVE OBJECT 1000, Delta(plSpeed#)
      IF jumpBack = 1 THEN MOVE OBJECT 1000, Delta((plSpeed#/2)*-1)
      IF jumpLeft = 1
         YROTATE OBJECT 1000, OBJECT ANGLE Y(1000)-90
         tSpd# = plSpeed#
         IF jumpFwd = 1 THEN tSpd# = plSpeed#/2
         MOVE OBJECT 1000, Delta(tSpd#)
         YROTATE OBJECT 1000, OBJECT ANGLE Y(1000)+90
      ENDIF
      IF jumpRight = 1
         YROTATE OBJECT 1000, OBJECT ANGLE Y(1000)-90
         tSpd# = plSpeed#
         IF jumpFwd = 1 THEN tSpd# = plSpeed#/2
         MOVE OBJECT 1000, Delta(tSpd#*-1)
         YROTATE OBJECT 1000, OBJECT ANGLE Y(1000)+90
      ENDIF
      POSITION CAMERA OBJECT POSITION X(1000), CAMERA POSITION Y(), OBJECT POSITION Z(1000)
   ENDIF
   plPosX# = CAMERA POSITION X()
   plPosY# = CAMERA POSITION Y()
   plPosZ# = CAMERA POSITION Z()
   moving = 0
   IF (tplPosX#+tplPosY#+tplPosZ#) <> (plPosX#+plPosY#+plPosZ#) THEN moving = 1
   IF KEYSTATE(57) = 1 AND jump = 0
      jump = 1
      jumpVel# = 2.5
      jumpFwd = KEYSTATE(17)
      jumpBack = KEYSTATE(31)
      jumpLeft = KEYSTATE(30)
      jumpRight = KEYSTATE(32)
      ROTATE OBJECT 1000, xAng#, yAng#, zAng#
   ENDIF


   DEC jumpVel#, Delta(grav#)
   INC plPosY#, Delta(jumpVel#)
   IF plPosY# < 15 THEN plPosY# = 15 : jump = 0 : jumpFwd = 0 : jumpBack = 0 : jumpLeft = 0 : jumpRight = 0

   IF plPosX# < -250 THEN plPosX# = -250
   IF plPosX# > 250 THEN plPosX# = 250
   IF plPosZ# < -250 THEN plPosZ# = -250
   IF plPosZ# > 250 THEN plPosZ# = 250

   POSITION CAMERA plPosX#, plPosY#, plPosZ#
   POSITION OBJECT 1000, plPosX#, plPosY#, plPosZ#
   FOR i = 1 to 20
      IF killBalls(i).up = 1
         POINT OBJECT killBalls(i).obj, plPosX#, plPosY#, plPosZ#
         killBalls(i).dist = ObjectXYZDistance(1000, killBalls(i).obj)
         tKBSpd# = (killBalls(i).startDist - killBalls(i).dist)*0.011
         `TEXT 5, 25, "SPD: "+STR$(tKBSpd#)+" "+STR$(killBalls(i).speed)
         IF tKBSpd# < killBalls(i).speed THEN tKBSpd# = killBalls(i).speed
         `TEXT 5, 45, "SPD: "+STR$(tKBSpd#)+" "+STR$(killBalls(i).speed)
         MOVE OBJECT killBalls(i).obj, Delta(tKBSpd#)
         IF killBalls(i).dist <= killBalls(i).killMax AND killBalls(i).dist >= killBalls(i).killMin
            IF killBalls(i).KILL = 0
               HIDE SPRITE killBalls(i).spr
               SHOW SPRITE killBalls(i).redSpr
               COLOR OBJECT killBalls(i).obj, RGB(255, 0, 0)
            ENDIF
            CENTER TEXT OBJECT SCREEN X(killBalls(i).obj), OBJECT SCREEN Y(killBalls(i).obj), "KILL ME!!"
            gooSpr = 4
            killBalls(i).KILL = 1
            tSpr = killBalls(i).redSpr
         ELSE
            IF killBalls(i).KILL = 1
               SHOW SPRITE killBalls(i).spr
               HIDE SPRITE killBalls(i).redSpr
               COLOR OBJECT killBalls(i).obj, RGB(255, 255, 255)
            ENDIF
            gooSpr = 3
            killBalls(i).KILL = 0
            tSpr = killBalls(i).spr
         ENDIF
         SPRITE tSpr, SPRITE X(2), SPRITE Y(2), gooSpr
         ROTATE SPRITE tSpr, WRAPVALUE(yAng# - OBJECT ANGLE Y(killBalls(i).obj))*-1
         MOVE SPRITE tSpr, INT(ObjectXZDistance(1000, killBalls(i).obj)/7.8125)*-1
         OFFSET SPRITE tSpr, 5, 5
         IF killBalls(i).dist <= 1.0 THEN DestroyKillBall(i) : DEC hp
      ENDIF
   NEXT i
   `TEXT 5, 65, STR$(WRAPVALUE(xAng#))
   mapOffsetX = 32+INT(plPosX#/8)
   mapOffsetY = 32-INT(plPosZ#/8)
   OFFSET SPRITE 2, 8, 10
   OFFSET SPRITE 1, mapOffsetX, mapOffsetY
   ROTATE SPRITE 1, yAng#*-1
ENDFUNCTION

FUNCTION UpdateDelta()
   dTimer = TIMER()
   loopTime = dTimer-lastTime
   lastTime= dTimer
ENDFUNCTION

FUNCTION Delta(val#)
   res# = val#*0.060*loopTime
ENDFUNCTION res#

FUNCTION ObjectXZDistance(obj1, obj2)
   dx# = OBJECT POSITION X(obj2)-OBJECT POSITION X(obj1)
   dz# = OBJECT POSITION Z(obj2)-OBJECT POSITION Z(obj1)
   res# = SQRT(dx#*dx# + dz#*dz#)
ENDFUNCTION res#

FUNCTION ObjectXYZDistance(obj1, obj2)
   dx# = OBJECT POSITION X(obj2)-OBJECT POSITION X(obj1)
   dy# = OBJECT POSITION Y(obj2)-OBJECT POSITION Y(obj1)
   dz# = OBJECT POSITION Z(obj2)-OBJECT POSITION Z(obj1)
   res# = SQRT(dx#*dx# + dy#*dy# + dz#*dz#)
ENDFUNCTION res#

FUNCTION NextSprite()
   FOR i = 1 TO 65535
      IF SPRITE EXIST(i) = 0 THEN res = i : EXIT
   NEXT i
ENDFUNCTION res

FUNCTION NextObj()
   FOR i = 1 TO 65535
      IF OBJECT EXIST(i) = 0 THEN res = i : EXIT
   NEXT i
ENDFUNCTION res

FUNCTION NextKillBall()
   res = -1
   FOR i = 1 TO 20
      IF killBalls(i).up = 0 THEN res = i : EXIT
   NEXT i
ENDFUNCTION res

FUNCTION GetKillBallByObj(obj)
   res = 0
   FOR i = 1 TO 20
      IF killBalls(i).obj = obj THEN res = i : EXIT
   NEXT i
ENDFUNCTION res

sync on:sync rate 120
sync
make camera 1
color backdrop 1,0

set text font "Times New Roman"
set text size 50

global sw
global sh
global wins
global finaltime
global time

sw=screen width()
sh=screen height()
finaltime=1000

center text sw/2,sh/2-200,"Wait until it says draw, then hit space"
sync
wait key


do


   walk()

   shoot()

   finaltime=finaltime*8
   finaltime=finaltime/10


loop

function with_gun(x,direction)

   for k=1 to 460 step 8
      i=20
      if direction=-1
         stick_figure(sw/2+x,sh/2,i)
         stick_figure(sw/2+x-480,sh/2,i)
      else
         stick_figure(sw/2-x,sh/2,i)
         stick_figure(sw/2-x+480,sh/2,i)
      endif

      gun(20*direction+sw/2+(x)*-direction,sh/2+50-15,direction)

      fire(20*direction+sw/2+(x)*-direction+k*direction,sh/2+50-15)

      center text sw/2,sh/2,str$(time)

      sync
   next k

endfunction

function fire(x,y)

   circle x,y,5

endfunction

function gun(x,y,direction)


   line x,y,x+30*direction,y
   line x+30*direction,y,x+30*direction,y+5
   line x+5*direction,y+5,x+30*direction,y+5
   line x,y,x,y+15
   line x+5*direction,y+5,x+5*direction,y+15
   line x,y+15,x+5*direction,y+15

endfunction

function shoot()

   center text sw/2,sh/2,"DRAW"

   x=240
   i=0
   stick_figure(sw/2+50+i+x,sh/2,i)
   stick_figure(sw/2-50-i-x,sh/2,i)

   sync

   if spacekey()
      space=2
   endif

   t1=timer()

   time=0

   repeat

      if spacekey()
         if space<>2
            space=1
         endif
      else
         space=0
      endif

      time=timer()-t1

      `center text sw/2,sh/2,str$(time)
      `sync

   until space=1 or time>finaltime

   if time>finaltime
      with_gun(sw/2-240,-1)
      You_loose()
   else
      with_gun(sw/2-240,1)
      wins=wins+1
   endif

endfunction

function you_loose()

   cls
   center text sw/2,sh/2,"You won "+str$(wins)+" times"
   sync
   wait key

   end

endfunction

function walk()

for k=1 to 3
   for j=1 to 2
      for i=1 to 40
         `cls
         stick_figure(sw/2+50+i+x,sh/2,i)
         stick_figure(sw/2-50-i-x,sh/2,i)
         text 0,0,"Wins "+str$(wins)
         sync
      next i

      x=x+40

   next j
   center text sw/2,sh/2,str$(k)

   i=0
   stick_figure(sw/2+50+i+x,sh/2,i)
   stick_figure(sw/2-50-i-x,sh/2,i)

   text 0,0,"Wins "+str$(wins)

   sync
   wait 500
next k

while rnd(1000)<>0:wait 1:endwhile

endfunction

function stick_figure(x,y,frame)

   xshift=abs(frame-20)

   circle x,y,20

   line x,y+20,x,y+80
   line x-20+xshift,y+50,x,y+30
   line x+20-xshift,y+50,x,y+30
   line x-20+xshift,y+110,x,y+80
   line x+20-xshift,y+110,x,y+80

endfunction

Jimmy
The FPS style of the game keeps you on your toes by throwing deadly spheres at you from every direction

Spopovich
It really pushes your reflexes to the limit by making you shoot him before he shoots you.