Sorry your browser is not supported!

` IBOL's beach scene, DBP coding challenges

set display mode 640,480,32
sync on
sync rate 0
sync
randomize timer()

 start_here:
 cls

 ` SKY:
 q=rnd(50)
box 0,0,640,480,rgb(28+q,28+q,255),rgb(205+q,205+q,255),rgb(108+q,108+q,255),rgb(158+q,158+q,255)

 ` SAND:
 hite=rnd(150)+280
for u=1 to 5
for t=hite to 480
 x=rnd(200)+55
 ink rgb(x,x,0),0
 line 0,t,640,480-rnd(5)
next t
next u

 ` TREES

trees=2+rnd(3)

for W=1 to trees

` TRUNKS:

ttx=rnd(200)+50
tty=rnd(200)+50
wid=rnd(6)+8

repeat
tbx=ttx+rnd(50)-25
tby=rnd(40)+440
until abs(ttx-tbx)>9

D=rnd(50)

for t=tbx-wid to tbx+wid
 c=rnd(50)+50+D
 ink rgb(c,c/1.4,c/2.8),0
 line ttx,tty,t,tby
next t

 ` LEAVES:

 Leaves=rnd(5)+5

 for L=1 to Leaves
  ang=rnd(360)
  wid=rnd(80)
  x=sin(ang)*(40+wid)+ttx
  y=cos(ang)*(40+wid)+tty

   for t=x-10 to x+10
    rb=rnd(75)+50
    g=rnd(128)+128
    ink rgb(rb,g,rb),0
    line ttx+rnd(5),tty+rnd(5),t,y
   next t

   for t=y-10 to y+10
    rb=rnd(75)+50
    g=rnd(128)+128
    ink rgb(rb,g,rb),0
    line ttx+rnd(5),tty+rnd(5),x,t
   next t


 next L

next W

if rnd(1)=1

` SECOND SAND DUNE sometimes:

 hite=rnd(100)+330
 mid=rnd(250)+100
for u=1 to 2
for t=hite to 480
 x=rnd(100)+155
 ink rgb(x,x,0),0
 line 640,t,mid,480-rnd(5)
next t
next u

endif


sync
wait key


goto start_here


END

rem Challenge: seascape
rem Author: AceLepage
rem Deadline: June 4, 2010

set display mode 1280,768,32
backdrop on
hide mouse
sync on
set camera range 1,30000
global imgnum
global objnum
rem Describe the leaves on the tree
global leaves=8
rem define the leaf segments, more segments=smoother curve to the leaf
seg=16
global dim leaf(leaves)
dim leafs(leaves) as float
rem Set to 0 for no hardware shadows
global shadow=1
global shlen=25
tp as dword

rem Make the frond leaves for the tree
makeleaves(seg)
rem Make the tree trunk
Itree=treetexture()
Otree=maketree(Itree)
position object Otree,500,0,0

rem shadow shader doesn't do transparent textures, so make the shadow manually for the tree
rem by grabbing an image of the tree, then painting it light grey, with a transparent background
rem To avoid antialias outline, set the backdrop color to the shadow color
Ishadow=nextimg()
Itemp=nextimg()
position camera 550,10,-300
point camera 500,0,0
sync
set current bitmap 0
get image Itemp,500,275,756,531
create bitmap 1,256,256
paste image Itemp,0,0
tp=point(0,0)
for x=0 to 255
  for y=0 to 255
    if point(x,y)=tp
      ink 0,0
    else
      ink rgb(191,127,67),0
    endif
    dot x,y
  next y
next x
get image Ishadow,0,0,255,255,0
delete bitmap 1
color backdrop rgb(210,136,80)

rem make the tree shadow so it can be laid on the sand
Oshadow=nextobj()
make object plain Oshadow,64,100
texture object Oshadow,Ishadow
set object transparency Oshadow,1
set object ambient Oshadow,0
rotate object Oshadow,90,-90,0
position object Oshadow,453,-45,5

rem make a sky box
Isky=skytexture()
Osky=nextobj()
make object cube Osky,20000
texture object Osky,Isky
position object Osky,500,30,-200
set object cull Osky,0
set object light Osky,0

rem make the water, atmospheric haze right on the texture
Iwater=watertexture()
Owater=nextobj()
Owater2=nextobj()
make object plain Owater,5000,1000
texture object Owater,Iwater
xrotate object Owater,90
set object emissive Owater,rgb(128,128,255)
position object Owater,500,-55,300

rem make some sand
Ognd=nextobj()
Ignd=textureground()
make object sphere Ognd,100,16,32
texture object Ognd,Ignd
scale object Ognd,700,10,300
position object Ognd,500,-50,0

rem make a couple of bottles
Obot1=bottle()
Obot2=nextobj()
clone object Obot2,Obot1
zrotate object Obot1,15
position object Obot1,450,-46,-20
zrotate object Obot2,-15
position object Obot2,455,-46,-25

rem make a deck chair, default to white, so no texture required
Ochair=makechair()
position object Ochair,420,-30,-50
yrotate object Ochair,-15
position light 0,700,50,-50

rem make a sailboat
Oboat=sailboat()
position object Oboat,400,-45,500

rem add hardware shadows to the chair and bottles
if shadow=1
  set shadow shading on Obot1,-1,shlen/2,1
  set shadow shading on Obot2,-1,shlen/2,1
  set shadow shading on Ochair,-1,shlen,1
endif

rem make the sky
num_clouds=800
Ocloud=nextobj()
create_clouds(Ocloud,num_clouds)

position camera 400,10,-200
point camera 400,0,0
boatspeed#=0.3
lasttime#=timer()
for x=1 to leaves
  leafs(x)=wrapvalue(x*20.0)
next x
gale#=40.0
while not escapekey()
  diff#=timer()-lasttime#
  speed#=diff#*boatspeed#
  position object Oboat,object position x(Oboat)-boatspeed#,object position y(Oboat),object position z(Oboat)
  for x=1 to leaves
    for i=1 to seg-1
      rotate limb leaf(x),i,limb angle x(leaf(x),i)+cos(leafs(x))/gale#,limb angle y(leaf(x),i),limb angle z(leaf(x),i)
    next i
    leafs(x)=wrapvalue(leafs(x)+10.0)
  next x
  sync
endwhile

end

function textureground()
  create bitmap 1,32,32
  ink rgb(255,160,80),0
  box 0,0,31,31
  ink rgb(255,200,120),0
  for x=1 to 250
    dot rnd(31),rnd(31)
  next x
  Ignd=nextimg()
  get image Ignd,0,0,31,31
  delete bitmap 1
endfunction Ignd
function makeleaves(seg)
  rem define the shape of the fronds
  spread=6
  fronds=25
  width=80
  rem  make the frond texture. this will be split into sections to texture each leaf segment
  set image colorkey 0,0,0
  create bitmap 1,width,fronds*spread+(width/4)+fronds
  for x=1 to fronds
    shade=rnd(10)*5
    curve=sin(x*10)*width/4
    hang=width/4+x
    ink rgb(shade,255,shade),0
    for i=-2 to 2
      line width/2+i,x*spread,width/4-curve+i,x*spread+hang-i
      line width/2+i,x*spread,(width*3)/4+curve-i,x*spread+hang-i
    next i
  next x
  line width/2,spread,width/2,fronds*spread
  length#=80
  wide=20
  sublength#=length#/seg
  segment=(fronds*spread+(width/4)+fronds+2)/seg
  bend=120
  rem get all the sections of the texture to be applied to the leaf sections
  dim tex(seg)
  for i= 1 to seg
    tex(i)=nextimg()
    get image tex(i),0,(i-1)*segment,width-1,segment*i-1,1
  next i
  delete bitmap 1
  rem build the leaf from multiple segments of plains, and texture each plain with a section of the frond
  leaf(1)=nextobj()
  make object plain leaf(1),wide,sublength#
  offset limb leaf(1),0,0,-sublength#/2,0
  make mesh from object 1,leaf(1)
  for i=1 to seg-1
    add limb leaf(1),i,1
    link limb leaf(1),(i-1),i
    if i=1
      off#=0
    else
      off#=sublength#
    endif
    offset limb leaf(1),i,0,-off#,0
    rotate limb leaf(1),i,-bend/(seg-1),0,0
  next i
  delete mesh 1
  for i=0 to seg-1
    texture limb leaf(1),i,tex(i+1)
  next i
  set object cull leaf(1),0
  set object transparency leaf(1),1
  rotate limb leaf(1),1,120,0,0
  rem create copies of the leaf
  for i=2 to leaves
    leaf(i)=nextobj()
    clone object leaf(i),leaf(1)
  next i
  rem position the leaves around the top of the three
  for i=1 to leaves
    position object leaf(i),500,15.5,0
    if i<=4
      yrotate object leaf(i),(i-1)*90
    else
      rotate object leaf(i),30,(i-1)*90+45,0
    endif
  next i
endfunction

function nextimg()
  inc imgnum
endfunction imgnum
function nextobj()
  inc objnum
endfunction objnum

function create_clouds(Ocloud,num_clouds)
  create bitmap 1,50,50
  ink rgb(128,128,100),0
  for x=1 to 1000
     ang=rnd(360)
     ra=rnd(20)
     sa=sin(ang)
     ca=cos(ang)
     box 25+sa*ra,25+ca*ra,rnd(3)+25+sa*ra,rnd(3)+25+ca*ra
  next x
  blur bitmap 1,3
  Icloud = nextimg()
  get image Icloud, 0, 0, 50, 50
  delete bitmap 1
  for c=Ocloud to Ocloud+num_clouds
    make object plain c,rnd(50)+800,rnd(50)+800
    zrnd=rnd(10000)
    yrnd=rnd(100)+150
    range=zrnd*2+500
    xrnd=rnd(range)-range/2
    position object c,xrnd+500,yrnd,zrnd
    xrotate object c,90
    texture object c,Icloud
    ghost object on c,0
    disable object zwrite c
    set object light c,0
  next c
endfunction

function watertexture()
  create bitmap 1,256,256
  for x=0 to 255
    ink rgb(x,x,255),0
    line 0,x,255,x
  next
  ink rgb(192,192,255),0
  for x=1 to 250
    dot rnd(128)+64,rnd(128)
  next x
  Iwater=nextimg()
  get image Iwater,0,0,255,255
  delete bitmap 1
endfunction Iwater

function skytexture()
  create bitmap 1,256,256
  for x=0 to 255
    ink rgb(x,x,255),0
    line 0,x,255,x
  next x
  Isky=nextimg()
  get image Isky,0,0,255,255
  delete bitmap 1
endfunction Isky

function treetexture()
  create bitmap 1,32,32
  ink rgb(140,64,0),0
  box 0,0,31,31
  ink 0,0
  for x=1 to 100
    dot rnd(31),rnd(31)
  next x
  Itree=nextimg()
  get image Itree,0,0,31,31
  delete bitmap 1
endfunction Itree
function maketree(Itree)
  rem build the tree trunk from a bunch of cone shapes
  Otree=nextobj()
  make object cone Otree,10
  rotate object Otree,180+x*2,0,-x*2
  scale object Otree,100,200,100
  position object Otree,10-cos(x*10)*10,x*8,x
  texture object Otree,Itree
  for x=1 to 10
    Ntree=nextobj()
    clone object Ntree,Otree
    rotate object Ntree,x*2,0,-x*3
    position object Ntree,object position x(Otree)+10-cos(x*10)*10,object position y(Otree)+x*3,object position z(Otree)+x
    glue object to limb Ntree,Otree,0
    texture object Ntree,Itree
  next x
endfunction Otree

function bottle()
  rem make a bottle with more detail than is really required in this picture
  bot=nextobj()
  temp=nextobj()
  limbnum=1
  meshnum=1
  make object sphere bot,5
  scale object bot,100,30,100
  make object cylinder temp,5
  scale object temp,100,200,100
  make mesh from object meshnum,temp
  delete object temp
  add limb bot,limbnum,meshnum
  scale limb bot,limbnum,100,300,100
  offset limb bot,limbnum,0,15.2,0
  inc limbnum
  delete mesh meshnum
  make object cone temp,5
  make mesh from object meshnum,temp
  delete object temp
  add limb bot,limbnum,meshnum
  scale limb bot,limbnum,100,300,100
  offset limb bot,limbnum,0,37.5,0
  inc limbnum
  delete mesh meshnum
  make object cylinder temp,2
  make mesh from object meshnum,temp
  delete object temp
  add limb bot,limbnum,meshnum
  scale limb bot,limbnum,100,400,100
  offset limb bot,limbnum,0,43,0
  inc limbnum
  delete mesh meshnum
  make object sphere temp,2
  scale object temp,100,30,100
  make mesh from object meshnum,temp
  delete object temp
  add limb bot,limbnum,meshnum
  offset limb bot,limbnum,0,47,0
  delete mesh meshnum

  set object smoothing bot,100
  color object bot,rgb(84,32,0)
  set object emissive bot,0
  set object ambience bot,rgb(84,32,0)
  set object ambient bot,0
  set object specular bot,0
  set object diffuse bot,rgb(84,32,0)
endfunction bot
function makechair()
  rem take a plank, and copy it lots of times to make a wooden chair
  Ochair=nextobj()
  meshnum=1
  read x#,y#,z#,rx,ry,rz
  make object box Ochair,x#,y#,z#
  make mesh from object meshnum,Ochair
  rotate limb Ochair,0,rx,ry,rz
  for limbnum=1 to 13
    read x#,y#,z#,rx,ry,rz,sx,sy,sz
    add limb Ochair,limbnum,meshnum
    rotate limb Ochair,limbnum,rx,ry,rz
    offset limb Ochair,limbnum,x#,y#,z#
    if sx>0
      scale limb Ochair,limbnum,sx,sy,sz
    endif
  next limbnum
  delete mesh meshnum
  rem manually built the chair then copied all of the data points into data statements to reduce the code
  data 3,16,1,-5,0.5,2.5
  data 4,0,0,-5,0.5,-2.5,0,0,0
  data 8,0,0.5,-5,-15,-5,0,0,0
  data -4,0,0.5,-5,15,5,0,0,0
  data 0.2,-8,6.6,90,-0.8,0,100,70,100
  data 3.8,-8,6.6,90,0.8,0,100,70,100
  data -3.6,-8,6.6,90,-5,0,100,70,100
  data 7.6,-8,6.6,90,5,0,100,70,100
  data -5.4,-10,0,0,90,0,0,0,0
  data -5.2,-10,8,0,90,0,0,0,0
  data 9.4,-10,0,0,90,0,0,0,0
  data 9.4,-10,8,0,90,0,0,0,0
  data 9.6,-1.2,3,90,0,0,0,0,0
  data -5.6,-1.2,3,90,0,0,0,0,0
endfunction Ochair
function sailboat()
  Oboat=nextobj()
  make object triangle Oboat,0,10,0,0,0,0,6,0,0
  create bitmap 1,11,7
  ink rgb(255,255,255),0
  box 0,0,10,6
  ink rgb(1,1,1),0
  box 9,0,10,6
  Iboat=nextimg()
  get image Iboat,0,0,10,6
  delete bitmap 1
  texture object Oboat,Iboat
endfunction Oboat

rem ********** seascape challenge entry **************
rem ********** owlman 03/06/10 ***********
 
#constant xzsq 32
#constant scaleterr 10.0

global dim shapexz(xzsq,xzsq) as integer
helpreq = -1
amdr =0
amwn =0 
rdrrun=1
amdr2 = 0
amwn2 =0
setup()

 gosub make_contour_map
 gosub make_object_texture
 gosub make_base_terrain
 gosub make_sky
 gosub make_extras



do
 
 if upkey() then move object dummyobjectnum, 1
 if downkey() then move object dummyobjectnum, -1
 
height# = get terrain ground height (terrnum, object position x (dummyobjectnum), object position z(dummyobjectnum) )
 position object dummyobjectnum, object position x (dummyobjectnum),height#, object position z(dummyobjectnum) 
if get terrain ground height (terrnum, object position x (dummyobjectnum), object position z(dummyobjectnum)) = 191
position camera 0, object position x(dummyobjectnum), object position y(dummyobjectnum) +10, object position z(dummyobjectnum)
  else 
 height# = get terrain ground height (terrnum, camera position x(0), camera position z(0)) 
 position object dummyobjectnum, camera position x(0), height#, camera position z (0)
 endif  
if leftkey()then yrotate camera 0, camera angle y() - 1
if rightkey()then yrotate camera 0,  camera angle y() + 1

key = scancode()
if key = 79 and amdr <8 
inc amdr,2
iddir = 1
ob = hutdoordummy
switches(ob,amdr, iddir,0)
endif
if key = 80 and amdr>0
dec amdr,2
iddir = 1
ob = hutdoordummy
switches(ob, amdr, iddir,0)
endif
if key = 75 and amwn<8
inc amwn,2
iddir=2
ob = hutwindowdummy
 switches(ob, amwn, iddir,0)
endif
if key = 76 and amwn>0
dec amwn,2
iddir=2
ob = hutwindowdummy
 switches(ob, amwn, iddir,0)
endif
if key = 72 and rdrrun= 1
rdrrun = 0
while scancode() = 72: endwhile
key = scancode()
endif
if key = 72 and rdrrun= 0
 rdrrun = 1
while scancode() = 72 : endwhile
key = scancode()
endif
if shiftkey() and keystate(79) and amdr2<8
inc amdr2,2
iddir = 1
ob = doornum2
switches(ob,amdr2, iddir, 90)
endif
if shiftkey() and keystate(80) and amdr2>0
dec amdr2,2
iddir = 1
ob = doornum2
switches(ob,amdr2, iddir,90)
endif
if shiftkey() and keystate(75) and amwn2<8
inc amwn2,2
iddir = 3
ob = windownum2
switches(ob,amwn2, iddir,90)
endif
if shiftkey() and keystate(76) and amwn2>0
dec amwn2,2
iddir = 3
ob = windownum2
switches(ob,amwn2, iddir,90)
endif

if rdrrun =1 then turn object left hutarnum,1
if key = 73 then turn object left boatdummyobj,1
if key = 81 then texture limb lifebeltnum,0, lifebelttexturenum2
if key = 77 then texture limb lifebeltnum,0, lifebelttexturenum
center text 640,50, "TOGGLE HELP [F1]"
if key = 59 then helpreq = - helpreq
while scancode()=59:endwhile
if helpreq>0 then gosub  showhelp 
key = 0 

loop

  cleanup()
end


function setup()
hide mouse
set display mode 1280, 1024,32
color backdrop RGB(0,0,0)  : backdrop on
autocam off
position camera 0, 0,10,0
point camera 0, 270, 0, 100
set ambient light 100
set image colorkey  0,0,0
set text size 32
set text font "ariel"
endfunction

 make_contour_map:
gosub make_data_array

for x = 1 to 32
   for z = 1 to 32


   select shapexz(x-1,z-1)

   
      case 1
      dot x,z,rgb(40,40,40)
      endcase
     
      case 3,5, 2,6,7
      dot x,z,RGB(191,191,191)
      endcase
      case 4
      dot x,z,RGB(255,255,255)
      endcase
      case default
      raise_alarm("out of range - shapexz(x,z)")
      endcase
   endselect 
   
   next z
next x

get image 1, 1,1,32,32

save image "contourmap.bmp",1
 
cls
return


make_object_texture:
for x = 1 to 32
  for z = 1 to 32
      select shapexz(x-1,z-1)
     
        rem case 1: dot x,z,RGB(14,52,240) :endcase
         case 1: dot x,z,RGB(255,255,46): endcase
        case 2: dot x,z,RGB(255,255,0): endcase
        
        rem case 3: dot x,z,RGB(177,181,73): endcase
         case 5: dot x,z,RGB(255,255,70): endcase
         
         case 4: dot x,z, RGB(179,182,136):endcase
         rem case 5: dot x,z,RGB(197,200,66): endcase
         case 3: dot x,z,RGB(142,120,100): endcase
         case 6: dot x,z,RGB(254,255,106): endcase
         case 7: dot x,z,RGB(0,0,200): endcase
         case default:  dot x,z,RGB(255,0,66): endcase
      endselect

  next z
next x

get image 2,1,1,32,32
save image "groundtexture.bmp", 2

skytexnum = get_image_num()
for x = 1 to 1024
	for z= 1 to 1024
	
	if z >345 and z < 400 
	 dot x,z, RGB(212,244,254)
	else
	 rem dot x,z, RGB(212,233,236)
	dot x,z, RGB(4,193,255)
	endif
	if z<350 then dot x,z, RGB(178,236,255)

	next z
	
next x

dot 400, 400, RGB(233,0,0)
dot 450, 450, RGB(233,0,0)
dot 700, 430, RGB(200,200,200)
for x = 100 to 300
dot x, 400, RGB(0,0,0)
dot x+300, 400, RGB(0,0,0)
dot x+700,400, RGB(0,0,0)
next x 
for x= 730 to 850
dot x, 399, RGB(0,0,0)
next x

 rem for x = 350 to 380
rem dot x, 399, RGB(0,0,0)
 rem next x 
ink rgb (255,255,255),rgb(255,255,255)
box 0, 180, 1024,350, RGB(178,236,255),RGB(178,236,255),RGB(212,244,254),RGB(212,244,254)
	 line 380, 200, 380, 300 
	 line 800, 180, 550, 350
	 line 200, 200, 300, 380
	
	
	 ink RGB(212,244,254),0
	 
	 line 1,350, 20, 190
	 line 5,180,5,350
     line 10, 349, 50, 350
     line 105, 349, 170, 350
     line 20,350, 0, 340
     ink RGB(178,236,255),0
     line 1000, 330, 1020, 315
     line 1025, 340, 990, 325
     line 1025, 341, 1000, 326
     line 500, 340, 750, 340
     line 550, 339, 600, 339 

box 1,410, 1024,700,  RGB(212,244,254),RGB(4,193,255), RGB(212,244,254),RGB(4,193,255)
 dot 420, 395, rgb(0,0,0)
  dot 520, 395, rgb(0,0,0)
	get image skytexnum, 1,1,1024,1024
	
	save image "skytexture.jpg", skytexnum

woodhuttexture = get_image_num()
 
for x = 1 to 20
	for y = 1 to 20
	if x=1 or  x= 10 or x=19 or y=1 or y=10 
	dot x,y, RGB(106,48,0)
	else
	 rem  dot x,y,  RGB(155,101,91)
	dot x,y,RGB(255,255,233)
	
	endif  
	if (x>3 and x< 8) and (y> 3 and y< 8)
	dot x,y, rgb(0,0,0)
	endif
 
	if ((x > 12 and x < 17) and Y > 3) 
	dot x, y, RGB(0,0,0)
	endif
	next y
next x
 
get image woodhuttexture, 1,1, 20, 20
save image "woodhuttexture.jpg", woodhuttexture


woodhutsidetexture = get_image_num()
for x = 1 to 20
	for y = 1 to 20
	if x=1 or  x= 9 or x=18 or y=1 or y=10 
	dot x,y, RGB(106,48,0)
	else
	 rem  dot x,y,  RGB(155,101,91)
	dot x,y,RGB(255,255,233)
	
	endif  
	next y
next x

get image woodhutsidetexture, 1,1, 20, 20
save image "woodhutsidetexture.bmp", woodhutsidetexture

woodhuttexturerooftiles = get_image_num()
for x = 1 to 20
	for y = 1 to 20
	if x=1 or x=19 or y=1 or y=19 
	dot x,y,rgb(106,48,0)
	else
	dot x,y,  RGB(212,200,174)
	endif
	next y
next x

get image woodhuttexturerooftiles, 1,1, 20, 20
save image "woodhuttexturerooftiles.jpg", woodhuttexturerooftiles


woodhutdoor1texture = get_image_num()
for x = 1 to 20
	for y = 1 to 20
	if x=1 or x=2 or   x=9 or x=10 or x=19 or x= 20 or y=1 or y = 2 or y = 3 or y = 4 or y= 19 or y= 18 or y=9 or y= 10 
	dot x,y,rgb(106,48,0)
	else
	dot x,y,  RGB(0,0,0)
	endif
	next y
next x
get image woodhutdoor1texture, 1,1, 20, 20
save image "woodhutdoor1tex.jpg", woodhutdoor1texture

woodhutdoor2texture = get_image_num()
for x = 1 to 20
	for y = 1 to 20
	 dot x,y,  RGB(212,200,174)
	 
	 next y
next x

get image woodhutdoor2texture, 1,1, 20, 20
save image "woodhutdoor2texture.jpg", woodhutdoor2texture

woodhutwindow1texture = get_image_num()
for x = 1 to 12
	for y = 1 to 12
	
	if x < 2 or x>10 or y<2 or y > 10 
	dot x,y,rgb(106,48,0)
	else
	dot x,y,  RGB(0,0,0)
	endif
	
	next y
next x
 
get image woodhutwindow1texture, 1,1, 12, 12
save image "woodhutwindow1texture.bmp", woodhutwindow1texture


woodhutwindow2texture = get_image_num()
for x = 1 to 4
	for y = 1 to 4
		dot	x,y, RGB(233,232,243)
	 next y
next x
 
get image woodhutwindow2texture, 1,1, 4, 4
save image "woodhutwindow2texture.bmp", woodhutwindow2texture

woodtable2texture = get_image_num()
for x = 1 to 20
	for y = 1 to 20
	if x=1 or x=19 or y=1 or y=19 
	dot x,y,rgb(106,48,0)
	else
	dot x,y,  RGB(148,117,0)
	endif
	next y
next x

get image woodtable2texture, 1,1, 20, 20
save image "woodtable2texture.jpg", woodtable2texture


boattex= get_image_num()
for x = 1 to 512
	for y = 1 to 512
		dot x,y,RGB(36,192,0)
	next y
next x
get image boattex,1,1,512,512
save image "boattex.bmp", boattex


boattex2 = get_image_num()
for x = 1 to 512
	for y = 1 to 512
		dot x,y,RGB(192,36,0)
	next y
next x
get image boattex2,1,1,512,512
save image "boattex2.bmp", boattex2

boattex3 = get_image_num()
for x = 1 to 512
	for y = 1 to 512
		dot x,y, RGB(195,195,0) 
	next y
next x
get image boattex3,1,1,512,512
save image "boattex3.bmp", boattex3

treetex1 = get_image_num()
for x = 1 to 512
	for y = 1 to 512
		dot x,y,  RGB(110,70,0)
	next y
next x
get image treetex1,1,1,512,512
save image "treetex1.bmp", treetex1

treetex2 = get_image_num()
for x = 1 to 512
	for y = 1 to 512
		dot x,y, RGB(18,128,0)  
	next y
next x
get image treetex2,1,1,512,512
save image "treetex2.bmp", treetex2

rem lifebelttexture

lifebelttexturenum = get_image_num()

for x = 0 to 20 
  for y = 0 to 20
  dot x, y,RGB(255,255,233) 
  next y
  next x
  
   for x = 3 to 7
  if x = 3 or x = 4  
  ink rgb(200,33,0),0
  else
   if x = 6 or x = 7
   ink rgb(200,33,0),0
   else
   	ink RGB(255,66,0),0
  	endif
  endif
  circle 10,10,x
  next x
  
  get image lifebelttexturenum, 1,1,20,20
  save image "lifebelttexturenum.bmp", lifebelttexturenum
  
  
  lifebelttexturenum2 = get_image_num()
for x = 0 to 20 
  for y = 0 to 20
   dot x, y,RGB(255,255,233) 
  next y
 next x
   get image lifebelttexturenum2, 1,1,20,20
  save image "lifebelttexturenum2.bmp", lifebelttexturenum2
  
  return

make_base_terrain:

 texnum = get_image_num()
 load image "groundtexture.bmp",texnum
connum = get_image_num()
 load image "contourmap.bmp", connum
terrnum = get_object_num()
make object terrain terrnum
set terrain heightmap terrnum, "contourmap.bmp"
set terrain scale terrnum, 10.0, 1.0, 10.0
set terrain texture terrnum, texnum, texnum
set terrain tiling terrnum, 32
build terrain terrnum
 
ypos# = get terrain ground height(terrnum,200.0,200.0)-50 
 position camera 200.0, 200.0 ,200.0
 dummyobjectnum = get_object_num()
 make object cube dummyobjectnum, 0
 
return



make_sky:
skynum = get_object_num()
make object sphere skynum, 3000, 50,50
set object cull skynum, 0  
 texture object skynum, skytexnum

return

make_extras:

basenum = get_object_num()
make object box basenum, 70,50,1
xrotate object basenum, -90
position object basenum, 150,191,220

texture object basenum, woodhuttexturerooftiles

walkobj = get_object_num()
make object box walkobj, 10, 30,1
position object walkobj, object position x(basenum)+20, 191, object position z(basenum) +40 
rotate object walkobj, 90,0,0
texture object walkobj,woodhuttexturerooftiles

tablenum = get_object_num()
make object box tablenum, 15, 0.5,1
tablems1 = get_mesh_num()
make mesh from object tablems1, tablenum
add limb tablenum, 1, tablems1
offset limb tablenum, 1, 0,0, -2 
add limb tablenum, 2, tablems1
offset limb tablenum, 2, 0,0,2
add limb tablenum, 3, tablems1
offset limb tablenum, 3, 0, -3, -3
add limb tablenum, 4, tablems1
offset limb tablenum, 4, 0, -3, 3
add limb tablenum, 5, tablems1
scale limb tablenum, 5, 50.0, 100.0,100.0
rotate limb tablenum, 5, 0, 90, 90 
offset limb tablenum, 5, 6,-4,0
add limb tablenum, 6, tablems1
scale limb tablenum, 6, 50, 100, 100
rotate limb tablenum, 6, 0,90,90
offset limb tablenum, 6, -6, -4,0
add limb tablenum, 7, tablems1
scale limb tablenum, 7, 50, 100,100
rotate limb tablenum, 7, 90,90,0
offset limb tablenum, 7, 0,-1.5,0
texture object tablenum, woodtable2texture
for x = 1 to 7
texture limb tablenum, x, woodtable2texture
next x

tablenum2 = get_object_num()
instance object tablenum2, tablenum
tablenum3 = get_object_num()
instance object tablenum3, tablenum
 yrotate object tablenum3, 60
position object tablenum, object position x(basenum) -23, 196, object position z(basenum) + 9 
position object tablenum2, object position x(basenum) , 196, object position z(basenum) - 15 
position object tablenum3, object position x(basenum)+23 , 196, object position z(basenum) 
rem end table
rem hut
hutnum = get_object_num()
make object sphere hutnum, 0 
hutbx = get_object_num()
make object box hutbx, 20,20,0.1
hutmeshnum = get_mesh_num()
make mesh from object hutmeshnum, hutbx
  delete object hutbx
 hutsidenum = get_mesh_num()
 make object box hutbx, 10,20,0.1
 make mesh from object hutsidenum, hutbx
 delete object hutbx
 hutroofnum = get_mesh_num()
make object box hutbx, 20,9,0.1
make mesh from object hutroofnum, hutbx
delete object hutbx
hutsideroofnum = get_mesh_num()
make object triangle hutbx, 0, 0, 0, 0, 0, 10, 0,5,5
make mesh from object hutsideroofnum, hutbx
 delete object hutbx
hutfloornum= get_mesh_num()
make object box hutbx, 20,10,0.3
make mesh from object hutfloornum, hutbx, 
delete object hutbx

add limb hutnum, 1, hutmeshnum
add limb hutnum, 2, hutsidenum
add limb hutnum, 3, hutroofnum
add limb hutnum, 4, hutsideroofnum 
add limb hutnum, 5, hutmeshnum 
add limb hutnum, 6, hutsidenum
add limb hutnum, 7, hutsideroofnum
add limb hutnum, 8, hutroofnum
add limb hutnum, 9, hutfloornum
 
offset limb hutnum, 1,  0,  0,-10
offset limb hutnum, 2, 10,  0,- 5
rotate limb hutnum, 2,  0, 90, 0
offset limb hutnum, 3,  0, 12, -8
rotate limb hutnum, 3, 45,  0,  0
offset limb hutnum, 4, 9.5, 10,  0
rotate limb hutnum, 4,  0,180,  0
offset limb hutnum, 5,  0,  0, 0
offset limb hutnum, 6, -10,0, -5
rotate limb hutnum, 6,  0,-90,0
offset limb hutnum, 7, -10,10,0
rotate limb hutnum, 7, 0, -180,0
offset limb hutnum, 8, 0,12,-2
rotate limb hutnum, 8, -45,0,0
offset limb hutnum, 9, 0,0,-5
rotate limb hutnum, 9, 90,0,0

texture limb hutnum,  1, woodhuttexture
texture limb hutnum,  2, woodhutsidetexture
texture limb hutnum,  3, woodhuttexturerooftiles
texture limb hutnum,  4, woodhuttexturerooftiles
texture limb hutnum,  5, woodhutsidetexture
texture limb hutnum,  6, woodhutsidetexture
texture limb hutnum,  7, woodhutsidetexture
texture limb hutnum,  8, woodhuttexturerooftiles
texture limb hutnum,  9, woodhuttexturerooftiles

hutdoordummy = get_object_num()
make object sphere hutdoordummy, 0
hutdoor1num = get_mesh_num()
hutdoortempbx = get_object_num()
make object box hutdoortempbx, 5,8,0.2
make mesh from object hutdoor1num, hutdoortempbx
delete object hutdoortempbx
add limb hutdoordummy, 1,hutdoor1num
offset limb hutdoordummy,1, -2.5,0,0  
texture limb hutdoordummy, 1, woodhutdoor1texture
scale limb texture hutdoordummy, 1, 2,2 
add limb hutdoordummy, 2, hutdoor1num
offset limb hutdoordummy, 2, -2.5, 0.5, 0.2
texture limb hutdoordummy, 2, woodhutdoor2texture
scale limb hutdoordummy, 2, 100, 100.2, 100 
hutwindowdummy = get_object_num()
make object sphere hutwindowdummy,0
hutwindowtempbx = get_object_num()
hutwindow1num = get_mesh_num()
make object box hutwindowtempbx, 6, 6, 0.3
make mesh from object hutwindow1num, hutwindowtempbx
delete object hutwindowtempbx
make object box hutwindowtempbx, 5,5,0.3
hutwindow2num = get_mesh_num()
make mesh from object hutwindow2num, hutwindowtempbx
delete object hutwindowtempbx
add limb hutwindowdummy, 1, hutwindow1num
 texture limb hutwindowdummy, 1, woodhutwindow1texture
add limb hutwindowdummy, 2, hutwindow2num
 texture limb hutwindowdummy, 2, woodhutwindow2texture

set object transparency hutnum, 4
set object transparency hutdoordummy, 4
set object transparency hutwindowdummy, 4
hut2 = get_object_num()
instance object hut2, hutnum 
position object hutnum, 160,192, 240  
position object hut2, 120, 192, 210

position object hutdoordummy, object position x(hutnum)+7, 196, object position z(hutnum)-10
doornum2 = get_object_num()
clone object doornum2, hutdoordummy, 0
yrotate object doornum2, -90
position object doornum2, object position x(hut2)+10, 196, object position z(hut2)+7
offset limb doornum2, 2, -2.5 , 0, 0.1
rem yrotate object hutnum, 0 
yrotate object hut2, -90
position object hutwindowdummy, object position x(hutnum)-4.8, 196.8 ,object position z(hutnum)-10 
windownum2 = get_object_num()
clone object windownum2, hutwindowdummy,0
yrotate object windownum2, 90
position object windownum2, object position x(hut2)+10,196.8, object position z(hut2)-5 
 hutarnum = get_object_num()
hutarnumms = get_mesh_num()
make object box hutarnum, 0.3,0.3,4.0
make mesh from object hutarnumms, hutarnum
position object hutarnum, object position x (hutnum), 209, object position z(hutnum)-3
add limb hutarnum, 1, hutarnumms
add limb hutarnum, 2, hutarnumms
add limb hutarnum, 3, hutarnumms
rotate limb hutarnum, 1, 0,90,0
rotate limb hutarnum, 2, 0,90,0
rotate limb hutarnum, 3, 90,0,0
offset limb hutarnum,1, 0,0,-2
offset limb hutarnum, 2, 0,0,2
offset limb hutarnum, 3, 0,-1.6,0
texture object hutarnum,  woodhutwindow2texture
 rem end hut
rem boat
tempobj=get_object_num()
boatmesh1 = get_mesh_num()
make object box tempobj, 20,10,10
make mesh from object boatmesh1,tempobj
delete object tempobj
boatmesh2 = get_mesh_num()
make object triangle tempobj, -25,3,0, -10,-5,5, -10,-5,-5
make mesh from object boatmesh2,tempobj
delete object tempobj
boatmesh3 = get_mesh_num()
 make object triangle tempobj,25,3,0, 10,-5,5, 10,-5,-5
 make mesh from object boatmesh3,tempobj
 delete object tempobj
boatdummyobj = get_object_num()
make object sphere boatdummyobj, 0

lock vertexdata for mesh boatmesh1
add mesh to vertexdata boatmesh2
add mesh to vertexdata boatmesh3
unlock vertexdata
 

add limb boatdummyobj,1,boatmesh1
add limb boatdummyobj,2,boatmesh2
add limb boatdummyobj,3,boatmesh3 

 for x = 1 to 3
texture limb boatdummyobj,x, boattex
next x

lock vertexdata for limb boatdummyobj,1
set vertexdata position 0, -15,0,-5
 set vertexdata position 4, -15,0,5
 set vertexdata position 11, -15,0,-5
 set vertexdata position 20, -15,0,-5
 set vertexdata position 8, -15, 0,5
 set vertexdata position 23, -15,0,5
 set vertexdata position 1, 15,0,-5
 set vertexdata position 10, 15,0,-5
 set vertexdata position 16,15,0,-5
 set vertexdata position 7, 15,0,5
 set vertexdata position 9, 15,0,5
 set vertexdata position 17, 15,0,5
 set indexdata 32,24
 set indexdata 35,24
 set indexdata 31,26
 set indexdata 33,25
 set indexdata 27,27
 set indexdata 24,27
 
 unlock vertexdata
 
 scale object boatdummyobj, 70,100,70
 set object cull boatdummyobj,0
   
 boatobj2= get_object_num()
 clone object boatobj2, boatdummyobj
  boatobj3= get_object_num()
 clone object boatobj3, boatdummyobj
   
for x = 1 to 3
texture limb boatobj2,x, boattex2
texture limb boatobj3,x, boattex3
next x
position object boatdummyobj, 100, 193,75
position object boatobj2, 140, 193,75
rotate object boatobj2, 0, 45,0
position object boatobj3, 120, 193,75
rotate object boatobj3, 0, 70,0
 
 rem tree
 treerootobj = get_object_num()
make object sphere treerootobj, 0.2,50,50

treetempobj= get_object_num()
make object sphere treetempobj, 5,50,50

lock vertexdata for limb treetempobj,0
ttlv =get vertexdata vertex count()
for tv = 0 to ttlv-1
	y#= get vertexdata position y(tv)
		if y#<0
			x#= get vertexdata position x(tv)
			y#=-3
			if x#>0 then x#=x#+5
			z#=get vertexdata position z(tv)
			set vertexdata position tv, x#,y#,z#
		endif
next tv
unlock vertexdata 

lock vertexdata for limb treerootobj,0
ttlverts=get vertexdata vertex count()
for tv = 0 to ttlverts-1
	y#= get vertexdata position y(tv)
		if y#<0
			x#=get vertexdata position x(tv)
			y#=-40
			z#= get vertexdata position z(tv)
			
			if y#<-38 
			if  x# <0 then x# = -1 else x#=1
			if z#<0 then z#=-1 else z#=1
			endif
			if y#>-10 then x#=x# +5 
			set vertexdata position tv,x#,y#,z#
		endif 
next tv
unlock vertexdata

treems1 = get_mesh_num()
make mesh from object treems1,treetempobj
delete object treetempobj
add limb treerootobj, 1, treems1 
 offset limb treerootobj, 1, 0,-38,0
 texture limb treerootobj,0,treetex1
texture limb treerootobj,1,treetex1
set object cull treerootobj, 0 
  position object treerootobj, 250,230,120

rem leaf
lfdummyobj = get_object_num()
make object sphere lfdummyobj,0
lftemp = get_object_num()
leafmesh1num = get_mesh_num()
make object triangle lftemp, 0,0,0, -1,6,0, 0,6,1
make mesh from object leafmesh1num, lftemp 
delete object lftemp
leafmesh2num = get_mesh_num()
make object triangle lftemp, 0,0,0, 0,6,1, 1,6,0
make mesh from object leafmesh2num, lftemp 
delete object lftemp
leafmesh3num = get_mesh_num()
make object triangle lftemp, 0,6,1, -1,6,0, 0,10,3
make mesh from object leafmesh3num, lftemp 
delete object lftemp
leafmesh4num = get_mesh_num()
make object triangle lftemp, 0,6,1, 0,10,3, 1,6,0
make mesh from object leafmesh4num, lftemp 
delete object lftemp
add limb lfdummyobj, 1, leafmesh1num
add limb lfdummyobj, 2, leafmesh2num
add limb lfdummyobj, 3, leafmesh3num
add limb lfdummyobj, 4, leafmesh4num

leafmesht= get_mesh_num()
make mesh from object leafmesht,lfdummyobj
delete object lfdummyobj

for lf = 2 to 13 
inc anglf, 30
add limb treerootobj, lf, leafmesht
scale limb treerootobj, lf, 100,200,100
rotate limb treerootobj, lf, -130,anglf,0
texture limb treerootobj, lf, treetex2
next lf
 for lf = 14 to 25 
inc anglf, 30
add limb treerootobj, lf, leafmesht
 scale limb treerootobj, lf, 100,180,100
rotate limb treerootobj, lf, -100,anglf,0
texture limb treerootobj, lf, treetex2
next lf
for lf = 26 to 37 
inc anglf, 30
add limb treerootobj, lf, leafmesht
scale limb treerootobj, lf, 100,150,100
rotate limb treerootobj, lf, 30,anglf,0
texture limb treerootobj, lf, treetex2
next lf
  
set object cull treerootobj, 0
tree2 = get_object_num()
instance object tree2,treerootobj
position object tree2, 270, 228, 100
rotate object tree2, 0,0,-15
rotate limb tree2, 1, 0,90,50
 
 for lf = 2 to 37
 rotate limb tree2, lf, 30,0,0
 next lf

rem lifebelt
lifebeltnum = get_object_num()
make object box lifebeltnum, 10,10, 0.5
for x = 1 to 7 
  add limb lifebeltnum, x, tablems1
 next x
 rotate limb lifebeltnum, 1, 90, 0, 0
 offset limb lifebeltnum, 1, 0,5,-0.5
  scale limb lifebeltnum, 1, 70,100,100 
 rotate limb lifebeltnum, 2, 90,0,0
 offset limb lifebeltnum, 2, 0,-5,-0.5
  scale limb lifebeltnum, 2, 70,100,100 
 offset limb lifebeltnum, 3, 0,-7,1 
 rotate limb lifebeltnum, 3, 0,0,90
 scale limb lifebeltnum, 3, 200,200,200
 rotate limb lifebeltnum, 4, 0,0,90
 offset limb lifebeltnum, 4, 5,0,0
 scale limb lifebeltnum, 4, 70,100,100 
 rotate limb lifebeltnum, 5, 0,0,90
 offset limb lifebeltnum, 5, -5,0,0
 scale limb lifebeltnum, 5, 70,100,100
rotate limb lifebeltnum, 6, 0,0,90
offset limb lifebeltnum, 6, -20,-7,-20
rotate limb lifebeltnum, 7, 0,0,90
offset limb lifebeltnum, 7, 20,-7,-20
for x = 1 to 7
texture limb lifebeltnum, x, woodtable2texture
next x
texture limb lifebeltnum,0, lifebelttexturenum
yrotate object lifebeltnum, 50
position object lifebeltnum, 260, 198, 215 
scale object lifebeltnum, 70,70,70

point camera 0, 210, 200, 110

return

function switches(ob,i, obdirid, fac)
if obdirid = 1 then yrotate object ob, 10*i-fac
if obdirid=2 then xrotate object ob, 10*i 
if obdirid = 3 then zrotate object ob, 10*i
endfunction


function get_object_num()
for objnum = 1 to 55555
if object exist(objnum) = 0
exitfunction objnum
endif
next objnum
endfunction 0

function get_image_num()
for imagenum = 1 to 55555
if image exist(imagenum) = 0
exitfunction imagenum
endif
next imagenum
endfunction 0

function get_mesh_num()
for meshnum= 1 to 55555
if mesh exist(meshnum)=0
exitfunction meshnum
endif
next meshnum
endfunction 0

function cleanup()
for i = 1 to 55555
 if object exist(i)
  delete object i
 else
  exit
 endif
next i

for i = 1 to 55555
  if image exist(i)
   delete image i
  else
   exit
  endif
next i
endfunction

make_data_array:

for x = 0 to 31
  for z = 0 to 31
 
 read shapexz(x,z)
  next z
next x

data 1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1
data 1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1
data 1,1,1,1,1,1,7,7,7,7,7,7,7,7,7,7,7,7,7,7,7,7,7,7,7,7,7,7,7,7,1,1 
data 1,1,1,1,1,1,3,3,3,2,2,2,2,2,2,3,2,2,2,2,7,7,7,7,7,7,7,7,7,7,1,1
data 1,1,1,1,1,1,3,3,3,3,3,3,3,3,3,3,3,3,3,3,3,3,3,2,2,2,6,6,7,7,7,1
data 1,1,1,1,1,1,3,3,3,4,4,4,4,4,4,4,4,3,3,3,3,3,3,2,2,2,6,6,7,7,7,1
data 1,1,1,1,1,1,3,3,3,4,4,4,4,4,4,4,4,4,3,3,3,3,3,2,2,2,6,6,6,6,7,1
data 1,1,1,1,1,1,3,3,3,3,3,3,3,3,3,3,3,3,3,3,3,3,3,2,2,2,2,3,6,6,7,1
data 1,1,1,1,1,1,3,3,3,3,3,3,3,3,3,3,3,3,3,3,3,3,3,2,2,2,2,6,6,6,7,1
data 1,1,1,1,1,1,3,3,3,3,3,3,3,3,3,3,3,3,3,3,3,3,3,2,2,2,2,6,6,6,7,1
data 1,1,1,1,1,1,3,3,5,5,3,3,3,3,3,3,3,3,3,3,3,3,3,2,2,2,2,6,6,6,7,1
data 1,1,1,1,1,1,3,3,5,3,3,3,3,3,3,3,3,3,3,3,3,3,3,2,2,2,2,6,6,6,7,1
data 1,1,1,1,1,1,3,3,3,3,3,3,3,3,3,3,3,3,3,3,3,3,3,2,2,2,2,6,6,6,7,1
data 1,1,1,1,1,1,3,3,3,3,3,3,3,3,3,3,3,3,3,3,3,3,3,6,6,2,2,6,6,6,7,1
data 1,1,1,1,1,1,3,3,3,3,3,3,3,3,3,3,3,3,3,3,3,3,3,2,6,6,2,6,6,6,7,1 
data 1,1,1,1,1,1,3,3,3,3,3,3,3,3,3,3,5,3,3,3,3,3,3,2,2,2,2,6,6,6,7,1
data 1,1,1,1,1,1,5,3,3,3,3,3,3,3,3,3,5,3,3,3,3,3,3,2,2,2,2,6,6,6,7,1
data 1,1,1,1,1,1,3,3,3,3,3,3,5,5,3,3,5,3,3,3,3,3,3,2,2,2,2,6,6,6,7,1
data 1,1,1,1,1,1,3,3,3,3,3,3,5,5,3,3,5,3,3,3,3,3,3,2,2,2,2,6,6,6,7,1
data 1,1,1,1,1,1,3,3,3,3,3,3,5,5,3,3,3,3,3,3,3,3,3,2,2,2,2,6,6,6,7,1
data 1,1,1,1,1,1,3,3,3,3,3,3,5,5,3,3,5,3,3,3,3,3,7,7,7,7,2,6,6,6,7,1
data 1,1,1,1,1,1,3,3,5,5,5,5,3,3,3,3,3,3,3,3,3,3,3,2,2,2,2,6,6,6,7,1
data 1,1,1,1,1,1,3,2,3,3,3,3,3,3,3,5,3,3,3,3,3,3,3,2,6,6,2,6,6,6,7,1
data 1,1,1,1,1,1,5,3,3,3,3,3,3,3,5,3,5,3,3,3,3,3,3,2,6,6,2,6,6,6,7,1
data 1,1,1,1,1,1,3,3,3,3,3,3,3,3,5,3,5,3,3,3,3,3,3,2,2,2,2,6,6,6,7,1
data 1,1,1,1,1,1,1,3,3,3,3,3,3,3,3,3,3,3,3,3,3,3,3,2,2,2,2,6,6,6,7,1
data 1,1,1,1,1,1,1,1,2,2,2,2,2,2,2,2,2,2,2,2,2,2,2,2,2,2,2,6,6,6,7,1
data 1,1,1,1,1,1,1,1,1,2,2,2,2,2,2,2,2,2,2,2,2,2,2,2,2,2,2,6,6,6,7,1
data 1,1,1,1,1,1,1,1,1,6,6,6,6,6,6,6,6,6,6,6,6,6,6,6,6,6,6,6,6,7,1,1
data 1,1,1,1,1,1,1,1,7,7,7,7,7,7,7,7,7,7,7,7,7,7,7,7,7,7,7,7,1,1,1,1
data 1,1,1,1,1,1,1,1,1,7,7,7,7,7,7,7,7,7,7,7,7,7,7,7,7,7,7,7,1,1,1,1
data 1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1
data 1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1
  
return

function raise_alarm(s$)
set cursor 10,10
print s$
wait key
endfunction 

showhelp:

 
   ink rgb(255,0,0),0
   center text 640, 160, "Welcome to owlman island" 
   
   center text 640,220, "hotkey help: (numeric keypad unless stated))"
   center text 640, 300, "open refreshment hut doors - [shift] + 1"
   center text 640, 350,"close refreshment hut doors - [shift] + 2"
   center text 640, 400,"open refreshment hut windows (for easier cleaning) - [shift] + 4"
   center text 640, 450, "close refreshment hut windows - [shift] + 5"
   center text 640, 500, "toggle radar antenna on/off (affects radar system - disable with caution)- 8"
   center text 640, 550, "rotate green canoe - 9"
   center text 640, 600, "jettison lifebelt into sea - 3"
   center text 640, 650, "replace lifebelt onto holder - 6"
   center text 640, 700, "the following camera keys are also available: "
   center text 640, 750, " move north - south: down arrow | south - north: - up arrow | rotate camera left/ right arrow as required" 
    center text 640, 800, "thank you for your visit today - please take litter home. "
return 
 

acelepage!

function weapon1()
    
endfunction

function weapon2()
    
endfunction

etc....

set display mode 1280,768,32

Itarget=1
Iground=2
Isky=3
Istick=4
Oground=1
Osky=2
Otarget=3
set image colorkey 0,0,0
rem make target texture
create bitmap 1,256,256
ink 0,0
box 0,0,255,255
dim c(1) as dword
c(0)=rgb(255,255,255)
c(1)=rgb(255,0,0)
i=0
for x=25 to 125 step 25
  ink c(i),0
  for y=x-25 to x
    circle 128,128,y
  next y
  i=1-i
next x
get image Itarget,0,0,255,255
rem make ground texture
ink rgb(64,255,128),0
box 0,0,255,255
ink rgb(192,255,192),0
for x=1 to 1000
  dot rnd(255),rnd(255)
next x
get image Iground,0,0,255,255
rem make sky texture
for x=0 to 255
  ink rgb(x,x,255),0
  line 0,x,255,x
next x
get image Isky,0,0,255,255
ink rgb(128,64,32),0
box 0,0,255,255
get image Istick,0,0,255,255
delete bitmap 1
rem make ground
make object plain Oground,1000,1000
texture object Oground,Iground
xrotate object Oground,90
position object Oground,0,-10,200
rem make sky
make object plain Osky,4000,2000
texture object Osky,Isky
position object Osky,0,500,300
rem make target
make object plain Otarget,20,20
texture object Otarget,1
make object plain Otarget+1,2,10
make mesh from object 1,Otarget+1
delete object Otarget+1
add limb Otarget,1,1
offset limb Otarget,1,0,-15,0
texture limb Otarget,1,Istick
set object transparency Otarget,1
for x=Otarget+1 to Otarget+9
  instance object x,Otarget
  yrotate object x,180
next x
position camera 0,0,-300
point camera 0,0,0
for x=Otarget to Otarget+9
  position object x,(x-Otarget)*50-250,5,0
next x
while not escapekey()
  if leftkey()
    turn camera left 1
  endif
  if rightkey()
    turn camera right 1
  endif
  if upkey()
    if camera position y()<100
      position camera camera position x(),camera position y()+1,camera position z()
    endif
  endif
  if downkey()
    if camera position y()>5
      position camera camera position x(),camera position y()-1,camera position z()
    endif
  endif
endwhile

autocam off
sync on:hide mouse
rem  ===== SOME TEXTURES  ===================================
rem grass texture
ink rgb(0,155,0),1
box 0,0,100,100
for i= 1 to 1000
ink rgb(0,rnd(255),0),1
dot rnd(100),rnd(100)
next i
get image 1,0,0,100,100

rem fire texture -------------------------------------------->
for i= 1 to 5500
col=rnd(100)
ink rgb(col,col,col),1
dot rnd(100),rnd(100)
next i
get image 2,0,0,100,100

rem grenade texture ----------------------------------------->
ink rgb(10,10,10),1
box 0,0,20,20
ink rgb(50,50,50),1
box 2,2,18,18
ink rgb(60,60,60),1
box 5,5,15,15
get image 3,0,0,20,20

rem wood texture -------------------------------------------->
create bitmap 1,100,100
ink rgb(160,70,40),1
box 0,0,100,100
ink rgb(140,50,20),1
for a= 1 to 2
for i= 1 to 100 step 5
line 0,i-13+rnd(16),100,i-13+rnd(16)
ink rgb(60+rnd(100),20,20),1
next i
next a
ink rgb(0,0,0),1
box 0,24,100,26
box 0,49,100,51
box 0,74,100,76
blur bitmap 1,4
get image 70,0,0,100,100
delete bitmap 1

rem light texture ------------------------------------------->
create bitmap 1,50,50
ink rgb(150,150,150),1
box 2,2,48,48
ink rgb(0,0,0),1
line 0,0,50,50
line 0,1,49,50
line 1,0,50,49
line 0,50,50,0
line 0,49,49,0
line 1,50,50,1
blur bitmap 1,2
get image 71,0,0,50,50,1
delete bitmap 1

rem light texture ------------------------------------------>
ink rgb(150,150,150),1
box 3,3,47,47
get image 72,0,0,50,50,1

rem load sound "boom 1.wav",1   rem  LOAD YOUR OWN SOUND .
rem ========================================================

make matrix 1,100,100,20,20
position matrix 1,0,-0.2,0
prepare matrix texture 1,1,1,1
//objeto 1 granada        objeto 2 regulador de altura
make object sphere 1,2,8,8
scale object 1,50,70,50
make object box 10,0.7,1,0.7
make mesh from object 1,10
add limb 1,1,1
offset limb 1,1,0,0.6,0
texture object 1,3
scale object texture 1,8,8
delete object 10


make object box 2,0.1,0.1,0.1 :hide object 2
rem explosion texture
make object cone 80,3
scale object 80,100,-0.1,100
texture object 80,2
set object 80,1,1,1,1,0
hide object 80


//obstacles
for i= 100 to 260
make object box i,1,1,1
texture object i,70
set light mapping on i,71+rnd(1)
set object emissive i,rgb(100+rnd(150),100+rnd(150),100+rnd(150))
position object i,5+rnd(90),0.3,5+rnd(90)
next i

rem diferenciando el objeto 200
scale object 200,300,300,300
offset limb 200,0,0,0.35,0
position object 200,20,1,20
set object emissive 200,rgb(255,255,255)
rem ===================================

rem margenes del terreno
make object box 1000,1,3,100:position object 1000,0,1,50
make object box 1001,1,3,100:position object 1001,100,1,50
make object box 1002,100,3,1:position object 1002,50,1,0
make object box 1003,100,3,1:position object 1003,50,1,100


position camera 10,10,10
dispara=0
x#=3
z#=3
do
set cursor 5,5
ink rgb(255,255,0),1
print "USE MOUSE TO FIRE "
color backdrop rgb(70,70,255)
if upkey() THEN x#=NEWXVALUE(x#,a#,0.03):if upkey() then z#=NEWZVALUE(z#,a#,0.03)
if downkey() THEN x#=NEWXVALUE(x#,a#,-0.03):if downkey() then z#=NEWZVALUE(z#,a#,-0.03)

rem forzamos al jugador a estar en un area cuadrada
if x#<2 then x#=2
if x#>98 then x#=98
if z#>98 then z#=98
if z#<2 then z#=2

rem movimiento de la camara
a#=wrapvalue(a#+mousemovex()/2)
cam#=wrapvalue(cam#+mousemovey()/2)
rotate camera  cam#,a#,0
rotate object 2,cam#,a#,0

position camera x#,2,z#
position object 1,x#,4,z#:move object right 1,1
position object 2,x#,4,z#
move object 2,6

//regulador de altura <<objeto 2>>
alt#=object position y(2)
if alt#>6 then push#=0.1 else push#=0
rem ==========================================================================
if dispara=0
set object to camera orientation 1
endif
if mouseclick() and dispara=0
dispara=1
endif

if dispara=1
la#=la#+0.2
run=run+1
pt#=pt#+0.3-push#  //para lanzar un poco mas lejos
move object 1,la#
xrotate object 1,pt#/alt#
endif

if run>300 or object position y(1)<0
run=0
la#=0
pt#=0
dispara=0
endif
if object position y(1)<0
rem play sound 1 rem *************************** activate this file if have a sound
position object 80,object position x(1),-0.15,object position z(1)
sc=rnd(100)
show object 80
scale object 80,100+sc,0.1,100+sc
endif
rem =========================================================================
rem obstacles behavior
for i=100 to 260
  dx#=object position x(i)-object position x(80)
  dz#=object position z(i)-object position z(80)
  dist#=sqrt((dx#*dx#)+(dz#*dz#))

  if dist#<10 and object position y(i)<20
     point object i,object position x(80),-1,object position z(80)
     move object i,-rnd(2)
    rem move object up i,1
  endif
next i
rem forcing objects rotation to 0,0,0
for i= 100 to 260
  if object position y(i)>0.5
    move object down i,0.09
  endif

  if object position y(i)<0.6
    rotate object i,0,0,0
  endif

  if object position y(i)>20
     position object i,5+rnd(90),0.5,5+rnd(90)
  endif
next i
rem ============================================================================

rem forcing obstacles being into the area
remstart
for i= 100 to 260
if object position x(i)<5 then position object i,5+rnd(90),0.5,5+rnd(90)
if object position x(i)>90 then position object i,5+rnd(90),0.5,2+rnd(90)
if object position z(i)<5 then position object i,5+rnd(90),0.5,2+rnd(90)
if object position z(i)>90 then position object i,5+rnd(90),0.5,2+rnd(90)
next i
remend
sync
loop