Sorry your browser is not supported!

Sync On
Sync Rate 60
color backdrop rgb(0,0,0)
Global Dim Ladders(20,3)

Gosub _LoadLevels
Gosub _LoadLadders
Gosub _LoadMiscObjects
Gosub _CreateBarrels
Gosub _CreateFire

Do
   set cursor 0,0
   Print "     Lives: "+str$(players)
   Print "     Level: "+str$(difficulty)
   Print "     Score: "+str$(score)
   Print " HighScore: "+str$(highscore)
   Print "       FPS: "+str$(screen fps())
   if players>0
      Gosub _GetInput
      Gosub _UpdateBarrels
      Gosub _UpdatePlayer
      Gosub _ScoreAnimation
      Gosub _UpdateFire
      if collide=1 then players=players-1:gosub _collision:gosub _StartGame
      if y#>67 then difficulty=difficulty+1:gosub _startgame
   else
      Gosub _Waitingforgame
   endif
   Sync
Loop

_UpdateFire:
   FireID=600
   for I=0 to NumFire
      if rnd(1000)>970 or fire#(i,1)>-33 then fire#(i,0)=rnd(6)-3:fire#(i,1)=-43:fire#(i,2)=200
      position object fireid+I,-50+fire#(i,0),fire#(i,1),0
      color object fireid+I,rgb(255,fire#(i,2),0)
      fire#(i,2)=fire#(i,2)-rnd(1)
      fire#(i,0)=(fire#(i,0)+((rnd(4)-2)*.03))*.99
      if ballhit>0
         fire#(i,1)=fire#(i,1)+.15
      else
         fire#(i,1)=fire#(i,1)+.05
      endif
   next I
   if ballhit>0 then ballhit=ballhit-1
Return

_UpdateBarrels:
   barrelrelease=barrelrelease+1
   if barrelrelease>300-30*difficulty
      if int(rnd(100))>=100-difficulty*5 then barrelrelease=0
   endif
   for i=0 to numbarrels
      if barrelstatus(i)=1
         mintemp#=3
         for j=0 to 5
            temp#=intersect object (levelid+j,barrel#(i,0),barrel#(i,1),0,barrel#(i,0),barrel#(i,1)-3,0)
            if temp#>0 and temp#<mintemp# then mintemp#=temp#
         next j
         if mintemp#<3
            barrel#(i,1)=barrel#(i,1)+(3-mintemp#)
            barrel#(i,3)=-barrel#(i,3)*.5
         else
            barrel#(i,3)=barrel#(i,3)+.03
         endif
         if barrel#(i,0)>47 then barrel#(i,2)=-barrel#(i,2)
         if barrel#(i,0)<-57 then barrel#(i,2)=-barrel#(i,2)
         if barrel#(i,0)<-47 and barrel#(i,1)<-47 then barrelstatus(i)=0:hide object barrelid+i:ballhit=200

         barrel#(i,0)=barrel#(i,0)+barrel#(i,2)
         barrel#(i,1)=barrel#(i,1)-barrel#(i,3)

         if Ladder(barrel#(i,0),barrel#(i,1)-15)
            if int(rnd(100))>=100-difficulty
               barrel#(i,0)=Ladder(barrel#(i,0),barrel#(i,1)-15)
               barrelstatus(i)=2
               barrel#(i,2)=-barrel#(i,2)
            endif
         endif
         if jump=1 and abs(barrel#(i,0)-x#)<2 and y#>barrel#(i,1) and y#-barrel#(i,1)<13 and barrelscored(i)=0 then barrelscored(i)=1:newscore=1
      endif

      if barrelstatus(i)=2
         if Ladder(barrel#(i,0),barrel#(i,1)-5)=0
            mintemp#=3
            for j=0 to 5
               temp#=intersect object (levelid+j,barrel#(i,0),barrel#(i,1),0,barrel#(i,0),barrel#(i,1)-3,0)
               if temp#>0 and temp#<mintemp# then mintemp#=temp#
            next j
            if mintemp#<3
               barrel#(i,1)=barrel#(i,1)+(3-mintemp#)
               barrel#(i,3)=0
               barrelstatus(i)=1
            endif
         endif
         if barrelstatus(i)=2 then barrel#(i,1)=barrel#(i,1)-.5
      endif

      if barrelstatus(i)=0 and barrelrelease=0
         barrelrelease=1
         barrelstatus(i)=1
         barrel#(i,0)=-45
         barrel#(i,1)=60
         barrel#(i,2)=.4
         barrel#(i,3)=0
         show object barrelid+i
      endif


      if barrelstatus(i)<>0
         position object barrelid+i,barrel#(i,0),barrel#(i,1),0
         if (x#-barrel#(i,0))*(x#-barrel#(i,0))+(y#-barrel#(i,1))*(y#-barrel#(i,1))<16 then collide=1
      endif
   next
Return

_ScoreAnimation:
   if scoreanimation>0
      set cursor scorex#,scorey#
      print tempscore
      scorey#=scorey#-.3
      scoreanimation=scoreanimation-1
   endif
return

_jumpscore:
   if newscore=1
      tempscore=0
      for i=0 to numbarrels
         if barrelscored(i)=1 then tempscore=tempscore+1
         barrelscored(i)=0
      next i
      tempscore=2^tempscore*100
      if tempscore>0
         score=score+tempscore
         scorex#=object screen x(1):scorey#=object screen y(1):scoreanimation=100
      endif
   newscore=0
   endif
Return

_collision:
   ghost object on 1
   for i=0 to 270 step 1
      rotate object 1,0,0,i
      position object 1,x#,y#,0
      sync
   next i
   rotate object 1,0,0,0
   ghost object off 1
Return

_CreateBarrels:
   Barrelid=200
   numbarrels=30
   dim barrel#(numbarrels,3)
   dim barrelstatus(numbarrels)
   dim barrelscored(numbarrels)
   for i=0 to numbarrels
      make object sphere barrelid+i,6
      color object barrelid+i,rgb(206,126,47)
      hide object barrelid+i
      barrel#(i,0)=-45
      barrel#(i,1)=60
      barrel#(i,2)=.2
      barrel#(i,3)=0
      barrelstatus(numbarrels)=0
   next i
Return

_UpdatePlayer:
   mintemp#=2
   for j=0 to 5
      temp#=intersect object (levelid+j,x#,y#-2,0,x#,y#-4,0)
      if temp#>0 and temp#<mintemp# then mintemp#=temp#
   next j
   if mintemp#<2
      onground=1:jump=0:gosub _jumpscore
      `if (2-mintemp#)>1 then climbing=0
      if climbing=0 then y#=y#+(2-mintemp#)
      ym#=0
   else
      onground=0
      ym#=ym#+.03
      if ym#>.06 then onground=0
   endif
   if climbing=1 and ym#>0 then ym#=0:jump=0:gosub _jumpscore
   y#=y#-ym#
   if x#>47 then x#=46:xm#=-xm#
   if x#<-57 then x#=-56:xm#=-xm#
   x#=x#+xm#
   position object 1,x#,y#,0

   camx#=camx#*.985+x#*.015
   camy#=camy#*.985+y#*.015
   camz#=camz#*.98+(-50)*.02
   position camera camx#,camy#,camz#
   point camera x#,y#,0
Return

_GetInput:
   onladder#=ladder(x#,y#-4)
   onladder2#=ladder(x#,y#-3)
   K_up=upkey()
   K_down=downkey()
   K_left=leftkey()
   K_right=rightkey()
   K_space=spacekey()

   if K_up=1 and jump=0 and onladder2#<>0 then climbing=1:y#=y#+.15:xm#=0:x#=onladder2#
   if K_down=1 and jump=0 and onladder#<>0 then climbing=1:y#=y#-.15:xm#=0:x#=onladder#

   if onground=1 then xm#=0
   if K_left=1 and onground=1 then xm#=-.35:climbing=0
   if K_right=1 and onground=1 then xm#=.35:climbing=0

   if K_space=1 and onground=1 then ym#=-.63:y#=y#+1:jump=1:climbing=0
Return

_Waitingforgame:
   if score>highscore then highscore=score
   score=0
   players=3
   difficulty=1
   Gosub _StartGame
Return

_StartGame:
   collide=0
   camx#=5000
   camz#=-20000
   camy#=0
   camxm#=0
   camym#=0
   camzm#=0
   ss#=10
   x#=-40
   y#=-48
   xm#=0
   ym#=0
   for i=0 to numbarrels
      hide object barrelid+i
      barrelstatus(i)=0
   next i
Return

_LoadLevels:
   Levelid=100
   for I=0 to 8
      read sizex,sizey,posx,posy,angle#
      make object box Levelid+i,sizex,sizey,10
      position object Levelid+i,posx,posy,0
      rotate object Levelid+i,0,0,angle#
      color object Levelid+i,rgb(255,0,0)
   next i
   data 110,2,-5,-50,3
   data 100,2,-10,-30,-3
   data 100,2,0,-10,3
   data 100,2,-10,10,-3
   data 100,2,0,30,3
   data 100,2,-10,50,-3
   data 40,2,-20,70,0
   data 2,120,-60,0,0
   data 2,120,50,0,0
Return

_LoadLadders:
   ladderid=400
   for i=0 to 18
      read sizey,posx,posy
      ladders(i,0)=posx-2
      ladders(i,1)=posy+(sizey*.5)
      ladders(i,2)=posx+2
      ladders(i,3)=posy-(sizey*.5)
      make object box Ladderid+i,4,sizey,1
      position object Ladderid+i,posx,posy,3
      color object Ladderid+i,rgb(255,255,0)
   next i
   data 6,-25,-48,10,-25,-33,16,35,-39
   data 18,-43,-21,22,1,-20
   data 20,8,1,7,-20,-8,11,-20,7
   data 18,33,0,10,13,14,10,13,27
   data 21,-14,21,17,-45,21,9,-9,35
   data 9,-9,47,17,30,41,23,-4,62
   data 50,-41,77,50,-56,77
Return

_LoadMiscObjects:
   make object box 1,4,8,4
   position object 1,-40,-48,0
   make object cylinder 300,10
   color object 300,rgb(0,0,255)
   position object 300,-50,-48,0
Return

Function Ladder(tempx#,tempy#)
   onladderval#=0
   for i=0 to 19
      if tempx#>=ladders(i,0) and tempx#<=ladders(i,2) and tempy#<=ladders(i,1) and tempy#>=ladders(i,3) then onladderval#=(ladders(i,0)+ladders(i,2))*.5
   next i

EndFunction onladderval#

_CreateFire:
   FireID=600
   NumFire=250
   Dim Fire#(numfire,2)
   for I=0 to NumFire
      `Make object sphere fireid+I,1.5
      Make object plain fireid+I,1,1
      rotate object fireid+I,rnd(360),rnd(360),0
      color object fireid+I,rgb(255,0,0)
      fire#(i,0)=0:fire#(i,1)=-43:fire#(i,2)=0
      ghost object on fireid+I
      position object fireid+I,-50,-43,0
   next I
Return

backdrop on
color backdrop 0
sync on
sync rate 60

randomize timer()

Global ASTEROID_SIZE = 50
Global ASTEROID_COUNT = 10

type asteroid
   pt1 as integer
   pt2 as integer
   pt3 as integer
   pt4 as integer
   pt5 as integer
   pt6 as integer
   x as integer
   y as integer
   speed as float
   angle as float
endtype

rem array to hold all asteroids
dim rocks(0) as asteroid

rem initialize the asteroids
for t = 1 to ASTEROID_COUNT
   array insert at bottom rocks()
   makeRandomAsteroid(t)
   resetAsteroid(t)
   rocks(t).x = rnd(640)
next t


DO


   gosub _player_controls
   gosub _update_asteroids
   gosub _handle_bullets
   gosub _draw_player
   gosub _draw_asteroids


   sync
LOOP







REM PLAYER CONTROLS
_player_controls:
  if upkey()=1 then dec py#,3.0+veloc#
  if downkey()=1 then inc py#,3.0+veloc#
  if leftkey()=1 then dec px#,4.0+veloc#
  if rightkey()=1 then inc px#,4.0+veloc#
  if controlkey() = 1 and bdelay >= waiting and ammo>0 then fireshot=1:bdelay=0
  if shiftkey()=1 then lazer=1
return



REM UPDATE PLAYER
_draw_player:
   rem ship boundaries
   remstart
   if px# < 1130 then px#=1130
   if px# > 1840 then px#=1840
   if py# < 20 then py#=20
   if py# > 590 then py#=590
   remend

   ink rgb(0,0,255),0
   line px#,py#,px#+40,py#
   line px#+40,py#,px#+50,py#+20
   line px#,py#,px#,py#+20
   line px#,py#+20,px#+50,py#+20

return



REM UPDATES POSITION OF ASTEROIDS
_update_asteroids:
   for t = 1 to ASTEROID_COUNT
      rocks(t).x = rocks(t).x - rocks(t).speed
      rocks(t).angle = rocks(t).angle + rocks(t).speed
      if rocks(t).x < 0-ASTEROID_SIZE then resetAsteroid(t)
   next t
return



REM DRAWS THE ASTEROIDS ON THE SCREEN
_draw_asteroids:
   for t = 1 to ASTEROID_COUNT
      remstart
      mx = mousex()
      my = mousey()
      if pointInAsteroid(mx,my,t) = 1
         ink rgb(255,0,0),0
      else
         ink rgb(255,255,255),0
      endif
      remend
      ink rgb(0,255,0),0
      x1 = sin(rocks(t).angle)*rocks(t).pt1
      y1 = cos(rocks(t).angle)*rocks(t).pt1
      x2 = sin(rocks(t).angle+60)*rocks(t).pt2
      y2 = cos(rocks(t).angle+60)*rocks(t).pt2
      x3 = sin(rocks(t).angle+120)*rocks(t).pt3
      y3 = cos(rocks(t).angle+120)*rocks(t).pt3
      x4 = sin(rocks(t).angle+180)*rocks(t).pt4
      y4 = cos(rocks(t).angle+180)*rocks(t).pt4
      x5 = sin(rocks(t).angle+240)*rocks(t).pt5
      y5 = cos(rocks(t).angle+240)*rocks(t).pt5
      x6 = sin(rocks(t).angle+300)*rocks(t).pt6
      y6 = cos(rocks(t).angle+300)*rocks(t).pt6
      line rocks(t).x + x1, rocks(t).y + y1,rocks(t).x + x2, rocks(t).y + y2
      line rocks(t).x + x2, rocks(t).y + y2,rocks(t).x + x3, rocks(t).y + y3
      line rocks(t).x + x3, rocks(t).y + y3,rocks(t).x + x4, rocks(t).y + y4
      line rocks(t).x + x4, rocks(t).y + y4,rocks(t).x + x5, rocks(t).y + y5
      line rocks(t).x + x5, rocks(t).y + y5,rocks(t).x + x6, rocks(t).y + y6
      line rocks(t).x + x6, rocks(t).y + y6,rocks(t).x + x1, rocks(t).y + y1
   next t

return


REM UPDATES BULLET POSITIONS AND FIRING
_handle_bullets:


return

REM MAKES A RANDOM ASTEROID
function makeRandomAsteroid(index as integer )
   rocks(index).pt1 = rnd(ASTEROID_SIZE-5)+5
   rocks(index).pt2 = rnd(ASTEROID_SIZE-5)+5
   rocks(index).pt3 = rnd(ASTEROID_SIZE-5)+5
   rocks(index).pt4 = rnd(ASTEROID_SIZE-5)+5
   rocks(index).pt5 = rnd(ASTEROID_SIZE-5)+5
   rocks(index).pt6 = rnd(ASTEROID_SIZE-5)+5
   `rocks(index).pt1 = ASTEROID_SIZE
   `rocks(index).pt2 = ASTEROID_SIZE
   `rocks(index).pt3 = ASTEROID_SIZE
   `rocks(index).pt4 = ASTEROID_SIZE
   `rocks(index).pt5 = ASTEROID_SIZE
   `rocks(index).pt6 = ASTEROID_SIZE
endfunction


function resetAsteroid(index as integer)
   makeRandomAsteroid(index)
   rocks(index).x = screen width() + ASTEROID_SIZE
   rocks(index).y = rnd(screen height())
   rocks(index).speed = (rnd(400)+100)/100.0
   rocks(index).angle = 0
endfunction


REM IF POINT IS INSIDE OF ASTEROID (OUTLINE EXCLUSIVE)
function pointInAsteroid(x as float, y as float, index as integer)
   count = 0
   answer = 0
   x1 = sin(rocks(index).angle)*rocks(index).pt1
   y1 = cos(rocks(index).angle)*rocks(index).pt1
   x2 = sin(rocks(index).angle+60)*rocks(index).pt2
   y2 = cos(rocks(index).angle+60)*rocks(index).pt2
   x3 = sin(rocks(index).angle+120)*rocks(index).pt3
   y3 = cos(rocks(index).angle+120)*rocks(index).pt3
   x4 = sin(rocks(index).angle+180)*rocks(index).pt4
   y4 = cos(rocks(index).angle+180)*rocks(index).pt4
   x5 = sin(rocks(index).angle+240)*rocks(index).pt5
   y5 = cos(rocks(index).angle+240)*rocks(index).pt5
   x6 = sin(rocks(index).angle+300)*rocks(index).pt6
   y6 = cos(rocks(index).angle+300)*rocks(index).pt6
   inc count, point_line(x,y,rocks(index).x + x1, rocks(index).y + y1,rocks(index).x + x2, rocks(index).y + y2)
   inc count, point_line(x,y,rocks(index).x + x2, rocks(index).y + y2,rocks(index).x + x3, rocks(index).y + y3)
   inc count, point_line(x,y,rocks(index).x + x3, rocks(index).y + y3,rocks(index).x + x4, rocks(index).y + y4)
   inc count, point_line(x,y,rocks(index).x + x4, rocks(index).y + y4,rocks(index).x + x5, rocks(index).y + y5)
   inc count, point_line(x,y,rocks(index).x + x5, rocks(index).y + y5,rocks(index).x + x6, rocks(index).y + y6)
   inc count, point_line(x,y,rocks(index).x + x6, rocks(index).y + y6,rocks(index).x + x1, rocks(index).y + y1)
   if count = 0 then answer = 1
endfunction answer


REM returns 1 if point is to the right of line, else 0
REM points must be in clockwise order
function point_line(px#,py#,x1#,y1#,x2#,y2#)
   dp# = (x2# - x1#) * (py# - y1#) - (px# - x1#) * (y2# - y1#)
   answer = (dp#>0)
endfunction answer

` By: Patrick Lewis
`18/Feb/2005
Hide Mouse
Type Coordinates
   x as Float
   y as Float
   z as Float
Endtype

Global Object As Coordinates
Global Target as Coordinates
Global AI as Coordinates
Global Camera as Coordinates

Type Attributes
   Energy as Integer
   Armor as Integer
   Health as Integer
   Damage as Integer
   Range as Integer
   Ablative as Integer
   Shield as Integer
   Pos as Coordinates
   Weapon as String
   Weap_ID as Integer
   Speed as Float
   Object_Num as Integer
   Velocity as Float
EndType

Global Robot as Attributes
Global Robot_Rating as Integer
Dim Enemy(20) as Attributes
Dim Enemy_Rating(20) as Integer

Type Weapons
   Weapon_ID as Integer
   Weapon_Name as String
   Weapon_Damage as Integer
   Weapon_Range as Integer
EndType

Global Robot_Weapon as Weapons
Dim Enemy_Weapon(20) as Weapons

Type Bullets
   Bullet_Damage as Integer
   Bullet_Range as Integer
   Bullet_Area as Integer
   Bullet_Speed as Integer
   Bullet_Object as Integer
   Bullet_Target as Coordinates
EndType

Global Robot_Bullet as Bullets
Dim Enemy_Bullet(20) as Bullets
Sync On
Sync Rate 60
Autocam Off

Do
   Global Level as Float
   Global Score as Integer
   Global EnemyCount as Integer

   Level =1
   Score = 0
   NextLevel=100
   EnemyCount=0
   Robot_Rating=Make_Robot(1)
   Make_Crosshair()
   Make_Road()
   Make_X_Road()
   Return_Object(1)
   Position Camera 0,Object.y+100,50
   Point Camera 0,0,51
   Position Object 501,0,-8,60
   Position Object 502,0,-8,60+174

   Do
      Move_Roads()
      Move_Robot()
      Start_Enemy()
      If Move_Enemy() Then Exit
      Move_Crosshair()
      If Mouseclick()=1
         Return_Target(3)
         Make_R_Bullet(Target.x,0,Target.z)
      Endif
      Move_R_Bullet()
      Ink RGB(171,180,254),0
      Set Cursor 0,0
      Print "Score: ";Score
      If Score>NextLevel
         Level=Level+1
         NextLevel=NextLevel+(Level*100)
      Endif
      Print "Level: ";Level
      Ink Rgb(255-Robot.Health*2,50,55+Robot.Health*2),0
      Print "Health: "; Robot.Health
      Sync
   Loop
Center Text Object Screen X(1),Object Screen Y(1)-20,"You died! Press the anykey to play again"
Sync
Sleep 1000
Clear Entry Buffer
Wait Key
For i = 1001 to 1020
   If Object Exist (i) Then Delete Object I
Next i
Loop




Function Make_Robot(ObjectID)
If Object Exist (ObjectID) Then Delete Object ObjectID
Make Object Cube ObjectID,5
If Object Exist(2) Then Delete Object 2
If Mesh Exist(2) Then Delete Mesh 2
Make Object Sphere 2,5
Make Mesh From Object 2,2
Add Limb ObjectID,1,2
Offset Limb ObjectID,1,0,4,0
Delete Mesh 2
Delete Object 2
Make Object Cylinder 2,4
Scale Object 2,30,100,30
Offset Limb 2,0,0,2,0
Roll Object Right 2,100
Fix Object Pivot 2
Make Mesh From Object 2,2
Add Limb ObjectID,2,2
Add Limb ObjectID,3,2
Offset Limb ObjectID,2,0,1,-3
Offset Limb ObjectID,3,0,1,3
Color Limb ObjectID,2,RGB(128,128,128)
Color Limb ObjectID,3,RGB(128,128,128)
Delete Mesh 2
Delete Object 2
Make Object Cylinder 2,10
Scale Object 2,100,20,20
Pitch Object Down 2,90
Fix Object Pivot 2
Make Mesh From Object 2,2
Add Limb ObjectID,4,2
Add Limb ObjectID,5,2
Offset Limb ObjectID,4,0,-3,-3
Offset Limb ObjectID,5,0,-3,3
Delete Object 2
Delete Mesh 2
Make Object Sphere 2,10
Scale Object 2,100,20,1
Make Mesh from Object 2,2
Add Limb ObjectID,6,2
Add Limb ObjectID,7,2
Offset Limb ObjectID,6,0,-3,-3.9
Offset Limb ObjectID,7,0,-3,3.9
Delete Object 2
Delete Mesh 2
Set Object Cull ObjectID,0
Turn Object Left ObjectID,90
Fix Object Pivot ObjectID
If Bitmap Exist(1) Then Delete Bitmap 1
Create Bitmap 1,100,20
Set Current Bitmap 1
Ink RGB(210,210,210),0
Box 0,0,99,19
Ink Rgb(40,40,40),0
For i = 0 to 90 step 10
   Box i,0,i+1,19
Next i
Get Image 1,0,0,99,19
Delete Bitmap 1
Texture Limb 1,4,1
Texture Limb 1,5,1
Set Object Collision Off 1
Robot.Health=100
Robot.Object_Num=1
EndFunction R

Function Move_Robot()
YRotate Object 1,0
Move Object Left 1,((LeftKey()*(Object Screen X(1)>20))-(RightKey()*(Object Screen X(1)<(Screen Width()-20))))*.8
Move Object 1,(Upkey()*(Object Screen Y(1)>Screen Height()*.1)-DownKey()*(Object Screen Y(1)<Screen Height()-40))*.8
YRotate Object 1,RightKey()*45-LeftKey()*45
Scroll Limb Texture 1,4,-.005,0
Scroll Limb Texture 1,5,-.005,0
Minimap(1,RGB(119,119,255))
EndFunction

Function Make_AI()
If Object Exist (2) then Delete Object 2
Make Object Sphere 2,1,10,10
Set Object Collision Off 2
Hide Object 2
Endfunction


Function Make_R_Bullet(Tx#,Ty#,Tz#)
If Object Exist(101) Then ExitFunction
Make Object Sphere 101,2
   Robot_Bullet.Bullet_Damage=rnd(4)+1
   Robot_Bullet.Bullet_Range=50
   Robot_Bullet.Bullet_Area=5
   Robot_Bullet.Bullet_Speed=6
   Robot_Bullet.Bullet_Object=101
   Robot_Bullet.Bullet_Target.x=Tx#
   Robot_Bullet.Bullet_Target.y=Ty#
   Robot_Bullet.Bullet_Target.z=Tz#
Return_Object(1)
Position Object 101,Object.x,Object.y,Object.z
Point Object 101,Tx#,Ty#,Tz#
EndFunction

Function Move_R_Bullet()
If Object Exist(101)=0 then ExitFunction
Speed=Robot_Bullet.Bullet_Speed
If Speed=0 then Speed=1
For i = 1 to Speed
   If Robot_Bullet.Bullet_Speed>0 Then Move Object 101,1
   Robot_Bullet.Bullet_Range=Robot_Bullet.Bullet_Range-1
   If Robot_Bullet.Bullet_Range=0
      Robot_Bullet.Bullet_Speed=0
      scale=Robot_Bullet.Bullet_Area/Object Size(101)*100
      Robot_Bullet.Bullet_Damage=Robot_Bullet.Bullet_Damage*3
      Scale Object 101,scale,scale,scale
      Color Object 101,Rgb(255,0,0)
      Ghost Object On 101
   Endif
   HitEnemy=Object Collision(101,0)
   If HitEnemy>1000 and HitEnemy<1021
      Enemy(HitEnemy-1000).Health=Enemy(HitEnemy-1000).Health-Robot_Bullet.Bullet_Damage
      If Enemy(HitEnemy-1000).Health<1 Then Delete Object HitEnemy:EnemyCount=EnemyCount-1
      Delete Object 101
      Score=Score+Robot_Bullet.Bullet_Damage
      ExitFunction
   Endif
   If Robot_Bullet.Bullet_Range<-10
      Delete Object 101
      ExitFunction
   Endif
Next i
EndFunction

Function Make_Crosshair()
If Object Exist (3) Then Delete Object 3
Make Object Cylinder 3,10
If Mesh Exist(2)Then Delete Mesh 2
Make Mesh From Object 2,3
Add Limb 3,1,2
Add Limb 3,2,2
Delete Mesh 2
Rotate Limb 3,1,0,0,90
Rotate Limb 3,2,90,0,0
Scale Limb 3,0,10,100,10
Scale Limb 3,1,10,100,10
Scale Limb 3,2,10,100,10
Pitch Object Down 3,90
Fix Object Pivot 3
Color Object 3,Rgb(255,0,0)
Position Object 3,0,5,0
Set Object Cull 3,0
Set Object Collision Off 3
Ghost Object On 3
EndFunction

Function Move_Crosshair()
mx=MouseX():my=MouseY()
cntr=0
Do
   cx=Object Screen X(3): cy=Object Screen Y(3)
   If cx=mx and cy=my then Exit
   Move Object Left 3,((cx>mx)-(cx<mx))*.2
   Move Object 3,((cy>my)-(cy<my))*.2
   cntr=cntr+1
   If cntr>40 Then Exit
Loop
Roll Object Left 3,1
Fix Object Pivot 3
EndFunction

Function Make_Enemy_Robot(ObjectID,ERID)
Make Object Cube ObjectID,5
If Object Exist(2) Then Delete Object 2
If Mesh Exist(2) Then Delete Mesh 2
Make Object Sphere 2,5
Make Mesh From Object 2,2
Add Limb ObjectID,1,2
Offset Limb ObjectID,1,0,4,0
Delete Mesh 2
Delete Object 2
Make Object Cylinder 2,4
Scale Object 2,30,100,30
Offset Limb 2,0,0,2,0
Roll Object Right 2,100
Fix Object Pivot 2
Make Mesh From Object 2,2
Add Limb ObjectID,2,2
Add Limb ObjectID,3,2
Offset Limb ObjectID,2,0,1,-3
Offset Limb ObjectID,3,0,1,3
Delete Mesh 2
Delete Object 2
Make Object Cylinder 2,10
Scale Object 2,100,20,20
Pitch Object Down 2,90
Fix Object Pivot 2
Make Mesh From Object 2,2
Add Limb ObjectID,4,2
Add Limb ObjectID,5,2
Offset Limb ObjectID,4,0,-3,-3
Offset Limb ObjectID,5,0,-3,3
Delete Object 2
Delete Mesh 2
Make Object Sphere 2,10
Scale Object 2,100,20,1
Make Mesh from Object 2,2
Add Limb ObjectID,6,2
Add Limb ObjectID,7,2
Offset Limb ObjectID,6,0,-3,-3.9
Offset Limb ObjectID,7,0,-3,3.9
Delete Object 2
Delete Mesh 2
Set Object Cull ObjectID,0
Turn Object Left ObjectID,90
Fix Object Pivot ObjectID
Color Object ObjectID,RGB(128,0,0)
Color Limb ObjectID,2,RGB(128,128,128)
Color Limb ObjectID,3,RGB(128,128,128)
Texture Limb 1,4,1
Texture Limb 1,5,1
Set Object Collision Off 1
Enemy(ERID).Health=10+Rnd(Level*2)
Enemy(ERID).Object_Num=ObjectID
EndFunction R


Function Start_Enemy()
If Rnd(800)>Level+((Level-EnemyCount)*3) Then ExitFunction
For i = 1001 to 1020
   If Object Exist(i)=0
      Make_Enemy_Robot(i,i-1000)
      EnemyCount=EnemyCount+1
      Position Object i,((rnd(400)-200)+(rnd(400)-200))/2,0,125+Rnd(200)
      Turn Object Right i,180
      Exit
   Endif
Next
EndFunction

Function Move_Enemy()
Make_AI()
Dead=0
Set Object Collision On 1
For i = 1 to 20
   If Object Exist(1000+i)
      Return_Object(1000+i)
      Return_Target(1)
      Position Object 2,Object.x,Object.y,Object.z
      Set Object To Object Orientation 2,1000+i
      Move Object 2,10
      Point Object 2,Target.x,Object.y,Target.z
      Move Object 2,Rnd(3)
      Return_AI()
      Point Object 1000+i,AI.x,Object.y,AI.z
      Move Object 1000+i,.75
      Minimap(1000+i,RGB(255,0,0))
      If Object Collision (1000+i,1)
         Dead=1
         Set Object Collision Off 1
         ExitFunction Dead
      Endif
   Endif
   Enemy_Shoot(i)
   If Move_E_Bullet(i) Then ExitFunction 1
Next i
Set Object Collision Off 1
EndFunction Dead

Function Enemy_Shoot(ERID)
If Object Exist(1000+ERID)=0 Then ExitFunction
If rnd(2000)>Level
   Return_Object(1000+ERID):Return_Target(1)
   Dist#=(Object.x-Target.x)^2+(Object.z-Target.z)^2
   If Dist#<55^2
      aimx#=rnd(20-(level/6))-(10-(level/3))+Target.x
      aimz#=rnd(20-(level/6))-(10-(level/3))+Target.z
      Make_E_Bullet(ERID,aimx#,target.y,aimz#)
   Endif
Endif
EndFunction


Function Make_E_Bullet(ERID,Tx#,Ty#,Tz#)
If Object Exist(2000+ERID) Then ExitFunction
If Object Exist(1000+ERID)=0 Then ExitFunction
Make Object Sphere 2000+ERID,2
   Enemy_Bullet(ERID).Bullet_Damage=rnd(Level)+1
   Enemy_Bullet(ERID).Bullet_Range=50
   Enemy_Bullet(ERID).Bullet_Area=5
   Enemy_Bullet(ERID).Bullet_Speed=3
   Enemy_Bullet(ERID).Bullet_Object=2000+ERID
   Enemy_Bullet(ERID).Bullet_Target.x=Tx#
   Enemy_Bullet(ERID).Bullet_Target.y=Ty#
   Enemy_Bullet(ERID).Bullet_Target.z=Tz#
Return_Object(1000+ERID)
Position Object 2000+ERID,Object.x,Object.y,Object.z
Point Object 2000+ERID,Tx#,Ty#,Tz#
EndFunction

Function Move_E_Bullet(ERID)
Dead=0
If Object Exist(2000+ERID)=0 then ExitFunction Dead
Speed=Enemy_Bullet(ERID).Bullet_Speed
If Speed=0 then Speed=1
For i = 1 to Speed
   If Enemy_Bullet(ERID).Bullet_Speed>0 Then Move Object 2000+ERID,1
   Enemy_Bullet(ERID).Bullet_Range=Enemy_Bullet(ERID).Bullet_Range-1
   If Enemy_Bullet(ERID).Bullet_Range=0
      Enemy_Bullet(ERID).Bullet_Speed=0
      scale=Enemy_Bullet(ERID).Bullet_Area/Object Size(2000+ERID)*100
      Enemy_Bullet(ERID).Bullet_Damage=Enemy_Bullet(ERID).Bullet_Damage*3
      Scale Object 2000+ERID,scale,scale,scale
      Color Object 2000+ERID,Rgb(255,0,0)
      Ghost Object On 2000+ERID
   Endif
   HitEnemy=Object Collision(2000+ERID,1)
   If HitEnemy
      Robot.Health=Robot.Health-Enemy_Bullet(ERID).Bullet_Damage
      If Robot.Health<1 Then Dead=1
      Delete Object 2000+ERID
      ExitFunction Dead
   Endif
   If Enemy_Bullet(ERID).Bullet_Range<-10
      Delete Object 2000+ERID
      ExitFunction Dead
   Endif
Next i
EndFunction Dead

Function Make_Road()
If Object Exist(501) Then Delete Object 501
If Bitmap Exist(1) Then Delete Bitmap 1
Create Bitmap 1,300,300
Set Current Bitmap 1
Ink RGB(128,128,128),0
Box 50,0,249,299
Ink RGB(75,75,75),0
For i = 1 to 300
   Dot rnd(200)+50,rnd(299)
Next i
Ink RGB(198,198,0),0
For i = 0 to 250 step 50
   Box 148,i,152,i+30
Next i
Get Image 501,0,0,299,299
Set Current Bitmap 0
Delete Bitmap 1
Make Object Plain 501,175,175
Texture Object 501,501
Pitch Object Down 501,90
EndFunction

Function Make_X_Road()
If Object Exist(502) Then Delete Object 502
If Bitmap Exist(1) Then Delete Bitmap 1
Create Bitmap 1,300,300
Set Current Bitmap 1
Ink RGB(128,128,128),0
Box 50,0,249,299
Box 0,50,299,249
Ink RGB(75,75,75),0
For i = 1 to 300
   Dot rnd(200)+50,rnd(299)
Next i
Ink RGB(198,198,0),0
For i = 0 to 250 step 50
   Box 148,i,152,i+30
   Box i,148,i+30,152
Next i
Get Image 502,0,0,299,299
Set Current Bitmap 0
Delete Bitmap 1
Make Object Plain 502,175,175
Texture Object 502,502
Pitch Object Down 502,90
EndFunction

Function Move_Roads()
Move Object Up 501,.65
Move Object Up 502,.65
Return_Object(501)
If Object.z<60-174 Then Position Object 501,0,-8,60+174
Return_Object(502)
If Object.z<60-174 Then Position Object 502,0,-8,60+174
EndFunction

Function Minimap(ObjectID,Color)
Return_Object(ObjectID)
Ink Color,0
Box (Object.x/5)+600,50-(Object.z/5),(Object.x/5)+602,52-(Object.z/5)
EndFunction

Function Return_Target(TargetID)
Target.x=Object Position X(TargetID):Target.y=Object Position Y(TargetID):Target.z=Object Position Z(TargetID)
EndFunction

Function Return_Object(ObjectID)
Object.x=Object Position X(ObjectID):Object.y=Object Position Y(ObjectID):Object.z=Object Position Z(ObjectID)
EndFunction

Function Return_AI()
AI.x=Object Position X(2):AI.y=Object Position Y(2):AI.z=Object Position Z(2)
EndFunction

Function Return_Camera()
Camera.x=Camera Position X():Camera.y=Camera Position Y():Camera.z=Camera Position Z()
EndFunction

Rem Project: sidescroller challenge
Rem Created: 19/02/2005 21:17:23

Rem ***** Main Source File *****

randomize timer()

`display
if check display mode(1024,768,32)=1 then set display mode 1024,768,32
hide mouse
autocam off
set camera range 1,10000
position camera 200,0,280
point camera 0,0,280
hide light 0
color backdrop rgb(0,0,0)
set ambient light 80
make light 1
position light 1,100,100,20
set light range 1,100000
color light 1,rgb(255,220,180)
set text font "sf automaton_mod"
set text size 25
fog on
fog distance 3500

`create green texture
for x=0 to 100
   for y=0 to 100
      ink rgb(0,x+y,0),0
      dot x,y
   next y
next x
get image 103,0,0,100,100

`create orange texture
cls
for x=0 to 100
   for y=0 to 100
      ink rgb((x+y)+50,50+(x+y)/1.5,100),0
      dot x,y
   next y
next x
get image 102,0,0,100,100

`create blue texture
cls
for x=0 to 100
   for y=0 to 100
      ink rgb(0,0,x+y),0
      dot x,y
   next y
next x
get image 101,0,0,100,100

`create red texture
cls
for x=0 to 100
   for y=0 to 100
      ink rgb((x+y)+50,0,0),0
      dot x,y
   next y
next x
get image 105,0,0,100,100

`create star texture
cls
for x=0 to 100
for y=0 to 100
d=rnd(20)
ink rgb(100+rnd(100),100+rnd(100),rnd(100)+100),0
if d=1 then dot x,y
next y
next x
get image 1,0,0,100,100

`create tile texture
cls
ink rgb(0,255,0),0
box 0,0,20,20
ink rgb(0,0,0),0
box 1,1,20,20
`ink rgb(0,0,155),0
`box 4,4,16,16
get image 2,0,0,20,20




`create stars
make object plain 1000,10600,8000
texture object 1000,1
scale object texture 1000,5,5
set object transparency 1000,1
yrotate object 1000,90
position object 1000,-4000,0,0
set object light 1000,0
set object emissive 1000,rgb(250,250,250)
set object fog 1000,0

make object plain 1001,10600,8000
texture object 1001,1
scale object texture 1001,5,5
set object transparency 1001,1
yrotate object 1001,90
position object 1001,-4010,0,0
set object light 1001,0
set object emissive 1001,rgb(250,250,250)
set object fog 1001,0





`aliens and fuel pods
dim azspeed#(5025)
dim ayspeed#(5025)
dim fuel(5025)
for alien=5000 to 5025
if alien>5020 then fuel(alien)=1
if fuel(alien)=0
  make object sphere alien,15,2,2
  texture object alien,105
else
  make object sphere alien,15,30,30
  texture object alien,103
endif
set object specular alien,rgb(200,200,200)
set object specular power alien,15
set object emissive alien,rgb(150,150,100)
set object ambient alien,0
set object collision on alien
set object fog alien,0
position object alien,-180,rnd(200)-100,rnd(2000)+500
next alien



`bottom wall
make object plain 4,3000,3000
xrotate object 4,90
set object collision on 4
texture object 4,2
scale object texture 4,20,10
set object transparency 4,1

`ghost object on 4

`top wall
make object plain 5,3000,3000
xrotate object 5,90
set object collision on 5
texture object 5,2
scale object texture 5,20,10
set object transparency 5,1
`ghost object on 5


`position walls
position object 4,0,-150,100
position object 5,0,150,100

`spaceship
make object cone 1,20
xrotate object 1,90
scale object 1,100,400,100
ghost object on 1
texture object 1,101
set object emissive 1,rgb(200,200,200)
set object specular 1,rgb(250,250,250)
set object specular power 1,10
set object fog 1,0
set object collision on 1
set object collision to boxes 1

`jet trail
make object sphere 777,-50,30,30
scale object 777,100,100,1500
texture object 777,102
ghost object on 777
set object emissive 777,rgb(200,200,200)
set object specular 777,rgb(250,250,250)
set object specular power 777,10
position object 777,1000,0,0
disable object zdepth 777

`reflection of ship
clone object 302,1 `top
xrotate object 302,90
scale object 302,100,400,100
fade object 302,90
clone object 303,1 `bottom
xrotate object 303,90
scale object 303,100,400,100
fade object 303,90
clone object 888,777
fade object 888,90
scale object 888,100,100,1500
position object 888,1000,0,0
clone object 999,777
fade object 999,90
scale object 999,100,100,1500
position object 999,1000,0,0
ink rgb(0,0,255),0

make object sphere 111,-300,30,30
scale object 111,100,100,180
texture object 111,101
ghost object on 111
set object emissive 111,rgb(200,200,200)
set object specular 111,rgb(250,250,250)
set object specular power 111,10
position object 111,0,0,350

remstart
make object sphere 222,-500,30,30
texture object 222,101
ghost object on 222
set object emissive 222,rgb(200,200,200)
set object specular 222,rgb(250,250,250)
set object specular power 222,10
position object 222,0,0,400
remend

restart:

cls
fuel#=3.0
lives=3
pz#=150
aliens=40
level=1
scrollspeed#=0.08

for alien=5000 to 5025
azspeed#(alien)=1+rnd(10)
ayspeed#(alien)=rnd(20)/10.0
next alien

while mouseclick()=0
text screen width()/2-220,210,"Kill 40 aliens before your fuel runs out!"
text screen width()/2-70,240,"Press FIRE!"
endwhile

sync on
sync rate 30

do

text 0,40,str$(screen fps())



py#=py#-mousemovey()
pz#=pz#+mousemovex()
if py#>110 then py#=110
if py#<-110 then py#=-110
if pz#>500 then pz#=500
if pz#<0 then pz#=0

`move ship
position object 1,-180,py#,pz#
position object 302,-180,-py#-300,pz#
position object 303,-180,-py#+300,pz#
position object 777,-180,py#,pz#-380
position object 888,-180,-py#-300,pz#-380
position object 999,-180,-py#+300,pz#-380

`scroll textures
scroll object texture 1000,0.01,0
scroll object texture 1001,0.008,0
scroll object texture 4,0,scrollspeed#
scroll object texture 5,0,scrollspeed#

`handle aliens
for alien=5000 to 5025
`alien movement
ay#=object position y(alien)+ayspeed#(alien)
az#=object position z(alien)-azspeed#(alien)
if ay#>100 or ay#<-100 then ayspeed#(alien)=ayspeed#(alien)*-1
if az#<object position z(1)-300 then inc az#,2000

`alien death
if fire=1
if object in screen (alien)=1
 if object position y(1)<object position y(alien)+8 and object position y(1)>object position y(alien)-8
   inc az#,2000
   dec aliens
  endif
endif
endif

`ship death
if object in screen(alien)=1
  if object position y(1)<object position y(alien)+8 and object position y(1)>object position y(alien)-8
    if object position z(1)<object position z(alien)+50 and object position z(1)>object position z(alien)-30
      inc az#,2000
      if fuel(alien)=0
           dec lives
           if lives<0 then goto dead
           text screen width()/2-70,240,"GET READY!"
           wait 1000
      endif
      if fuel(alien)=1 then inc fuel#
    endif
  endif
endif

position object alien,-180,ay#,az#
next alien

`fire
if mouseclick()=1 and charge<0
  fire=1
  charge=20
  length=5
endif

if fire=1
line object screen x(1),object screen y(1),screen width(),object screen y(1)
endif

dec charge
dec length
if length<0 then fire=0

`text

text 40,0,"Lives: "+str$(lives)
if fuel#<1.0
   ink rgb(255,0,0),0
endif
text screen width()-130,0,"Fuel: "+left$(str$(fuel#),4)
ink rgb(0,0,255),0
text screen width()/2-60,0,"Aliens: "+str$(aliens)


dec fuel#,0.005

if fuel#<0
   text screen width()/2-70,210,"Out of fuel!"
   text screen width()/2-70,240,"GET READY..."
   sync
   wait 1000
  dec lives
  fuel#=3.0
endif

if aliens<1
  inc level
  text screen width()/2-70,210,"Level "+str$(level)
  text screen width()/2-70,240,"GET READY..."
  sync
  wait 1000
  aliens=40
  inc scrollspeed#,0.02
  fuel#=3.0
  for alien=5000 to 5025
    inc azspeed#(alien),3
    inc ayspeed#(alien),0.2
  next alien
endif



dead:
if lives<0
while mouseclick()=0
  text screen width()/2-70,240,"GAME OVER!"
  text screen width()/2-120,270,"You got to level "+str$(level)
  text screen width()/2-90,320,"Press fire ...."
  sync
endwhile
  goto restart
endif

turn object right 111,0.5

sync
loop

REM Project: side scroller
Rem By Coding Fodder

sync on:sync rate 0
color backdrop 0
backdrop off
hide mouse
dim screen(33,24)

global bd_height#
global bd_dx#
global bd_dx2
global score
global tiles
bd_height#=0.0
bd_dx2=1

create bitmap 1,640,480


make_sprites()
for i=1 to 640
   generate_background()
next i
for i=1 to 33
   screen(i,23)=1
next i
ballx#=320
bally#=20

DO
   if rightkey()=1
      inc ballx#
      rotate sprite 103,wrapvalue(sprite angle(103)+5.73)
         if ballx#>320
            ballx#=320
            dec x
            inc cycle
         endif
         if x=-20
            x=0
            make_level()
            inc tiles
            if tiles>1000 then endgame()
         endif
   endif

   if leftkey()=1
      dec ballx#
      if ballx#<0 then ballx#=0
      rotate sprite 103,wrapvalue(sprite angle(103)-5.73)
   endif

   bvy#=bvy#+0.1
   bally#=bally#+bvy#

   if screen(int(ballx#/20.0+0.5),int(bally#/20.0))=1 or screen(int(ballx#/20.0+0.5)+1,int(bally#/20.0))=1
      bally#=20*(int(bally#/20.0))
      if spacekey()=1
         bvy#=0
      else
         bvy#=-bvy#
      endif
      if bvy#<1
         if ballx#=0 then bvy#=-4
      endif
   endif

   if screen(int(ballx#/20.0+0.5),int(bally#/20.0-1.0))=1 or screen(int(ballx#/20.0+0.5)+1,int(bally#/20.0-1.0))=1
      bally#=20*(int(bally#/20.0+1))
      if spacekey()=1
         bvy#=-bvy#
      else
         bvy#=0
      endif
   endif

   if screen(int(ballx#/20.0+0.5),int(bally#/20.0-1))=2 or screen(int(ballx#/20.0+0.5)+1,int(bally#/20.0-1))=2
      bally#=20*(int(bally#/20.0))
      bvy#=-4
   endif

   if screen(int(ballx#/20.0+1),int(bally#/20.0-1.0))=3
      screen(int(ballx#/20.0+1),int(bally#/20.0-1.0))=0
      inc score,10
   endif

   if screen(int(ballx#/20.0),int(bally#/20.0-1.0))=3
      screen(int(ballx#/20.0),int(bally#/20.0-1.0))=0
      inc score,10
   endif

   if bally#>460
      bally#=460
      bvy#=0
   endif

   if bally#<20
      bally#=20
   endif

   if cycle=3
      generate_background()
      cycle=0
   endif

   copy bitmap 1,0
   for i=0 to 32
      for j=0 to 23
         if screen(i,j)=1 then paste sprite 101,i*20+x,j*20
         if screen(i,j)=2 then paste sprite 102,i*20+x,j*20
         if screen(i,j)=3 then paste sprite 104,i*20+x,j*20
      next j
   next i
   paste sprite 103,int(ballx#)-cos(sprite angle(103)+45)*10.0*sqrt(2.0)+10,int(bally#)-sin(sprite angle(103)+45)*10.0*sqrt(2.0)-10
   text 100,1,"Score "+str$(score)
   text 1,1,"Distance "+str$(tiles)
sync
LOOP

function make_sprites()
br#=0.2
for i=0 to 20
   for j=0 to 20
      am=100-int(sqrt((i-10.0)^2.0+(j-10.0)^2.0)*5.5)
      ink rgb(am-abs((i-10)*(j-10)*br#),am-abs((i-10)*(j-10)*br#),am+155),0
      dot i,j
   next j
next i

get image 101,0,0,20,20
sprite 101,0,0,101
`set sprite alpha 101,99.9
hide sprite 101

ink 0,0
cls
br#=0.2
for i=0 to 20
   for j=0 to 20
      if i+j>=19
         am=100-int(sqrt((i-10.0)^2.0+(j-10.0)^2.0)*5.5)
         ink rgb(am-abs((i-10)*(j-10)*br#),am-abs((i-10)*(j-10)*br#),am+155),0
         dot i+20,j+20
      endif
   next j
next i

get image 102,20,20,40,40
sprite 102,20,20,102
SET SPRITE TEXTURE COORD 102, 0, 0.05, 0.05
hide sprite 102

cls
br#=0.2
for i=0 to 20
   for j=0 to 20
      if sqrt((i-10.0)^2.0+(j-10.0)^2.0)-0.5<=10.0
         am=100-int(sqrt((i-10.0)^2.0+(j-10.0)^2.0)*5.5)
         ink rgb(am+155,am,am),0
         dot i+40,j+40
      endif
   next j
next i

get image 103,40,40,60,60
sprite 103,20,20,103
`set sprite alpha 103,99.9
hide sprite 103

cls
br#=0.2
for i=0 to 20
   for j=0 to 20
      if abs(i-10.0)+abs(j-10.0)<=10.0
         am=100-int((abs(i-10.0)+abs(j-10.0))*5.5)
         ink rgb(am+155,am+100,am),0
         dot i+40,j+40
      endif
   next j
next i

get image 104,40,40,60,60
sprite 104,20,20,104
`set sprite alpha 103,99.9
hide sprite 104
endfunction

function make_level()
   for i=0 to 32
      for j=0 to 23
         screen(i,j)=screen(i+1,j)
      next j
   next i

   screen(33,23)=1
   for j=3 to 22
      if rnd(100)<2
         if screen(32,j-1)=0 and screen(33,j-1)=0 and screen(32,j-2)=0 and screen(33,j-2)=0 and (screen(32,j+1)=1 or screen(32,j+2)=0) then screen(33,j)=2
      else
         screen(33,j)=0
      endif

      if screen(32,j)>0 and screen(32,j)<3
         if rnd(100)<92
            screen(33,j)=1
         else
            screen(33,j)=0
         endif
      endif
      if rnd(100)<2
         if screen(33,j)=0
            screen(33,j)=3
         endif
      endif
   next j

endfunction

function generate_background()
   set current bitmap 1
   copy bitmap 1,1,0,640,479,1,0,0,639,479
   max_slope#=0.6
   lock pixels

   if bd_dx2=1
      bd_dx#=bd_dx#+(rnd(10)/200.0)
      if bd_dx#>max_slope# then bd_dx#=max_slope#
      bd_height#=bd_height#+bd_dx#
      if bd_height#>230.0 then bd_dx2=-1
   else
      bd_dx#=bd_dx#-(rnd(10)/200.0)
      if bd_dx#<-max_slope# then bd_dx#=-max_slope#
      bd_height#=bd_height#+bd_dx#
      if bd_height#<50.0 then bd_dx2=1
   endif

   if rnd(500)<10
      if bd_dx2=1
         bd_dx2=-1
      else
         bd_dx2=1
      endif
   endif

   for i=0 to 479-int(bd_height#)
      if i>-1 and i<480 then set_locked_pixel(639,i,rgb(i/4,i/4,i/2.3+50))
   next i

   for i=479-int(bd_height#) to 479
      if i>-1 and i<480 then set_locked_pixel(639,i,rgb(int((479-i)/3),rnd(50)+10+int((479-i)*190.0/bd_height#),int((479-i)/2.5)))
   next i

   unlock pixels
   set current bitmap 0
endfunction

function set_locked_pixel(x,y,color_value)
   start=get pixels pointer()
   repeat_number=get pixels pitch()
   bits_per_pixel=bitmap depth(num)/8
   pointer=start+y*repeat_number+x*bits_per_pixel
   *pointer=color_value
endfunction

function endgame()
   copy bitmap 1,0
   text 100,1,"Score "+str$(score)
   text 1,1,"Distance "+str$(tiles)
   text 1,20,"Game Over"
   sync
   suspend for key
   end
endfunction

`   'Aargh - not another Pong Clone!' by Ric.

if check display mode(1024,768,32)=1 then set display mode 1024,768,32
hide mouse
sync on
sync rate 50
autocam off
hide light 0
color backdrop rgb(0,0,0)
set ambient light 80
make light 1
position light 1,100,100,20
set light range 1,100000
color light 1,rgb(255,220,180)

fog on
fog color 0
fog distance 1000

`create green texture
for x=0 to 100
   for y=0 to 100
      ink rgb(0,x+y,0),0
      dot x,y
   next y
next x
get image 103,0,0,100,100

cls

`create purple texture
for x=0 to 100
   for y=0 to 100
      ink rgb(x+y,0,x+y),0
      dot x,y
   next y
next x
get image 102,0,0,100,100

cls

`create blue texture
for x=0 to 100
   for y=0 to 100
      ink rgb(0,0,x+y),0
      dot x,y
   next y
next x
get image 101,0,0,100,100

`create star texture
for x=0 to 100
for y=0 to 100
d=rnd(20)
ink rgb(100+rnd(100),100+rnd(100),rnd(100)+100),0
if d=1 then dot x,y
next y
next x
get image 1,0,0,100,100

`create tile texture
cls
ink rgb(0,0,255),0
box 0,0,10,10
box 10,10,20,20
get image 2,0,0,20,20

set text font "sf automaton_mod"
set text size 25

`create starsphere
make object sphere 1000,-1000,50,50
texture object 1000,1
scale object texture 1000,5,5
xrotate object 1000,-90

`player paddle
make object sphere 1,20,20,20
scale object 1,100,400,100
ghost object on 1
texture object 1,102
set object emissive 1,rgb(200,200,200)
set object specular 1,rgb(250,250,250)
set object specular power 1,10
set object fog 1,0
set object collision on 1
set object collision to boxes 1


`reflection of player paddle
clone object 302,1 `top
scale object 302,100,400,100
fade object 302,90
clone object 303,1 `bottom
scale object 303,100,400,100
fade object 303,90

`computer paddle
make object sphere 2,20,20,20
scale object 2,100,400,100
ghost object on 2
texture object 2,103
set object emissive 2,rgb(200,200,200)
set object specular 2,rgb(250,250,250)
set object specular power 2,10
set object fog 2,0
set object collision on 2
set object collision to boxes 2

`reflection of computer paddle
clone object 304,2 `top
scale object 304,100,400,100
fade object 304,90
clone object 305,2 `bottom
scale object 305,100,400,100
fade object 305,90

`ball
make object sphere 3,20,40,40
texture object 3,101
set object specular 3,rgb(200,200,200)
set object specular power 3,15
set object emissive 3,rgb(150,150,100)
set object ambient 3,0
set object collision on 3
set object fog 3,0

`reflection of ball
clone object 300,3 `top reflection
fade object 300,50
clone object 301,3 `bottom reflection
fade object 301,50

`bottom wall
make object plain 4,500,800
xrotate object 4,90
set object collision on 4
texture object 4,2
scale object texture 4,5,5
set object transparency 4,1

`top wall
make object plain 5,500,800
xrotate object 5,90
set object collision on 5
texture object 5,2
scale object texture 5,5,5
set object transparency 5,1

`back wall
make object plain 6,500,100
texture object 6,101
scale object texture 6,2,10
set object texture 6,2,0
set object transparency 6,1
set object fog 6,0
ghost object on 6

`position walls
position object 4,0,-150,100
position object 5,0,150,100
position object 6,0,0,300

`restart point for new game (the goto command is not dead yet!)
newgame:

for object=300 to 305
hide object object
next object

`zoom in
paddlex#=0
position object 1,-paddlex#,0,0
position object 2,paddlex#,0,0
position object 3,0,0,0


zrotate camera 0
camz#=-2000.0
position camera 0,0,0,camz#
while camz#<-500.0
inc camz#,5
position camera 0,0,camz#
sync
endwhile
position camera 0,0,0,-500

`set paddle positions

while paddlex#<180
inc paddlex#
position object 1,-paddlex#,0,0
position object 2,paddlex#,0,0
sync
endwhile



do
text screen width()/2-100,200,"Gravity on? (y/n)"
if inkey$()="y" then gravity=1:exit
if inkey$()="n" then gravity=0:exit
sync
loop

text screen width()/2-70,240,"GET READY!"
sync
wait 600

for object=300 to 305
show object object
next object

`set initial variables
level=1
pscore=0
cscore=0
pv#=10 `player paddle velocity
bvx#=10 `ball velocity
if gravity=1
cv#=3.5 `computer paddle velocity
g#=0.5
else
cv#=2
g#=0
endif

`restart point for new serve or new level
restart:
randomize timer()
wait 800
py#=-10+rnd(20) `player's initial y position
cy#=-10+rnd(20)           `computer's initial y position
bx#=0           `ball x
by#=0           `ball y
bvy#=1.5+rnd(10)/10          `ball direction (in degrees:- horizontal=0)
bvx#=abs(bvx#)
`main loop

do

text 0,0,str$(screen fps())

`player input
remstart
if upkey()>0 and object collision (1,5)=0
   py#=py#+pv#
endif

if downkey()>0 and object collision (1,4)=0
   py#=py#-pv#
endif
remend


py#=py#-mousemovey()
if py#>110 then py#=110
if py#<-110 then py#=-110

`move player paddle
position object 1,-180,py#,100
position object 302,-180,-py#-300,100
position object 303,-180,-py#+300,100
`position object 401,-180,py#,100

`ball motion
bvy#=bvy#+g#
bx#=bx#+bvx#
by#=by#-bvy#

`collision with court
if by#>140
by#=by#-10
bvy#=bvy#*-1
endif

if by#<-140
by#=by#+10
bvy#=bvy#*-1
endif

`collision with player paddle
if object collision(3,0)=1
  bvx#=bvx#*-1 `reverse velocity
  bx#=-150 `prevent embedding
`measure offset between player paddle and ball and adjust direction
    po#=by#-py#
    bvy#=bvy#-po#*0.15
endif

`and same for computer paddle.....
if object collision(3,0)=2
  bvx#=bvx#*-1
  bx#=150
    co#=by#-cy#
    bvy#=bvy#-co#*0.15
endif

if bvy#>15.0 then bvy#=15.0
if bvy#<-15.0 then bvy#=-15.0

`new ball position
position object 3,bx#,by#,100
position object 300,bx#,-by#+300,100
position object 301,bx#,-by#-300,100

`computer paddle A.I.

`return to middle
if bvx#<0
  if cy#>2 then a#=-cv#
  if cy#<2 then a#=cv#
  if cy#<=2 and cy#>=-2 then a#=0
  cy#=cy#+a#
endif

`move towards ball
if bvx#>0
  if by#>cy# then a#=cv#
  if by#<cy# then a#=-cv#
  cy#=cy#+a#
endif

position object 2,180,cy#,100
position object 304,180,-cy#+300,100
position object 305,180,-cy#-300,100

`win or lose
if object position x(3) < -250
   cscore=cscore+1
   vb#=vb#*-1
   goto restart
endif

if object position x(3) > 250
  pscore = pscore +1
  goto restart
endif

`print score
text screen width()/2-20,screen height()/2-12,str$(pscore)+" : "+str$(cscore)

`goto next level, increase difficulty and reset scores
if pscore>2
   bv#=bv#+1
   pv#=pv#+0.3
   cv#=cv#+0.5
   level=level+1
   pscore=0
   cscore=0
   goto restart
endif

`display level
text screen width()/2-40,screen height()/2-100,"Level "+str$(level)


`game over text
if cscore>2
set text font "impact"
ink rgb(0,200,0),0
text screen width()/2-50,screen height()/2+200,"Game Over"
text screen width()/2-80,screen height()/2+250,"You reached level "+str$(level)
text screen width()/2-100,screen height()/2+280,"Press any key to restart"
sync
wait key
set text font "sf automaton_mod"
ink rgb(0,0,255),0
goto newgame
endif

if inkey$()="q" then goto restart

if level>3
  `scroll textures
  scroll object texture 1000,0,-0.014
  scroll object texture 4,0,0.08
  scroll object texture 5,0,0.08

  if clockwise=1 then roll camera right 0.1
  if camera angle z()>30 then clockwise=0:turn camera left 0.1
  if clockwise=0 then roll camera left 0.1
  if camera angle z()<-30 then clockwise=1:turn camera right 0.1

else

 `scroll textures
  scroll object texture 1000,0,-0.004
  scroll object texture 4,0,0.004
  scroll object texture 5,0,0.004

endif

sync
loop

`By Patrick Lewis
20/Feb/2005
Type Coordinates
  x as Float
   y as Float
   z as Float
Endtype

Global Object As Coordinates
Global Target as Coordinates
Global AI as Coordinates
Global Camera as Coordinates

Type Attributes
   Energy as Integer
   Armor as Integer
   Health as Integer
   Damage as Integer
   Range as Integer
   Ablative as Integer
   Shield as Integer
   Pos as Coordinates
   Weapon as String
   Weap_ID as Integer
   Speed as Float
   Object_Num as Integer
   Velocity as Float
   Color as DWord
EndType

Global Robot as Attributes
Global Robot_Rating as Integer
Dim Enemy(20) as Attributes
Dim Enemy_Rating(20) as Integer

Type Weapons
   Weapon_ID as Integer
   Weapon_Name as String
   Weapon_Damage as Integer
   Weapon_Range as Integer
EndType

Global Robot_Weapon as Weapons
Dim Enemy_Weapon(20) as Weapons

Type Bullets
   Bullet_Damage as Integer
   Bullet_Range as Integer
   Bullet_Area as Integer
   Bullet_Speed as Integer
   Bullet_Object as Integer
   Bullet_Target as Coordinates
EndType

Global Robot_Bullet as Bullets
Dim Enemy_Bullet(20) as Bullets



Sync On
Sync Rate 60
Autocam Off

Do
   Flush Video Memory
   Global Level as Float
   Global NextLevel as Float
   Global Score as Integer
   Global EnemyCount as Integer
   Global Special As Integer
   Global Special$ as String
   Global Kills as Integer
   Global Shots as Float
   Global Hits as Float
   Global SkillHits as Float
   Global Accuracy as Float
   Position Camera 0,0,0
   Rotate Camera 0,0,0
   Set Camera Range 5,1000
   Start_Menu()
   Hide Mouse
   Level =1
   Score = 0
   NextLevel=100
   EnemyCount=0
   Kills=0
   Robot_Rating=Make_Robot(1)
   Make_Crosshair()
   Make_Road()
   Make_X_Road()
   Return_Object(1)
   Position Camera 0,Object.y+100,50
   Point Camera 0,0,51
   Position Object 501,0,-8,60
   Position Object 502,0,-8,60+174

   Do
      Move_Roads()
      Move_Special()
      Move_Robot()
      Start_Enemy()
      If Move_Enemy() Then Exit
      Move_Crosshair()
      If Mouseclick()=1
         Return_Target(3)
         Make_R_Bullet(Target.x,0,Target.z)
      Endif
      Move_R_Bullet()
      Ink RGB(171,180,254),0
      Print_Stats()
      Sync
   Loop
Print_Stats()
Center Text Object Screen X(1),Object Screen Y(1)-20,"Game Over. Press the anykey to play again"
Sync
Sleep 1000
Clear Entry Buffer
Wait Key
For i = 1 to 5000
   If Object Exist(i) Then Delete Object i
   If Image Exist(i) Then Delete Image i
Next i
Loop


Function Print_Stats()
Ink RGB(171,180,254),0
Set Cursor 0,0
Print "Score: ";Score
If Score>NextLevel
   Level=Level+1
   NextLevel=NextLevel+(Level*100)
Endif
Print "Level: ";Level
Ink Rgb(255-Robot.Health*2,50,55+Robot.Health*2),0
Print "Health: "; Robot.Health
Ink RGB(179,188,251),0
Print "Armor: "; Robot.Armor
Print "Range: +"; Robot.Range
Print "Speed: +"; Robot.Speed
Print "Damage: +"; Robot.Damage
Ink Rgb(255,0,0),0
Print "Kills: "; Kills
Accuracy=Int(Hits/Shots*100)
Ink Rgb(0,0,255),0
Print "Accuracy: " ; Accuracy ; "%"
EndFunction

Function Make_Robot(ObjectID)
If Object Exist (ObjectID) Then Delete Object ObjectID
Make Object Cube ObjectID,5
If Object Exist(2) Then Delete Object 2
If Mesh Exist(2) Then Delete Mesh 2
Make Object Sphere 2,5
Make Mesh From Object 2,2
Add Limb ObjectID,1,2
Offset Limb ObjectID,1,0,4,0
Delete Mesh 2
Delete Object 2
Make Object Cylinder 2,4
Scale Object 2,30,100,30
Offset Limb 2,0,0,2,0
Roll Object Right 2,100
Fix Object Pivot 2
Make Mesh From Object 2,2
Add Limb ObjectID,2,2
Add Limb ObjectID,3,2
Offset Limb ObjectID,2,0,1,-3
Offset Limb ObjectID,3,0,1,3
Color Limb ObjectID,2,RGB(128,128,128)
Color Limb ObjectID,3,RGB(128,128,128)
Delete Mesh 2
Delete Object 2
Make Object Cylinder 2,10
Scale Object 2,100,20,20
Pitch Object Down 2,90
Fix Object Pivot 2
Make Mesh From Object 2,2
Add Limb ObjectID,4,2
Add Limb ObjectID,5,2
Offset Limb ObjectID,4,0,-3,-3
Offset Limb ObjectID,5,0,-3,3
Delete Object 2
Delete Mesh 2
Make Object Sphere 2,10
Scale Object 2,100,20,1
Make Mesh from Object 2,2
Add Limb ObjectID,6,2
Add Limb ObjectID,7,2
Offset Limb ObjectID,6,0,-3,-3.9
Offset Limb ObjectID,7,0,-3,3.9
Delete Object 2
Delete Mesh 2
Set Object Cull ObjectID,0
Turn Object Left ObjectID,90
Fix Object Pivot ObjectID
Color Object ObjectID,Robot.Color
If Bitmap Exist(1) Then Delete Bitmap 1
Create Bitmap 1,100,20
Set Current Bitmap 1
Ink RGB(210,210,210),0
Box 0,0,99,19
Ink Rgb(40,40,40),0
For i = 0 to 90 step 10
   Box i,0,i+1,19
Next i
Get Image 1,0,0,99,19
Delete Bitmap 1
Texture Limb ObjectID,4,1
Texture Limb ObjectID,5,1
Set Object Collision Off ObjectID
Robot.Health=100
Robot.Object_Num=1
Robot.Speed=0
Robot.Damage=0
Robot.Armor=0
Robot.Range=0
Set Object Collision to Boxes ObjectID
EndFunction R

Function Move_Robot()
YRotate Object 1,0
Return_Object(1)
Make_AI()
Position Object 2,Object.x,Object.y,Object.z
Set Object To Object Orientation 2,1
Move Object Left 2,((LeftKey()*(Object Screen X(1)>20))-(RightKey()*(Object Screen X(1)<(Screen Width()-20))))
Move Object 2,(Upkey()*(Object Screen Y(1)>Screen Height()*.1)-DownKey()*(Object Screen Y(1)<Screen Height()-40))
Return_AI()
If (AI.x<>Object.x) or (AI.z<>Object.z)
   Point Object 1,AI.x,Object.y,AI.z
   Move Object 1,.8+(Robot.Speed/10)
Endif
YRotate Object 1,RightKey()*45-LeftKey()*45
Scroll Limb Texture 1,4,-.005,0
Scroll Limb Texture 1,5,-.005,0
Minimap(1,RGB(119,119,255))
EndFunction

Function Make_AI()
If Object Exist (2) then Delete Object 2
Make Object Sphere 2,1,10,10
Set Object Collision Off 2
Hide Object 2
Endfunction


Function Make_R_Bullet(Tx#,Ty#,Tz#)
If Object Exist(101) Then ExitFunction
Make Object Sphere 101,2
   Robot_Bullet.Bullet_Damage=rnd(4+Robot.Damage)+1
   Robot_Bullet.Bullet_Range=50+(Robot.Range*2)
   Robot_Bullet.Bullet_Area=5
   Robot_Bullet.Bullet_Speed=6
   Robot_Bullet.Bullet_Object=101
   Robot_Bullet.Bullet_Target.x=Tx#
   Robot_Bullet.Bullet_Target.y=Ty#
   Robot_Bullet.Bullet_Target.z=Tz#
Return_Object(1)
Position Object 101,Object.x,Object.y,Object.z
Point Object 101,Tx#,Ty#,Tz#
Shots=Shots+1
EndFunction

Function Move_R_Bullet()
If Object Exist(101)=0 then ExitFunction
Speed=Robot_Bullet.Bullet_Speed
If Speed=0 then Speed=1
For i = 1 to Speed
   If Robot_Bullet.Bullet_Speed>0 Then Move Object 101,1
   Robot_Bullet.Bullet_Range=Robot_Bullet.Bullet_Range-1
   If Robot_Bullet.Bullet_Range=0
      Robot_Bullet.Bullet_Speed=0
      scale=Robot_Bullet.Bullet_Area/Object Size(101)*100
      Robot_Bullet.Bullet_Damage=Robot_Bullet.Bullet_Damage*3
      Scale Object 101,scale,scale,scale
      Color Object 101,Rgb(255,0,0)
      Ghost Object On 101
   Endif
   HitEnemy=Object Collision(101,0)
   If HitEnemy>1000 and HitEnemy<1021
      Hits=Hits+1
      If Object Size(101)>2 Then SkillHits=SkillHits+1
      Enemy(HitEnemy-1000).Health=Enemy(HitEnemy-1000).Health-Robot_Bullet.Bullet_Damage
      If Enemy(HitEnemy-1000).Health<1
         Return_Object(HitEnemy)
         Delete Object HitEnemy
         EnemyCount=EnemyCount-1
         Kills=Kills+1
         If rnd((Level^2)*10)<Accuracy/2 Then Make_Special(Object.x,Object.z)
      Endif
      Delete Object 101
      Score=Score+Robot_Bullet.Bullet_Damage
      ExitFunction
   Endif
   If Robot_Bullet.Bullet_Range<-10
      Delete Object 101
      ExitFunction
   Endif
Next i
EndFunction

Function Make_Crosshair()
If Object Exist (3) Then Delete Object 3
Make Object Cylinder 3,10
If Mesh Exist(2)Then Delete Mesh 2
Make Mesh From Object 2,3
Add Limb 3,1,2
Add Limb 3,2,2
Delete Mesh 2
Rotate Limb 3,1,0,0,90
Rotate Limb 3,2,90,0,0
Scale Limb 3,0,10,100,10
Scale Limb 3,1,10,100,10
Scale Limb 3,2,10,100,10
Pitch Object Down 3,90
Fix Object Pivot 3
Color Object 3,Rgb(255,0,0)
Position Object 3,0,5,0
Set Object Cull 3,0
Set Object Collision Off 3
Ghost Object On 3
EndFunction

Function Move_Crosshair()
mx=MouseX():my=MouseY()
cntr=0
Do
   cx=Object Screen X(3): cy=Object Screen Y(3)
   If cx=mx and cy=my then Exit
   Move Object Left 3,((cx>mx)-(cx<mx))*.2
   Move Object 3,((cy>my)-(cy<my))*.2
   cntr=cntr+1
   If cntr>40 Then Exit
Loop
Roll Object Left 3,1
Fix Object Pivot 3
EndFunction

Function Make_Enemy_Robot(ObjectID,ERID)
Make Object Cube ObjectID,5
If Object Exist(2) Then Delete Object 2
If Mesh Exist(2) Then Delete Mesh 2
Make Object Sphere 2,5
Make Mesh From Object 2,2
Add Limb ObjectID,1,2
Offset Limb ObjectID,1,0,4,0
Delete Mesh 2
Delete Object 2
Make Object Cylinder 2,4
Scale Object 2,30,100,30
Offset Limb 2,0,0,2,0
Roll Object Right 2,100
Fix Object Pivot 2
Make Mesh From Object 2,2
Add Limb ObjectID,2,2
Add Limb ObjectID,3,2
Offset Limb ObjectID,2,0,1,-3
Offset Limb ObjectID,3,0,1,3
Delete Mesh 2
Delete Object 2
Make Object Cylinder 2,10
Scale Object 2,100,20,20
Pitch Object Down 2,90
Fix Object Pivot 2
Make Mesh From Object 2,2
Add Limb ObjectID,4,2
Add Limb ObjectID,5,2
Offset Limb ObjectID,4,0,-3,-3
Offset Limb ObjectID,5,0,-3,3
Delete Object 2
Delete Mesh 2
Make Object Sphere 2,10
Scale Object 2,100,20,1
Make Mesh from Object 2,2
Add Limb ObjectID,6,2
Add Limb ObjectID,7,2
Offset Limb ObjectID,6,0,-3,-3.9
Offset Limb ObjectID,7,0,-3,3.9
Delete Object 2
Delete Mesh 2
Set Object Cull ObjectID,0
Turn Object Left ObjectID,90
Fix Object Pivot ObjectID
Color Object ObjectID,RGB(128,0,0)
Color Limb ObjectID,2,RGB(128,128,128)
Color Limb ObjectID,3,RGB(128,128,128)
Texture Limb ObjectID,4,1
Texture Limb ObjectID,5,1
Set Object Collision to Boxes ObjectID
Enemy(ERID).Health=10+Rnd(Level*2)
Enemy(ERID).Object_Num=ObjectID
EndFunction R


Function Start_Enemy()
If Rnd(800)>Level+((Level-EnemyCount)*2) Then ExitFunction
For i = 1001 to 1020
   If Object Exist(i)=0
      Make_Enemy_Robot(i,i-1000)
      EnemyCount=EnemyCount+1
      Position Object i,((rnd(400)-200)+(rnd(400)-200))/2,0,125+Rnd(200)
      Turn Object Right i,180
      Exit
   Endif
Next
EndFunction

Function Move_Enemy()
Make_AI()
Dead=0
Set Object Collision On 1
For i = 1 to 20
   If Object Exist(1000+i)
      Return_Object(1000+i)
      Return_Target(1)
      Position Object 2,Object.x,Object.y,Object.z
      Set Object To Object Orientation 2,1000+i
      Move Object 2,10
      Point Object 2,Target.x,Object.y,Target.z
      Move Object 2,Rnd(3)
      Return_AI()
      Point Object 1000+i,AI.x,Object.y,AI.z
      Move Object 1000+i,.75
      Scroll Limb Texture 1000+i,4,-.005,0
      Scroll Limb Texture 1000+i,5,-.005,0
      Minimap(1000+i,RGB(255,0,0))
      If Object Collision (1000+i,1)
         Dead=1
         Set Object Collision Off 1
         ExitFunction Dead
      Endif
   Endif
   Enemy_Shoot(i)
   If Move_E_Bullet(i) Then ExitFunction 1
Next i
Set Object Collision Off 1
EndFunction Dead

Function Enemy_Shoot(ERID)
If Object Exist(1000+ERID)=0 Then ExitFunction
If rnd(2000)<Level*50
   Return_Object(1000+ERID):Return_Target(1)
   Dist#=(Object.x-Target.x)^2+(Object.z-Target.z)^2
   If Dist#<55^2
      aimx#=rnd(20-(level/6))-(10-(level/3))+Target.x
      aimz#=rnd(20-(level/6))-(10-(level/3))+Target.z
      Make_E_Bullet(ERID,aimx#,target.y,aimz#)
   Endif
Endif
EndFunction


Function Make_E_Bullet(ERID,Tx#,Ty#,Tz#)
If Object Exist(2000+ERID) Then ExitFunction
If Object Exist(1000+ERID)=0 Then ExitFunction
Make Object Sphere 2000+ERID,2
   Enemy_Bullet(ERID).Bullet_Damage=rnd(Level/2)+1
   Enemy_Bullet(ERID).Bullet_Range=47+Level/3
   Enemy_Bullet(ERID).Bullet_Area=3
   Enemy_Bullet(ERID).Bullet_Speed=3
   Enemy_Bullet(ERID).Bullet_Object=2000+ERID
   Enemy_Bullet(ERID).Bullet_Target.x=Tx#
   Enemy_Bullet(ERID).Bullet_Target.y=Ty#
   Enemy_Bullet(ERID).Bullet_Target.z=Tz#
Return_Object(1000+ERID)
Position Object 2000+ERID,Object.x,Object.y,Object.z
Point Object 2000+ERID,Tx#,Ty#,Tz#
EndFunction

Function Move_E_Bullet(ERID)
Dead=0
If Object Exist(2000+ERID)=0 then ExitFunction Dead
Speed=Enemy_Bullet(ERID).Bullet_Speed
If Speed=0 then Speed=1
For i = 1 to Speed
   If Enemy_Bullet(ERID).Bullet_Speed>0 Then Move Object 2000+ERID,1
   Enemy_Bullet(ERID).Bullet_Range=Enemy_Bullet(ERID).Bullet_Range-1
   If Enemy_Bullet(ERID).Bullet_Range=0
      Enemy_Bullet(ERID).Bullet_Speed=0
      scale=Enemy_Bullet(ERID).Bullet_Area/Object Size(2000+ERID)*100
      Enemy_Bullet(ERID).Bullet_Damage=Enemy_Bullet(ERID).Bullet_Damage*3
      Scale Object 2000+ERID,scale,scale,scale
      Color Object 2000+ERID,Rgb(255,0,0)
      Ghost Object On 2000+ERID
   Endif
   HitEnemy=Object Collision(2000+ERID,1)
   If HitEnemy
      armr=Rnd(Robot.Armor)
      If armr>Enemy_Bullet(ERID).Bullet_Damage Then armr=Enemy_Bullet(ERID).Bullet_Damage
      Robot.Health=Robot.Health-(Enemy_Bullet(ERID).Bullet_Damage-armr)
      If Robot.Health<1 Then Dead=1
      Delete Object 2000+ERID
      ExitFunction Dead
   Endif
   If Enemy_Bullet(ERID).Bullet_Range<-10
      Delete Object 2000+ERID
      ExitFunction Dead
   Endif
Next i
EndFunction Dead

Function Make_Road()
If Object Exist(501) Then Delete Object 501
If Bitmap Exist(1) Then Delete Bitmap 1
Create Bitmap 1,300,300
Set Current Bitmap 1
Ink RGB(128,128,128),0
Box 50,0,249,299
Ink RGB(75,75,75),0
For i = 1 to 300
   Dot rnd(200)+50,rnd(299)
Next i
Ink RGB(198,198,0),0
For i = 0 to 250 step 50
   Box 148,i,152,i+30
Next i
Get Image 501,0,0,299,299
Set Current Bitmap 0
Delete Bitmap 1
Make Object Plain 501,175,175
Texture Object 501,501
Pitch Object Down 501,90
EndFunction

Function Make_X_Road()
If Object Exist(502) Then Delete Object 502
If Bitmap Exist(1) Then Delete Bitmap 1
Create Bitmap 1,300,300
Set Current Bitmap 1
Ink RGB(128,128,128),0
Box 50,0,249,299
Box 0,50,299,249
Ink RGB(75,75,75),0
For i = 1 to 300
   Dot rnd(200)+50,rnd(299)
Next i
Ink RGB(198,198,0),0
For i = 0 to 250 step 50
   Box 148,i,152,i+30
   Box i,148,i+30,152
Next i
Get Image 502,0,0,299,299
Set Current Bitmap 0
Delete Bitmap 1
Make Object Plain 502,175,175
Texture Object 502,502
Pitch Object Down 502,90
EndFunction

Function Move_Roads()
Move Object Up 501,.65
Move Object Up 502,.65
Return_Object(501)
If Object.z<60-174 Then Position Object 501,0,-8,60+174
Return_Object(502)
If Object.z<60-174 Then Position Object 502,0,-8,60+174
EndFunction

Function Make_Special(sx#,sz#)
If Object Exist(600) Then ExitFunction
Special=Rnd(5)
If Rnd(90)>Robot.Health And Special<>4 Then Special=Rnd(5)
Select Special
   Case 0
      Make Object Cube 600,5
      Color Object 600,RGB(0,255,0)
      Special$="Health"
   Endcase
   Case 1
      Make Object Sphere 600,5
      Color Object 600,RGB(255,128,0)
      Special$="Range"
   Endcase
   Case 2
      Make Object Cone 600,5
      Color Object 600,RGB(0,0,255)
      Special$="Armor"
   Endcase
   Case 3
      Make Object Cylinder 600,5
      Color Object 600,RGB(128,0,128)
      Roll Object Left 600,90
      Fix Object Pivot 600
      Special$="Damage"
   Endcase
   Case 4
      If Mesh Exist(600) Then Delete Mesh 600
      Make Mesh From Object 600,1
      Make Object 600,600,0
      Scale Object 600,50,50,50
      Color Object 600,RGB(255,255,0)
      Delete Mesh 600
      Special$="Repair"
   Endcase
   Case 5
      Make Object Cone 600,3
      If Mesh Exist(600) Then Delete Mesh 600
      Make Mesh From Object 600,600
      Add Limb 600,1,600
      Delete Mesh 600
      Rotate Limb 600,1,180,0,0
      Offset Limb 600,1,0,2,0
      Roll Object Right 600,90
      Fix Object Pivot 600
      Special$="Speed"
   Endcase
EndSelect
Turn Object Right 600,180
Ghost Object On 600
Set Object Cull 600,0
Position Object 600,sx#,0,sz#
EndFunction

Function Move_Special()
If Object Exist(600)=0 then ExitFunction
Move Object 600,.65
Ink rgb(255,255,255),0
Center Text Object Screen X(600),Object Screen Y(600),Special$
Set Object Collision On 1
If Object Collision(600,1)
   Delete Object 600
   Select Special
      Case 0
         Robot.Health=Robot.Health+20
      Endcase
      Case 1
         Robot.Range=Robot.Range+1
      EndCase
      Case 2
         Robot.Armor=Robot.Armor+1
      EndCase
      Case 3
         Robot.Damage=Robot.Damage+1
      EndCase
      Case 4
         If Robot.Health<100 Then Robot.Health=100
      EndCase
      Case 5
         Robot.Speed=Robot.Speed+1
      Endcase
   EndSelect
   ExitFunction
Endif
Set Object Collision Off 1
If Object Screen Y(600)>Screen Height()+3 Then Delete Object 600
EndFunction


Function Start_Menu()
Robot.Color=Rgb(255,255,255)
Make_Road()
Position Object 501,0,0,60
Pitch Object Up 501,90
Make_Robot(901)
Position Object 901,0,0,50
If Bitmap Exist(1) Then Delete Bitmap 1
Create Bitmap 1,150,100
Set Current Bitmap 1

Ink RGB(0,255,0),0
Box 0,0,149,149
Ink RGB(15,24,140),0
Center Text 74,49,"START"
Get Image 902,0,0,149,99

Ink RGB(255,255,0),0
Box 0,0,149,149
Ink RGB(15,24,140),0
Center Text 74,49,"EXIT"
Get Image 903,0,0,149,99

Ink RGB(255,255,255),0
Box 0,0,149,149,RGB(255,255,255),RGB(255,255,255),0,RGB(255,255,255)
Ink RGB(0,0,0),0
Center Text 74,49,"COLOR"
Get Image 904,0,0,149,99

Ink RGB(0,255,0),0
Box 0,0,149,149,RGB(0,255,0),RGB(0,255,0),0,RGB(0,255,0)
Ink RGB(0,0,0),0
Center Text 74,49,"COLOR"
Get Image 905,0,0,149,99

Ink RGB(0,0,255),0
Box 0,0,149,149,RGB(0,0,255),RGB(0,0,255),0,RGB(0,0,255)
Ink RGB(0,0,0),0
Center Text 74,49,"COLOR"
Get Image 906,0,0,149,99

Delete Bitmap 1
Set Current Bitmap 0

Return_Camera()

If Object Exist(902) Then Delete Object 902
Make Object Sphere 902,5,20,20
Scale Object 902,-300,-100,-100
Texture Object 902,902
Pitch Object Down 902,180
Fix Object Pivot 902
Position Object 902,0,15,50
Point Object 902,Camera.x,Camera.y,Camera.z

If Object Exist(903) Then Delete Object 903
Make Object Sphere 903,5,20,20
Scale Object 903,-300,-100,-100
Texture Object 903,903
Pitch Object Down 903,180
Fix Object Pivot 903
Position Object 903,0,-15,50
Point Object 903,Camera.x,Camera.y,Camera.z

For i=1 to 3
   Ob=903+i
   If Object Exist(Ob) then Delete Object i
   Make Object Sphere Ob,5,20,20
   Scale Object Ob,-150,-100,-100
   Texture Object Ob,Ob
   Pitch Object Down Ob,180
   Fix Object Pivot Ob
   Position Object Ob,(i-2)*10,-7,50
   Point Object Ob,Camera.x,Camera.y,Camera.z
Next i
Show Mouse
Do
   po=Pick Object(MouseX(),MouseY(),901,906)
   Select po
      Case 0
         If Flag<>0
            For i = 902 to 906
               Return_Object(i)
               If Object.z<50 Then Move Object i,Object.z-50
            Next i
            YRotate Object 901,0
            Flag=0
         Endif
      Endcase
      Case 901
         Turn Object Left 901,1
         Flag=1
      Endcase
      Case Default
         If Mouseclick()=1 Then Start=Do_Menu_Item(po)
         If Start=1 Then Exit
         Return_Object(po)
         If Object.z>48 Then Move Object po,5
         Flag=1
      Endcase
   EndSelect
Sync
Loop
For i = 901 to 906
   If Object Exist(i) Then Delete Object i
Next i
Endfunction

Function Do_Menu_Item(OBID)
strt=0
Select OBID
   Case 902
      strt=1
   Endcase
   Case 903
      End
   Endcase
   Case 904,905,906
      Robot.Color=Point(MouseX(),MouseY())
      Color Object 901,Robot.Color
   Endcase
EndSelect
Endfunction strt

Function Minimap(ObjectID,Color)
Return_Object(ObjectID)
Ink Color,0
Box (Object.x/5)+600,50-(Object.z/5),(Object.x/5)+602,52-(Object.z/5)
EndFunction

Function Return_Target(TargetID)
Target.x=Object Position X(TargetID):Target.y=Object Position Y(TargetID):Target.z=Object Position Z(TargetID)
EndFunction

Function Return_Object(ObjectID)
Object.x=Object Position X(ObjectID):Object.y=Object Position Y(ObjectID):Object.z=Object Position Z(ObjectID)
EndFunction

Function Return_AI()
AI.x=Object Position X(2):AI.y=Object Position Y(2):AI.z=Object Position Z(2)
EndFunction

Function Return_Camera()
Camera.x=Camera Position X():Camera.y=Camera Position Y():Camera.z=Camera Position Z()
EndFunction 

Rem Project: sidescroller challenge
Rem Created: 19/02/2005 21:17:23

Rem ***** Main Source File *****

randomize timer()

`display
if check display mode(1024,768,32)=1 then set display mode 1024,768,32
hide mouse
autocam off
set camera range 1,10000
position camera 200,0,280
point camera 0,0,280
hide light 0
color backdrop rgb(0,0,0)
set ambient light 80
make light 1
position light 1,100,100,20
set light range 1,100000
color light 1,rgb(255,220,180)
set text font "sf automaton_mod"
set text size 25
fog on
fog distance 3500

`create green texture
for x=0 to 100
   for y=0 to 100
      ink rgb(0,x+y,0),0
      dot x,y
   next y
next x
get image 103,0,0,100,100

`create orange texture
cls
for x=0 to 100
   for y=0 to 100
      ink rgb((x+y)+50,50+(x+y)/1.5,100),0
      dot x,y
   next y
next x
get image 102,0,0,100,100

`create blue texture
cls
for x=0 to 100
   for y=0 to 100
      ink rgb(0,0,x+y),0
      dot x,y
   next y
next x
get image 101,0,0,100,100

`create red texture
cls
for x=0 to 100
   for y=0 to 100
      ink rgb((x+y)+50,0,0),0
      dot x,y
   next y
next x
get image 105,0,0,100,100

`create star texture
cls
for x=0 to 100
for y=0 to 100
d=rnd(20)
ink rgb(100+rnd(100),100+rnd(100),rnd(100)+100),0
if d=1 then dot x,y
next y
next x
get image 1,0,0,100,100

`create tile texture
cls
ink rgb(0,255,0),0
box 0,0,20,20
ink rgb(0,0,0),0
box 1,1,20,20
`ink rgb(0,0,155),0
`box 4,4,16,16
get image 2,0,0,20,20




`create stars
make object plain 1000,10600,8000
texture object 1000,1
scale object texture 1000,5,5
set object transparency 1000,1
yrotate object 1000,90
position object 1000,-4000,0,0
set object light 1000,0
set object emissive 1000,rgb(250,250,250)
set object fog 1000,0

make object plain 1001,10600,8000
texture object 1001,1
scale object texture 1001,5,5
set object transparency 1001,1
yrotate object 1001,90
position object 1001,-4010,0,0
set object light 1001,0
set object emissive 1001,rgb(250,250,250)
set object fog 1001,0



make object sphere 8888,0.1
make mesh from object 1,8888
delete object 8888

`aliens and fuel pods
dim azspeed#(5025)
dim ayspeed#(5025)
dim fuel(5025)
for alien=5000 to 5025
if alien>5020 then fuel(alien)=1
if fuel(alien)=0
  make object sphere alien,15,2,2
  texture object alien,105
  make object cone alien+50000,10
  scale object alien+50000,100,200,100
  texture object alien+50000,102
  add limb alien,1,1
  glue object to limb alien+50000,alien,1
else
  make object sphere alien,15,30,30
  texture object alien,103
endif
set object specular alien,rgb(200,200,200)
set object specular power alien,15
set object emissive alien,rgb(150,150,100)
set object ambient alien,0
set object collision on alien
set object fog alien,0
position object alien,-180,rnd(200)-100,rnd(2000)+500
next alien



`bottom wall
make object plain 4,3000,3000
xrotate object 4,90
set object collision on 4
texture object 4,2
scale object texture 4,20,10
set object transparency 4,1

`ghost object on 4

`top wall
make object plain 5,3000,3000
xrotate object 5,90
set object collision on 5
texture object 5,2
scale object texture 5,20,10
set object transparency 5,1
`ghost object on 5


`position walls
position object 4,0,-150,100
position object 5,0,150,100

`spaceship
make object cone 1,20
xrotate object 1,90
scale object 1,100,400,100
ghost object on 1
texture object 1,101
set object emissive 1,rgb(200,200,200)
set object specular 1,rgb(250,250,250)
set object specular power 1,10
set object fog 1,0
set object collision on 1
set object collision to boxes 1

`jet trail
make object sphere 777,-50,30,30
scale object 777,100,100,1500
texture object 777,102
ghost object on 777
set object emissive 777,rgb(200,200,200)
set object specular 777,rgb(250,250,250)
set object specular power 777,10
position object 777,1000,0,0
disable object zdepth 777

`reflection of ship
clone object 302,1 `top
xrotate object 302,90
scale object 302,100,400,100
fade object 302,90
clone object 303,1 `bottom
xrotate object 303,90
scale object 303,100,400,100
fade object 303,90
clone object 888,777
fade object 888,90
scale object 888,100,100,1500
position object 888,1000,0,0
clone object 999,777
fade object 999,90
scale object 999,100,100,1500
position object 999,1000,0,0
ink rgb(0,0,255),0

`vapour
make object sphere 111,-80,30,30
scale object 111,500,100,1560
texture object 111,101
ghost object on 111
set object emissive 111,rgb(200,200,200)
set object specular 111,rgb(250,250,250)
set object specular power 111,30
position object 111,0,0,350

createsound("laser",1,1500,700,8000,0.01,0.2)
createsound("explosion",2,6200,700,2000,20,0.2)
createsound("explosion2",3,1200,1400,3000,10,0.1)
createsound("fuelup",4,800,700,8000,-0.02,0.2)
createsound("fuelwarning",5,800,1000,6000,0.5,0.1)

restart:

cls
value#=0.1
fuel#=3.0
lives=3
pz#=150
aliens=40
level=1
scrollspeed#=0.08

for alien=5000 to 5025
azspeed#(alien)=1+rnd(10)
ayspeed#(alien)=rnd(20)/10.0
next alien

while mouseclick()=0
text screen width()/2-220,210,"Kill 40 aliens before your fuel runs out!"
text screen width()/2-70,240,"Press FIRE!"
endwhile

sync on
sync rate 30

do

text 0,40,str$(screen fps())



py#=py#-mousemovey()
pz#=pz#+mousemovex()
if py#>110 then py#=110
if py#<-110 then py#=-110
if pz#>500 then pz#=500
if pz#<0 then pz#=0

`move ship
position object 1,-180,py#,pz#
position object 302,-180,-py#-300,pz#
position object 303,-180,-py#+300,pz#
position object 777,-180,py#,pz#-380
position object 888,-180,-py#-300,pz#-380
position object 999,-180,-py#+300,pz#-380

`scroll textures
scroll object texture 1000,0.01,0
scroll object texture 1001,0.008,0
scroll object texture 4,0,scrollspeed#
scroll object texture 5,0,scrollspeed#
scroll object texture 777,-scrollspeed#/6,0
if level>2 then scroll object texture 111,0.01,0.01

`handle aliens
for alien=5000 to 5025
`alien movement
ay#=object position y(alien)+ayspeed#(alien)
az#=object position z(alien)-azspeed#(alien)
if ay#>100 or ay#<-100 then ayspeed#(alien)=ayspeed#(alien)*-1
if az#<object position z(1)-300 then inc az#,2000

`alien death
if fire=1
if object in screen (alien)=1
 if object position y(1)<object position y(alien)+8 and object position y(1)>object position y(alien)-8
   inc az#,2000
   play sound 2
   dec aliens
  endif
endif
endif

`ship death
if object in screen(alien)=1
  if object position y(1)<object position y(alien)+8 and object position y(1)>object position y(alien)-8
    if object position z(1)<object position z(alien)+50 and object position z(1)>object position z(alien)-30
      inc az#,2000
      if fuel(alien)=0
           dec lives
           play sound 3
           if lives<0 then goto dead
           text screen width()/2-70,240,"GET READY!"
           wait 1000
      endif
      if fuel(alien)=1 then inc fuel#
      play sound 4
    endif
  endif
endif

position object alien,-180,ay#,az#
turn object left alien,10
next alien

`fire
if mouseclick()=1 and charge<0
  fire=1
  charge=20
  length=5
endif

if fire=1
play sound 1
line object screen x(1),object screen y(1),screen width(),object screen y(1)
endif

dec charge
dec length
if length<0 then fire=0

`text

text 40,0,"Lives: "+str$(lives)
if fuel#<1.0
   fuelwarning=1
   ink rgb(255,0,0),0
endif
if fuelwarning=1 and warningon=0 then play sound 5:warningon=1
text screen width()-130,0,"Fuel: "+left$(str$(fuel#),4)
ink rgb(0,0,255),0
text screen width()/2-60,0,"Aliens: "+str$(aliens)
if fuel#>1 then fuelwarning=0:warningon=0

dec fuel#,0.005

if fuel#<0
   play sound 3
   text screen width()/2-70,210,"Out of fuel!"
   text screen width()/2-70,240,"GET READY..."
   sync
   wait 1000
  dec lives
  fuel#=3.0
endif

if aliens<1
  inc level
  text screen width()/2-70,210,"Level "+str$(level)
  text screen width()/2-70,240,"GET READY..."
  sync
  wait 1000
  aliens=40
  inc scrollspeed#,0.02
  fuel#=3.0
  for alien=5000 to 5025
    inc azspeed#(alien),3
    inc ayspeed#(alien),0.2
  next alien
endif

if level>1
position camera 200,ht#,280+ht#
point camera 0,0,280
ht#=30*sin(theta#)
theta#=wrapvalue(theta#)+0.8
endif

dead:
if lives<0

  text screen width()/2-70,240,"GAME OVER!"
  text screen width()/2-120,270,"You got to level "+str$(level)
  sync
  wait 3000
  while mouseclick()=0
  text screen width()/2-90,320,"Press fire ...."
  sync
endwhile
  goto restart
endif

sync
loop

function createsound(name$,soundnumber,frequency#,length#,loudness#,bend#,decay#)

if file exist(name$+".wav")=1 then delete file name$+".wav"
open to write 1,name$+".wav"
chunk=int(((length#/1000)*44100*16)/8) `sample size (no of samples * bitrate * channels / 8)
samples=int((length#/1000)*44100) `length *44100
restore
for x=1 to 40
   read byte2
   write byte 1, byte2
next x
write long 1,chunk
rem generate and write wave
for x=1 to samples
  output#=int(sin((x/122.5)*frequency#)*loudness#)*3.0
  dec frequency#,bend#
  if loudness#>0 then dec loudness#,decay#
  write word 1,output#
next x
close file 1

load sound name$+".wav",soundnumber

data 82:data 73:data 70:data 70:data 208:data 59:data 1:data 0:data 87
data 65:data 86:data 69:data 102:data 109:data 116:data 32:data 16
data 0:data 0:data 0:data 1:data 0:data 2:data 0:data 34:data 86:data 0
data 0:data 136:data 88:data 1:data 0:data 4:data 0:data 16:data 0
data 100:data 97:data 116:data 97

endfunction