Sorry your browser is not supported!

set display mode 1280, 1024, 32
sync on
sync rate 0
autocam off
backdrop on
color backdrop 0
randomize timer()
hide mouse
set directional light 0, 1.0, -1.0, -1.0
set ambient light 0

#constant ARENA_SIZE 18.0
make object plain 1, ARENA_SIZE*1.2, ARENA_SIZE*1.2
position object 1, 0, 0, 0
point object 1, 0, 1, 0
color object 1, rgb(0, 128, 0)

#constant bgSize 1024
make memblock 1, 12 + (bgSize * bgSize * 4)
write memblock dword 1, 0, bgSize
write memblock dword 1, 4, bgSize
write memblock dword 1, 8, 32

for y = 0 to bgSize-1
   for x = 0 to bgSize-1
       write memblock dword 1, (((y * bgSize) + x) * 4) + 12, rgb(0, 64 + rnd(64), 0)
   next x
next y
make image from memblock 1, 1
texture object 1, 1
delete memblock 1





`Create ant texture
#constant antTextureSize 32
make memblock 1, 12 + (antTextureSize * antTextureSize * 4)
write memblock dword 1, 0, antTextureSize
write memblock dword 1, 4, antTextureSize
write memblock dword 1, 8, 32
col as dword
for y = 0 to antTextureSize-1
   for x = 0 to antTextureSize-1
      b# = 255 - (sqrt(((x-16)*(x-16)) + ((y-16)*(y-16))) * 16.0)
      if b# < 0.0 then b# = 0.0
      col = rgb(0, 0, b#)
      write memblock dword 1, (((y * antTextureSize) + x) * 4) + 12, col
   next x
next y
make image from memblock 10, 1
delete memblock 1






`Create pointer texture
#constant antTextureSize 32
make memblock 1, 12 + (antTextureSize * antTextureSize * 4)
write memblock dword 1, 0, antTextureSize
write memblock dword 1, 4, antTextureSize
write memblock dword 1, 8, 32
col as dword
for y = 0 to antTextureSize-1
   for x = 0 to antTextureSize-1
      r# = 255 - (sqrt(((x-16)*(x-16)) + ((y-16)*(y-16))) * 12.0)
      if r# < 0.0 then r# = 0.0
      col = rgba(r#, 0, 0, 128)
      write memblock dword 1, (((y * antTextureSize) + x) * 4) + 12, col
   next x
next y
make image from memblock 11, 1
delete memblock 1







`Make Pointer
make object triangle 2, -0.3, 0.0, -0.6,   0.0, 0.0, 0.1,   0.3, 0.0, -0.6
position object 2, 0, 0.25, 0
`color object 2, rgb(255,255,255)
texture object 2, 11
set object transparency 2, 3
set object light 2, 0
position mouse screen width() * 0.5, screen height() * 0.5
Type FeederData
   x#
   z#
   mx#
   mz#
   lastCreated
endtype
Feeder as FeederData

















#constant ANT_SPEED 4.0
#constant MAX_ANT_COUNT = 15
Type AntData
   x#
   z#
   angle#
   cx#
   cz#
   reproduce_progress#
EndType

Dim Ants(MAX_ANT_COUNT) as AntData
for i = 1 to 5 : createRandomAnt(i) : next i



position camera 0, 20.0, 0
point camera 0,0,0
null = make vector2(1)

`Memblock for ant data
#constant outW 11
#constant outH 33
#constant outAlpha 96
MEM_SIZE as integer
MEM_SIZE = 12 + ((outW * outH)*4)
`template memblock
make memblock 1, MEM_SIZE
write memblock dword 1, 0, outW
write memblock dword 1, 4, outH
write memblock dword 1, 8, 32

`memblock to use
make memblock 2, MEM_SIZE

`define color variable
col as DWORD
col = rgba(0,0,0,outAlpha)
for y = 0 to outH-1
   for x = 0 to outW-1
      write memblock dword 1, (((y*outW)+x)*4)+12, col
   next x
next y







`Create menu's
get image 999, 0,0, 1,1
sprite 999, mousex(), mousey(), 999
hide sprite 999
Dim alphas#(20)
#constant MENU_W 128
#constant MENU_H 32
#constant MENU_MIN_ALPHA 64
#constant MENU_MAX_ALPHA 144
global black as dword   : black  = rgb(0,0,0)
global menu as dword : menu = rgb(192, 192, 192)

set text font "Arial"
set text size 24

MakeMenuItem("File", 1000, 0, 0)
MakeMenuItem("Load Game", 1001, 0, MENU_H)
MakeMenuItem("Save Game", 1002, 0, MENU_H*2)
MakeMenuItem("Exit", 1003, 0, MENU_H*3)

MakeMenuItem("Tools", 1010, MENU_W, 0)
MakeMenuItem("Pause", 1011, MENU_W, MENU_H)
MakeMenuItem("Feeder", 1012, MENU_W, MENU_H*2)
MakeMenuItem("Ant Editor", 1013, MENU_W, MENU_H*3)
ink rgb(255,255,255), black



`Mouse Status
`  0 = normal
`  1 = feeder
MouseStatus = 1
MouseButton = 0
`Pause Status
`  0 = Not Paused
`  1 = Pause
PauseStatus = 0


`START OF GAME
set text font "Courier New"
set text size 16
frameTime# = 1.0
startTime = timer()
do
   if PauseStatus = 0
      frameTime# = (frameTime# * 0.8) + ((timer() - startTime) * 0.2)
   else
      frameTime# = 0.0
   endif
   startTime = timer()
   text 288,10, "FPS: " + str$(screen fps())

   if mouseclick() = 2
      MouseStatus = 0
      show mouse
   endif


   gosub _MOVE_ANTS
   if MouseStatus = 1 then gosub _POSITION_FEEDER
   if MouseStatus = 0 then gosub _HANDLE_MENUS

   sync
loop




_HANDLE_MENUS:
   sprite 999, mousex(), mousey(), 999
   col = sprite collision(999,0)

   for i = 1000 to 1003
      `File Menu
      if i = col
         alphas#(i-1000) = curvevalue(MENU_MAX_ALPHA, alphas#(i-1000), 100.0 / frameTime#)
      else
         alphas#(i-1000) = curvevalue(MENU_MIN_ALPHA, alphas#(i-1000), 100.0 / frameTime#)
      endif
      set sprite alpha i, alphas#(i-1000)

      `Tools Menu
      if i+10 = col
          alphas#(i-990) = curvevalue(MENU_MAX_ALPHA, alphas#(i-990), 100.0 / frameTime#)
      else
          alphas#(i-990) = curvevalue(MENU_MIN_ALPHA, alphas#(i-990), 100.0 / frameTime#)
      endif
      set sprite alpha i+10, alphas#(i-990)
   next i

   if col = 1000
      if sprite visible(1001) = 0
         for i = 1001 to 1003 : show sprite i : next i
      endif
      for i = 1011 to 1013 : hide sprite i : next i
   else
      if col = 1010
         if sprite visible(1011) = 0
            for i = 1011 to 1013 : show sprite i : next i
         endif
         for i = 1001 to 1003 : hide sprite i : next i
      endif
   endif


   if mouseclick() = 1
      if MouseButton = 0
         MouseButton = 1
         select col
            case 1000
            endcase

            case 1001
            endcase

            case 1002
            endcase

            case 1003
               `Exit button
               end
            endcase




            case 1010
               if sprite visible(1011)
                  for i = 1011 to 1013 : hide sprite i : next i
               else
                  for i = 1011 to 1013 : show sprite i : next i
               endif
               for i = 1001 to 1003 : hide sprite i : next i
            endcase

            case 1013
               `change to feeder
               MouseStatus = 1
               null = mousemovex()
               null = mousemovey()
               hide mouse
               for i = 1011 to 1013 : hide sprite i : next i
            endcase
         endselect
      endif
   else
      if MouseButton = 1 then MouseButton = 0
   endif
return

function MakeMenuItem(txt$, v, x, y)
   txtHeight = text height(txt$)

   ink menu, black : box 0,0, MENU_W, MENU_H : ink black, menu : center text MENU_W*0.5, (MENU_H-txtHeight)*0.5, txt$
   get image v, 0, 0, MENU_W, MENU_H
   sprite v, x, y, v
   set sprite alpha v, MENU_MIN_ALPHA
   alphas#(v-1000) = MENU_MIN_ALPHA
   if v mod 10 <> 0 then hide sprite v
endfunction















_POSITION_FEEDER:
   inc Feeder.mx#, mousemovex() * frameTime# *  0.0001
   inc Feeder.mz#, mousemovey() * frameTime# * -0.0001
   Feeder.mx# = curvevalue(0.0, Feeder.mx#, 100.0 / frameTime#)
   Feeder.mz# = curvevalue(0.0, Feeder.mz#, 100.0 / frameTime#)

   if Feeder.mx# <> 0 OR Feeder.mz# <> 0
      inc Feeder.x#, Feeder.mx#
      inc Feeder.z#, Feeder.mz#
      if (Feeder.x# < -ARENA_SIZE*0.5 AND Feeder.mx# < 0) OR (Feeder.x# > ARENA_SIZE*0.5 AND Feeder.mx# > 0) then Feeder.mx# = -Feeder.mx#
      if (Feeder.z# < -ARENA_SIZE*0.5 AND Feeder.mz# < 0) OR (Feeder.z# > ARENA_SIZE*0.5 AND Feeder.mz# > 0) then Feeder.mz# = -Feeder.mz#

      position object 2, Feeder.x#, 0.25, Feeder.z#
      yrotate object 2, atanfull(Feeder.mx#, Feeder.mz#)
   endif

   if mouseclick() = 1
      if object collision(2, 0) >= 200
         i = object collision(2, 0)
         s# = object size x(i)
         inc s#, frameTime# * 0.0005
         s# = (s# / 0.5) * 100.0
         scale object i, s#, 50.0, s#
      else
         if timer() - lastCreated > 750
            i = 200
            while object exist(i) AND i < 205
               inc i
            endwhile
            if object exist(i) = 0
               make object sphere i, 0.5
               scale object i, 100.0, 50.0, 100.0
               position object i,Feeder.x#, 0.25, Feeder.z#
               color object i, rgb(192, 0, 0)
               if object collision(i,0) >= 100 then delete object i
               lastCreated = timer()
            endif
         endif
      endif
   endif
return




_MOVE_ANTS:
   for i = 1 to MAX_ANT_COUNT
      obj = 100+i
      if object exist(obj)
         closestID = -1
         closest# = -1.0
         for j = 200 to 220
            if object exist(j)
               if object collision(obj, j) = 1
                  `Ant eats food
                  s# = object size x(obj)
                  inc s#, object size x(j) * 0.05
                  s# = (s# / 0.2) * 100.0
                  if s# > 300.0 then s# = 300.0
                  scale object obj, s#, 100.0, s#
                  delete object j
               else
                  `Find closest food source
                  dx# = (object position x(j) - Ants(i).x#)
                  dz# = (object position z(j) - Ants(i).z#)

                  set vector2 1, dx#, dz#
                  dist# = length vector2(1)
                  if closestID = -1 OR dist# < closest# then closestID = j : closest# = dist#
               endif
            endif
         next j

         if closestID > -1
            `Head for food source
            dx# = (object position x(closestID) - Ants(i).x#)
            dz# = (object position z(closestID) - Ants(i).z#)
            set vector2 1, dx#, dz#
            dist# = length vector2(1)
         else
            `set heading for patrol zone
            dx# = (Ants(i).cx# - Ants(i).x#)
            dz# = (Ants(i).cz# - Ants(i).z#)
            set vector2 1, dx#, dz#
            dist# = length vector2(1)
            if dist# < 5.0
               inc Ants(i).cx#, (rnd(5.0)-2.5) * frameTime# * 0.001
               inc Ants(i).cz#, (rnd(5.0)-2.5) * frameTime# * 0.001
            endif
         endif

         `Give the ant a radius for patrol
         if dist# < 3.0 then dist# = 3.0

         `calculate the angle between ant and target (patrol zone or food)
         dAngle# = atanfull(dx#, dz#)
         `gradually turn ant towards target based on the distance to target
         Ants(i).angle# = curveangle(dAngle#, Ants(i).angle#, dist# * (100.0 / frameTime#))

         `Set Ant Speed based on how "fat" they are
         sp# = ANT_SPEED - (object size x(obj) * 10.0)
         if sp# < 0.5 then sp# = 0.5

         `Calculate new position based on angle and speed and time.
         inc Ants(i).x#, sp# * sin(Ants(i).angle#) * frameTime# * 0.001
         inc Ants(i).z#, sp# * cos(Ants(i).angle#) * frameTime# * 0.001
         position object obj, Ants(i).x#, 0.25, Ants(i).z#
         yrotate object obj, Ants(i).angle#


         s# = (object size x(obj) / 0.002) - frameTime# * 0.001
         if s# < 75.0
            `Dead Ant
            delete object obj
            j = 205
            `Search for available object to create food from dead ant
            while object exist(j) AND j < 221 : inc j : endwhile

            if object exist(j) = 0
               `Create food from dead ant
               make object sphere j, 0.5
               scale object j, 100.0, 50.0, 100.0
               position object j, Ants(i).x#, 0.25, Ants(i).z#
               color object j, rgb(192, 0, 0)
            endif
         else
            if Ants(i).reproduce_progress# > 30.0
               `REPRODUCE CODE HERE
               j = 101
               while object exist(j) = 1 AND j < MAX_ANT_COUNT + 100 : inc j : endwhile
               if object exist(j) = 0
                  createAnt(j-100, Ants(i).x#, Ants(i).z#)
                  Ants(i).reproduce_progress# = 0.0
                  dec s#, 100.0
               endif
            else
               if s# > 200.0 then inc Ants(i).reproduce_progress#, frameTime# * 0.003
            endif
            rep# = Ants(i).reproduce_progress#

            scale object obj, s#, 100.0, s#


            sX# = object screen x(obj) + 15.0
            sY# = object screen y(obj) - 15.0

            `Max = 30.0
            `Min = 7.5
            `Range = 22.5
            `Factor to turn 22.5 to 30 = 1.33…

            `Bar cols:
            `  0 = black
            `  1,2,3,4 = Health
            `  5 = black
            `  6,7,8,9 = reproduce progress
            `  10 = black


            s# = ((object size x(obj) / 0.02) - 7.5) * 1.33333333333333333333333
            if s# < 0.0 then s# = 0.0

            `Copy template into usable
            copy memblock 1, 2, 0, 0, MEM_SIZE

            `Create health bar
            r# = 255.0 - (s# * 8.5) : if r# < 0 then r# = 0 else if r# > 255 then r# = 255
            g# =         (s# * 8.5) : if g# < 0 then g# = 0 else if g# > 255 then g# = 255
            col = rgba(r#, g#, 0, outAlpha)
            y = 31
            while s# > 0.0
               for x = 1 to 4
                  write memblock dword 2, (((y*outW)+x)*4)+12, col
               next x
               dec s#, 1
               dec y
            endwhile
            `Create reproduction bar
            col = rgba(0, 128, 255, outAlpha)
            y = 31
            while rep# > 0.0
               for x = 6 to 9
                  write memblock dword 2, (((y*outW)+x)*4)+12, col
               next x
               dec rep#, 1
               dec y
            endwhile

            make image from memblock 2, 2
            paste image 2, sX#, sY#, 1
         endif
      endif
   next i
return


end
function createRandomAnt(i)
   Ants(i).x# = rnd(ARENA_SIZE)-(ARENA_SIZE*0.5)
   Ants(i).z# = rnd(ARENA_SIZE)-(ARENA_SIZE*0.5)

   Ants(i).cx# = rnd(ARENA_SIZE*0.5)-(ARENA_SIZE*0.25)
   Ants(i).cz# = rnd(ARENA_SIZE*0.5)-(ARENA_SIZE*0.25)

   Ants(i).angle# = atanfull(-Ants(i).x#, -Ants(i).z#)

   Ants(i).reproduce_progress# = 0.0

   make object triangle 100+i, -0.1, 0.0, 0.0,    0.0, 0.0, 0.25,    0.1, 0.0, 0.0
   position object 100+i, Ants(i).x#, 0.25, Ants(i).z#
   yrotate object 100+i, Ants(i).angle#
   set object light 100+i, 0
   texture object 100+i, 10
endfunction


function createAnt(i, x#, z#)
   Ants(i).x# = x#
   Ants(i).z# = z#

   Ants(i).cx# = rnd(ARENA_SIZE*0.5)-(ARENA_SIZE*0.25)
   Ants(i).cz# = rnd(ARENA_SIZE*0.5)-(ARENA_SIZE*0.25)

   Ants(i).angle# = atanfull(-Ants(i).x#, -Ants(i).z#)

   Ants(i).reproduce_progress# = 0.0

   make object triangle 100+i, -0.1, 0.0, 0.0,    0.0, 0.0, 0.25,    0.1, 0.0, 0.0
   position object 100+i, Ants(i).x#, 0.25, Ants(i).z#
   yrotate object 100+i, Ants(i).angle#
   set object light 100+i, 0
   texture object 100+i, 10
endfunction

function rgba(r as integer,g as integer,b as integer,a as integer)
  colour as dword
  colour = (b)+(g*256)+(r*65536)+(a*16777216)
endfunction colour

Rii.  Congrats.  :) 

Rem Project: AI Challenge
Rem Created: 03/04/2005 14:52:41
Rem Best viewed in a 800x600 window

Rem Do I really need to tell you?
set window on : set window title "AI Challenge" : set window size 800,600
sync on : sync rate 0 : autocam off

Rem Constants for images made from memblocks,  for the gui
#constant GUI_IMAGE_1 2
#constant GUI_IMAGE_2 3
#constant GUI_IMAGE_3 4
#constant GUI_IMAGE_4 5
#constant GUI_IMAGE_5 6
#constant GUI_IMAGE_6 7
#constant GUI_IMAGE_7 8
#constant GUI_IMAGE_8 9
#constant GUI_IMAGE_9 10

Rem Pet guis
#constant OB_PET 1000
#constant OB_PET_IMAGE 1

Rem Constants for the Gui
#constant GUI_WINDOW 1 : Rem Constant for a window..
#constant GUI_BUTTON 2 : Rem Is a button
#constant GUI_PROGRESS 3 : Rem A progress bar

Rem The UDT for the widgets
type widget_GUI
   gui_draw as integer : Rem Draw it or not
   gui_number as integer : Rem The number of sprites to start from, this is the main limitation
   gui_title as string : Rem The widgets title or caption
   gui_position_x as integer : Rem The x position
   gui_position_y as integer : Rem ^ y
   gui_width as integer : Rem The width...duh
   gui_height as integer : Rem The height..ffs thats obvious
   gui_type as integer : Rem The type, defined by constants
   gui_action as integer : Rem If the widget is acting or not. So far only buttons act.
   gui_parent as integer : Rem The widgets parent, where it belongs. 0 is the background.
   gui_extra as string : Rem Anything else needed for the widget. Depends on type.
endtype

Rem The array using the above type
dim gui_widget(100) as widget_GUI

Rem Define the window data. The first few bits will be commented :|
gui_widget(1).gui_draw = 1
gui_widget(1).gui_number = 100
gui_widget(1).gui_title = "AI Challenge"
gui_widget(1).gui_position_x = 0
gui_widget(1).gui_position_y = 0
gui_widget(1).gui_width = 110
gui_widget(1).gui_height = 48
gui_widget(1).gui_type = GUI_WINDOW
gui_widget(1).gui_action = 0
gui_widget(1).gui_parent = 0
gui_widget(1).gui_extra = "STATIC" : Rem Means teh bastage trying to break my GUI cant (it can't be moved)..

gui_widget(2).gui_draw = 1
gui_widget(2).gui_number = 104
gui_widget(2).gui_title = "Exit"
gui_widget(2).gui_position_x = 4
gui_widget(2).gui_position_y = 4
gui_widget(2).gui_width = 102
gui_widget(2).gui_height = 21
gui_widget(2).gui_type = GUI_BUTTON
gui_widget(2).gui_action = 0
gui_widget(2).gui_parent = 1
gui_widget(2).gui_extra = "EXIT" : Rem The action is to quit


gui_widget(6).gui_draw = 1
gui_widget(6).gui_number = 200
gui_widget(6).gui_title = "Pet Data"
gui_widget(6).gui_position_x = 0
gui_widget(6).gui_position_y = 47
gui_widget(6).gui_width = 110
gui_widget(6).gui_height = 125
gui_widget(6).gui_type = GUI_WINDOW
gui_widget(6).gui_action = 0
gui_widget(6).gui_parent = 0
gui_widget(6).gui_extra = "STATIC"

gui_widget(7).gui_draw = 1
gui_widget(7).gui_number = 204
gui_widget(7).gui_title = "Health"
gui_widget(7).gui_position_x = 4
gui_widget(7).gui_position_y = 4
gui_widget(7).gui_width = 102
gui_widget(7).gui_height = 21
gui_widget(7).gui_type = GUI_PROGRESS
gui_widget(7).gui_action = 0
gui_widget(7).gui_parent = 6
gui_widget(7).gui_extra = str$(GUI_IMAGE_5) : Rem The background image it should use.

gui_widget(8).gui_draw = 1
gui_widget(8).gui_number = 208
gui_widget(8).gui_title = "Stanima"
gui_widget(8).gui_position_x = 4
gui_widget(8).gui_position_y = 29
gui_widget(8).gui_width = 102
gui_widget(8).gui_height = 21
gui_widget(8).gui_type = GUI_PROGRESS
gui_widget(8).gui_action = 0
gui_widget(8).gui_parent = 6
gui_widget(8).gui_extra = str$(GUI_IMAGE_6)

gui_widget(9).gui_draw = 1
gui_widget(9).gui_number = 212
gui_widget(9).gui_title = "Level [1]"
gui_widget(9).gui_position_x = 4
gui_widget(9).gui_position_y = 54
gui_widget(9).gui_width = 102
gui_widget(9).gui_height = 21
gui_widget(9).gui_type = GUI_PROGRESS
gui_widget(9).gui_action = 0
gui_widget(9).gui_parent = 6
gui_widget(9).gui_extra = str$(GUI_IMAGE_8)

gui_widget(10).gui_draw = 1
gui_widget(10).gui_number = 216
gui_widget(10).gui_title = "Happiness"
gui_widget(10).gui_position_x = 4
gui_widget(10).gui_position_y = 79
gui_widget(10).gui_width = 102
gui_widget(10).gui_height = 21
gui_widget(10).gui_type = GUI_PROGRESS
gui_widget(10).gui_action = 0
gui_widget(10).gui_parent = 6
gui_widget(10).gui_extra = str$(GUI_IMAGE_9)


gui_widget(11).gui_draw = 1
gui_widget(11).gui_number = 300
gui_widget(11).gui_title = "Actions"
gui_widget(11).gui_position_x = 0
gui_widget(11).gui_position_y = 171
gui_widget(11).gui_width = 110
gui_widget(11).gui_height = 125
gui_widget(11).gui_type = GUI_WINDOW
gui_widget(11).gui_action = 0
gui_widget(11).gui_parent = 0
gui_widget(11).gui_extra = "STATIC"

gui_widget(12).gui_draw = 1
gui_widget(12).gui_number = 304
gui_widget(12).gui_title = "Add Food"
gui_widget(12).gui_position_x = 4
gui_widget(12).gui_position_y = 4
gui_widget(12).gui_width = 102
gui_widget(12).gui_height = 21
gui_widget(12).gui_type = GUI_BUTTON
gui_widget(12).gui_action = 0
gui_widget(12).gui_parent = 11
gui_widget(12).gui_extra = "FOOD"


Rem Define the type for the pet. I'm not going over this..
type petData
   health as integer
   stamina as integer
   level as integer
   level_exp as integer
   happy as integer
   x as integer
   y as integer
endtype

Rem Data var
global pet_data as petData
pet_data.health = 500
pet_data.stamina = 100
pet_data.level = 1
pet_data.happy = 250
pet_data.x = 200
pet_data.y = 200

type fooodness
   exists as integer
   x as integer
   y as integer
endtype

food as fooodness

Rem Globals for mouse positions, allows me to take them into functions, without being gay.
global mox : global moy
Rem For the AI
global loops2

Rem Create the images for the GUI
createGuiSprites()

Rem Environment set up:
backdrop on
color backdrop 0,rgb(70,122,175)

Rem pet set up:
sprite OB_PET,pet_data.x,pet_data.y,OB_PET_IMAGE
stretch sprite OB_PET,3500,3500
set sprite OB_PET,0,0

Rem Sync all this to screen and begin the loop.
sync
do
   Rem Update the mouse position
   mox = mousex() : moy = mousey()

   Rem Print dt and the FPS to the screen.
   set cursor 200,200 : ink rgb(255,255,255),0
   print screen FPS();" ";pet_data.happy

   Rem Control the pet
   if loops=0
      pet()
      inc loops
   else
      loops=0
   endif
   Rem Handle the gui
   handleGui()
   Rem Draw him!
   sprite OB_PET,pet_data.x,pet_data.y,OB_PET_IMAGE
   set sprite OB_PET,0,0

   Rem Sync and loop
   sync
loop

Rem End. The short and sweet command..
end

REM --------------------------------------
REM GENERAL FUNCTIONS
REM --------------------------------------

function lose()

   exit prompt "Next time round you better treat your poor, little, well-coloured, square pet better, otherwise it'll be a case of Mr Psycotic-Neofish on your back!!1","You lose!!!!!11onetwo!"
   end

endfunction

REM --------------------------------------
REM AI FUNCTIONS
REM --------------------------------------

function pet()

   Rem You lose if pet has no health
   if pet_data.health = 0 then lose()

   Rem Move it away if in the last 20 pixels of screen:
   if pet_data.x > 760 then dec pet_data.x,5
   if pet_data.x < 5 then inc pet_data.x,5
   if pet_data.y < 5 then inc pet_data.y,5
   if pet_data.y > 560 then dec pet_data.y,5

   Rem Basic, non script control - makes pet tired as it struggles
   if rightkey()=1
      inc pet_data.x,5
      forcedMovement()
   endif
   if leftkey()=1
      dec pet_data.x,5
      forcedMovement()
   endif
   if upkey()=1
      dec pet_data.y,5
      forcedMovement()
   endif
   if downkey()=1
      inc pet_data.y,5
      forcedMovement()
   endif

   Rem These things must happen less than other stuff
   if loops2<>6 then inc loops2
   select loops2

      case 1:

         Rem Inc the experience
         if pet_data.happy > 250 then inc pet_data.level_exp
         if spacekey()=1 then inc pet_data.happy,2
         if pet_data.level_exp > (100 * pet_data.level)-1 or pet_data.happy > 499

            Rem Give him level, reset exp, life and stamina
            inc pet_data.level
            pet_data.level_exp = 0
            pet_data.health = 500
            pet_data.stamina = 100
            pet_data.happy = 200

            Rem Change the level progress bar's caption, and delete the image so it updates
            gui_widget(9).gui_title = "Level ["+str$(pet_data.level)+"]"
            num = gui_widget(9).gui_number + 3
            if image exist(num)=1 then delete image num

         endif
      endcase

      case 3:
         Rem Make his stamina go up if its down :)
         if pet_data.stamina <> 100 then inc pet_data.stamina
      endcase

      case 6
         Rem revert it so those pieces of gay go get to cycle more than once
         loops2 = 0
      endcase

   endselect

endfunction

Rem Pet grows tired and gets hurt, teh poor thing.
function forcedMovement()

   if pet_data.stamina <> 0 then dec pet_data.stamina

   if pet_data.stamina = 0
      if pet_data.health <> 0 then dec pet_data.health
      if pet_data.happy <> 0 then dec pet_data.happy
      if pet_data.health = 0 and pet_data.health > 1 then dec pet_data.health
   endif

endfunction

Rem Adds food that the pet should run to :)
function addFood()

   food.exists = 1

   x = rnd (300)+200
   y = rnd (200)+100

   food.x = x
   food.y = y

endfunction

REM --------------------------------------
REM GUI FUNCTIONS
REM --------------------------------------

Rem Loads the images for the sprites.
function createGuiSprites()

   Remstart
      Memblock images: 3 dwords and 4 bytes (for a 1 pixel image)
      which makes 4x3 + 4  = 16
   Remend
   size = 16

   Rem GUI_IMAGE_1 - Blue
   make memblock GUI_IMAGE_1,size
   write memblock dword GUI_IMAGE_1,0,1     : `width
   write memblock dword GUI_IMAGE_1,4,1     : `height
   write memblock dword GUI_IMAGE_1,8,32    : `depth
   write memblock byte GUI_IMAGE_1,12,204   : `blue
   write memblock byte GUI_IMAGE_1,13,102   : `green
   write memblock byte GUI_IMAGE_1,14,0     : `red
   write memblock byte GUI_IMAGE_1,15,255   : `alpha
   make image from memblock GUI_IMAGE_1,GUI_IMAGE_1 : Rem Make the image

   Rem GUI_IMAGE_2 - Grey
   make memblock GUI_IMAGE_2,size
   write memblock dword GUI_IMAGE_2,0,1     : `width
   write memblock dword GUI_IMAGE_2,4,1     : `height
   write memblock dword GUI_IMAGE_2,8,32    : `depth
   write memblock byte GUI_IMAGE_2,12,221   : `blue
   write memblock byte GUI_IMAGE_2,13,221   : `green
   write memblock byte GUI_IMAGE_2,14,221   : `red
   write memblock byte GUI_IMAGE_2,15,255   : `alpha
   make image from memblock GUI_IMAGE_2,GUI_IMAGE_2

   Rem GUI_IMAGE_3 - Black
   make memblock GUI_IMAGE_3,size
   write memblock dword GUI_IMAGE_3,0,1     : `width
   write memblock dword GUI_IMAGE_3,4,1     : `height
   write memblock dword GUI_IMAGE_3,8,32    : `depth
   write memblock byte GUI_IMAGE_3,12,0     : `blue
   write memblock byte GUI_IMAGE_3,13,0     : `green
   write memblock byte GUI_IMAGE_3,14,0     : `red
   write memblock byte GUI_IMAGE_3,15,255   : `alpha
   make image from memblock GUI_IMAGE_3,GUI_IMAGE_3

   Rem GUI_IMAGE_4 - Light Grey
   make memblock GUI_IMAGE_4,size
   write memblock dword GUI_IMAGE_4,0,1     : `width
   write memblock dword GUI_IMAGE_4,4,1     : `height
   write memblock dword GUI_IMAGE_4,8,32    : `depth
   write memblock byte GUI_IMAGE_4,12,241   : `blue
   write memblock byte GUI_IMAGE_4,13,241   : `green
   write memblock byte GUI_IMAGE_4,14,241   : `red
   write memblock byte GUI_IMAGE_4,15,255   : `alpha
   make image from memblock GUI_IMAGE_4,GUI_IMAGE_4

   Rem GUI_IMAGE_4 - Bright Red
   make memblock GUI_IMAGE_5,size
   write memblock dword GUI_IMAGE_5,0,1     : `width
   write memblock dword GUI_IMAGE_5,4,1     : `height
   write memblock dword GUI_IMAGE_5,8,32    : `depth
   write memblock byte GUI_IMAGE_5,12,0     : `blue
   write memblock byte GUI_IMAGE_5,13,0     : `green
   write memblock byte GUI_IMAGE_5,14,240   : `red
   write memblock byte GUI_IMAGE_5,15,255   : `alpha
   make image from memblock GUI_IMAGE_5,GUI_IMAGE_5

   Rem GUI_IMAGE_6 - Bright Blue
   make memblock GUI_IMAGE_6,size
   write memblock dword GUI_IMAGE_6,0,1     : `width
   write memblock dword GUI_IMAGE_6,4,1     : `height
   write memblock dword GUI_IMAGE_6,8,32    : `depth
   write memblock byte GUI_IMAGE_6,12,240   : `blue
   write memblock byte GUI_IMAGE_6,13,0     : `green
   write memblock byte GUI_IMAGE_6,14,0     : `red
   write memblock byte GUI_IMAGE_6,15,255   : `alpha
   make image from memblock GUI_IMAGE_6,GUI_IMAGE_6

   Rem GUI_IMAGE_7 - White
   make memblock GUI_IMAGE_7,size
   write memblock dword GUI_IMAGE_7,0,1     : `width
   write memblock dword GUI_IMAGE_7,4,1     : `height
   write memblock dword GUI_IMAGE_7,8,32    : `depth
   write memblock byte GUI_IMAGE_7,12,255   : `blue
   write memblock byte GUI_IMAGE_7,13,255   : `green
   write memblock byte GUI_IMAGE_7,14,255   : `red
   write memblock byte GUI_IMAGE_7,15,255   : `alpha
   make image from memblock GUI_IMAGE_7,GUI_IMAGE_7

   Rem GUI_IMAGE_8 - Bright Green
   make memblock GUI_IMAGE_8,size
   write memblock dword GUI_IMAGE_8,0,1     : `width
   write memblock dword GUI_IMAGE_8,4,1     : `height
   write memblock dword GUI_IMAGE_8,8,32    : `depth
   write memblock byte GUI_IMAGE_8,12,0     : `blue
   write memblock byte GUI_IMAGE_8,13,255   : `green
   write memblock byte GUI_IMAGE_8,14,0     : `red
   write memblock byte GUI_IMAGE_8,15,255   : `alpha
   make image from memblock GUI_IMAGE_8,GUI_IMAGE_8

   Rem GUI_IMAGE_9 - Bright Orange
   make memblock GUI_IMAGE_9,size
   write memblock dword GUI_IMAGE_9,0,1     : `width
   write memblock dword GUI_IMAGE_9,4,1     : `height
   write memblock dword GUI_IMAGE_9,8,32    : `depth
   write memblock byte GUI_IMAGE_9,12,0     : `blue
   write memblock byte GUI_IMAGE_9,13,255   : `green
   write memblock byte GUI_IMAGE_9,14,255   : `red
   write memblock byte GUI_IMAGE_9,15,255   : `alpha
   make image from memblock GUI_IMAGE_9,GUI_IMAGE_9

   Rem OB_PET_IMAGE - Black
   make memblock OB_PET_IMAGE,size
   write memblock dword OB_PET_IMAGE,0,1     : `width
   write memblock dword OB_PET_IMAGE,4,1     : `height
   write memblock dword OB_PET_IMAGE,8,32    : `depth
   write memblock byte OB_PET_IMAGE,12,0     : `blue
   write memblock byte OB_PET_IMAGE,13,0     : `green
   write memblock byte OB_PET_IMAGE,14,0     : `red
   write memblock byte OB_PET_IMAGE,15,255   : `alpha
   make image from memblock OB_PET_IMAGE,OB_PET_IMAGE

endfunction

Rem Handle the gui...duh
function handleGui()

   Rem Repeat through the array items, drawing them and making them act if necessary
   a=1
   repeat
      if gui_widget(a).gui_draw = 1 then drawGui(a)
      guiAction(a)
      inc a
   until a=array count(gui_widget(0))+1

endfunction

Rem Draw a window based on the info passed in. This will be tedious :'(
function drawGui(index as integer)

   Rem Don't go be calling the array all the time (shorter names).
   num = gui_widget(index).gui_number
   title$ = gui_widget(index).gui_title
   x = gui_widget(index).gui_position_x
   y = gui_widget(index).gui_position_y
   width = gui_widget(index).gui_width
   height = gui_widget(index).gui_height
   wtype = gui_widget(index).gui_type
   parent = gui_widget(index).gui_parent
   extra$ = gui_widget(index).gui_extra

   Rem Select a case based on what it wants to draw (a pony!).
   select wtype

      case GUI_WINDOW

         Rem If the image for the caption/title of the widget doesn't exist, create it.
         if image exist(num+3)=0
            Rem Set the text teh right
            ink rgb(255,255,255),0 : set text opaque : set text font "verdana" : set text size 14
            text x,y,title$ : set image colorkey 0,0,0
            Rem Get the image
            get image num+3,x,y,x+text width(title$),y+text height(title$),1
         endif

         Rem Make the black background sprite
         sprite num,x,y,GUI_IMAGE_3
         Rem Make it faster
         set sprite num,0,0
         Rem Stretch it to the right size
         stretch sprite num,100*width,100*height

         Rem Make the blue title sprite
         sprite num+1,x+1,y+1,GUI_IMAGE_1

         set sprite num+1,0,0
         stretch sprite num+1,100*(width-2),1900

         Rem Make the grey main bit sprite
         sprite num+2,x+1,y+21,GUI_IMAGE_2
         set sprite num+2,0,0
         stretch sprite num+2,100*(width-2),100*(height-22)

         Rem Make the title sprite
         sprite num+3,x+4,y+4,num+3
         set sprite num+3,0,1

      endcase

      case GUI_BUTTON
      Rem I'm only going to comment bits that have changed!

         if image exist(num+2)=0
            ink rgb(10,10,10),0 : set text opaque : set text font "verdana" : set text size 14
            text x,y,title$ : set image colorkey 0,0,0
            get image num+2,x,y,x+text width(title$),y+text height(title$),1
         endif

         Rem Get teh parent positions, so the position is relative.
         parent_x = gui_widget(parent).gui_position_x
         parent_y = gui_widget(parent).gui_position_y + 20
         x = x + parent_x
         y = y + parent_y

         Rem Rollover image
         if (mox => x and mox <= x+width) and (moy => y and moy <= y+20)
            image = GUI_IMAGE_7
         else
            image = GUI_IMAGE_4
         endif

         sprite num,x,y,GUI_IMAGE_3
         set sprite num,0,0
         stretch sprite num,100*width,100*height

         sprite num+1,x+1,y+1,image
         set sprite num+1,0,0
         stretch sprite num+1,100*(width-2),100*(height-2)

         sprite num+2,x+4,y+4,num+2
         set sprite num+2,0,1

      endcase

      case GUI_PROGRESS
      Rem This one is the hard one: progress bars

         if image exist(num+3)=0
            ink rgb(10,10,10),0 : set text opaque : set text font "verdana" : set text size 14
            text x,y,title$ : set image colorkey 0,0,0
            get image num+3,x,y,x+text width(title$),y+text height(title$),1
         endif

         parent_x = gui_widget(parent).gui_position_x
         parent_y = gui_widget(parent).gui_position_y + 20
         x = x + parent_x
         y = y + parent_y

         Rem Get the correct image for the particular bar and the right data
         image = val(extra$)
         select image

            case GUI_IMAGE_5:
               prog = pet_data.health / 5
            endcase

            case GUI_IMAGE_6:
               prog = pet_data.stamina
            endcase

            case GUI_IMAGE_8:
               prog = pet_data.level_exp / pet_data.level
            endcase

            case GUI_IMAGE_9:
               prog = pet_data.happy / 5
            endcase

         endselect

         sprite num,x,y,GUI_IMAGE_3
         set sprite num,0,0
         stretch sprite num,100*width,100*height

         Rem Draw the coloured bar bit
         sprite num+1,x+1,y+1,image
         set sprite num+1,0,0
         stretch sprite num+1,100*prog,100*(height-2)

         Rem Draw the grey bar to fill the gap
         sprite num+2,x+1+prog,y+1,GUI_IMAGE_2
         set sprite num+2,0,0
         stretch sprite num+2,100*(100-prog),100*(height-2)

         sprite num+3,x+4,y+4,num+3
         set sprite num+3,0,1

      endcase

   endselect

endfunction

Rem Run the widget actions.
function guiAction(index as integer)

   Rem Load the widget data
   x = gui_widget(index).gui_position_x
   y = gui_widget(index).gui_position_y
   width = gui_widget(index).gui_width
   Rem if its a button find its actual position
   if gui_widget(index).gui_type = GUI_BUTTON
      parent = gui_widget(index).gui_parent
      parent_x = gui_widget(parent).gui_position_x
      parent_y = gui_widget(parent).gui_position_y + 20
      x = x + parent_x
      y = y + parent_y
   endif

   Rem Left clicking on the widget will activate it.
   if (mox => x and mox <= x+width) and (moy => y and moy <= y+20) and mouseclick()=1
      gui_widget(index).gui_action = 1
   endif

   Rem Run the button's action
   if gui_widget(index).gui_action = 1 and gui_widget(index).gui_type = GUI_BUTTON
      Rem Exit the piece of gay
      if gui_widget(index).gui_extra = "EXIT" then end
      Rem Reset the action
      gui_widget(index).gui_action = 0
   endif

endfunction

Rem Well I'm finished and off for a coffee. You're welcome to join me if you so wish, or just bask in the 133bness of this code O_o

set display mode 1024,768,32
sync on
sync rate 0
sync
randomize timer()
backdrop on
color backdrop 0
set image colorkey 0,0,0
autocam off
PERFORM CHECKLIST FOR FONTS
SET TEXT FONT "ERAS LIGHT ITC"
EMPTY CHECKLIST

 ` you
make object box 1,11,11,11
 ` the dummy object you point at
make object box 2,0,0,0
hide object 2
 ` the sphere that represents the thing that you don't want the ball to hit
make object sphere 3,24
position object 3,0,0,0
 ` the ball
make object sphere 4,5

make_images()
makeexplosionboxes()


level=1

beginanewlevelhere:
delobs()

leveldatarestore(level)

read spd#,spdinc#,maxspd#
read numbox,boxsize,boxdist
read boxmove#,oscilate

x=0
for t=101 to 100+numbox
 make object box t,boxsize,boxsize,boxsize
 texture object t,level
next t

offset#=0.0
ballheld=1
boxleft=numbox


make object cube 100,1000
set object light 100,0
set object cull 100,0
texture object 100,level
set object collision off 100
position object 100,0,0,-250

for t=1 to 4
 texture object t,11
next t


position camera 0,0,-250

T1#=TIMER()

do

 ` timer-based movement:
GS#=(TIMER()-T1#)*0.010
T1#=TIMER()

inc degree
if degree>359 then degree=0

offset#=offset#+(rightkey()-leftkey())*30*gs#
position object 1,sin(offset#)*20,cos(offset#)*20,0
position object 2,sin(offset#)*230,cos(offset#)*230,0
point object 1,object position x(2),object position y(2),object position z(2)

x=0
y=(360/numbox)
d=(boxdist+(sin(degree)*oscilate))
if d<50 then d=50
if d>150 then d=150
for t=101 to 100+numbox
 boxpos#=boxpos#+(boxmove#*gs#)
 if boxpos#>360.0 then boxpos#=boxpos#-360.0
 position object t,sin(boxpos#+x)*d,cos(boxpos#+x)*d,0
 x=x+y
next t

if ballheld=1
 position object 4,object position x(1),object position y(1),object position z(1)
 point object 4,object position x(2),object position y(2),object position z(2)
 move object 4,8

 if spacekey() then  ballheld=0

endif

if ballheld=0
 move object 4,spd#*gs#

 x=object collision(4,0)
 if x>100 and x<200
  explode(x,level)
  hide object x
  set object collision off x
  redirball()
  dec boxleft
 endif  : ` hit a box object

if x=1
 rotate object 4,object angle x(1),object angle y(1),object angle z(1)
endif : ` hit your paddle

if x=3
 dec life
 ballheld=1
endif

 endif : ` if ball is NOT HELD

if sqdisob(1,4)>23000
 redirball()
 spd#=spd#+spdinc#
 if spd#>maxspd# then spd#=maxspd#
endif

if boxleft<1 then inc level : goto beginanewlevelhere

`yrotate object 100,object angle y(100)+gs#

rotate object 100,object angle x(100)+gs#,object angle y(100)+gs#,object angle z(100)+gs#

for t=201 to 220
` move object t,(t-190)*gs#
 move object t,15*gs#
next t

rotate object 3,rnd(360),rnd(360),rnd(360)

sync : loop



function leveldatarestore(l)
select l

case 1
 restore LEVEL_one_DATA
endcase

case 2
 restore LEVEL_two_DATA
endcase

case 3
 restore LEVEL_three_DATA
endcase

case 4
 restore LEVEL_four_DATA
endcase

case 5
 restore LEVEL_five_DATA
endcase

case 6
` restore LEVEL_six_DATA
endcase

case 7
` restore LEVEL_seven_DATA
endcase

case 8
` restore LEVEL_eight_DATA
endcase

endselect

endfunction

LEVEL_ONE_DATA:
`spd#,spdinc#,maxspd#
data 10.0,0.250,20.0
`numbox,boxsize,boxdist
data 10,50,100
`boxmove#,oscilate
data 0.035,0

LEVEL_Two_DATA:
`spd#,spdinc#,maxspd#
data 11.0,0.250,30.0
`numbox,boxsize,boxdist
data 40,15,100
`boxmove#,oscilate
data -0.05,10

LEVEL_Three_DATA:
`spd#,spdinc#,maxspd#
data 12.0,0.250,40.0
`numbox,boxsize,boxdist
data 20,30,100
`boxmove#,oscilate
data 0.10,25

LEVEL_four_DATA:
`spd#,spdinc#,maxspd#
data 13.0,0.350,40.0
`numbox,boxsize,boxdist
data 30,20,100
`boxmove#,oscilate
data -0.15,250

LEVEL_five_DATA:
`spd#,spdinc#,maxspd#
data 14.0,0.350,20.0
`numbox,boxsize,boxdist
data 60,50,135
`boxmove#,oscilate
data 0.25,0

LEVEL_six_DATA:
`spd#,spdinc#,maxspd#
data 15.0,0.250,30.0
`numbox,boxsize,boxdist
data 5,15,125
`boxmove#,oscilate
data -0.50,25

function sqdisob(a,b)
 dist=(object position x(a)-object position x(b))^2+(object position y(a)-object position y(b))^2
endfunction dist

function delobs()
for t=100 to 199
 if object exist(t) then delete object t
next t
for t=201 to 220
 position object t,0,0,-300
 point object t,0,0,-400
next t
endfunction

function redirball()
 point object 4,rnd(60)-30,rnd(60)-30,0
endfunction

function makeexplosionboxes()
for t=201 to 220
 make object box t,5,5,5
` rotate object t,rnd(360),rnd(360),rnd(360)
` fix object pivot t
 position object t,0,0,-300
 point object t,0,0,-400
next t
endfunction

function make_images()

 for z=1 to 10
create bitmap 1,32,32
 ink rgb(rnd(150+50),rnd(150+50),rnd(150+50)),0
 box 0,0,31,31
for t=1 to 15
 ink rgb(rnd(150+50),rnd(150+50),rnd(150+50)),0
 x=rnd(29-t)
 y=rnd(29-t)
 box x,y,x+2+t,y+2+t
next t
get image z,0,0,31,31
delete bitmap 1
 next z

create bitmap 1,32,32
ink rgb(255,255,255),0
 for t=1 to 300
  dot rnd(31),rnd(31)
 next t
get image 11,0,0,31,31
delete bitmap 1

endfunction

function explode(a,b)

x=object position x(a)
y=object position y(a)

for t=201 to 220
 position object t,x,y,0
 rotate object t,rnd(360),rnd(360),rnd(360)
 texture object t,b
` fix object pivot t
next t

endfunction