Sorry your browser is not supported!

Pricey, because he met every requirement of the challenge perfectly, and had lots of extras too, such as good collision, and I love the eyes on all the people :P. Also, the animated walking was a nice touch

ThinkDigital, because it was an excellent game, but unfortunately one of the few people who could do better entered this challenge as well.

REM Traffic Simulation
REM By qwe

REM Ini
sync on
sync rate 45
set display mode 1024, 768, 32
set window on
autocam off

REM Set
global maxcars as integer : maxcars = 50
global gridsize as integer : gridsize = 8
set camera range 1.0, 500.0

REM Typ
type cars
	x as float
	z as float
	a as float
	v as float
	tox as float
	toy as float
	to as integer
	zone as integer
	o as integer
endtype

type zones
	enter_x as float
	enter_y as float
	to as integer
	stop as boolean
endtype

type stoplights
	to as integer
	i as integer
	ra as integer
	rb as integer
	rc as integer
	g as integer
	y as integer
endtype

type clouds
	offx as float
	offz as float
	o as integer
endtype

REM Var
global stoplight_green_time as integer : stoplight_green_time = 300
global stoplight_yellow_time as integer : stoplight_yellow_time = 60
global character_height as float : character_height = 2.0
global cam_mode : cam_mode = 1
global obj_sidewalkgrass
global img_road
global mc
global oldmc
global keytab
global oldkeytab
global obj_sun
global low_bound as float : low_bound = 100.0-5.0
global high_bound as float : high_bound = ((gridsize-1)*100.0) + 5.0
global maxclouds as integer : maxclouds = 5

REM Arr
DIM s(gridsize, gridsize) as stoplights
DIM c(maxcars) as cars
DIM cloud(maxclouds) as clouds
DIM l(4) as string

REM Load
loading(0, "Initializing")
load_sidewalkgrass()
loading(1, "Loading Roads")
place_roads()
loading(2, "Loading Stoplights and Buildings")
place_stoplights()
loading(3, "Loading Cars")
place_cars()
loading(4, "Loading environment")
place_clouds()
color backdrop rgb(128, 255, 255)
position camera ((gridsize/2.0) * 100.0)-50.0, character_height, ((gridsize/2.0) * 100.0)-50.0

REM Main
do
	set cursor 0,0
	print "FPS: "; screen fps()
	print "Press tab to toggle WALK / ZOOM"
	print "Press enter/+ on numpad to toggle FPS"
	print "WASD moves, Right-Click Looks"
	
	mouse_control()
	run_stoplights()
	run_cars()
	run_clouds()
	if cam_mode = 1 then run_collision()
	
	sync
loop

function run_collision()
	local dist2 as float
	local dx as float
	local dz as float
	local cx as float
	local cz as float
	local ox as float
	local oz as float
	
	REM Var
	cx = camera position x()
	cz = camera position z()
	
	REM Bound camera within map
	if camera position x() < low_bound then position camera low_bound, camera position y(), camera position z()
	if camera position z() < low_bound then position camera camera position x(), camera position y(), low_bound
	if camera position x() > high_bound then position camera high_bound, camera position y(), camera position z()
	if camera position z() > high_bound then position camera camera position x(), camera position y(), high_bound
	
	
	REM Box collision with buildings
	for x = 0 to gridsize
		for y = 0 to gridsize
			
			ox = x*100-50
			oz = y*100-50
			
			dx = cx - ox
			dz = cz - oz
			
			dist2 = dx*dx + dz*dz
			
			`do collision if distance is less than 100 units
			if dist2 < 10000 then boxcol(cx, cz, ox, oz, 42, 42)
			
		next y
	next x
	
	REM Box collision with cars
	for i = 0 to maxcars
		
		ox = object position x(c(i).o)
		oz = object position z(c(i).o)
		
		dx = cx - ox
		dz = cz - oz
		
		dist2 = dx*dx + dz*dz
		
		if dist2 < 100 ` if distance to car is less than 10
			
			if c(i).to = 0 or c(i).to = 2
				`facing z directoin
				boxcol(cx, cz, ox, oz, 2.0, 3.0)
			endif
			if c(i).to = 1 or c(i).to = 3
				`facing x direction
				boxcol(cx, cz, ox, oz, 3.0, 2.0)
			endif
			
		endif
		
	next i
	
endfunction

function boxcol(cx as float, cz as float, ox as float, oz as float, xr as float, zr as float)			
	if cx > ox - xr
		if cx < ox + xr
			if cz > oz - zr
				if cz < oz + zr
					
					za# = abs(cz - oz+zr)
					zc# = abs(cz - oz-zr)
					
					xb# = abs(cx - ox+xr)
					xd# = abs(cx - ox-xr)
					
					a = get_smallest_of_4_floats(za#, zc#, xb#, xd#)
					
					if a = 0
						position camera camera position x(), camera position y(), oz - zr
					endif
					if a = 1
						position camera camera position x(), camera position y(), oz + zr
					endif
					if a = 2
						position camera ox - xr, camera position y(), camera position z()
					endif
					if a = 3
						position camera ox + xr, camera position y(), camera position z()
					endif
					
				endif
			endif
		endif
	endif
endfunction

function get_smallest_of_4_floats(a as float, b as float, c as float, d as float)
	
	if a < b and a < c and a < d then e = 0
	if b < a and b < c and b < d then e = 1
	if c < a and c < b and c < d then e = 2
	if d < a and d < b and d < c then e = 3
	
endfunction e

function run_stoplights()
	for a = 0 to gridsize
		for b = 0 to gridsize
			
			dec s(a, b).i
			
			if s(a, b).i = stoplight_yellow_time
				show object s(a, b).y
				hide object s(a, b).g
			endif
			
			if s(a, b).i = 0
				s(a, b).i = stoplight_green_time
				inc s(a, b).to
				if s(a, b).to = 4 then s(a, b).to = 0
				hide object s(a, b).y
				show object s(a, b).g
				set_stoplight_object(a, b)
			endif
			
		next b
	next a
endfunction

function run_cars()
	for i = 0 to maxcars
		
		if keystate(2) = 1 then move object c(i).o, 0.1
		
	next i
endfunction

function place_cars()
	local rndxpos as float
	local rndzpos as float
	
	for i = 0 to maxcars
		REM Make car object
		c(i).o = free_obj()
		o = c(i).o
		make object box o, 2, 1, 4
		
		REM Get random direction and position
		rndpos = rnd(gridsize * 100)
		rndlane = rnd(gridsize)
		
		face = rnd(3)
		if face = 0`posz
			yrotate object o, 0
			rndxpos = rndlane*100-2.5
			rndzpos = rndpos
		endif
		if face = 1`negx
			yrotate object o, 90
			rndxpos = rndpos
			rndzpos = rndlane*100-2.5
		endif
		if face = 2`negz
			yrotate object o, 180
			rndxpos = rndlane*100+2.5
			rndzpos = rndpos
		endif
		if face = 3`posx
			yrotate object o, 270
			rndxpos = rndpos
			rndzpos = rndlane*100+2.5
		endif
		
		position object o, rndxpos, 0.75, rndzpos
		c(i).x = object position x(o)
		c(i).z = object position z(o)
		c(i).a = object angle y(o)
		c(i).to = face
	next i
endfunction

function place_roads()
	local x as float
	local y as float
	
	REM Load source objects
	
	`texture
	img_road = free_img()
	texture(0, 0, 64, 64, 128, 128, 128)
	get image img_road, 0, 0, 64, 64
	
	` Road to right
	obj_right = free_obj()
	make object plain obj_right, 90, 10
	set object cull obj_right, 1
	hide object obj_right
	texture object obj_right, img_road
	scale object texture obj_right, 9, 1
			
	` Road to bottom
	obj_bottom = free_obj()
	make object plain obj_bottom, 10, 90
	set object cull obj_bottom, 1
	hide object obj_bottom
	texture object obj_bottom, img_road
	scale object texture obj_bottom, 1, 9
	
	` streetlight
	o = free_obj()
	make object box o, 0.4, 10, 0.4
	position object o, 0, 5, 0
	inc o
	make object box o, 0.4, 0.4, 2.0
	position object o, 0, 9.8, 1.2
	inc o
	make object box o, 1.0, 0.4, 1.0
	position object o, 0, 9.8, 2.7
	inc o
	make object box o, 90, 0.05, 0.05
	position object o, 0, 9.8, 1.5
	
	obj_streetlight = free_obj()
	merge_objects(o-3, o, obj_streetlight)
	hide object obj_streetlight
	color object obj_streetlight, rgb(192,192,192)
	
	
	
	REM Load instances
	
	for a = 0 to gridsize-1
		for b = 0 to gridsize-1
			
			x = a * 100
			y = b * 100
			
			` Road to right
			o = free_obj()
			instance object o, obj_right
			position object o, x+50, 0, y
			rotate object o, 90, 0, 0
			
			` Road to bottom
			o = free_obj()
			instance object o, obj_bottom
			position object o, x, 0, y+50
			rotate object o, 90, 0, 0
			
			`Streetlight right
			o = free_obj()
			instance object o, obj_streetlight
			position object o, x+33, 0, y-6.0
			
			`Streetlight right
			o = free_obj()
			instance object o, obj_streetlight
			position object o, x+66, 0, y-6.0
			
			`Streetlight bottom
			o = free_obj()
			instance object o, obj_streetlight
			position object o, x-6.0, 0, y+33
			rotate object o, 0, 90, 0
			
			`Streetlight bottom
			o = free_obj()
			instance object o, obj_streetlight
			position object o, x-6.0, 0, y+66
			rotate object o, 0, 90, 0
			
			if a = gridsize-1
				` Road to bottom bottom
				o = free_obj()
				instance object o, obj_bottom
				position object o, x+100, 0, y+50
				rotate object o, 90, 0, 0
			endif
			
			if b = gridsize-1
				` Road to right right
				o = free_obj()
				instance object o, obj_right
				position object o, x+50, 0, y+100
				rotate object o, 90, 0, 0
			endif
			
		next b
	next a
endfunction

function place_stoplights()
	local x as float
	local y as float
	
	REM Load source objects
	
	`intersection road
	obj_intersection_road = free_obj()
	make object plain obj_intersection_road, 10, 10
	set object cull obj_intersection_road, 1
	hide object obj_intersection_road
	texture object obj_intersection_road, img_road
	
	`intersection structure that holds stoplights
	o = free_obj()
	make object box o, 0.4, 10, 0.4
	position object o, -5.2, 5, -5.2
	inc o
	make object box o, 1.5, 2, 1.5
	position object o, -5, 10.2, -5
	inc o
	make object box o, 0.2, 0.2, 6.0
	position object o, 0, 11, 0
	inc o
	make object box o, 0.2, 0.2, 10.0
	position object o, -1.5, 11, -1.5
	obj_structure = free_obj()
	merge_objects(o-3, o, obj_structure)
	rotate limb obj_structure, 3, 0, 135, 0
	rotate limb obj_structure, 4, 0, 45, 0
	color object obj_structure, rgb(192,192,192)
	hide object obj_structure
	
	`stoplight boxes
	obj_stoplight_box = free_obj()
	make object box obj_stoplight_box, 0.4, 1.5, 0.4
	hide object obj_stoplight_box
	color object obj_stoplight_box, rgb(255,255,0)
	obj_stoplight_red = free_obj()
	make object sphere obj_stoplight_red, 0.35, 4, 4
	hide object obj_stoplight_red
	color object obj_stoplight_red, rgb(128,0,0)
	obj_stoplight_yellow = free_obj()
	make object sphere obj_stoplight_yellow, 0.35, 4, 4
	hide object obj_stoplight_yellow
	color object obj_stoplight_yellow, rgb(128,128,0)
	obj_stoplight_green = free_obj()
	make object sphere obj_stoplight_green, 0.35, 4, 4
	hide object obj_stoplight_green
	color object obj_stoplight_green, rgb(0,128,0)
	obj_red = free_obj()
	make object sphere obj_red, 0.45, 4, 4
	hide object obj_red
	color object obj_red, rgb(255,0,0)
	set object emissive obj_red, rgb(255,0,0)
	ghost object on obj_red
	obj_yellow = free_obj()
	make object sphere obj_yellow, 0.45, 4, 4
	hide object obj_yellow
	color object obj_yellow, rgb(255,255,0)
	set object emissive obj_yellow, rgb(255,255,0)
	ghost object on obj_yellow
	obj_green = free_obj()
	make object sphere obj_green, 0.45, 4, 4
	hide object obj_green
	color object obj_green, rgb(0,255,0)
	set object emissive obj_green, rgb(0,255,0)
	ghost object on obj_green
	
	
	REM Load instances
	
	for a = 0 to gridsize
		for b = 0 to gridsize
			
			x = a * 100
			y = b * 100
			
			REM Intersection ground/road object
			o = free_obj()
			instance object o, obj_intersection_road
			position object o, x, 0, y
			rotate object o, 90, 0, 0
			
			REM Building
			if a = gridsize/2 and b = gridsize/2
			else
				place_random_building(x-50, y-50)
			endif
			
			REM sidewalk and grass model
			o = free_obj()
			instance object o, obj_sidewalkgrass
			position object o, x-50, 0, y-50
			rotate object o, 90, 0, 0
			
			REM Stoplight system (var)
			s(a, b).to = rnd(3)
			s(a, b).i = rnd(stoplight_green_time) + 1
			
			REM Stoplight structure model
			o = free_obj()
			instance object o, obj_structure
			position object o, a*100, 0, b*100
			
			REM Stoplights (model)
			o = free_obj()
			instance object o, obj_stoplight_box
			position object o, a*100+2, 10, b*100+2
			inc o
			instance object o, obj_stoplight_box
			position object o, a*100+2, 10, b*100-2
			inc o
			instance object o, obj_stoplight_box
			position object o, a*100-2, 10, b*100+2
			inc o
			instance object o, obj_stoplight_box
			position object o, a*100-2, 10, b*100-2
			inc o
			instance object o, obj_stoplight_red
			position object o, a*100+2.2, 10.375, b*100+2
			inc o
			instance object o, obj_stoplight_red
			position object o, a*100+2, 10.375, b*100-2.2
			inc o
			instance object o, obj_stoplight_red
			position object o, a*100-2, 10.375, b*100+2.2
			inc o
			instance object o, obj_stoplight_red
			position object o, a*100-2.2, 10.375, b*100-2
			inc o
			instance object o, obj_stoplight_yellow
			position object o, a*100+2.2, 10, b*100+2
			inc o
			instance object o, obj_stoplight_yellow
			position object o, a*100+2, 10, b*100-2.2
			inc o
			instance object o, obj_stoplight_yellow
			position object o, a*100-2, 10, b*100+2.2
			inc o
			instance object o, obj_stoplight_yellow
			position object o, a*100-2.2, 10, b*100-2
			inc o
			instance object o, obj_stoplight_green
			position object o, a*100+2.2, 9.625, b*100+2
			inc o
			instance object o, obj_stoplight_green
			position object o, a*100+2, 9.625, b*100-2.2
			inc o
			instance object o, obj_stoplight_green
			position object o, a*100-2, 9.625, b*100+2.2
			inc o
			instance object o, obj_stoplight_green
			position object o, a*100-2.2, 9.625, b*100-2
			
			REM Load brightened circles (reds)
			s(a, b).ra = free_obj()
			instance object s(a, b).ra, obj_red
			s(a, b).rb = free_obj()
			instance object s(a, b).rb, obj_red
			s(a, b).rc = free_obj()
			instance object s(a, b).rc, obj_red
			
			REM Load brightened circles (green and yellow)
			s(a, b).g = free_obj()
			instance object s(a, b).g, obj_green
			s(a, b).y = free_obj()
			instance object s(a, b).y, obj_yellow
			
			REM Set lightened circles to correspond with which direction stoplight is allowing cars to pass
			set_stoplight_object(a, b)
			
		next b
	next a
endfunction

function set_stoplight_object(a, b)
	REM Replace object with correct direction object
	if s(a, b).to = 0 `pos z
		position object s(a, b).g, a*100+2, 9.625, b*100-2.2
		position object s(a, b).y, a*100+2, 10, b*100-2.2
		position object s(a, b).ra, a*100-2.2, 10.375, b*100-2
		position object s(a, b).rb, a*100-2, 10.375, b*100+2.2
		position object s(a, b).rc, a*100+2.2, 10.375, b*100+2
	endif
	if s(a, b).to = 1 `neg x
		position object s(a, b).g, a*100-2.2, 9.625, b*100-2
		position object s(a, b).y, a*100-2.2, 10, b*100-2
		position object s(a, b).ra, a*100+2, 10.375, b*100-2.2
		position object s(a, b).rb, a*100-2, 10.375, b*100+2.2
		position object s(a, b).rc, a*100+2.2, 10.375, b*100+2
	endif
	if s(a, b).to = 2 `neg z
		position object s(a, b).g, a*100-2, 9.625, b*100+2.2
		position object s(a, b).y, a*100-2, 10, b*100+2.2
		position object s(a, b).ra, a*100-2.2, 10.375, b*100-2
		position object s(a, b).rb, a*100+2, 10.375, b*100-2.2
		position object s(a, b).rc, a*100+2.2, 10.375, b*100+2
	endif
	if s(a, b).to = 3 `pos x
		position object s(a, b).g, a*100+2.2, 9.625, b*100+2
		position object s(a, b).y, a*100+2.2, 10, b*100+2
		position object s(a, b).ra, a*100-2.2, 10.375, b*100-2
		position object s(a, b).rb, a*100-2, 10.375, b*100+2.2
		position object s(a, b).rc, a*100+2, 10.375, b*100-2.2
	endif
endfunction

function load_sidewalkgrass()
	`texture
	texture(0, 0, 512, 512, 0, 192, 0)
	texture(4, 0, 20, 512, 192, 192, 192)
	texture(0, 4, 512, 20, 192, 192, 192)
	texture(512-20, 0, 512-4, 512, 192, 192, 192)
	texture(0, 512-20, 512, 512-4, 192, 192, 192)
	img_sidewalkgrass = free_img()
	get image img_sidewalkgrass, 0, 0, 512, 512
	`model
	obj_sidewalkgrass = free_obj()
	make object plain obj_sidewalkgrass, 90, 90
	set object cull obj_sidewalkgrass, 0
	hide object obj_sidewalkgrass
	texture object obj_sidewalkgrass, img_sidewalkgrass
endfunction

function place_random_building(pos_x as float, pos_z as float)
	local height as float
		
		`building var
		height = (rnd(15)+1) * 10.0
		`building texture
		r=rnd(255)
		g=rnd(255)
		b=rnd(255)
		if r > 128
			r = r - abs(r - 128)/2
		else
			r = r + abs(r - 128)/2
		endif
		if g > 128
			g = g - abs(g - 128)/2
		else
			g = g + abs(g - 128)/2
		endif
		if b > 128
			b = b - abs(b - 128)/2
		else
			b = b + abs(b - 128)/2
		endif
		lock pixels
		ink rgb(r, g, b), 0
		box 0, 0, 256, 512
		for x = 1 to 16
			for y = 1 to 32
				if rnd(1) = 1
					ink rgb(255,255,0),0
				else
					ink rgb(0,0,0),0
				endif
				box x*16, y*16, x*16+8, y*16+8
			next y
		next x
		i = free_img()
		unlock pixels
		get image i, 0, 0, 256, height*3.2
		`building model
		o = free_obj()
		make object box o, 80, height, 80
		offset limb o, 0, 0, height/2, 0
		texture object o, i
		position object o, pos_x, 0, pos_z
		`ceiling
		inc o
		make object box o, 80, 1, 80
		color object o, rgb(r,g,b)
		position object o, pos_x, height+0.5, pos_z
	
endfunction

function mouse_control()
	local mmy as float
	local mmx as float
	local spd as float
	
	REM Var
	spd = 0.1
	oldmc = mc
	mc = mouseclick()
	mmy = mousemovey() / 5.0
	mmx = mousemovex() / 5.0
	oldkeytab = keytab
	keytab = keystate(15)
	
	REM Toggle camera mode
	if keytab = 1 and oldkeytab = 0
		if cam_mode = 0
			cam_mode = 1
		else
			cam_mode = 0
		endif
	endif
	
	REM Toggle FPS
	if keystate(78) then sync rate 0
	if keystate(156) then sync rate 45
	
	REM Look
	if mc = 2 and oldmc = 2
		`hide moues while looking around
		hide mouse
		position mouse 512, 384
		`turn camera
		xrotate camera wrapvalue(camera angle x() + mmy)
		yrotate camera wrapvalue(camera angle y() + mmx)
		`bound camera angle
		if camera angle x()>89 and camera angle x()<180 then xrotate camera 89
		if camera angle x()<271 and camera angle x()>180 then xrotate camera 271
	else
		show mouse
	endif
	
	if cam_mode = 1
		REM Move (walk)
		if keystate(42)
			spd = spd * 4
		endif
		if keystate(17)
			position camera newxvalue(camera position x(), camera angle y(), spd), character_height, newzvalue(camera position z(), camera angle y(), spd)
		endif
		if keystate(31)
			position camera newxvalue(camera position x(), camera angle y()-180.0, spd), character_height, newzvalue(camera position z(), camera angle y()-180.0, spd)
		endif          
		if keystate(30)
			position camera newxvalue(camera position x(), camera angle y()-90.0, spd), character_height, newzvalue(camera position z(), camera angle y()-90.0, spd)
		endif
		if keystate(32)
			position camera newxvalue(camera position x(), camera angle y()+90.0, spd), character_height, newzvalue(camera position z(), camera angle y()+90.0, spd)
		endif
	else
		REM Move (zoom)
		spd = spd * 5.0
		if keystate(42)
			spd = spd * 10
		endif
		if keystate(17)
			move camera spd
		endif
		if keystate(31)
			move camera -spd
		endif          
		if keystate(30)
			position camera newxvalue(camera position x(), camera angle y()-90.0, spd), camera position y(), newzvalue(camera position z(), camera angle y()-90.0, spd)
		endif
		if keystate(32)
			position camera newxvalue(camera position x(), camera angle y()+90.0, spd), camera position y(), newzvalue(camera position z(), camera angle y()+90.0, spd)
		endif          
		if keystate(16)
			position camera camera position x(), camera position y() - spd, camera position z()
		endif
		if keystate(18)
			position camera camera position x(), camera position y() + spd, camera position z()
		endif
		if camera position y() < 1.0 then position camera camera position x(), 1.0, camera position z()
	endif

endfunction

function place_clouds()
	o = free_obj()
	
	for i = 0 to maxclouds
		REM Make cloud object
		inc o
		make object sphere o, 100, 6, 6
		inc o
		make object sphere o, 100, 6, 6
		inc o
		make object sphere o, 100, 6, 6
		inc o
		make object sphere o, 100, 6, 6
		inc o
		make object sphere o, 100, 6, 6
		inc o
		make object sphere o, 100, 6, 6
		
		for j = o-5 to o
			position object j, rnd(100), rnd(50), rnd(100)
		next j
		
		merge_objects(o-5, o, o+1)
		
		set object emissive o+1, rgb(255, 255, 255)
		cloud(i).o = o+1
		cloud(i).offx = rnd(600)-300
		cloud(i).offz = rnd(600)-300
		
		inc o
	next i
	
	obj_sun = free_obj()
	make object sphere obj_sun, 25, 12, 12
	set object emissive obj_sun, rgb(255,255,64)
endfunction

function run_clouds()
	for i = 0 to maxclouds
		
		position object cloud(i).o, camera position x() + cloud(i).offx, 200, camera position z() + cloud(i).offz
		inc cloud(i).offx, 0.1
		if cloud(i).offx > 300 then cloud(i).offx = -300.0
		
		position object obj_sun, camera position x(), 400, camera position z()
		
	next i
endfunction

function free_obj()
	repeat
		inc i
		if object exist(i)=0 then found=1
	until found
endfunction i

function free_img()
	repeat
		inc i
		if image exist(i)=0 then found=1
	until found
endfunction i

function merge_objects(SObj,EObj,TOBj)
	Limb=1
	
	make object cube TObj,0.1
	
	for m = SOBj to EObj
		make mesh from object m,m
		add limb TObj,Limb,m
		offset Limb TObj,Limb,Object Position x(m),Object Position y(m),Object Position z(m)
		rotate limb TObj,Limb,Object angle x(m),Object angle y(m),Object angle z(m)
		inc Limb
		delete object m
		delete mesh m
	next m
	
	hide limb TObj, 0
endfunction

function texture(xa, ya, xb, yb, r, g, b)
	lock pixels
	
	ink rgb(r, g, b), 0
	box xa, ya, xb, yb
	
	
	ink rgb(tinc(r), tinc(g), tinc(b)), 0
	for x = xa to xb
		for y = ya to yb
			if rnd(3)
				box x, y, x+1, y+1
			endif
		next y
	next x
	ink rgb(tdec(r), tdec(g), tdec(b)), 0
	for x = xa to xb
		for y = ya to yb
			if rnd(3)
				box x, y, x+1, y+1
			endif
		next y
	next x
	
	unlock pixels
endfunction           

function tinc(a)
	
	inc a, 8
	if a > 255 then a = 255
	
endfunction a

function tdec(a)
	
	dec a, 8
	if a < 0 then a = 0
	
endfunction a

function loading(i as integer, msg as string)
	l(i) = msg
	cls
	ink rgb(255, 255, 0), 0
	for i = 0 to 4
		print l(i)
	next i
	sync
endfunction

sync on:sync rate 0:sync

randomize timer()

make_textures()

make camera 1
color backdrop 1,0x00bfff
position light 0,0,300,0
make light 1
position light 1,0,-300,0

`turn camera right 1,45
`pitch camera down 1,30


move camera 1,-1000
move camera up 1,10




global stopNum
global car
global dim cars(1000,2)
global dim lights(100,2)



build_city2()
make_cars(100)


do

   sync
   text 0,0,str$(screen fps())
   control_cars()
   work_stoplight()
   control camera using arrowkeys 1,8,3


loop

function make_textures()

   ink rgb(178,34,34),rgb(178,34,34)
   box 1,1,10,5
   ink rgb(100,100,100),rgb(100,100,100)
   line 1,1,10,1
   line 1,1,1,5
   line 1,5,10,5
   line 10,1,10,5
   get image 1,0,0,11,6,1
   cls



   for j=0 to 150
      for i=0 to 51
         if j mod 2
            paste image 1,i*10,j*5
         else
            paste image 1,i*10-5,j*5
         endif
      next i
   next j

   ink rgb(176,226,255),rgb(176,226,255)
   windows()

   get image 1,0,0,500,750,1

   cls

   ink rgb(255,231,186),rgb(255,231,186)
   box 0,0,500,750
   ink rgb(54,100,139),rgb(54,100,139)
   windows()

   get image 2,0,0,500,750,1

   cls


   ink rgb(20,20,20),rgb(20,20,20)
   box 0,0,500,750

   ink rgb(176,226,255),rgb(176,226,255)
   windows()

   get image 3,0,0,500,750,1

endfunction

function windows()


   for j=5 to 145 step 10
      for i=1 to 50 step 5
         box i*10,j*5,i*10+5,j*5+10
      next i
   next j

endfunction

function control_cars()

   for i=1 to car
      no=0
      for j=0 to stopNum-1
         if object collision(i+5000,j*15+1002)
            no=1
            if lights(j,2)=cars(i,1)
               move object i+5000,1
               cars(i,2)=1
            else
               if cars(i,2)=1
                  move object i+5000,1
               endif
            endif
         endif
      next j

      if no=0
         move object i+5000,1
         cars(i,2)=0
      endif
   next i



endfunction


function make_cars(n)

   for i=1 to n
      make_car()
   next i

endfunction

function make_car()

   car=car+1

   make object box car+5000,5,5,10
   a=rnd(3)
   select a
      case 0
         x=rnd(9)-5
         x=x*100
         cars(car,1)=0
         y=-550
      endcase
      case 1
         x=rnd(9)-5
         x=x*100
         cars(car,1)=0
         y=550
         yrotate object car+5000,180
      endcase
      case 2
         y=rnd(10)-5
         y=y*100
         cars(car,1)=1
         x=-550
         yrotate object car+5000,90
      endcase
      case 3
         y=rnd(10)-5
         y=y*100
         cars(car,1)=1
         x=550
         yrotate object car+5000,-90
      endcase
   endselect

   position object car+5000,x,2.6,y
   move object right car+5000,10

endfunction


function build_city2()

   make object plain 1,1200,1100
   pitch object down 1,90
   position object 1,0,0,-50
   color object 1,0

   num=1

   for x=0 to 10
      for y=0 to 10
         num=num+1
         make object box num,60,rnd(200-50)+50,60
         position object num,x*100-550,object size y(num)/2,y*100-550
         texture object num,rnd(2)+1
      next y
   next x

   for x=-5 to 4
      for y=-5 to 4
         make_stoplight(x*100,y*100)
      next y
   next x

endfunction



function make_stoplight(x,y)

   objnum=stopNum*15+1000

   stopNum=stopNum+1


   make object cylinder objnum,10
   scale object objnum,5,100,5
   make object box objnum+1,2,3,2
   position object objnum,x,5,y
   position object objnum+1,x,10,y

   for i=objnum+3 to objnum+14
      make object sphere i,1
   next i

   for i=1 to 3
      position object i+objnum+2,x,i+8,y-1
   next i
   for i=1 to 3
      position object i+objnum+5,x,i+8,y+1
   next i
   for i=1 to 3
      position object i+objnum+8,x+1,i+8,y
   next i
   for i=1 to 3
      position object i+objnum+11,x-1,i+8,y
   next i

   for i=3 to 14 step 3
      color object i+objnum,rgb(0,100,0)
   next i

   for i=4 to 14 step 3
      color object i+objnum,rgb(100,100,0)
   next i

   for i=5 to 14 step 3
      color object i+objnum,rgb(100,0,0)
   next i

   make object box 2+objnum,40,10,40
   position object 2+objnum,x,5,y
   hide object 2+objnum

   lights(stopNum-1,1)=rnd(300)
   lights(stopNum-1,2)=rnd(1)

endfunction

function work_stoplight()

   for j=0 to stopNum-1

      change=0

      objnum=j*15+1000

      lights(j,1)=lights(j,1)+1

      if lights(j,1)>300
         lights(j,1)=0
         if lights(j,2)=1
            lights(j,2)=0
         else
            lights(j,2)=1
         endif
         change=1
      endif

      if change=1 or lights(j,1)=250
         for i=3 to 14 step 3
            color object i+objnum,rgb(0,50,0)
         next i

         for i=4 to 14 step 3
            color object i+objnum,rgb(50,50,0)
         next i

         for i=5 to 14 step 3
            color object i+objnum,rgb(50,0,0)
         next i

         select lights(j,2)
            case 0

               if lights(j,1)<250
                  color object 3+objnum,rgb(0,255,0)
                  color object 6+objnum,rgb(0,255,0)
               else
                  color object 4+objnum,rgb(255,255,0)
                  color object 7+objnum,rgb(255,255,0)
               endif

               color object 11+objnum,rgb(255,0,0)
               color object 14+objnum,rgb(255,0,0)
            endcase
            case 1
               if lights(j,1)<250
                  color object 9+objnum,rgb(0,255,0)
                  color object 12+objnum,rgb(0,255,0)
               else
                  color object 10+objnum,rgb(255,255,0)
                  color object 13+objnum,rgb(255,255,0)
               endif
               color object 5+objnum,rgb(255,0,0)
               color object 8+objnum,rgb(255,0,0)
            endcase
         endselect
      endif

   next j

endfunction

sync on:sync rate 0:sync

set display mode 1024,768,16

randomize timer()



make camera 1
color backdrop 1,0x00bfff
set camera range 1,1,500
position light 0,0,600,0
make light 1
position light 1,0,-600,0
make light 2
position light 2,0,0,-600
make light 3
position light 3,0,0,600
make light 4
position light 4,-600,0,0
make light 5
position light 5,600,0,0



move camera 1,-1000
pitch camera up 1,90
move camera 1,10
pitch camera down 1,90




global stopNum
global col_check
global car
global dim cars(1000,7)
global dim lights(100,2)

ink 0,0


make_first_car()

make_textures()

make_stoplight()

build_city2()

make_cars(200)




do

   fastsync
   text 0,0,"FPS "+str$(screen fps())


   control_cars()

   x=object position x(5005)
   z=object position z(5005)

   text 0,40,str$(x)
   text 0,60,str$(z)
   `position camera 1,x,100,z
   `point camera 1,x,0,z
   work_stoplight()
   control camera using arrowkeys 1,8,3


loop

function make_textures()

   ink rgb(178,34,34),rgb(178,34,34)
   box 1,1,10,5
   ink rgb(100,100,100),rgb(100,100,100)
   line 1,1,10,1
   line 1,1,1,5
   line 1,5,10,5
   line 10,1,10,5
   get image 1,0,0,11,6,1
   cls



   for j=0 to 150
      for i=0 to 51
         if j mod 2
            paste image 1,i*10,j*5
         else
            paste image 1,i*10-5,j*5
         endif
      next i
   next j

   ink rgb(176,226,255),rgb(176,226,255)
   windows()

   get image 1,0,0,500,750,1

   cls

   ink rgb(255,231,186),rgb(255,231,186)
   box 0,0,500,750
   ink rgb(54,100,139),rgb(54,100,139)
   windows()

   get image 2,0,0,500,750,1

   cls


   ink rgb(20,20,20),rgb(20,20,20)
   box 0,0,500,750

   ink rgb(176,226,255),rgb(176,226,255)
   windows()

   get image 3,0,0,500,750,1
   cls
   sync

endfunction

function windows()


   for j=5 to 145 step 10
      for i=1 to 50 step 5
         box i*10,j*5,i*10+5,j*5+10
      next i
   next j

endfunction

function control_cars()

   for i=1 to car
      cars(i,5)=object position x(i+5000)
      cars(i,6)=object position z(i+5000)
   next i


   col_check=col_check+1
   if col_check>5
      col_check=1
   endif


   for i=1 to car


         moved=0
         no=0
         x=object position x(i+5000)
         y=object position z(i+5000)

         for j=1 to stopNum
            x2=object position x(j+1000)
            y2=object position z(j+1000)
            if x>x2-25 and x<x2+25 and y>y2-25 and y<y2+25
               no=1

               if cars(i,3)=0
                  cars(i,3)=rnd(1)+1
                  if cars(i,3)=2
                     cars(i,4)=24
                  endif
               endif

               if lights(j,2)=cars(i,1)
                  move object i+5000,1

                  if cars(i,3)=2
                     if cars(i,4)>0
                        turn object right i+5000,3.75`yrotate object i+5000,object angle y(i+5000)+10
                        cars(i,4)=cars(i,4)-1
                     else
                        if cars(i,1)=1
                           cars(i,1)=0
                        else
                           cars(i,1)=1
                        endif
                        cars(i,3)=1
                        cars(i,4)=100
                     endif
                  endif


                  moved=1
                  cars(i,2)=1
               else
                  if cars(i,2)=1
                     move object i+5000,1
                     moved=1
                  endif

               endif
            endif
         next j

         if no=0
            move object i+5000,1
            moved=1
            if cars(i,3)=2
               move object left i+5000,1.78
            endif
            cars(i,2)=0
            cars(i,3)=0
         endif



         if moved

            for j=1 to car
                if i<>j
                   if car_col(i,j)

                     if cars(i,3)=2
                        cars(i,4)=cars(i,4)+1
                        turn object right i+5000,-3.75
                     endif

                     move object i+5000,-1

                   endif
                endif
            next j
         endif


   next i



endfunction

function car_col(num1,num2)

   dist=(cars(num2,5)-cars(num2,5))^2+(cars(num1,6)-cars(num2,6))^2

   if dist<400
      yes=object collision(num1+5000,num2+5000)
   endif

endfunction yes


function make_cars(n)

   for i=1 to n
      make_car()
   next i

endfunction

function make_first_car()

   make object box 4999,5,5,10
   hide object 4999
   make object collision box 4999,-2.5,0,-7.5,2.5,5,7.5,1

endfunction

function make_car()

   car=car+1

   instance object car+5000,4999
   show object car+5000

   repeat
      redo=0
      a=rnd(3)
      select a
         case 0
            x=rnd(9)-5
            x=x*100
            cars(car,1)=0

            y=rnd(1100)-550
            yrotate object car+5000,0
         endcase
         case 1
            x=rnd(9)-5
            x=x*100
            cars(car,1)=0

            y=rnd(1100)-550

            yrotate object car+5000,180
         endcase
         case 2
            y=rnd(9)-5
            y=y*100
            cars(car,1)=1
            x=rnd(1100)-550

            yrotate object car+5000,90
         endcase
         case 3
            y=rnd(9)-5
            y=y*100
            cars(car,1)=1

            x=rnd(1100)-550

            yrotate object car+5000,-90
         endcase
      endselect

      position object car+5000,x,2.6,y
      move object right car+5000,10

      for j=1 to stopNum
         x2=object position x(j+1000)
         y2=object position z(j+1000)
         if x>x2-25 and x<x2+25 and y>y2-25 and y<y2+25
            redo=1
         endif
      next j

      for j=1 to car-2
          if object collision(car+5000,j+5000)
            redo=1
          endif
      next j

   until redo=0

   cars(car,2)=1


endfunction


function build_city2()

   make object plain 1,1200,1100
   pitch object down 1,90
   position object 1,0,0,-50
   color object 1,0

   num=1

   for x=0 to 10
      for y=0 to 10
         num=num+1
         make object box num,60,rnd(200-50)+50,60
         position object num,x*100-550,object size y(num)/2,y*100-550
         texture object num,rnd(2)+1
      next y
   next x

   for x=-5 to 4
      for y=-5 to 4
         make_stoplights(x*100,y*100)
      next y
   next x

endfunction

function make_stoplights(x,y)

   stopNum=stopNum+1
   objnum=stopNum+1000


   lights(stopNum,1)=rnd(300)
   lights(stopNum,2)=rnd(1)
   clone object objnum,1000
   position object objnum,x,object size y(objnum)/5,y

endfunction

function make_stoplight()

   objnum=1000



   make object cylinder objnum,10
   scale limb objnum,0,5,100,5
   make object box objnum+1,2,3,2
   make mesh from object 1,objnum+1
   delete object objnum+1
   add limb objnum,1,1
   position object objnum,0,5,0
   offset limb objnum,1,0,5,0
   delete mesh 1
   make object sphere objnum+1,1
   make mesh from object 2,objnum+1
   delete object objnum+1



   for i=2 to 13
      add limb objnum,i,2
   next i
   delete mesh 2

   for i=1 to 3
      offset limb objnum,i+1,0,i+3,-1
   next i
   for i=1 to 3
      offset limb objnum,i+4,0,i+3,1
   next i
   for i=1 to 3
      offset limb objnum,i+7,1,i+3,0
   next i
   for i=1 to 3
      offset limb objnum,i+10,-1,i+3,0
   next i

   for i=2 to 13 step 3
      color limb objnum,i,rgb(0,100,0)
   next i

   for i=3 to 13 step 3
      color limb objnum,i,rgb(100,100,0)
   next i

   for i=4 to 13 step 3
      color limb objnum,i,rgb(100,0,0)
   next i

   hide object objnum



endfunction

function work_stoplight()

   for j=1 to stopNum

      change=0

      objnum=j+1000

      lights(j,1)=lights(j,1)+1

      if lights(j,1)>300
         lights(j,1)=0
         if lights(j,2)=1
            lights(j,2)=0
         else
            lights(j,2)=1
         endif
         change=1
      endif

      if change=1 or lights(j,1)=250
         for i=2 to 13 step 3
            color limb objnum,i,rgb(0,100,0)
         next i

         for i=3 to 13 step 3
            color limb objnum,i,rgb(100,100,0)
         next i

         for i=4 to 13 step 3
            color limb objnum,i,rgb(100,0,0)
         next i

         select lights(j,2)
            case 0

               if lights(j,1)<250
                  color limb objnum,2,rgb(0,255,0)
                  color limb objnum,5,rgb(0,255,0)
               else
                  color limb objnum,3,rgb(255,255,0)
                  color limb objnum,6,rgb(255,255,0)
               endif

               color limb objnum,10,rgb(255,0,0)
               color limb objnum,13,rgb(255,0,0)
            endcase
            case 1
               if lights(j,1)<250
                  color limb objnum,8,rgb(0,255,0)
                  color limb objnum,11,rgb(0,255,0)
               else
                  color limb objnum,9,rgb(255,255,0)
                  color limb objnum,12,rgb(255,255,0)
               endif
               color limb objnum,4,rgb(255,0,0)
               color limb objnum,7,rgb(255,0,0)
            endcase
         endselect
      endif

   next j

endfunction

sync on
autocam off

tilecolour=0
heatmap=1
tilescalemax=10

roadcolour=rgb(100,100,100)
pavementcolour=rgb(150,150,150)
grasscolour1=rgb(0,100,0)
grasscolour2=rgb(0,80,0)


ink grasscolour1,0
box 0,0,49,49
ink grasscolour2,0
for count=0 to 200
  dot rnd(49),rnd(49)
next count
get image 1,0,0,49,49,1

ink roadcolour,0
box 0,0,99,49
ink pavementcolour,0
box 0,0,49,4
box 0,44,49,49
box 50,0,54,49
box 94,0,99,49
get image 9,0,0,49,49
get image 14,50,0,99,49

ink pavementcolour,0
box 0,0,49,49
ink roadcolour,0
fillcircle(49,49,45) 
ink pavementcolour,0
fillcircle(49,49,5)
get image 16,0,0,49,49,1

ink pavementcolour,0
box 0,0,49,49
ink roadcolour,0
fillcircle(0,49,45) 
ink pavementcolour,0
fillcircle(0,49,5)
get image 13,0,0,49,49,1

ink pavementcolour,0
box 0,0,49,49
ink roadcolour,0
fillcircle(49,0,45) 
ink pavementcolour,0
fillcircle(49,0,5)
get image 10,0,0,49,49,1

ink pavementcolour,0
box 0,0,49,49
ink roadcolour,0
fillcircle(0,0,44) 
ink pavementcolour,0
fillcircle(0,0,4)
get image 7,0,0,49,49,1

ink roadcolour,0
box 0,0,49,49
ink pavementcolour,0
fillcircle(0,0,5)
fillcircle(49,0,5)
fillcircle(0,49,5)
fillcircle(49,49,5)
get image 19,0,0,49,49,1

ink roadcolour,0
box 0,0,49,49
ink pavementcolour,0
fillcircle(49,0,5)
fillcircle(49,49,5)
box 0,0,4,49
get image 18,0,0,49,49,1

ink roadcolour,0
box 0,0,49,49
ink pavementcolour,0
fillcircle(0,49,5)
fillcircle(49,49,5)
box 0,0,49,4
get image 17,0,0,49,49,1

ink roadcolour,0
box 0,0,49,49
ink pavementcolour,0
fillcircle(0,0,5)
fillcircle(0,49,5)
box 44,0,49,49
get image 15,0,0,49,49,1

ink roadcolour,0
box 0,0,49,49
ink pavementcolour,0
fillcircle(0,0,5)
fillcircle(49,0,5)
box 0,44,49,49
get image 11,0,0,49,49,1

ink pavementcolour,0
box 0,0,49,49
ink roadcolour,0
fillcircle(24,24,20)
get image 4,0,0,49,49,1

ink pavementcolour,0
box 0,0,49,49
ink roadcolour,0
fillcircle(24,24,20)
box 0,4,25,44
get image 5,0,0,49,49,1

ink pavementcolour,0
box 0,0,49,49
ink roadcolour,0
fillcircle(24,24,20)
box 4,0,44,25
get image 6,0,0,49,49,1

ink pavementcolour,0
box 0,0,49,49
ink roadcolour,0
fillcircle(24,24,20)
box 25,4,49,44
get image 8,0,0,49,49,1

ink pavementcolour,0
box 0,0,49,49
ink roadcolour,0
fillcircle(24,24,20)
box 4,25,44,49
get image 12,0,0,49,49,1

global roadcount as integer
dim landobjects(50,50)
dim landtestobjects(50,50)
dim landtile(50,50)
dim landstate(50,50)
dim landoccupied(50,50,8)
dim landheat(50,50)
dim landheated(50,50)


for countx=0 to 50
  for countz=0 to 50
    landobjects(countx,countz)=findobj()
    make object plain landobjects(countx,countz),1,1
    xrotate object landobjects(countx,countz),-90
    position object landobjects(countx,countz),countx,0,countz
    texture object landobjects(countx,countz),1
    landtile(countx,countz)=1
    landstate(countx,countz)=0
  next countz
next countx


ink rgb(255,255,255),0
box 0,0,50,50
ink 0,0
text 10,15,"dest"
get image 20,1,1,50,50

destobj=findobj()
make object plain destobj,1,1
xrotate object destobj,-90
hide object destobj
texture object destobj,20
set alpha mapping on destobj,50

ink rgb(255,50,50),0
box 0,0,50,50
ink 0,0
text 10,15,"next"
get image 21,1,1,50,50

nextobj=findobj()
make object plain nextobj,1,1
xrotate object nextobj,-90
hide object nextobj
texture object nextobj,21
set alpha mapping on nextobj,50

ink rgb(50,50,255),0
box 0,0,50,50
ink 0,0
text 10,15,"curr"

get image 22,1,1,50,50

currobj=findobj()
make object plain currobj,1,1
xrotate object currobj,-90
hide object currobj
texture object currobj,22
set alpha mapping on currobj,50


cursorx=20
cursorz=20
cursorobj=findobj()
make object box cursorobj,1,0.1,1
position object cursorobj,cursorx,0.05,cursorz
ghost object on cursorobj,1
`set alpha mapping on cursorobj,30

position camera 21,10,10
point camera 21,0,21

updateland()

dim targeterobj(5)
for count=1 to 5
  targeterobj(count)=findobj()
  make object plain targeterobj(count),0.1,0.1
  hide object targeterobj(count)
next count

type Car
 obj as integer
 testobj as integer
 colour as integer
 posx as integer
 posy as integer
 destx as integer
 desty as integer
 nextx as integer
 nexty as integer
 prevx as integer
 prevy as integer
 propx as integer
 propy as integer
 sideofroad as integer
 changed as integer
endtype

dim cars(0) as Car

sw=screen width()
sh=screen height()
camtilt#=50
camzoom#=8
camrot#=0
cammodrange=2
camx#=25
camz#=0
position camera camx#,0,camz#
xrotate camera camtilt#
yrotate camera camrot#
move camera -camzoom#
mmx=mousemovex()
mmy=mousemovey() 

time=timer()

ink rgb(255,255,255),0

do
  
  lasttime=time
  time=timer()
  carupdate#=carupdate#+((time-lasttime)/1000.0)

  mx=mousex()
  my=mousey()
  closest=1
  if movingcam=0
    while closest<>5
      position object targeterobj(1),cursorx-1,0,cursorz
      position object targeterobj(2),cursorx,0,cursorz+1
      position object targeterobj(3),cursorx+1,0,cursorz
      position object targeterobj(4),cursorx,0,cursorz-1
      position object targeterobj(5),cursorx,0,cursorz
      mx=mousex()
      my=mousey()
      closestdist=sqrt(sqr(object screen x(targeterobj(1))-mx)+sqr(object screen y(targeterobj(1))-my))
      closest=1
      dist=sqrt(sqr(object screen x(targeterobj(2))-mx)+sqr(object screen y(targeterobj(2))-my))
      if dist<closestdist
        closest=2
        closestdist=dist
      endif
      dist=sqrt(sqr(object screen x(targeterobj(3))-mx)+sqr(object screen y(targeterobj(3))-my))
      if dist<closestdist
        closest=3
        closestdist=dist
      endif
      dist=sqrt(sqr(object screen x(targeterobj(4))-mx)+sqr(object screen y(targeterobj(4))-my))
      if dist<closestdist
        closest=4
        closestdist=dist
      endif
          dist=sqrt(sqr(object screen x(targeterobj(5))-mx)+sqr(object screen y(targeterobj(5))-my))
      if dist<closestdist
        closest=5
      endif
      select closest
        case 1
          cursorx=cursorx-1
          tilechange=0
        endcase
        case 2
          cursorz=cursorz+1
          tilechange=0
        endcase
        case 3
          cursorx=cursorx+1 
          tilechange=0 
        endcase
        case 4
          cursorz=cursorz-1
          tilechange=0
        endcase
      endselect
    endwhile
    
    position object cursorobj,cursorx,0.05,cursorz
  endif
  
  mmx=mousemovex()
  mmy=mousemovey()
  movecam=0
  lmb=0
  mmb=0
  rmb=0
  
  mv=mouseclick()
  if int(mv/8)=1
    mv=mv-8
  endif
  if int(mv/4)=1
    mv=mv-4
    mmb=1
  endif
  if int(mv/2)=1
    mv=mv-2
    rmb=1
  endif
  if mv=1
    lmb=1
  endif
  
  if (mmb=1) OR (rmb=1)
    if movingcam=0
      cammousex=mousex()
      cammousey=mousey()
    endif
    if rmb=1
      if (mmx<>0) OR (mmy<>0)
        mcamx#=mcamx#-(mmx/30.0)
        mcamz#=mcamz#+(mmy/30.0)
        movecam=1
      endif
    else
      if (mmx<>0) OR (mmy<>0)
        camrot#=camrot#+(mmx/2)
        camtilt#=camtilt#+(mmy/2)
        movecam=1
      endif
    endif

    if camtilt#>90 then camtilt#=90
    if camtilt#<20 then camtilt#=20
    if camrot#>180 then camrot#=180
    if camrot#<-180 then camrot#=-180
    movingcam=1
    hide mouse
  else 
    if movingcam=1
      show mouse
      set cursor cammousex,cammousey
    endif
    movingcam=0
  endif
  
  mz=mousemovez()
  if mz<>0
    camzoom#=camzoom#-(mz/100)
      if camzoom#>50 then camzoom#=50
      if camzoom#<1.5 then camzoom#=1.5
      movecam=1
  endif
  
  if movecam=1
    position camera camx#,0,camz#
    rotate camera 0,0,0
    yrotate camera camrot#
    move camera mcamz#
    yrotate camera camera angle y()+90
    move camera mcamx#
    camx#=camera position x()
    camz#=camera position z()
    yrotate camera camrot#
    xrotate camera camtilt#

    move camera -camzoom#

    mcamx#=0
    mcamz#=0
  endif
  
  if spacekey() or (lmb=1)
    if tilechange=0  
      if ((cursorx>-1) AND (cursorx<51)) AND ((cursorz>-1) AND (cursorz<51))
        if changestate=-1
          if landstate(cursorx,cursorz)=1
            landstate(cursorx,cursorz)=0
            changestate=0
          else
            landstate(cursorx,cursorz)=1
            changestate=1
          endif
        else
          landstate(cursorx,cursorz)=changestate
        endif
        updateland()
      endif
    endif
    tilechange=1
  else
    tilechange=0
    changestate=-1
  endif
  
  if  returnkey()
    if ((landoccupied(25,0,1)=0) AND (landoccupied(25,0,2)=0)) AND ((landoccupied(25,0,4)=0) AND (landoccupied(25,0,8)=0))
      addcar()
    endif
  endif
  
  position object cursorobj,cursorx,0.05,cursorz

  updatecar=0
  if carupdate#>1.0
    updatecar=1
    carupdate#=0.0
    dim landoccupied(0,0,0)
    dim landoccupied(50,50,8)
    landoccupied(0,0,0)=0
    dim landheated(0,0)
    dim landheated(50,50)
    landheated(0,0)=0
  endif
  

    
  for c=1 to array count(cars(0))
    
    if updatecar=1
      if (cars(c).posx<>cars(c).nextx) OR (cars(c).posy<>cars(c).nexty)
        cars(c).prevx=cars(c).posx
        cars(c).prevy=cars(c).posy 
      endif
      cars(c).posx=cars(c).nextx
      cars(c).posy=cars(c).nexty
      
      if tilecolour=1 then position object cars(c).testobj,cars(c).posx,0.01,cars(c).posy

      if ((cars(c).posx=cars(c).destx) AND (cars(c).posy=cars(c).desty)) OR (landstate(cars(c).destx,cars(c).desty)=0)
        givedestination(c)
      endif
      dim pathfindnums(0,0)
      dim pathfindnums(50,50)
  
      
      for cx=0 to 50
        for cy=0 to 50
          pathfindnums(cx,cy)=-1
        next cy
      next cx
      pathfindnums(cars(c).destx,cars(c).desty)=1
      pathnum=1  
      largest=0 
      roadmarked=0
      do
        pathnum=pathnum+1
        stop=0
        
        for cx=0 to 50
          for cy=0 to 50
            if ((pathnum-1)-landheat(cx,cy))>0
              if pathfindnums(cx,cy)=(pathnum-1)-landheat(cx,cy)
                roadmarked=roadmarked+1
                if cx>0
                  if ((landstate(cx-1,cy)=1) AND (pathfindnums(cx-1,cy)=-1))
                    pathfindnums(cx-1,cy)=pathnum
                    if c=selectedcar then text object screen x(landobjects(cx-1,cy)),object screen y(landobjects(cx-1,cy)),str$(pathnum)
                    if (cx-1=cars(c).posx) AND (cy=cars(c).posy)
                      stop=1
                    endif
                  endif
                endif
                if cx<50
                  if ((landstate(cx+1,cy)=1) AND (pathfindnums(cx+1,cy)=-1))
                    pathfindnums(cx+1,cy)=pathnum
                    largest=pathnum
                    if c=selectedcar then text object screen x(landobjects(cx+1,cy)),object screen y(landobjects(cx+1,cy)),str$(pathnum)
                    if (cx+1=cars(c).posx) AND (cy=cars(c).posy)
                      stop=1
                    endif
                  endif
                endif
                if cy>0
                  if ((landstate(cx,cy-1)=1) AND (pathfindnums(cx,cy-1)=-1))
                    pathfindnums(cx,cy-1)=pathnum
                    if c=selectedcar then text object screen x(landobjects(cx,cy-1)),object screen y(landobjects(cx,cy-1)),str$(pathnum)
                    if (cx=cars(c).posx) AND (cy-1=cars(c).posy)
                      stop=1
                    endif
                  endif
                endif
                if cy<50
                  if ((landstate(cx,cy+1)=1) AND (pathfindnums(cx,cy+1)=-1))
                    pathfindnums(cx,cy+1)=pathnum
                    if c=selectedcar then text object screen x(landobjects(cx,cy+1)),object screen y(landobjects(cx,cy+1)),str$(pathnum)
                    if (cx=cars(c).posx) AND (cy+1=cars(c).posy)
                      stop=1
                    endif
                  endif
                endif
              endif
            endif
          next cy
        next cx
        if stop=1
          exit
        endif
        if pathnum>1000
          cars(c).destx=cars(c).posx
          cars(c).desty=cars(c).posy
          exit
        endif
      loop
        if (controlkey()) AND (c=selectedcar)
          text 5,25,str$(roadmarked)
          sync
          wait key
        endif  
      if cars(c).posx>0
        if pathfindnums(cars(c).posx-1,cars(c).posy)>-1
          cars(c).nextx=cars(c).posx-1
          cars(c).nexty=cars(c).posy
          cars(c).sideofroad=8
          landoccupied(cars(c).nextx,cars(c).nexty,8)=landoccupied(cars(c).nextx,cars(c).nexty,8)+1
        endif
      endif
      if cars(c).posx<50
        if pathfindnums(cars(c).posx+1,cars(c).posy)>-1
          cars(c).nextx=cars(c).posx+1
          cars(c).nexty=cars(c).posy
          cars(c).sideofroad=2
          landoccupied(cars(c).nextx,cars(c).nexty,2)=landoccupied(cars(c).nextx,cars(c).nexty,2)+1
        endif
      endif
      if cars(c).posy>0
        if pathfindnums(cars(c).posx,cars(c).posy-1)>-1
          cars(c).nextx=cars(c).posx
          cars(c).nexty=cars(c).posy-1
          cars(c).sideofroad=4
          landoccupied(cars(c).nextx,cars(c).nexty,4)=landoccupied(cars(c).nextx,cars(c).nexty,4)+1
        endif
      endif
      if cars(c).posy<50
        if pathfindnums(cars(c).posx,cars(c).posy+1)>-1
          cars(c).nextx=cars(c).posx
          cars(c).nexty=cars(c).posy+1
          cars(c).sideofroad=1
          landoccupied(cars(c).nextx,cars(c).nexty,1)=landoccupied(cars(c).nextx,cars(c).nexty,1)+1
        endif
      endif   
      cars(c).propx=cars(c).nextx
      cars(c).propy=cars(c).nexty
    cars(c).changed=0  
    endif
      
  movecar(cars(c).obj,carupdate#,cars(c).prevx,cars(c).prevy,cars(c).posx,cars(c).posy,cars(c).nextx,cars(c).nexty)
  next c

  
  
  if updatecar=1


    stoploop=0
    changestext=0
    while stoploop=0
      changes=0
      for c=1 to array count(cars(0))
        if cars(c).changed=0
        
          waitcar=0
          
          if (cars(c).posx=cars(c).nextx) AND (cars(c).posy=cars(c).nexty)
            waitcar=1
          endif
          if landoccupied(cars(c).nextx,cars(c).nexty,cars(c).sideofroad)-1>0
            waitcar=1
          endif
          `if landoccupied(cars(c).nextx,cars(c).nexty,rotatevalc(cars(c).sideofroad))>0
            `waitcar=1
          `endif
          `if landoccupied(cars(c).nextx,cars(c).nexty,rotatevalcc(cars(c).sideofroad))>0
            `waitcar=1
          `endif
          select cars(c).sideofroad
            case 1
              if cars(c).nextx<50
                if landoccupied(cars(c).nextx+1,cars(c).nexty,rotatevalc(cars(c).sideofroad))>0
                  waitcar=1
                endif
              endif
            endcase
            case 2
              if cars(c).nexty>0
                if landoccupied(cars(c).nextx,cars(c).nexty-1,rotatevalc(cars(c).sideofroad))>0
                  waitcar=1
                endif
              endif
            endcase
            case 4
              if cars(c).nextx>0
                if landoccupied(cars(c).nextx-1,cars(c).nexty,rotatevalc(cars(c).sideofroad))>0
                  waitcar=1
                endif
              endif
            endcase
            case 8
              if cars(c).nexty<50
                if landoccupied(cars(c).nextx,cars(c).nexty+1,rotatevalc(cars(c).sideofroad))>0
                  waitcar=1
                endif
              endif
            endcase
          endselect
          
          if waitcar=1
            landheat(cars(c).posx,cars(c).posy)=landheat(cars(c).posx,cars(c).posy)+1
            landheated(cars(c).posx,cars(c).posy)=1
            cars(c).changed=1
            changestext=changestext+1
            landoccupied(cars(c).nextx,cars(c).nexty,cars(c).sideofroad)=landoccupied(cars(c).nextx,cars(c).nexty,cars(c).sideofroad)-1
            cars(c).nextx=cars(c).posx
            cars(c).nexty=cars(c).posy
            calculateprevsor(c)
            landoccupied(cars(c).nextx,cars(c).nexty,cars(c).sideofroad)=landoccupied(cars(c).nextx,cars(c).nexty,cars(c).sideofroad)+1
            changes=changes+1
          endif
        endif
      next c
      if changes=0 then stoploop=1
    endwhile
      for cx=0 to 50
        for cy=0 to 50
          if landheated(cx,cy)=0 then landheat(cx,cy)=0
        next cy
      next cx

  endif

remstart 
for cx=0 to 50
  for cy=0 to 50
    if landheat(cx,cy)>0
      if object in screen(landobjects(cx,cy))
        value#=landheat(cx,cy)/10.0
        if value#>1.0 then value#=1.0   
        ink rgb(255,255-(value#*255.0),255-(value#*255.0)),0
        text object screen x(landobjects(cx,cy)),object screen y(landobjects(cx,cy)), str$(landheat(cx,cy))
        
      endif
    endif
  next cy
next cx


for c=1 to array count(cars(0))
  if (cars(c).posx=cars(c).propx) AND (cars(c).posy=cars(c).propy)
    text object screen x(cars(c).obj),object screen y(cars(c).obj),"!!!"
  endif
next c

if shiftkey()=1
  if keyshift=0
    selectedcar=pick object(mousex(),mousey(),cars(1).obj,cars(array count(cars(0))).obj)
    if selectedcar<>0 then selectedcar=(selectedcar-cars(1).obj)+1
  endif
  keyshift=1
else
  keyshift=0
endif remend

if selectedcar<>0
  text object screen x(cars(selectedcar).obj),object screen y(cars(selectedcar).obj),"<--"
  show object destobj
  show object nextobj
  show object currobj
  position object destobj,cars(selectedcar).destx,0.001,cars(selectedcar).desty
  position object nextobj,cars(selectedcar).propx,0.001,cars(selectedcar).propy
  position object currobj,cars(selectedcar).posx,0.001,cars(selectedcar).posy
else
hide object destobj
hide object nextobj
hide object currobj
endif

ink rgb(255,255,255),0       
sync
loop

function calculateprevsor(carnum)
  xdif=cars(carnum).prevx-cars(carnum).posx
  ydif=cars(carnum).prevy-cars(carnum).posy
  if (xdif=0) AND (ydif=-1)
    sor=1
  endif
  if (xdif=-1) AND (ydif=0)
    sor=2
  endif
  if (xdif=0) AND (ydif=1)
    sor=4
  endif
  if (xdif=1) AND (ydif=0)
    sor=8
  endif
  cars(carnum).sideofroad=sor
endfunction

function movecar(obj,time#,prevx,prevy,posx,posy,nextx,nexty)
  if (offsettovalue(prevx-posx,prevy-posy))<>(offsettovalue(nextx-posx,nexty-posy))
    direction=offsettovalue(prevx-posx,prevy-posy)+offsettovalue(nextx-posx,nexty-posy)
    if (posx=nextx) AND (posy=nexty) 
      direction=offsettovalue(prevx-posx,prevy-posy)+oppval(offsettovalue(prevx-posx,prevy-posy))
      time#=0
    endif
    if (direction=5) or (direction=10) 
      x#=(time#*toward#(nextx,0.5,posx))+((1.0-time#)*toward#(prevx,0.5,posx))
      y#=(time#*toward#(nexty,0.5,posy))+((1.0-time#)*toward#(prevy,0.5,posy))   
    endif
    select direction
      case 5
        angle#=90
        if offsettovalue(prevx-posx,prevy-posy)=4
          y#=y#-0.2
        else
          y#=y#+0.2
        endif
      endcase
      case 10
        angle#=0
        if offsettovalue(prevx-posx,prevy-posy)=8
          x#=x#-0.2
        else
          x#=x#+0.2
        endif
      endcase
      case 12
        if prevy-posy=-1
          x#=(posx+0.5)+rotatex#(-0.7,0,-time#*90.0)
          y#=(posy-0.5)+rotatey#(-0.7,0,-time#*90.0)
          angle#=(90.0*time#)
        else
          x#=(posx+0.5)+rotatex#(0,0.3,time#*90.0)
          y#=(posy-0.5)+rotatey#(0,0.3,time#*90.0)
          angle#=270.0-(90.0*time#)
        endif
      endcase
      case 9
        if prevx-posx=-1
          x#=(posx-0.5)+rotatex#(0,0.7,-time#*90.0)
          y#=(posy-0.5)+rotatey#(0,0.7,-time#*90.0)
          angle#=(90.0*time#)+90.0
        else
          x#=(posx-0.5)+rotatex#(0.3,0,time#*90.0)
          y#=(posy-0.5)+rotatey#(0.3,0,time#*90.0)
          angle#=180.0-(90.0*time#)
        endif
      endcase
      case 3
        if prevy-posy=1
          x#=(posx-0.5)+rotatex#(0.7,0,-time#*90.0)
          y#=(posy+0.5)+rotatey#(0.7,0,-time#*90.0)
          angle#=(90.0*time#)+180.0
        else
          x#=(posx-0.5)+rotatex#(0,-0.3,time#*90.0)
          y#=(posy+0.5)+rotatey#(0,-0.3,time#*90.0)
          angle#=90.0-(90.0*time#)
        endif
      endcase
      case 6
        if prevx-posx=1
          x#=(posx+0.5)+rotatex#(0,-0.7,-time#*90.0)
          y#=(posy+0.5)+rotatey#(0,-0.7,-time#*90.0)
          angle#=(90.0*time#)+270.0
        else
          x#=(posx+0.5)+rotatex#(-0.3,0,time#*90.0)
          y#=(posy+0.5)+rotatey#(-0.3,0,time#*90.0)
          angle#=-(90.0*time#)
        endif
      endcase
    endselect
  else
    select offsettovalue(prevx-posx,prevy-posy)
      case 1
        x#=(posx-0.5)+rotatex#(0,0.2,-time#*180.0)
        y#=(posy)+rotatey#(0,0.2,-time#*180.0)
        angle#=(180.0*time#)+90
      endcase
      case 2
        x#=(posx)+rotatex#(0.2,0,-time#*180.0)
        y#=(posy+0.5)+rotatey#(0.2,0,-time#*180.0)
        angle#=(180.0*time#)
      endcase
      case 4
        x#=(posx+0.5)+rotatex#(0,-0.2,-time#*180.0)
        y#=(posy)+rotatey#(0,-0.2,-time#*180.0)
        angle#=(180.0*time#)+90
      endcase
      case 8
        x#=(posx)+rotatex#(-0.2,0,-time#*180.0)
        y#=(posy-0.5)+rotatey#(-0.2,0,-time#*180.0)
        angle#=(180.0*time#)
      endcase
    endselect
  endif
  yrotate object obj,angle#
  position object obj,x#,0.1,y#
endfunction

function rotatex#(x#,y#,value#)
       result#=((x#*cos(value#))-(y#*sin(value#)));;
endfunction result#

function rotatey#(x#,y#,value#)
       result#=((x#*sin(value#))+(y#*cos(value#)));
endfunction result#

function toward#(value#,amount#,target#)
  ret#=value#
  if value#<target#
    ret#=value#+amount#
  endif
  if value#>target#
    ret#=value#-amount#
  endif
endfunction ret#

function offsettovalue(xoffset,yoffset)
ret=0
if xoffset<0 then ret=ret+1
if xoffset>0 then ret=ret+4
if yoffset<0 then ret=ret+8
if yoffset>0 then ret=ret+2
endfunction ret

function oppval(value)
  select value
    case 1
      res=4
    endcase
    case 2
      res=8
    endcase
    case 4
      res=1
    endcase
    case 8
      res=2
    endcase
  endselect
endfunction res

function rotatevalc(value)
  select value
    case 1
      res=2
    endcase
    case 2
      res=4
    endcase
    case 4
      res=8
    endcase
    case 8
      res=1
    endcase
  endselect
endfunction res

function rotatevalcc(value)
  select value
    case 1
      res=8
    endcase
    case 2
      res=1
    endcase
    case 4
      res=2
    endcase
    case 8
      res=4
    endcase
  endselect
endfunction res

function contains(value,direction)
  ret=0
  v=value
  if int(v/8)=1
    v=v-8
    if direction=8 then ret=1
  endif
  if int(v/4)=1
    v=v-4
    if direction=4 then ret=1
  endif
  if int(v/2)=1
    v=v-2
    if direction=2 then ret=1
  endif
  if v=1
    if direction=1 then ret=1
  endif
endfunction ret

function addcar()
  array insert at bottom cars(0)
  curr=array count(cars(0))
  cars(curr).obj=findobj()
  make object box cars(curr).obj,0.25,0.15,0.4
  position object cars(curr).obj,25,0.1,0
  cars(curr).prevx=25
  cars(curr).prevy=-2
  cars(curr).posx=25
  cars(curr).posy=-1
  cars(curr).nextx=25
  cars(curr).nexty=0
  cars(curr).destx=25
  cars(curr).desty=0
  cars(curr).colour=rgb(rnd(255),rnd(255),rnd(255))
  color object cars(curr).obj,cars(curr).colour
  if tilecolour=1  
    cars(curr).testobj=findobj()
    make object plain cars(curr).testobj,1,1
    xrotate object cars(curr).testobj,-90
    color object cars(curr).testobj,cars(curr).colour
  endif
  landoccupied(25,0,1)=landoccupied(25,0,1)+1
endfunction

function givedestination(c)
dim possiblesx(0)
dim possiblesy(0)

for countx=0 to 50
  for county=0 to 50
    if (landstate(countx,county)=1) AND ((cars(c).posx<>countx) OR (cars(c).posy<>county))
      array insert at bottom possiblesx(0)
      array insert at bottom possiblesy(0)
      possiblesx(array count(possiblesx(0)))=countx
      possiblesy(array count(possiblesy(0)))=county
    endif
  next county
next countx
num=rnd(array count(possiblesy(0))-1)+1
cars(c).destx=possiblesx(num)
cars(c).desty=possiblesy(num)
endfunction




function sqr(value)
ret=value*value
endfunction ret


function updateland() 
landstate(25,0)=1
landstate(25,1)=1
landstate(25,2)=1
landstate(25,3)=1
landstate(25,4)=1
roadcount=0
for countx=0 to 50
  for countz=0 to 50
    tile=1
    if landstate(countx,countz)=1
      roadcount=roadcount+1
      tile=4
      if countx>0
        if landstate(countx-1,countz)=1
          tile=tile+1
        endif
      endif
      if countz<50
        if landstate(countx,countz+1)=1
          tile=tile+2
        endif
      endif
      if countx<50
        if landstate(countx+1,countz)=1
          tile=tile+4
        endif
      endif
      if countz>0
        if landstate(countx,countz-1)=1
          tile=tile+8
        endif
      endif
    endif
    if tile<>landtile(countx,countz)
      texture object landobjects(countx,countz),tile
      landtile(countx,countz)=tile
    endif
  next countz
next countx
endfunction

function findobj()
res=1
while object exist(res)=1
res=res+1
endwhile
endfunction res

function FillCircle( CX as integer, CY as integer, R as integer ) `Not mine!!! From somewhere on the DBPro forums
   local x as integer
   local y as integer
   local i as integer
   local s as integer

   s=R*0.70710678 : ` this number is sin(45) - precalculate!
   box CX-s, CY-s, CX+s+1, CY+s+1
   s=s+1 : ` Faster than 'inc s'?
   i=R*R
   for y=s to R
      x=sqrt( i-(y*y) )

      ` Draw top and bottom
      box CX-x, CY-y, CX+x+1, CY-y+1
      box CX-x, CY+y, CX+x+1, CY+y+1

      ` Draw left and right
      box CX-y, CY-x, CX-y+1, CY+x+1
      box CX+y, CY-x, CX+y+1, CY+x+1
   next y
endfunction

REM Traffic Simulation
REM By qwe

REM Ini
sync on
sync rate 45
set display mode 1024, 768, 32
set window on
autocam off

REM Set
global maxcars as integer : maxcars = 200
global gridsize as integer : gridsize = 8
global car_speed as float : car_speed = 0.1
set camera range 1.0, 500.0

REM Typ
type cars
	x as float
	z as float
	a as float
	v as float
	to_x as float
	to_z as float
	to as integer
	zone as integer
	o as integer
	xlane as integer
	zlane as integer
	mode as integer
	spot as integer
	light_x as integer
	light_z as integer
endtype

type zones
	enter_x as float
	enter_y as float
	to as integer
	stop as boolean
endtype

type stoplights
	to as integer
	i as integer
	ra as integer
	rb as integer
	rc as integer
	g as integer
	y as integer
	spots_a
	spots_b
	spots_c
	spots_d
	
endtype

type clouds
	offx as float
	offz as float
	o as integer
endtype

REM Var
global stoplight_green_time as integer : stoplight_green_time = 300
global stoplight_yellow_time as integer : stoplight_yellow_time = 60
global character_height as float : character_height = 1.5
global cam_mode : cam_mode = 1
global obj_sidewalkgrass
global img_road
global mc
global oldmc
global keytab
global oldkeytab
global obj_sun
global low_bound as float : low_bound = 100.0-5.0
global high_bound as float : high_bound = ((gridsize-1)*100.0) + 5.0
global maxclouds as integer : maxclouds = 5

REM Arr
DIM s(gridsize, gridsize) as stoplights
DIM c(maxcars) as cars
DIM cloud(maxclouds) as clouds
DIM l(4) as string

REM Load
loading(0, "Initializing")
load_sidewalkgrass()
loading(1, "Loading Roads")
place_roads()
loading(2, "Loading Stoplights and Buildings")
place_stoplights()
loading(3, "Loading Cars")
place_cars()
loading(4, "Loading environment")
place_clouds()

color backdrop rgb(128, 255, 255)
position camera ((gridsize/2.0) * 100.0)-50.0, character_height, ((gridsize/2.0) * 100.0)-50.0

REM Main
do
	set cursor 0,0
	print "FPS: "; screen fps()
	print "Press tab to toggle WALK / ZOOM"
	print "Press enter/+ on numpad to toggle FPS"
	print "WASD moves, Right-Click Looks"
	
	mouse_control()
	run_stoplights()
	run_cars()
	run_clouds()
	if cam_mode = 1 then run_collision()
	
	sync
loop

function run_collision()
	local dist2 as float
	local dx as float
	local dz as float
	local cx as float
	local cz as float
	local ox as float
	local oz as float
	
	REM Var
	cx = camera position x()
	cz = camera position z()
	
	REM Box collision with buildings
	for x = 0 to gridsize
		for y = 0 to gridsize
			
			ox = x*100-50
			oz = y*100-50
			
			dx = cx - ox
			dz = cz - oz
			
			dist2 = dx*dx + dz*dz
			
			`do collision if distance is less than 100 units
			if dist2 < 10000 then boxcol(cx, cz, ox, oz, 42, 42)
			
		next y
	next x
	
	REM Box collision with cars
	for i = 0 to maxcars
		
		ox = object position x(c(i).o)
		oz = object position z(c(i).o)
		
		dx = cx - ox
		dz = cz - oz
		
		dist2 = dx*dx + dz*dz
		
		if dist2 < 100 ` if distance to car is less than 10
			
			if c(i).to = 0 or c(i).to = 2
				`facing z directoin
				boxcol(cx, cz, ox, oz, 2.0, 3.0)
			endif
			if c(i).to = 1 or c(i).to = 3
				`facing x direction
				boxcol(cx, cz, ox, oz, 3.0, 2.0)
			endif
			
		endif
		
	next i
	
endfunction

function boxcol(cx as float, cz as float, ox as float, oz as float, xr as float, zr as float)			
	if cx > ox - xr
		if cx < ox + xr
			if cz > oz - zr
				if cz < oz + zr
					
					za# = abs(cz - oz+zr)
					zc# = abs(cz - oz-zr)
					
					xb# = abs(cx - ox+xr)
					xd# = abs(cx - ox-xr)
					
					a = get_smallest_of_4_floats(za#, zc#, xb#, xd#)
					
					if a = 0
						position camera camera position x(), camera position y(), oz - zr
					endif
					if a = 1
						position camera camera position x(), camera position y(), oz + zr
					endif
					if a = 2
						position camera ox - xr, camera position y(), camera position z()
					endif
					if a = 3
						position camera ox + xr, camera position y(), camera position z()
					endif
					
				endif
			endif
		endif
	endif
endfunction

function get_smallest_of_4_floats(a as float, b as float, c as float, d as float)
	
	if a < b and a < c and a < d then e = 0
	if b < a and b < c and b < d then e = 1
	if c < a and c < b and c < d then e = 2
	if d < a and d < b and d < c then e = 3
	
endfunction e

function run_stoplights()
	for a = 0 to gridsize
		for b = 0 to gridsize
			
			dec s(a, b).i
			
			if s(a, b).i = stoplight_yellow_time
				show object s(a, b).y
				hide object s(a, b).g
			endif
			
			if s(a, b).i = 0
				s(a, b).i = stoplight_green_time
				inc s(a, b).to
				if s(a, b).to = 4 then s(a, b).to = 0
				hide object s(a, b).y
				show object s(a, b).g
				set_stoplight_object(a, b)
			endif
			
		next b
	next a
endfunction

function place_roads()
	local x as float
	local y as float
	
	REM Load source objects
	
	`texture
	img_road = free_img()
	texture(0, 0, 64, 64, 128, 128, 128)
	get image img_road, 0, 0, 64, 64
	
	` Road to right
	obj_right = free_obj()
	make object plain obj_right, 90, 10
	set object cull obj_right, 1
	hide object obj_right
	texture object obj_right, img_road
	scale object texture obj_right, 9, 1
			
	` Road to bottom
	obj_bottom = free_obj()
	make object plain obj_bottom, 10, 90
	set object cull obj_bottom, 1
	hide object obj_bottom
	texture object obj_bottom, img_road
	scale object texture obj_bottom, 1, 9
	
	` streetlight
	o = free_obj()
	make object box o, 0.4, 10, 0.4
	position object o, 0, 5, 0
	inc o
	make object box o, 0.4, 0.4, 2.0
	position object o, 0, 9.8, 1.2
	inc o
	make object box o, 1.0, 0.4, 1.0
	position object o, 0, 9.8, 2.7
	inc o
	make object box o, 90, 0.05, 0.05
	position object o, 0, 9.8, 1.5
	
	obj_streetlight = free_obj()
	merge_objects(o-3, o, obj_streetlight)
	hide object obj_streetlight
	color object obj_streetlight, rgb(192,192,192)
	
	
	
	REM Load instances
	
	for a = 0 to gridsize-1
		for b = 0 to gridsize-1
			
			x = a * 100
			y = b * 100
			
			` Road to right
			o = free_obj()
			instance object o, obj_right
			position object o, x+50, 0, y
			rotate object o, 90, 0, 0
			
			` Road to bottom
			o = free_obj()
			instance object o, obj_bottom
			position object o, x, 0, y+50
			rotate object o, 90, 0, 0
			
			`Streetlight right
			o = free_obj()
			instance object o, obj_streetlight
			position object o, x+33, 0, y-6.0
			
			`Streetlight right
			o = free_obj()
			instance object o, obj_streetlight
			position object o, x+66, 0, y-6.0
			
			`Streetlight bottom
			o = free_obj()
			instance object o, obj_streetlight
			position object o, x-6.0, 0, y+33
			rotate object o, 0, 90, 0
			
			`Streetlight bottom
			o = free_obj()
			instance object o, obj_streetlight
			position object o, x-6.0, 0, y+66
			rotate object o, 0, 90, 0
			
			if a = gridsize-1
				` Road to bottom bottom
				o = free_obj()
				instance object o, obj_bottom
				position object o, x+100, 0, y+50
				rotate object o, 90, 0, 0
			endif
			
			if b = gridsize-1
				` Road to right right
				o = free_obj()
				instance object o, obj_right
				position object o, x+50, 0, y+100
				rotate object o, 90, 0, 0
			endif
			
		next b
	next a
endfunction

function place_stoplights()
	local x as float
	local y as float
	
	REM Load source objects
	
	`intersection road
	obj_intersection_road = free_obj()
	make object plain obj_intersection_road, 10, 10
	set object cull obj_intersection_road, 1
	hide object obj_intersection_road
	texture object obj_intersection_road, img_road
	
	`intersection structure that holds stoplights
	o = free_obj()
	make object box o, 0.4, 10, 0.4
	position object o, -5.2, 5, -5.2
	inc o
	make object box o, 1.5, 2, 1.5
	position object o, -5, 10.2, -5
	inc o
	make object box o, 0.2, 0.2, 6.0
	position object o, 0, 11, 0
	inc o
	make object box o, 0.2, 0.2, 10.0
	position object o, -1.5, 11, -1.5
	obj_structure = free_obj()
	merge_objects(o-3, o, obj_structure)
	rotate limb obj_structure, 3, 0, 135, 0
	rotate limb obj_structure, 4, 0, 45, 0
	color object obj_structure, rgb(192,192,192)
	hide object obj_structure
	
	`stoplight boxes
	obj_stoplight_box = free_obj()
	make object box obj_stoplight_box, 0.4, 1.5, 0.4
	hide object obj_stoplight_box
	color object obj_stoplight_box, rgb(255,255,0)
	obj_stoplight_red = free_obj()
	make object sphere obj_stoplight_red, 0.35, 4, 4
	hide object obj_stoplight_red
	color object obj_stoplight_red, rgb(128,0,0)
	obj_stoplight_yellow = free_obj()
	make object sphere obj_stoplight_yellow, 0.35, 4, 4
	hide object obj_stoplight_yellow
	color object obj_stoplight_yellow, rgb(128,128,0)
	obj_stoplight_green = free_obj()
	make object sphere obj_stoplight_green, 0.35, 4, 4
	hide object obj_stoplight_green
	color object obj_stoplight_green, rgb(0,128,0)
	obj_red = free_obj()
	make object sphere obj_red, 0.45, 4, 4
	hide object obj_red
	color object obj_red, rgb(255,0,0)
	set object emissive obj_red, rgb(255,0,0)
	ghost object on obj_red
	obj_yellow = free_obj()
	make object sphere obj_yellow, 0.45, 4, 4
	hide object obj_yellow
	color object obj_yellow, rgb(255,255,0)
	set object emissive obj_yellow, rgb(255,255,0)
	ghost object on obj_yellow
	obj_green = free_obj()
	make object sphere obj_green, 0.45, 4, 4
	hide object obj_green
	color object obj_green, rgb(0,255,0)
	set object emissive obj_green, rgb(0,255,0)
	ghost object on obj_green
	
	
	REM Load instances
	
	for a = 0 to gridsize
		for b = 0 to gridsize
			
			x = a * 100
			y = b * 100
			
			REM Intersection ground/road object
			o = free_obj()
			instance object o, obj_intersection_road
			position object o, x, 0, y
			rotate object o, 90, 0, 0
			
			REM Building
			if a = gridsize/2 and b = gridsize/2
			else
				place_random_building(x-50, y-50)
			endif
			
			REM sidewalk and grass model
			o = free_obj()
			instance object o, obj_sidewalkgrass
			position object o, x-50, 0, y-50
			rotate object o, 90, 0, 0
			
			REM Stoplight system (var)
			s(a, b).to = rnd(3)
			s(a, b).i = rnd(stoplight_green_time) + 1
			
			REM Stoplight structure model
			o = free_obj()
			instance object o, obj_structure
			position object o, a*100, 0, b*100
			
			REM Stoplights (model)
			o = free_obj()
			instance object o, obj_stoplight_box
			position object o, a*100+2, 10, b*100+2
			inc o
			instance object o, obj_stoplight_box
			position object o, a*100+2, 10, b*100-2
			inc o
			instance object o, obj_stoplight_box
			position object o, a*100-2, 10, b*100+2
			inc o
			instance object o, obj_stoplight_box
			position object o, a*100-2, 10, b*100-2
			inc o
			instance object o, obj_stoplight_red
			position object o, a*100+2.2, 10.375, b*100+2
			inc o
			instance object o, obj_stoplight_red
			position object o, a*100+2, 10.375, b*100-2.2
			inc o
			instance object o, obj_stoplight_red
			position object o, a*100-2, 10.375, b*100+2.2
			inc o
			instance object o, obj_stoplight_red
			position object o, a*100-2.2, 10.375, b*100-2
			inc o
			instance object o, obj_stoplight_yellow
			position object o, a*100+2.2, 10, b*100+2
			inc o
			instance object o, obj_stoplight_yellow
			position object o, a*100+2, 10, b*100-2.2
			inc o
			instance object o, obj_stoplight_yellow
			position object o, a*100-2, 10, b*100+2.2
			inc o
			instance object o, obj_stoplight_yellow
			position object o, a*100-2.2, 10, b*100-2
			inc o
			instance object o, obj_stoplight_green
			position object o, a*100+2.2, 9.625, b*100+2
			inc o
			instance object o, obj_stoplight_green
			position object o, a*100+2, 9.625, b*100-2.2
			inc o
			instance object o, obj_stoplight_green
			position object o, a*100-2, 9.625, b*100+2.2
			inc o
			instance object o, obj_stoplight_green
			position object o, a*100-2.2, 9.625, b*100-2
			
			REM Load brightened circles (reds)
			s(a, b).ra = free_obj()
			instance object s(a, b).ra, obj_red
			s(a, b).rb = free_obj()
			instance object s(a, b).rb, obj_red
			s(a, b).rc = free_obj()
			instance object s(a, b).rc, obj_red
			
			REM Load brightened circles (green and yellow)
			s(a, b).g = free_obj()
			instance object s(a, b).g, obj_green
			s(a, b).y = free_obj()
			instance object s(a, b).y, obj_yellow
			
			REM Set lightened circles to correspond with which direction stoplight is allowing cars to pass
			set_stoplight_object(a, b)
			
		next b
	next a
endfunction

function set_stoplight_object(a, b)
	REM Replace object with correct direction object
	if s(a, b).to = 0 `pos z
		position object s(a, b).g, a*100+2, 9.625, b*100-2.2
		position object s(a, b).y, a*100+2, 10, b*100-2.2
		position object s(a, b).ra, a*100-2.2, 10.375, b*100-2
		position object s(a, b).rb, a*100-2, 10.375, b*100+2.2
		position object s(a, b).rc, a*100+2.2, 10.375, b*100+2
	endif
	if s(a, b).to = 1 `neg x
		position object s(a, b).g, a*100-2.2, 9.625, b*100-2
		position object s(a, b).y, a*100-2.2, 10, b*100-2
		position object s(a, b).ra, a*100+2, 10.375, b*100-2.2
		position object s(a, b).rb, a*100-2, 10.375, b*100+2.2
		position object s(a, b).rc, a*100+2.2, 10.375, b*100+2
	endif
	if s(a, b).to = 2 `neg z
		position object s(a, b).g, a*100-2, 9.625, b*100+2.2
		position object s(a, b).y, a*100-2, 10, b*100+2.2
		position object s(a, b).ra, a*100-2.2, 10.375, b*100-2
		position object s(a, b).rb, a*100+2, 10.375, b*100-2.2
		position object s(a, b).rc, a*100+2.2, 10.375, b*100+2
	endif
	if s(a, b).to = 3 `pos x
		position object s(a, b).g, a*100+2.2, 9.625, b*100+2
		position object s(a, b).y, a*100+2.2, 10, b*100+2
		position object s(a, b).ra, a*100-2.2, 10.375, b*100-2
		position object s(a, b).rb, a*100-2, 10.375, b*100+2.2
		position object s(a, b).rc, a*100+2, 10.375, b*100-2.2
	endif
endfunction

function load_sidewalkgrass()
	`texture
	texture(0, 0, 512, 512, 0, 192, 0)
	texture(4, 0, 20, 512, 192, 192, 192)
	texture(0, 4, 512, 20, 192, 192, 192)
	texture(512-20, 0, 512-4, 512, 192, 192, 192)
	texture(0, 512-20, 512, 512-4, 192, 192, 192)
	img_sidewalkgrass = free_img()
	get image img_sidewalkgrass, 0, 0, 512, 512
	`model
	obj_sidewalkgrass = free_obj()
	make object plain obj_sidewalkgrass, 90, 90
	set object cull obj_sidewalkgrass, 0
	hide object obj_sidewalkgrass
	texture object obj_sidewalkgrass, img_sidewalkgrass
endfunction

function place_random_building(pos_x as float, pos_z as float)
	local height as float
		
		`building var
		height = (rnd(15)+1) * 10.0
		`building texture
		r=rnd(255)
		g=rnd(255)
		b=rnd(255)
		if r > 128
			r = r - abs(r - 128)/2
		else
			r = r + abs(r - 128)/2
		endif
		if g > 128
			g = g - abs(g - 128)/2
		else
			g = g + abs(g - 128)/2
		endif
		if b > 128
			b = b - abs(b - 128)/2
		else
			b = b + abs(b - 128)/2
		endif
		lock pixels
		ink rgb(r, g, b), 0
		box 0, 0, 256, 512
		for x = 1 to 16
			for y = 1 to 32
				if rnd(1) = 1
					ink rgb(255,255,0),0
				else
					ink rgb(0,0,0),0
				endif
				box x*16, y*16, x*16+8, y*16+8
			next y
		next x
		i = free_img()
		unlock pixels
		get image i, 0, 0, 256, height*3.2
		`building model
		o = free_obj()
		make object box o, 80, height, 80
		offset limb o, 0, 0, height/2, 0
		texture object o, i
		position object o, pos_x, 0, pos_z
		`ceiling
		inc o
		make object box o, 80, 1, 80
		color object o, rgb(r,g,b)
		position object o, pos_x, height+0.5, pos_z
	
endfunction

function mouse_control()
	local mmy as float
	local mmx as float
	local spd as float
	
	REM Var
	spd = 0.1
	oldmc = mc
	mc = mouseclick()
	mmy = mousemovey() / 5.0
	mmx = mousemovex() / 5.0
	oldkeytab = keytab
	keytab = keystate(15)
	
	REM Toggle camera mode
	if keytab = 1 and oldkeytab = 0
		if cam_mode = 0
			cam_mode = 1
		else
			cam_mode = 0
		endif
	endif
	
	REM Toggle FPS
	if keystate(78) then sync rate 0
	if keystate(156) then sync rate 45
	
	REM Look
	if mc = 2 and oldmc = 2
		`hide moues while looking around
		hide mouse
		position mouse 512, 384
		`turn camera
		xrotate camera wrapvalue(camera angle x() + mmy)
		yrotate camera wrapvalue(camera angle y() + mmx)
		`bound camera angle
		if camera angle x()>89 and camera angle x()<180 then xrotate camera 89
		if camera angle x()<271 and camera angle x()>180 then xrotate camera 271
	else
		show mouse
	endif
	
	if cam_mode = 1
		REM Move (walk)
		if keystate(42)
			spd = spd * 4
		endif
		if keystate(17)
			position camera newxvalue(camera position x(), camera angle y(), spd), character_height, newzvalue(camera position z(), camera angle y(), spd)
		endif
		if keystate(31)
			position camera newxvalue(camera position x(), camera angle y()-180.0, spd), character_height, newzvalue(camera position z(), camera angle y()-180.0, spd)
		endif          
		if keystate(30)
			position camera newxvalue(camera position x(), camera angle y()-90.0, spd), character_height, newzvalue(camera position z(), camera angle y()-90.0, spd)
		endif
		if keystate(32)
			position camera newxvalue(camera position x(), camera angle y()+90.0, spd), character_height, newzvalue(camera position z(), camera angle y()+90.0, spd)
		endif
	else
		REM Move (zoom)
		spd = spd * 5.0
		if keystate(42)
			spd = spd * 10
		endif
		if keystate(17)
			move camera spd
		endif
		if keystate(31)
			move camera -spd
		endif          
		if keystate(30)
			position camera newxvalue(camera position x(), camera angle y()-90.0, spd), camera position y(), newzvalue(camera position z(), camera angle y()-90.0, spd)
		endif
		if keystate(32)
			position camera newxvalue(camera position x(), camera angle y()+90.0, spd), camera position y(), newzvalue(camera position z(), camera angle y()+90.0, spd)
		endif          
		if keystate(16)
			position camera camera position x(), camera position y() - spd, camera position z()
		endif
		if keystate(18)
			position camera camera position x(), camera position y() + spd, camera position z()
		endif
		if camera position y() < 1.0 then position camera camera position x(), 1.0, camera position z()
	endif

endfunction

function place_clouds()
	
	for i = 0 to maxclouds
		REM Make cloud object
		o = 1000
		make object sphere o, 100, 6, 6
		inc o
		make object sphere o, 100, 6, 6
		inc o
		make object sphere o, 100, 6, 6
		inc o
		make object sphere o, 100, 6, 6
		inc o
		make object sphere o, 100, 6, 6
		inc o
		make object sphere o, 100, 6, 6
		
		for j = o-5 to o
			position object j, rnd(100), rnd(50), rnd(100)
		next j
		
		obj = free_obj()
		merge_objects(o-5, o, obj)
		
		set object emissive obj, rgb(255, 255, 255)
		cloud(i).o = obj
		cloud(i).offx = rnd(600)-300
		cloud(i).offz = rnd(600)-300
		
		inc o
	next i
	
	obj_sun = free_obj()
	make object sphere obj_sun, 25, 12, 12
	set object emissive obj_sun, rgb(255,255,64)
endfunction

function run_clouds()
	for i = 0 to maxclouds
		
		position object cloud(i).o, camera position x() + cloud(i).offx, 200, camera position z() + cloud(i).offz
		inc cloud(i).offx, 0.1
		if cloud(i).offx > 300 then cloud(i).offx = -300.0
		
		position object obj_sun, camera position x(), 400, camera position z()
		
	next i
endfunction

function free_obj()
	repeat
		inc i
		if object exist(i)=0 then found=1
	until found
endfunction i

function free_img()
	repeat
		inc i
		if image exist(i)=0 then found=1
	until found
endfunction i

function merge_objects(SObj,EObj,TOBj)
	Limb=1
	
	make object cube TObj,0.1
	
	for m = SOBj to EObj
		make mesh from object m,m
		add limb TObj,Limb,m
		offset Limb TObj,Limb,Object Position x(m),Object Position y(m),Object Position z(m)
		rotate limb TObj,Limb,Object angle x(m),Object angle y(m),Object angle z(m)
		inc Limb
		delete object m
		delete mesh m
	next m
	
	hide limb TObj, 0
endfunction

function texture(xa, ya, xb, yb, r, g, b)
	lock pixels
	
	ink rgb(r, g, b), 0
	box xa, ya, xb, yb
	
	
	ink rgb(tinc(r), tinc(g), tinc(b)), 0
	for x = xa to xb
		for y = ya to yb
			if rnd(3)
				box x, y, x+1, y+1
			endif
		next y
	next x
	ink rgb(tdec(r), tdec(g), tdec(b)), 0
	for x = xa to xb
		for y = ya to yb
			if rnd(3)
				box x, y, x+1, y+1
			endif
		next y
	next x
	
	unlock pixels
endfunction           

function tinc(a)
	inc a, 8
	if a > 255 then a = 255
endfunction a

function tdec(a)
	dec a, 8
	if a < 0 then a = 0
endfunction a

function loading(i as integer, msg as string)
	l(i) = msg
	cls
	ink rgb(255, 255, 0), 0
	for i = 0 to 4
		print l(i)
	next i
	sync
endfunction

function place_cars()
	local rndxpos as float
	local rndzpos as float
	
	for i = 0 to maxcars
		REM Make car object
		o = create_car()
		c(i).o = o
		
		REM Get random direction and position
		rndpos = rnd(gridsize * 100)
		rndlane = rnd(gridsize)
		
		face = rnd(3)
		if face = 0`posz
			yrotate object o, 0
			rndxpos = rndlane*100+2.5
			rndzpos = rndpos
			c(i).xlane = rndlane
		endif
		if face = 1`negx
			yrotate object o, 90
			rndxpos = rndpos
			rndzpos = rndlane*100+2.5
			c(i).zlane = rndlane
		endif
		if face = 2`negz
			yrotate object o, 180
			rndxpos = rndlane*100-2.5
			rndzpos = rndpos
			c(i).xlane = rndlane
		endif
		if face = 3`posx
			yrotate object o, 270
			rndxpos = rndpos
			rndzpos = rndlane*100-2.5
			c(i).zlane = rndlane
		endif
		
		position object o, rndxpos, 0.00, rndzpos
		c(i).x = object position x(o)
		c(i).z = object position z(o)
		c(i).a = object angle y(o)
		c(i).to = face
	next i
endfunction

function run_cars()
	
	for i = 0 to maxcars
		
		if c(i).mode = 0
			if c(i).to = 0	`if going up
				
				`check to see if near stoplight, if so then goto wait for stoplight mode
				for z = 0 to gridsize
					
					if c(i).z < z*100 - 5 and c(i).z > z*100 - 40
						
						c(i).mode = 1
						c(i).light_x = c(i).xlane
						c(i).light_z = z
						c(i).spot = get_spot_in_line(c(i).light_x, c(i).light_z, c(i).to)
						c(i).to_x = c(i).x
						c(i).to_z = z*100 -  7.5 - c(i).spot * 5
						c(i).v = car_speed
						
					endif
					
				next z
				
				`move along
				inc c(i).z, car_speed
				
			endif
			if c(i).to = 1	`if going left
				
				`check to see if near stoplight, if so then goto wait for stoplight mode
				for x = 0 to gridsize
					
					if c(i).x > x*100 + 5 and c(i).x < x*100 + 40
						
						c(i).mode = 1
						c(i).light_x = x
						c(i).light_z = c(i).zlane
						c(i).spot = get_spot_in_line(c(i).light_x, c(i).light_z, c(i).to)
						c(i).to_x = x*100 +  7.5 + c(i).spot * 5
						c(i).to_z = c(i).z
						c(i).v = car_speed
						
					endif
					
				next z
				
				`move along
				dec c(i).x, car_speed
				
			endif
			if c(i).to = 2	`if going down
				
				`check to see if near stoplight, if so then goto wait for stoplight mode
				for z = 0 to gridsize
					
					if c(i).z < z*100 + 40 and c(i).z > z*100 + 5
						
						c(i).mode = 1
						c(i).light_x = c(i).xlane
						c(i).light_z = z
						c(i).spot = get_spot_in_line(c(i).light_x, c(i).light_z, c(i).to)
						c(i).to_x = c(i).x
						c(i).to_z = z*100 +  7.5 + c(i).spot * 5
						c(i).v = car_speed
						
					endif
					
				next z
				
				`move along
				dec c(i).z, car_speed
				
			endif
			if c(i).to = 3	`if going right
				
				`check to see if near stoplight, if so then goto wait for stoplight mode
				for x = 0 to gridsize
					
					if c(i).x > x*100 - 40 and c(i).x < x*100 - 5
						
						c(i).mode = 1
						c(i).light_x = x
						c(i).light_z = c(i).zlane
						c(i).spot = get_spot_in_line(c(i).light_x, c(i).light_z, c(i).to)
						c(i).to_x = x*100 - 7.5 - c(i).spot * 5
						c(i).to_z = c(i).z
						c(i).v = car_speed
						
					endif
					
				next z
				
				`move along
				inc c(i).x, car_speed
				
			endif
		endif
		
		if c(i).mode = 1
			green = is_stoplight_green(c(i).light_x, c(i).light_z, c(i).to)
			
			if green = 1
				REM If stoplight is GREEN then accelerate and see when enters intersection
				
				inc c(i).v, 0.001
				if c(i).v > car_speed then c(i).v = car_speed
				
				if c(i).to = 0
					inc c(i).z, car_speed
				endif
				if c(i).to = 1
					dec c(i).x, car_speed
				endif
				if c(i).to = 2
					dec c(i).z, car_speed
				endif
				if c(i).to = 3
					inc c(i).x, car_speed
				endif
				
				
				if c(i).x < c(i).light_x*100+4
					if c(i).x > c(i).light_x*100-4
						if c(i).z < c(i).light_z*100+4
							if c(i).z > c(i).light_z*100-4
								REM if car is in intersection
								
								`subtract from slots in line
								erase_slot_in_line(c(i).light_x, c(i).light_z, c(i).to)
								`get new random direction
								c(i).to = get_direction(c(i).light_x, c(i).light_z, c(i).to)
								`set speed
								c(i).v = car_speed
								`new mode: car is now turning towards new lane
								c(i).mode = 2
								
							endif
						endif
					endif
				endif
				
			else
				REM If stoplight is red then stop at place in line
				
				dec c(i).v, 0.0001
				if c(i).v < 0.0 then c(i).v = 0.0
				if c(i).x < c(i).to_x then inc c(i).x, c(i).v
				if c(i).x > c(i).to_x then dec c(i).x, c(i).v
				if c(i).z < c(i).to_z then inc c(i).z, c(i).v
				if c(i).z > c(i).to_z then dec c(i).z, c(i).v
				
			endif
			
		endif
		
		if c(i).mode = 2
			
			x# = c(i).light_x*100
			z# = c(i).light_z*100
			
			if c(i).to = 0
				tox# = x#+2.5
				toz# = z#+5
			endif
			if c(i).to = 1
				tox# = x#-5
				toz# = z#+2.5
			endif
			if c(i).to = 2
				tox# = x#-2.5
				toz# = z#-5
			endif
			if c(i).to = 3
				tox# = x#+5
				toz# = z#-2.5
			endif
			
			point object c(i).o, tox#, 0.00, toz#
			c(i).a = object angle y(c(i).o)
			move object c(i).o, c(i).v
			c(i).x = object position x(c(i).o)
			c(i).z = object position z(c(i).o)
			
			if c(i).x < c(i).light_x*100+5 and c(i).x > c(i).light_x*100-5 and c(i).z < c(i).light_z*100+5 and c(i).z > c(i).light_z*100-5
			else
				REM if car is out of intersection
				`rotate car correctly
				if c(i).to = 0
					c(i).a = 0
				endif
				if c(i).to = 1
					c(i).a = 90
				endif
				if c(i).to = 2
					c(i).a = 180
				endif
				if c(i).to = 3
					c(i).a = 270
				endif
				`set variables
				c(i).mode = 0
				c(i).xlane = c(i).light_x
				c(i).zlane = c(i).light_z
				`place correctly
				c(i).x = tox#
				c(i).z = toz#
			endif
			
		endif
		
		
		
		position object c(i).o, c(i).x, 0.00, c(i).z
		rotate object c(i).o, 0, c(i).a, 0
		
	next i
endfunction

function get_direction(x, z, orig)
	repeat
		
		face = rnd(3)
		found = 1
		
		if x = 0
			if face = 1 then found = 0
		endif
		if x = gridsize
			if face = 3 then found = 0
		endif
		if z = 0
			if face = 2 then found = 0
		endif
		if z = gridsize
			if face = 0 then found = 0
		endif
		
		if face = orig+2 then found = 0
		if face = orig-2 then found = 0
		
	until found = 1
endfunction face

function get_spot_in_line(x, z, face)
	if face = 0
		inc s(x, z).spots_a
		ret = s(x, z).spots_a
	endif
	if face = 1
		inc s(x, z).spots_b
		ret = s(x, z).spots_b
	endif
	if face = 2
		inc s(x, z).spots_c
		ret = s(x, z).spots_c
	endif
	if face = 3
		inc s(x, z).spots_d
		ret = s(x, z).spots_d
	endif
endfunction ret

function erase_slot_in_line(x, z, face)
	if face = 0
		dec s(x, z).spots_a
	endif
	if face = 1
		dec s(x, z).spots_b
	endif
	if face = 2
		dec s(x, z).spots_c
	endif
	if face = 3
		dec s(x, z).spots_d
	endif
endfunction

function is_stoplight_green(x, z, face)
	if face = 0
		if s(x, z).to = 0 then ret = 1
	endif
	if face = 1
		if s(x, z).to = 3 then ret = 1
	endif
	if face = 2
		if s(x, z).to = 2 then ret = 1
	endif
	if face = 3
		if s(x, z).to = 1 then ret = 1
	endif
endfunction ret

function create_car()
	
	o = 1000
	make object box o, 1.5, 1, 3
	position object o, 0, 0.5, 0
	inc o
	make object cylinder o, 0.5
	position object o, 0.75, 0.25, 1
	rotate object o, 90, 0, 90
	inc o
	make object cylinder o, 0.5
	position object o, -0.75, 0.25, 1
	rotate object o, 90, 0, 90
	inc o
	make object cylinder o, 0.5
	position object o, 0.75, 0.25, -1
	rotate object o, 90, 0, 90
	inc o
	make object cylinder o, 0.5
	position object o, -0.75, 0.25, -1
	rotate object o, 90, 0, 90
	inc o
	make object box o, 1.5, 0.66, 1
	position object o, 0, 1.333, 0
	
	ret_obj = free_obj()
	merge_objects(o-5, o, ret_obj)
	
	color object ret_obj, rgb(rnd(255), rnd(255), rnd(255))
	
endfunction ret_obj

sync on
autocam off

tilecolour=0
heatmap=1
tilescalemax=10

roadcolour=rgb(100,100,100)
pavementcolour=rgb(150,150,150)
grasscolour1=rgb(0,100,0)
grasscolour2=rgb(0,80,0)


ink grasscolour1,0
box 0,0,49,49
ink grasscolour2,0
for count=0 to 200
  dot rnd(49),rnd(49)
next count
get image 1,0,0,49,49,1

ink roadcolour,0
box 0,0,99,49
ink pavementcolour,0
box 0,0,49,4
box 0,44,49,49
box 50,0,54,49
box 94,0,99,49
get image 9,0,0,49,49
get image 14,50,0,99,49

ink pavementcolour,0
box 0,0,49,49
ink roadcolour,0
fillcircle(49,49,45) 
ink pavementcolour,0
fillcircle(49,49,5)
get image 16,0,0,49,49,1

ink pavementcolour,0
box 0,0,49,49
ink roadcolour,0
fillcircle(0,49,45) 
ink pavementcolour,0
fillcircle(0,49,5)
get image 13,0,0,49,49,1

ink pavementcolour,0
box 0,0,49,49
ink roadcolour,0
fillcircle(49,0,45) 
ink pavementcolour,0
fillcircle(49,0,5)
get image 10,0,0,49,49,1

ink pavementcolour,0
box 0,0,49,49
ink roadcolour,0
fillcircle(0,0,44) 
ink pavementcolour,0
fillcircle(0,0,4)
get image 7,0,0,49,49,1

ink roadcolour,0
box 0,0,49,49
ink pavementcolour,0
fillcircle(0,0,5)
fillcircle(49,0,5)
fillcircle(0,49,5)
fillcircle(49,49,5)
get image 19,0,0,49,49,1

ink roadcolour,0
box 0,0,49,49
ink pavementcolour,0
fillcircle(49,0,5)
fillcircle(49,49,5)
box 0,0,4,49
get image 18,0,0,49,49,1

ink roadcolour,0
box 0,0,49,49
ink pavementcolour,0
fillcircle(0,49,5)
fillcircle(49,49,5)
box 0,0,49,4
get image 17,0,0,49,49,1

ink roadcolour,0
box 0,0,49,49
ink pavementcolour,0
fillcircle(0,0,5)
fillcircle(0,49,5)
box 44,0,49,49
get image 15,0,0,49,49,1

ink roadcolour,0
box 0,0,49,49
ink pavementcolour,0
fillcircle(0,0,5)
fillcircle(49,0,5)
box 0,44,49,49
get image 11,0,0,49,49,1

ink pavementcolour,0
box 0,0,49,49
ink roadcolour,0
fillcircle(24,24,20)
get image 4,0,0,49,49,1

ink pavementcolour,0
box 0,0,49,49
ink roadcolour,0
fillcircle(24,24,20)
box 0,4,25,44
get image 5,0,0,49,49,1

ink pavementcolour,0
box 0,0,49,49
ink roadcolour,0
fillcircle(24,24,20)
box 4,0,44,25
get image 6,0,0,49,49,1

ink pavementcolour,0
box 0,0,49,49
ink roadcolour,0
fillcircle(24,24,20)
box 25,4,49,44
get image 8,0,0,49,49,1

ink pavementcolour,0
box 0,0,49,49
ink roadcolour,0
fillcircle(24,24,20)
box 4,25,44,49
get image 12,0,0,49,49,1

ink pavementcolour,0
box 0,0,49,49
ink roadcolour,0
box 22,5,27,49
box 19,5,30,28
ink rgb(255,0,0),0
fillcircle(24,9,3)
ink rgb(255,128,0),0
fillcircle(24,16,3)
ink rgb(0,200,0),0
fillcircle(24,23,3)

get image 25,0,0,49,49,1

ink rgb(50,50,50),0
box 0,0,19,39
ink rgb(128,0,0),0
fillcircle(9,9,4)
ink rgb(128,64,0),0
fillcircle(9,19,4)
ink rgb(0,255,0),0
fillcircle(9,29,5)
get image 26,0,0,19,39,1

ink rgb(50,50,50),0
box 0,0,19,39
ink rgb(128,0,0),0
fillcircle(9,9,4)
ink rgb(255,128,0),0
fillcircle(9,19,5)
ink rgb(0,128,0),0
fillcircle(9,29,4)
get image 28,0,0,19,39,1

ink rgb(50,50,50),0
box 0,0,19,39
ink rgb(255,0,0),0
fillcircle(9,9,5)
ink rgb(128,64,0),0
fillcircle(9,19,4)
ink rgb(0,128,0),0
fillcircle(9,29,4)
get image 27,0,0,19,39,1

type lights
  exist as boolean
  direction as integer
  timecount as integer
  waiting as integer
  changing as integer
endtype

global roadcount as integer
dim landobjects(50,50)
dim landtestobjects(50,50)
dim landtile(50,50)
dim landstate(50,50)
dim landoccupied(50,50,8)
dim landheat(50,50)
dim landheated(50,50)
dim landbuildobjects(50,50,4)
dim landlights(50,50) as lights

for countx=0 to 50
  for countz=0 to 50
    landobjects(countx,countz)=findobj()
    make object plain landobjects(countx,countz),1,1
    xrotate object landobjects(countx,countz),-90
    position object landobjects(countx,countz),countx,0,countz
    texture object landobjects(countx,countz),1
    landtile(countx,countz)=1
    landstate(countx,countz)=0
  next countz
next countx


ink rgb(255,255,255),0
box 0,0,50,50
ink 0,0
text 10,15,"dest"
get image 20,1,1,50,50

destobj=findobj()
make object plain destobj,1,1
xrotate object destobj,-90
hide object destobj
texture object destobj,20
set alpha mapping on destobj,50

ink rgb(255,50,50),0
box 0,0,50,50
ink 0,0
text 10,15,"next"
get image 21,1,1,50,50

nextobj=findobj()
make object plain nextobj,1,1
xrotate object nextobj,-90
hide object nextobj
texture object nextobj,21
set alpha mapping on nextobj,50

ink rgb(50,50,255),0
box 0,0,50,50
ink 0,0
text 10,15,"curr"

get image 22,1,1,50,50

currobj=findobj()
make object plain currobj,1,1
xrotate object currobj,-90
hide object currobj
texture object currobj,22
set alpha mapping on currobj,50

global trafficlightobj as integer
trafficlightobj=findobj()
make object box trafficlightobj,0.05,0.4,0.05
color object trafficlightobj,rgb(150,150,150)

templightobj=findobj()
make object plain templightobj,0.1,0.2
yrotate object templightobj,90
fix object pivot templightobj

make mesh from object 1,templightobj
add limb trafficlightobj,1,1
offset limb trafficlightobj,1,-0.05,0.3,0

yrotate object templightobj,90
fix object pivot templightobj
delete mesh 1
make mesh from object 1,templightobj
add limb trafficlightobj,2,1
offset limb trafficlightobj,2,0,0.3,0.05

yrotate object templightobj,90
fix object pivot templightobj
delete mesh 1
make mesh from object 1,templightobj
add limb trafficlightobj,3,1
offset limb trafficlightobj,3,0.05,0.3,0

yrotate object templightobj,90
fix object pivot templightobj
delete mesh 1
make mesh from object 1,templightobj
add limb trafficlightobj,4,1
offset limb trafficlightobj,4,0,0.3,-0.05

delete object templightobj
make object plain templightobj,0.1,0.1
xrotate object templightobj,90
fix object pivot templightobj
delete mesh 1
make mesh from object 1,templightobj
add limb trafficlightobj,5,1
offset limb trafficlightobj,5,0,0.2,0
add limb trafficlightobj,6,1
offset limb trafficlightobj,6,0,0.4,0

hide object trafficlightobj
//position object trafficlightobj,24.5,0.2,1.5
//newlight=findobj()
//clone object newlight,trafficlightobj
//position object newlight,25.5,0.2,1.5


cursorx=20
cursorz=20
cursorobj=findobj()
make object box cursorobj,1,0.1,1
position object cursorobj,cursorx,0.05,cursorz
ghost object on cursorobj,1
`set alpha mapping on cursorobj,30

cursormode=0

position camera 21,10,10
point camera 21,0,21

updateland()

dim targeterobj(5)
for count=1 to 5
  targeterobj(count)=findobj()
  make object plain targeterobj(count),0.1,0.1
  hide object targeterobj(count)
next count

type Car
 obj as integer
 testobj as integer
 colour as integer
 posx as integer
 posy as integer
 destx as integer
 desty as integer
 nextx as integer
 nexty as integer
 prevx as integer
 prevy as integer
 propx as integer
 propy as integer
 sideofroad as integer
 changed as integer
endtype

dim cars(0) as Car

sw=screen width()
sh=screen height()
camtilt#=50
camzoom#=8
camrot#=0
cammodrange=2
camx#=25
camz#=0
position camera camx#,0,camz#
xrotate camera camtilt#
yrotate camera camrot#
move camera -camzoom#
mmx=mousemovex()
mmy=mousemovey() 

time=timer()

ink rgb(255,255,255),0

do
  
  lasttime=time
  time=timer()
  carupdate#=carupdate#+((time-lasttime)/1000.0)

  mx=mousex()
  my=mousey()
  closest=1
  if movingcam=0
    stop=0
    while (closest<>5) AND (stop=0)
      if ((cursorx>50) OR (cursorx<0)) OR ((cursorz>50) OR (cursorz<0)) then stop=1
      position object targeterobj(1),cursorx-1,0,cursorz
      position object targeterobj(2),cursorx,0,cursorz+1
      position object targeterobj(3),cursorx+1,0,cursorz
      position object targeterobj(4),cursorx,0,cursorz-1
      position object targeterobj(5),cursorx,0,cursorz
      mx=mousex()
      my=mousey()
      closestdist=sqrt(sqr(object screen x(targeterobj(1))-mx)+sqr(object screen y(targeterobj(1))-my))
      closest=1
      dist=sqrt(sqr(object screen x(targeterobj(2))-mx)+sqr(object screen y(targeterobj(2))-my))
      if dist<closestdist
        closest=2
        closestdist=dist
      endif
      dist=sqrt(sqr(object screen x(targeterobj(3))-mx)+sqr(object screen y(targeterobj(3))-my))
      if dist<closestdist
        closest=3
        closestdist=dist
      endif
      dist=sqrt(sqr(object screen x(targeterobj(4))-mx)+sqr(object screen y(targeterobj(4))-my))
      if dist<closestdist
        closest=4
        closestdist=dist
      endif
          dist=sqrt(sqr(object screen x(targeterobj(5))-mx)+sqr(object screen y(targeterobj(5))-my))
      if dist<closestdist
        closest=5
      endif
      select closest
        case 1
          cursorx=cursorx-1
          tilechange=0
        endcase
        case 2
          cursorz=cursorz+1
          tilechange=0
        endcase
        case 3
          cursorx=cursorx+1 
          tilechange=0 
        endcase
        case 4
          cursorz=cursorz-1
          tilechange=0
        endcase
      endselect
      
    endwhile
    if cursorx>50 then cursorx=50   
    if cursorx<0 then cursorx=0   
    if cursorz>50 then cursorz=50   
    if cursorz<0 then cursorz=0
    position object cursorobj,cursorx,0.05,cursorz
  endif
  
  mmx=mousemovex()
  mmy=mousemovey()
  movecam=0
  lmb=0
  mmb=0
  rmb=0
  
  mv=mouseclick()
  if int(mv/8)=1
    mv=mv-8
  endif
  if int(mv/4)=1
    mv=mv-4
    mmb=1
  endif
  if int(mv/2)=1
    mv=mv-2
    rmb=1
  endif
  if mv=1
    lmb=1
  endif
  
  if (mmb=1) OR (rmb=1)
    if movingcam=0
      cammousex=mousex()
      cammousey=mousey()
    endif
    if rmb=1
      if (mmx<>0) OR (mmy<>0)
        mcamx#=mcamx#-(mmx/30.0)
        mcamz#=mcamz#+(mmy/30.0)
        movecam=1
      endif
    else
      if (mmx<>0) OR (mmy<>0)
        camrot#=camrot#+(mmx/2)
        camtilt#=camtilt#+(mmy/2)
        movecam=1
      endif
    endif

    if camtilt#>90 then camtilt#=90
    if camtilt#<20 then camtilt#=20
    if camrot#>180 then camrot#=180
    if camrot#<-180 then camrot#=-180
    movingcam=1
    hide mouse
  else 
    if movingcam=1
      show mouse
      set cursor cammousex,cammousey
    endif
    movingcam=0
  endif
  
  mz=mousemovez()
  if mz<>0
    camzoom#=camzoom#-(mz/100)
      if camzoom#>50 then camzoom#=50
      if camzoom#<1.5 then camzoom#=1.5
      movecam=1
  endif
  
  if movecam=1
    position camera camx#,0,camz#
    rotate camera 0,0,0
    yrotate camera camrot#
    move camera mcamz#
    yrotate camera camera angle y()+90
    move camera mcamx#
    camx#=camera position x()
    camz#=camera position z()
    yrotate camera camrot#
    xrotate camera camtilt#

    move camera -camzoom#

    mcamx#=0
    mcamz#=0
  endif
  
  if spacekey() or (lmb=1)
    if (mousex()<120) AND (mousey()<60)
      cursormode=mousex()/60
    else
      select cursormode
        case 0
          if tilechange=0  
            if ((cursorx>-1) AND (cursorx<51)) AND ((cursorz>-1) AND (cursorz<51))
              if changestate=-1
                if landstate(cursorx,cursorz)=1
                  landstate(cursorx,cursorz)=0
                  changestate=0
                else
                  landstate(cursorx,cursorz)=1
                  changestate=1
                endif
              else
                landstate(cursorx,cursorz)=changestate
              endif
              updateland()
            endif
          endif 
          tilechange=1
        endcase
        case 1
          if tilechange=0  
            if ((cursorx>-1) AND (cursorx<51)) AND ((cursorz>-1) AND (cursorz<51))
              if changestate=-1
                if landlights(cursorx,cursorz).exist=1
                  deletelights(cursorx,cursorz)
                  changestate=0
                else
                  if (landlights(cursorx,cursorz).exist=0) AND (landtile(cursorx,cursorz)=19)
                    addlights(cursorx,cursorz)
                  endif
                  changestate=1
                endif
              else
                if changestate=0
                  if landlights(cursorx,cursorz).exist=1
                    deletelights(cursorx,cursorz)         
                  endif         
                else
                  if (landlights(cursorx,cursorz).exist=0) AND (landtile(cursorx,cursorz)=19)
                    addlights(cursorx,cursorz)
                  endif
                endif
              endif
              updateland()
            endif
          endif 
          tilechange=1
        endcase
      endselect
    endif
  else
    tilechange=0
    changestate=-1
  endif
  
  if keystate(15)=1
    if keytab=0
      cursormode=cursormode+1
      if cursormode>1 then cursormode=0
    endif
    keytab=1
  else
    keytab=0
  endif
  
  if  returnkey()
    if ((landoccupied(25,0,1)=0) AND (landoccupied(25,0,2)=0)) AND ((landoccupied(25,0,4)=0) AND (landoccupied(25,0,8)=0))
      addcar()
    endif
  endif
  
  position object cursorobj,cursorx,0.05,cursorz

  updatecar=0
  if carupdate#>1.0
    updatecar=1
    carupdate#=0.0
    dim landoccupied(0,0,0)
    dim landoccupied(50,50,8)
    landoccupied(0,0,0)=0
    dim landheated(0,0)
    dim landheated(50,50)
    landheated(0,0)=0
  endif
  

    
  for c=1 to array count(cars(0))
    
    if updatecar=1
      if (cars(c).posx<>cars(c).nextx) OR (cars(c).posy<>cars(c).nexty)
        cars(c).prevx=cars(c).posx
        cars(c).prevy=cars(c).posy 
      endif
      cars(c).posx=cars(c).nextx
      cars(c).posy=cars(c).nexty
      
      if tilecolour=1 then position object cars(c).testobj,cars(c).posx,0.01,cars(c).posy

      if ((cars(c).posx=cars(c).destx) AND (cars(c).posy=cars(c).desty)) OR (landstate(cars(c).destx,cars(c).desty)=0)
        givedestination(c)
      endif
      dim pathfindnums(0,0)
      dim pathfindnums(50,50)
  
      
      for cx=0 to 50
        for cy=0 to 50
          pathfindnums(cx,cy)=-1
        next cy
      next cx
      pathfindnums(cars(c).destx,cars(c).desty)=1
      pathnum=1  
      largest=0 
      roadmarked=0
      do
        pathnum=pathnum+1
        stop=0
        
        for cx=0 to 50
          for cy=0 to 50
            if ((pathnum-1)-landheat(cx,cy))>0
              if pathfindnums(cx,cy)=(pathnum-1)-landheat(cx,cy)
                roadmarked=roadmarked+1
                if cx>0
                  if ((landstate(cx-1,cy)=1) AND (pathfindnums(cx-1,cy)=-1))
                    pathfindnums(cx-1,cy)=pathnum
                    if c=selectedcar then text object screen x(landobjects(cx-1,cy)),object screen y(landobjects(cx-1,cy)),str$(pathnum)
                    if (cx-1=cars(c).posx) AND (cy=cars(c).posy)
                      stop=1
                    endif
                  endif
                endif
                if cx<50
                  if ((landstate(cx+1,cy)=1) AND (pathfindnums(cx+1,cy)=-1))
                    pathfindnums(cx+1,cy)=pathnum
                    largest=pathnum
                    if c=selectedcar then text object screen x(landobjects(cx+1,cy)),object screen y(landobjects(cx+1,cy)),str$(pathnum)
                    if (cx+1=cars(c).posx) AND (cy=cars(c).posy)
                      stop=1
                    endif
                  endif
                endif
                if cy>0
                  if ((landstate(cx,cy-1)=1) AND (pathfindnums(cx,cy-1)=-1))
                    pathfindnums(cx,cy-1)=pathnum
                    if c=selectedcar then text object screen x(landobjects(cx,cy-1)),object screen y(landobjects(cx,cy-1)),str$(pathnum)
                    if (cx=cars(c).posx) AND (cy-1=cars(c).posy)
                      stop=1
                    endif
                  endif
                endif
                if cy<50
                  if ((landstate(cx,cy+1)=1) AND (pathfindnums(cx,cy+1)=-1))
                    pathfindnums(cx,cy+1)=pathnum
                    if c=selectedcar then text object screen x(landobjects(cx,cy+1)),object screen y(landobjects(cx,cy+1)),str$(pathnum)
                    if (cx=cars(c).posx) AND (cy+1=cars(c).posy)
                      stop=1
                    endif
                  endif
                endif
              endif
            endif
          next cy
        next cx
        if stop=1
          exit
        endif
        if pathnum>1000
          cars(c).destx=cars(c).posx
          cars(c).desty=cars(c).posy
          exit
        endif
      loop
        if (controlkey()) AND (c=selectedcar)
          text 5,25,str$(roadmarked)
          sync
          wait key
        endif  
      if cars(c).posx>0
        if pathfindnums(cars(c).posx-1,cars(c).posy)>-1
          cars(c).nextx=cars(c).posx-1
          cars(c).nexty=cars(c).posy
          cars(c).sideofroad=8
          landoccupied(cars(c).nextx,cars(c).nexty,8)=landoccupied(cars(c).nextx,cars(c).nexty,8)+1
        endif
      endif
      if cars(c).posx<50
        if pathfindnums(cars(c).posx+1,cars(c).posy)>-1
          cars(c).nextx=cars(c).posx+1
          cars(c).nexty=cars(c).posy
          cars(c).sideofroad=2
          landoccupied(cars(c).nextx,cars(c).nexty,2)=landoccupied(cars(c).nextx,cars(c).nexty,2)+1
        endif
      endif
      if cars(c).posy>0
        if pathfindnums(cars(c).posx,cars(c).posy-1)>-1
          cars(c).nextx=cars(c).posx
          cars(c).nexty=cars(c).posy-1
          cars(c).sideofroad=4
          landoccupied(cars(c).nextx,cars(c).nexty,4)=landoccupied(cars(c).nextx,cars(c).nexty,4)+1
        endif
      endif
      if cars(c).posy<50
        if pathfindnums(cars(c).posx,cars(c).posy+1)>-1
          cars(c).nextx=cars(c).posx
          cars(c).nexty=cars(c).posy+1
          cars(c).sideofroad=1
          landoccupied(cars(c).nextx,cars(c).nexty,1)=landoccupied(cars(c).nextx,cars(c).nexty,1)+1
        endif
      endif   
      cars(c).propx=cars(c).nextx
      cars(c).propy=cars(c).nexty
    cars(c).changed=0  
    endif
      
  movecar(cars(c).obj,carupdate#,cars(c).prevx,cars(c).prevy,cars(c).posx,cars(c).posy,cars(c).nextx,cars(c).nexty)
  
  next c

  
  
  if updatecar=1
    updatelights()

    stoploop=0
    changestext=0
    while stoploop=0
      changes=0
      for c=1 to array count(cars(0))
        if cars(c).changed=0
        
          waitcar=0
          if (cars(c).posx=cars(c).nextx) AND (cars(c).posy=cars(c).nexty)
            waitcar=1
          endif
          if landoccupied(cars(c).nextx,cars(c).nexty,cars(c).sideofroad)-1>0
            waitcar=1
          endif
          `if landoccupied(cars(c).nextx,cars(c).nexty,rotatevalc(cars(c).sideofroad))>0
            `waitcar=1
          `endif
          `if landoccupied(cars(c).nextx,cars(c).nexty,rotatevalcc(cars(c).sideofroad))>0
            `waitcar=1
          `endif
          if (landlights(cars(c).posx,cars(c).posy).exist=1)
            if (cars(c).sideofroad=2) OR (cars(c).sideofroad=8)
              if landlights(cars(c).posx,cars(c).posy).direction=1
                waitcar=1 
                landlights(cars(c).posx,cars(c).posy).waiting=landlights(cars(c).posx,cars(c).posy).waiting+1            
              endif
            else
              if landlights(cars(c).posx,cars(c).posy).direction=0
                waitcar=1 
                landlights(cars(c).posx,cars(c).posy).waiting=landlights(cars(c).posx,cars(c).posy).waiting+1 
              endif
            endif
          else
            select cars(c).sideofroad
              case 1
                if cars(c).nextx<50
                  if landoccupied(cars(c).nextx+1,cars(c).nexty,rotatevalc(cars(c).sideofroad))>0
                    waitcar=1
                  endif
                endif
              endcase
              case 2
                if cars(c).nexty>0
                  if landoccupied(cars(c).nextx,cars(c).nexty-1,rotatevalc(cars(c).sideofroad))>0
                    waitcar=1
                  endif
                endif
              endcase
              case 4
                if cars(c).nextx>0
                  if landoccupied(cars(c).nextx-1,cars(c).nexty,rotatevalc(cars(c).sideofroad))>0
                    waitcar=1
                  endif
                endif
              endcase
              case 8
                if cars(c).nexty<50
                  if landoccupied(cars(c).nextx,cars(c).nexty+1,rotatevalc(cars(c).sideofroad))>0
                    waitcar=1
                  endif
                endif
              endcase
            endselect
          endif
          
          if waitcar=1
            landheat(cars(c).posx,cars(c).posy)=landheat(cars(c).posx,cars(c).posy)+1
            landheated(cars(c).posx,cars(c).posy)=1
            cars(c).changed=1
            changestext=changestext+1
            landoccupied(cars(c).nextx,cars(c).nexty,cars(c).sideofroad)=landoccupied(cars(c).nextx,cars(c).nexty,cars(c).sideofroad)-1
            cars(c).nextx=cars(c).posx
            cars(c).nexty=cars(c).posy
            calculateprevsor(c)
            landoccupied(cars(c).nextx,cars(c).nexty,cars(c).sideofroad)=landoccupied(cars(c).nextx,cars(c).nexty,cars(c).sideofroad)+1
            changes=changes+1
          endif
        endif
      next c
      if changes=0 then stoploop=1
    endwhile
      for cx=0 to 50
        for cy=0 to 50
          if landheated(cx,cy)=0 then landheat(cx,cy)=0
        next cy
      next cx

  endif

remstart 
for cx=0 to 50
  for cy=0 to 50
    if landheat(cx,cy)>0
      if object in screen(landobjects(cx,cy))
        value#=landheat(cx,cy)/10.0
        if value#>1.0 then value#=1.0   
        ink rgb(255,255-(value#*255.0),255-(value#*255.0)),0
        text object screen x(landobjects(cx,cy)),object screen y(landobjects(cx,cy)), str$(landheat(cx,cy))
        
      endif
    endif
  next cy
next cx


for c=1 to array count(cars(0))
  if (cars(c).posx=cars(c).propx) AND (cars(c).posy=cars(c).propy)
    text object screen x(cars(c).obj),object screen y(cars(c).obj),"!!!"
  endif
next c

if shiftkey()=1
  if keyshift=0
    selectedcar=pick object(mousex(),mousey(),cars(1).obj,cars(array count(cars(0))).obj)
    if selectedcar<>0 then selectedcar=(selectedcar-cars(1).obj)+1
  endif
  keyshift=1
else
  keyshift=0
endif remend

if selectedcar<>0
  text object screen x(cars(selectedcar).obj),object screen y(cars(selectedcar).obj),"<--"
  show object destobj
  show object nextobj
  show object currobj
  position object destobj,cars(selectedcar).destx,0.001,cars(selectedcar).desty
  position object nextobj,cars(selectedcar).propx,0.001,cars(selectedcar).propy
  position object currobj,cars(selectedcar).posx,0.001,cars(selectedcar).posy
else
hide object destobj
hide object nextobj
hide object currobj
endif

    
ink 0,0   

box (cursormode*55)+3,3,((cursormode+1)*55)+1,56

ink rgb(255,255,255),0   
paste image 14,5,5
paste image 25,60,5
sync
loop

function deletelights(x,y)
  delete object landbuildobjects(x,y,1)
  delete object landbuildobjects(x,y,2)
  delete object landbuildobjects(x,y,3)
  delete object landbuildobjects(x,y,4)
  landlights(x,y).exist=0
endfunction

function updatelights
  for cx=0 to 50
    for cy=0 to 50
      if landlights(cx,cy).exist=1
        landlights(cx,cy).timecount=landlights(cx,cy).timecount+1
        
        if landlights(cx,cy).changing=1
          landlights(cx,cy).changing=0
          landlights(cx,cy).timecount=0
          landlights(cx,cy).waiting=0
          if landlights(cx,cy).direction=0
            landlights(cx,cy).direction=1
          else
            landlights(cx,cy).direction=0
          endif          
          for c=1 to 4
            texture limb landbuildobjects(cx,cy,c),1,26+landlights(cx,cy).direction
            texture limb landbuildobjects(cx,cy,c),2,27-landlights(cx,cy).direction
            texture limb landbuildobjects(cx,cy,c),3,26+landlights(cx,cy).direction
            texture limb landbuildobjects(cx,cy,c),4,27-landlights(cx,cy).direction
          next c
        endif

        if (landlights(cx,cy).timecount>3) AND (landlights(cx,cy).timecount+landlights(cx,cy).waiting>10)
          landlights(cx,cy).changing=1
          for c=1 to 4
            texture limb landbuildobjects(cx,cy,c),1,28
            texture limb landbuildobjects(cx,cy,c),2,28
            texture limb landbuildobjects(cx,cy,c),3,28
            texture limb landbuildobjects(cx,cy,c),4,28
          next c
        endif
      endif
    next cx
  next cy
endfunction

function addlights(x,y)
  landbuildobjects(x,y,1)=findobj()
  clone object landbuildobjects(x,y,1),trafficlightobj
  position object landbuildobjects(x,y,1),x-0.5,0.2,y-0.5
  landbuildobjects(x,y,2)=findobj()
  clone object landbuildobjects(x,y,2),trafficlightobj
  position object landbuildobjects(x,y,2),x-0.5,0.2,y+0.5
  landbuildobjects(x,y,3)=findobj()
  clone object landbuildobjects(x,y,3),trafficlightobj
  position object landbuildobjects(x,y,3),x+0.5,0.2,y+0.5
  landbuildobjects(x,y,4)=findobj()
  clone object landbuildobjects(x,y,4),trafficlightobj
  position object landbuildobjects(x,y,4),x+0.5,0.2,y-0.5
  
  landlights(x,y).exist=1
  for c=1 to 4
    texture limb landbuildobjects(x,y,c),1,26
    texture limb landbuildobjects(x,y,c),2,27
    texture limb landbuildobjects(x,y,c),3,26
    texture limb landbuildobjects(x,y,c),4,27
  next c
endfunction

function calculateprevsor(carnum)
  xdif=cars(carnum).prevx-cars(carnum).posx
  ydif=cars(carnum).prevy-cars(carnum).posy
  if (xdif=0) AND (ydif=-1)
    sor=1
  endif
  if (xdif=-1) AND (ydif=0)
    sor=2
  endif
  if (xdif=0) AND (ydif=1)
    sor=4
  endif
  if (xdif=1) AND (ydif=0)
    sor=8
  endif
  cars(carnum).sideofroad=sor
endfunction

function movecar(obj,time#,prevx,prevy,posx,posy,nextx,nexty)
  if (offsettovalue(prevx-posx,prevy-posy))<>(offsettovalue(nextx-posx,nexty-posy))
    direction=offsettovalue(prevx-posx,prevy-posy)+offsettovalue(nextx-posx,nexty-posy)
    if (posx=nextx) AND (posy=nexty) 
      direction=offsettovalue(prevx-posx,prevy-posy)+oppval(offsettovalue(prevx-posx,prevy-posy))
      time#=0
    endif
    if (direction=5) or (direction=10) 
      x#=(time#*toward#(nextx,0.5,posx))+((1.0-time#)*toward#(prevx,0.5,posx))
      y#=(time#*toward#(nexty,0.5,posy))+((1.0-time#)*toward#(prevy,0.5,posy))   
    endif
    select direction
      case 5
        angle#=90
        if offsettovalue(prevx-posx,prevy-posy)=4
          y#=y#-0.2
        else
          y#=y#+0.2
        endif
      endcase
      case 10
        angle#=0
        if offsettovalue(prevx-posx,prevy-posy)=8
          x#=x#-0.2
        else
          x#=x#+0.2
        endif
      endcase
      case 12
        if prevy-posy=-1
          x#=(posx+0.5)+rotatex#(-0.7,0,-time#*90.0)
          y#=(posy-0.5)+rotatey#(-0.7,0,-time#*90.0)
          angle#=(90.0*time#)
        else
          x#=(posx+0.5)+rotatex#(0,0.3,time#*90.0)
          y#=(posy-0.5)+rotatey#(0,0.3,time#*90.0)
          angle#=270.0-(90.0*time#)
        endif
      endcase
      case 9
        if prevx-posx=-1
          x#=(posx-0.5)+rotatex#(0,0.7,-time#*90.0)
          y#=(posy-0.5)+rotatey#(0,0.7,-time#*90.0)
          angle#=(90.0*time#)+90.0
        else
          x#=(posx-0.5)+rotatex#(0.3,0,time#*90.0)
          y#=(posy-0.5)+rotatey#(0.3,0,time#*90.0)
          angle#=180.0-(90.0*time#)
        endif
      endcase
      case 3
        if prevy-posy=1
          x#=(posx-0.5)+rotatex#(0.7,0,-time#*90.0)
          y#=(posy+0.5)+rotatey#(0.7,0,-time#*90.0)
          angle#=(90.0*time#)+180.0
        else
          x#=(posx-0.5)+rotatex#(0,-0.3,time#*90.0)
          y#=(posy+0.5)+rotatey#(0,-0.3,time#*90.0)
          angle#=90.0-(90.0*time#)
        endif
      endcase
      case 6
        if prevx-posx=1
          x#=(posx+0.5)+rotatex#(0,-0.7,-time#*90.0)
          y#=(posy+0.5)+rotatey#(0,-0.7,-time#*90.0)
          angle#=(90.0*time#)+270.0
        else
          x#=(posx+0.5)+rotatex#(-0.3,0,time#*90.0)
          y#=(posy+0.5)+rotatey#(-0.3,0,time#*90.0)
          angle#=-(90.0*time#)
        endif
      endcase
    endselect
  else
    select offsettovalue(prevx-posx,prevy-posy)
      case 1
        x#=(posx-0.5)+rotatex#(0,0.2,-time#*180.0)
        y#=(posy)+rotatey#(0,0.2,-time#*180.0)
        angle#=(180.0*time#)+90
      endcase
      case 2
        x#=(posx)+rotatex#(0.2,0,-time#*180.0)
        y#=(posy+0.5)+rotatey#(0.2,0,-time#*180.0)
        angle#=(180.0*time#)
      endcase
      case 4
        x#=(posx+0.5)+rotatex#(0,-0.2,-time#*180.0)
        y#=(posy)+rotatey#(0,-0.2,-time#*180.0)
        angle#=(180.0*time#)+90
      endcase
      case 8
        x#=(posx)+rotatex#(-0.2,0,-time#*180.0)
        y#=(posy-0.5)+rotatey#(-0.2,0,-time#*180.0)
        angle#=(180.0*time#)
      endcase
    endselect
  endif
  yrotate object obj,angle#
  position object obj,x#,0.1,y#
endfunction

function rotatex#(x#,y#,value#)
       result#=((x#*cos(value#))-(y#*sin(value#)));;
endfunction result#

function rotatey#(x#,y#,value#)
       result#=((x#*sin(value#))+(y#*cos(value#)));
endfunction result#

function toward#(value#,amount#,target#)
  ret#=value#
  if value#<target#
    ret#=value#+amount#
  endif
  if value#>target#
    ret#=value#-amount#
  endif
endfunction ret#

function offsettovalue(xoffset,yoffset)
ret=0
if xoffset<0 then ret=ret+1
if xoffset>0 then ret=ret+4
if yoffset<0 then ret=ret+8
if yoffset>0 then ret=ret+2
endfunction ret

function oppval(value)
  select value
    case 1
      res=4
    endcase
    case 2
      res=8
    endcase
    case 4
      res=1
    endcase
    case 8
      res=2
    endcase
  endselect
endfunction res

function rotatevalc(value)
  select value
    case 1
      res=2
    endcase
    case 2
      res=4
    endcase
    case 4
      res=8
    endcase
    case 8
      res=1
    endcase
  endselect
endfunction res

function rotatevalcc(value)
  select value
    case 1
      res=8
    endcase
    case 2
      res=1
    endcase
    case 4
      res=2
    endcase
    case 8
      res=4
    endcase
  endselect
endfunction res

function contains(value,direction)
  ret=0
  v=value
  if int(v/8)=1
    v=v-8
    if direction=8 then ret=1
  endif
  if int(v/4)=1
    v=v-4
    if direction=4 then ret=1
  endif
  if int(v/2)=1
    v=v-2
    if direction=2 then ret=1
  endif
  if v=1
    if direction=1 then ret=1
  endif
endfunction ret

function addcar()
  array insert at bottom cars(0)
  curr=array count(cars(0))
  cars(curr).obj=findobj()
  make object box cars(curr).obj,0.25,0.15,0.4
  position object cars(curr).obj,25,0.1,0
  cars(curr).prevx=25
  cars(curr).prevy=-2
  cars(curr).posx=25
  cars(curr).posy=-1
  cars(curr).nextx=25
  cars(curr).nexty=0
  cars(curr).destx=25
  cars(curr).desty=0
  cars(curr).colour=rgb(rnd(255),rnd(255),rnd(255))
  color object cars(curr).obj,cars(curr).colour
  if tilecolour=1  
    cars(curr).testobj=findobj()
    make object plain cars(curr).testobj,1,1
    xrotate object cars(curr).testobj,-90
    color object cars(curr).testobj,cars(curr).colour
  endif
  landoccupied(25,0,1)=landoccupied(25,0,1)+1
endfunction

function givedestination(c)
dim possiblesx(0)
dim possiblesy(0)

for countx=0 to 50
  for county=0 to 50
    if (landstate(countx,county)=1) AND ((cars(c).posx<>countx) OR (cars(c).posy<>county))
      array insert at bottom possiblesx(0)
      array insert at bottom possiblesy(0)
      possiblesx(array count(possiblesx(0)))=countx
      possiblesy(array count(possiblesy(0)))=county
    endif
  next county
next countx
num=rnd(array count(possiblesy(0))-1)+1
cars(c).destx=possiblesx(num)
cars(c).desty=possiblesy(num)
endfunction




function sqr(value)
ret=value*value
endfunction ret


function updateland() 
landstate(25,0)=1
landstate(25,1)=1
landstate(25,2)=1
landstate(25,3)=1
landstate(25,4)=1
roadcount=0
for countx=0 to 50
  for countz=0 to 50
    tile=1
    if landstate(countx,countz)=1
      roadcount=roadcount+1
      tile=4
      if countx>0
        if landstate(countx-1,countz)=1
          tile=tile+1
        endif
      endif
      if countz<50
        if landstate(countx,countz+1)=1
          tile=tile+2
        endif
      endif
      if countx<50
        if landstate(countx+1,countz)=1
          tile=tile+4
        endif
      endif
      if countz>0
        if landstate(countx,countz-1)=1
          tile=tile+8
        endif
      endif
    endif
    if tile<>landtile(countx,countz)
      texture object landobjects(countx,countz),tile
      landtile(countx,countz)=tile
    endif
    if (tile<>19) AND (landlights(countx,countz).exist=1) then deletelights(countx,countz)
  next countz
next countx
endfunction

function findobj()
res=1
while object exist(res)=1
res=res+1
endwhile
endfunction res

function FillCircle( CX as integer, CY as integer, R as integer ) `Not mine!!! From somewhere on the DBPro forums
   local x as integer
   local y as integer
   local i as integer
   local s as integer

   s=R*0.70710678 : ` this number is sin(45) - precalculate!
   box CX-s, CY-s, CX+s+1, CY+s+1
   s=s+1 : ` Faster than 'inc s'?
   i=R*R
   for y=s to R
      x=sqrt( i-(y*y) )

      ` Draw top and bottom
      box CX-x, CY-y, CX+x+1, CY-y+1
      box CX-x, CY+y, CX+x+1, CY+y+1

      ` Draw left and right
      box CX-y, CY-x, CX-y+1, CY+x+1
      box CX+y, CY-x, CX+y+1, CY+x+1
   next y
endfunction

maxpoints=20
read roads
dim points(roads)
dim speedlimit(roads)
dim way(roads)
dim rx(roads,maxpoints)
dim ry(roads,maxpoints)
dim inter(roads,maxpoints)
dim sect(roads,maxpoints)
dim flow(roads,maxpoints)
dim lights(roads,4)
scale=4
traffic_lights=0
for j=1 to roads
  read points(j),speedlimit(j),way(j)
  for i=1 to points(j)
    read rx(j,i),ry(j,i),inter(j,i),sect(j,i),flow(j,i)
    rx(j,i)=rx(j,i)*scale
    ry(j,i)=ry(j,i)*scale
    if flow(j,i)>1
      if lights(flow(j,i),1)=0
        lights(flow(j,i),0)=0
        lights(flow(j,i),1)=j
        lights(flow(j,i),2)=i
        traffic_lights=flow(j,i)
      endif
    endif
  next i
next j
read cars
dim cx(cars) as float
dim cy(cars) as float
dim carroad(cars)
dim carpoint(cars)
dim road(cars)
dim carp(cars)
dim cardir(cars)
dim carturn(cars)
dim carspeed(cars) as float
dim carflow(cars)
for i=1 to cars
  read carroad(i),carpoint(i),cardir(i)
  cx(i)=rx(carroad(i),carpoint(i))
  cy(i)=ry(carroad(i),carpoint(i))
  road(i)=carroad(i)
  carp(i)=carpoint(i)
  carspeed(i)=0.0
  carturn(i)=0
next i
set display mode 1024,768,32
sync on
loops=0
do
  cls
  ink rgb(64,64,64),0
  for j=1 to roads
    for i=1 to points(j)
      if i>1
        for thick=-3 to 3
          line rx(j,i),ry(j,i)+thick,rx(j,i-1),ry(j,i-1)+thick
          line rx(j,i)+thick,ry(j,i),rx(j,i-1)+thick,ry(j,i-1)
        next thick
      endif
      if flow(j,i)=1
        x=rx(j,i)-rx(j,i-1)
        y=ry(j,i)-ry(j,i-1)
        h#=sqrt(x^2+y^2)
        ink rgb(255,0,0),0
        for thick=1 to 3
          if i>1 then circle rx(j,i)-x/h#-6,ry(j,i)-y/h#+6,thick
          if i<points(j) then circle rx(j,i)-x/h#+6,ry(j,i)-y/h#-6,thick
        next thick
        ink rgb(64,64,64),0
      endif
    next i
  next j
  for j=2 to traffic_lights
    if lights(j,0)<1000 then l1=1:l2=1
    if lights(j,0)>999 and lights(j,0)<3000 then l1=3:l2=1
    if lights(j,0)>3599 and lights(j,0)<4000 then l1=2:l2=1
    if lights(j,0)>3999 and lights(j,0)<4500 then l1=1:l2=1
    if lights(j,0)>4499 and lights(j,0)<6000 then l1=1:l2=3
    if lights(j,0)>5999 and lights(j,0)<6500 then l1=1:l2=2
    if lights(j,0)>5999 then lights(j,0)=0
    inc lights(j,0)
    x=rx(lights(j,1),lights(j,2))-rx(lights(j,1),lights(j,2)-1)
    y=ry(lights(j,1),lights(j,2))-ry(lights(j,1),lights(j,2)-1)
    h#=sqrt(x^2+y^2)
    ink rgb(255,0,0),0
    for thick=1 to 2
      if i>1 then circle rx(lights(j,1),lights(j,2))-x/h#-6,ry(lights(j,1),lights(j,2))-y/h#+6,thick
      if i<points(j) then circle rx(lights(j,1),lights(j,2))-x/h#+6,ry(lights(j,1),lights(j,2))-y/h#-6,thick
    next thick
  next j
  ink rgb(128,128,255),0
  for j=1 to cars
    col=0
    for k=1 to cars
      if k<>j
        if int(cx(j)/3)=int(cx(k)/3) and int(cy(j)/3)=int(cy(k)/3) and j>k
          col=1
        endif
      endif
    next k
    if col=0
      if cardir(j)=1
        box cx(j),cy(j),cx(j)+4,cy(j)+4
      else
        box cx(j)-4,cy(j)-4,cx(j),cy(j)
      endif
      if int(cx(j))=rx(road(j),carp(j)) and int(cy(j))=ry(road(j),carp(j))
        if carturn(j)=0 or inter(road(j),carp(j))=0
          carp(j)=carp(j)+cardir(j)
        else
          newroad=inter(road(j),carp(j))
          newpoint=sect(road(j),carp(j))
          cx(j)=rx(newroad,newpoint)
          cy(j)=ry(newroad,newpoint)
          cardir(j)=carturn(j)
          road(j)=newroad
          carp(j)=newpoint+cardir(j)
        endif
        if carp(j)>points(road(j)) or carp(j)=0
          carp(j)=carp(j)-cardir(j)
          newroad=inter(road(j),carp(j))
          newpoint=sect(road(j),carp(j))
          if newroad=0
            newroad=carroad(j)
            newpoint=carpoint(j)
            cx(j)=rx(newroad,newpoint)
            cy(j)=ry(newroad,newpoint)
          endif
          if newpoint+1<=points(newroad)
            cardir(j)=1
          else
            cardir(j)=-1
          endif
          road(j)=newroad
          carp(j)=newpoint+cardir(j)
        endif
        if inter(road(j),carp(j))>0
          if carp(j)<points(road(j)) and carp(j)>0
            turn=rnd(1)
          else
            turn=1
          endif
          if turn=1
            if way(inter(road(j),carp(j)))=0
              carturn(j)=rnd(1)*2-1
              if sect(road(j),carp(j))+carturn(j)>points(inter(road(j),carp(j))) or sect(road(j),carp(j))+carturn(j)=0
                carturn(j)=carturn(j)*-1
              endif
            else
              carturn(j)=way(inter(road(j),carp(j)))
              if sect(road(j),carp(j))+carturn(j)>points(inter(road(j),carp(j))) or sect(road(j),carp(j))+carturn(j)=0
                carturn(j)=0
              endif
            endif
          else
            carturn(j)=0
          endif
        endif
        if flow(road(j),carp(j))>0
          carflow(j)=1
        endif
      endif
      difx=rx(road(j),carp(j))-cx(j)
      dify=ry(road(j),carp(j))-cy(j)
      hyp#=sqrt(difx^2+dify^2)
      if inter(road(j),carp(j))>0 and flow(road(j),carp(j))>0 and hyp#<20.0 and carflow(j)>0
        if carspeed(j)>0.0
          carspeed(j)=carspeed(j)-0.5
          if carspeed(j)<=0.0
            carspeed(j)=0.0
          endif
          if hyp#<3.0 then carspeed(j)=0.0
          if carspeed(j)=0.0
            if flow(road(j),carp(j))=1
              col=0
              for k=1 to cars
                if k<>j
                  if road(k)=inter(road(j),carp(j)) and carp(k)=sect(road(j),carp(j))
                    disx=rx(road(k),carp(k))-cx(k)
                    disy=ry(road(k),carp(k))-cy(k)
                    colhyp#=sqrt(disx^2+disy^2)
                    if colhyp#<50.0
                      col=1
                    endif
                  endif
                endif
              next k
              if col=0 then carflow(j)=0
            endif
          endif
        else
          carspeed(j)=carspeed(j)+0.6
        endif
      else
        if (carp(j)=1 or carp(j)=points(road(j)) or carturn(j)<>0) and hyp#<10.0
          carspeed(j)=carspeed(j)-1.0
          if carspeed(j)<20.0 and carflow(j)=0 then carspeed(j)=20.0
        else
          if carspeed(j)<speedlimit(road(j))
            carspeed(j)=carspeed(j)+0.6
          else
            if carspeed(j)>speedlimit(road(j))
              carspeed(j)=carspeed(j)-0.5
              if carspeed(j)<0.0 then carspeed(j)=0.0
            endif
          endif
        endif
      endif
      cx(j)=cx(j)+difx/hyp#*carspeed(j)/100.0
      cy(j)=cy(j)+dify/hyp#*carspeed(j)/100.0
      col=0
      for k=1 to cars
        if k<>j
          if road(k)=road(j) and carp(k)=carp(j)
            disx=rx(road(k),carp(k))-cx(k)
            disy=ry(road(k),carp(k))-cy(k)
            colhyp#=sqrt(disx^2+disy^2)
            if hyp#>colhyp# and (hyp#-colhyp#)<10.0
              col=k
            endif
          endif
        endif
      next k
      if col>0
        carspeed(j)=carspeed(j)-carspeed(col)/2.0
        if carspeed(j)<0.0 then carspeed(j)=0.0
      endif
    endif
  next j
  inc loops
  sync
loop
data 21
data 20,50,0,28,190,2,1,0,138,190,6,1,0,182,190,0,0,0,187,189,0,0,0,192,185,0,0,0,195,180,0,0,0,196,176,0,0,0,196,172,0,0,0,198,167,0,0,0,202,163,0,0,0,208,160,0,0,0,214,158,0,0,0,236,158,0,0,0,242,156,0,0,0,246,153,0,0,0,249,148,0,0,0,250,143,0,0,0,251,117,7,2,0,251,38,11,6,0,251,16,12,2,0
data 3,50,0,28,190,1,1,0,28,166,3,1,0,28,110,5,1,0
data 3,50,0,28,166,2,2,1,68,166,4,1,0,138,166,6,2,1
data 2,50,0,68,166,3,2,1,68,110,5,2,0
data 2,50,0,28,110,2,3,0,68,110,4,2,0
data 8,60,0,138,190,1,2,1,138,166,3,3,0,138,112,20,1,0,138,108,17,4,0,138,94,18,1,0,138,90,19,1,0,138,76,9,2,0,138,38,11,3,1
data 2,50,0,219,117,8,1,0,251,117,1,18,1
data 2,50,0,219,117,7,1,0,219,38,11,5,1
data 3,50,0,99,76,13,1,0,138,76,6,7,1,188,76,10,1,0
data 3,50,0,188,76,9,3,0,188,38,11,4,1,188,16,12,1,0
data 6,50,0,36,38,15,1,0,99,38,13,2,1,138,38,6,6,0,188,38,10,2,1,219,38,8,2,1,251,38,1,19,1
data 2,50,0,188,16,10,3,0,251,16,1,20,0
data 3,50,0,99,76,9,1,0,99,38,11,2,1,99,15,14,2,0
data 2,50,0,36,15,15,2,0,99,15,13,3,0
data 2,50,0,36,38,11,1,0,36,15,14,1,0
data 6,100,1,0,49,0,0,0,109,91,0,0,0,115,93,17,1,0,157,110,0,0,0,161,111,0,0,0,256,148,0,0,0
data 4,50,1,115,93,16,3,0,121,102,0,0,0,132,107,0,0,0,138,108,6,4,1
data 5,50,-1,138,94,6,5,1,143,94,0,0,0,151,98,0,0,0,154,106,0,0,0,161,110,0,0,0
data 3,50,1,138,90,0,0,0,126,92,0,0,0,109,90,21,2,0
data 4,50,1,138,112,0,0,0,145,112,0,0,0,151,110,0,0,0,157,110,16,4,0
data 6,100,-1,0,48,0,0,0,109,90,0,0,0,115,92,0,0,0,157,109,0,0,0,161,110,18,5,0,256,147,0,0,0
data 30
data 16,1,1
data 16,1,1
data 16,1,1
data 16,1,1
data 16,1,1
data 16,1,1
data 16,1,1
data 16,1,1
data 16,1,1
data 16,1,1
data 16,1,1
data 16,1,1
data 16,1,1
data 16,1,1
data 16,1,1
data 21,6,-1
data 21,6,-1
data 21,6,-1
data 21,6,-1
data 21,6,-1
data 21,6,-1
data 21,6,-1
data 21,6,-1
data 21,6,-1
data 21,6,-1
data 21,6,-1
data 21,6,-1
data 21,6,-1
data 21,6,-1
data 21,6,-1